[deliverable/linux.git] / arch / arm / kernel / entry-common.S

/*
 *  linux/arch/arm/kernel/entry-common.S
 *
 *  Copyright (C) 2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <asm/unistd.h>
#include <asm/ftrace.h>
#include <mach/entry-macro.S>
#include <asm/unwind.h>

#include "entry-header.S"


	.align	5
/*
 * This is the fast syscall return path.  We do as little as
 * possible here, and this includes saving r0 back into the SVC
 * stack.
 */
ret_fast_syscall:
 UNWIND(.fnstart	)
 UNWIND(.cantunwind	)
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	fast_work_pending

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	@ fast_restore_user_regs
	ldr	r1, [sp, #S_OFF + S_PSR]	@ get calling cpsr
	ldr	lr, [sp, #S_OFF + S_PC]!	@ get pc
	msr	spsr_cxsf, r1			@ save in spsr_svc
	ldmdb	sp, {r1 - lr}^			@ get calling r1 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE - S_PC
	movs	pc, lr				@ return & move spsr_svc into cpsr
 UNWIND(.fnend		)

/*
 * Ok, we need to do extra processing, enter the slow path.
 */
fast_work_pending:
	str	r0, [sp, #S_R0+S_OFF]!		@ returned r0
work_pending:
	tst	r1, #_TIF_NEED_RESCHED
	bne	work_resched
	tst	r1, #_TIF_SIGPENDING
	beq	no_work_pending
	mov	r0, sp				@ 'regs'
	mov	r2, why				@ 'syscall'
	bl	do_notify_resume
	b	ret_slow_syscall		@ Check work again

work_resched:
	bl	schedule
/*
 * "slow" syscall return path.  "why" tells us if this was a real syscall.
 */
ENTRY(ret_to_user)
ret_slow_syscall:
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	work_pending
no_work_pending:
	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	@ slow_restore_user_regs
	ldr	r1, [sp, #S_PSR]		@ get calling cpsr
	ldr	lr, [sp, #S_PC]!		@ get pc
	msr	spsr_cxsf, r1			@ save in spsr_svc
	ldmdb	sp, {r0 - lr}^			@ get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE - S_PC
	movs	pc, lr				@ return & move spsr_svc into cpsr
ENDPROC(ret_to_user)

/*
 * This is how we return from a fork.
 */
ENTRY(ret_from_fork)
	bl	schedule_tail
	get_thread_info tsk
	ldr	r1, [tsk, #TI_FLAGS]		@ check for syscall tracing
	mov	why, #1
	tst	r1, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	beq	ret_slow_syscall
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall
ENDPROC(ret_from_fork)

	.equ NR_syscalls,0
#define CALL(x) .equ NR_syscalls,NR_syscalls+1
#include "calls.S"
#undef CALL
#define CALL(x) .long x

#ifdef CONFIG_FUNCTION_TRACER
#ifdef CONFIG_DYNAMIC_FTRACE
ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl mcount_call
mcount_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

ENTRY(ftrace_caller)
	stmdb sp!, {r0-r3, lr}
	ldr r1, [fp, #-4]
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl ftrace_call
ftrace_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

#else

ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	ldr r0, =ftrace_trace_function
	ldr r2, [r0]
	adr r0, ftrace_stub
	cmp r0, r2
	bne trace
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

trace:
	ldr r1, [fp, #-4]			@ lr of instrumented routine
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE
	mov lr, pc
	mov pc, r2
	mov lr, r1				@ restore lr
	ldmia sp!, {r0-r3, pc}

#endif /* CONFIG_DYNAMIC_FTRACE */

	.globl ftrace_stub
ftrace_stub:
	mov pc, lr

#endif /* CONFIG_FUNCTION_TRACER */

/*=============================================================================
 * SWI handler
 *-----------------------------------------------------------------------------
 */

	/* If we're optimising for StrongARM the resulting code won't 
	   run on an ARM7 and we can save a couple of instructions.  
								--pb */
#ifdef CONFIG_CPU_ARM710
#define A710(code...) code
.Larm710bug:
	ldmia	sp, {r0 - lr}^			@ Get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE
	subs	pc, lr, #4
#else
#define A710(code...)
#endif

	.align	5
ENTRY(vector_swi)
	sub	sp, sp, #S_FRAME_SIZE
	stmia	sp, {r0 - r12}			@ Calling r0 - r12
	add	r8, sp, #S_PC
	stmdb	r8, {sp, lr}^			@ Calling sp, lr
	mrs	r8, spsr			@ called from non-FIQ mode, so ok.
	str	lr, [sp, #S_PC]			@ Save calling PC
	str	r8, [sp, #S_PSR]		@ Save CPSR
	str	r0, [sp, #S_OLD_R0]		@ Save OLD_R0
	zero_fp

	/*
	 * Get the system call number.
	 */

#if defined(CONFIG_OABI_COMPAT)

	/*
	 * If we have CONFIG_OABI_COMPAT then we need to look at the swi
	 * value to determine if it is an EABI or an old ABI call.
	 */
#ifdef CONFIG_ARM_THUMB
	tst	r8, #PSR_T_BIT
	movne	r10, #0				@ no thumb OABI emulation
	ldreq	r10, [lr, #-4]			@ get SWI instruction
#else
	ldr	r10, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, r10, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)
#endif

#elif defined(CONFIG_AEABI)

	/*
	 * Pure EABI user space always put syscall number into scno (r7).
	 */
  A710(	ldr	ip, [lr, #-4]			@ get SWI instruction	)
  A710(	and	ip, ip, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#elif defined(CONFIG_ARM_THUMB)

	/* Legacy ABI only, possibly thumb mode. */
	tst	r8, #PSR_T_BIT			@ this is SPSR from save_user_regs
	addne	scno, r7, #__NR_SYSCALL_BASE	@ put OS number in
	ldreq	scno, [lr, #-4]

#else

	/* Legacy ABI only. */
	ldr	scno, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, scno, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#endif

#ifdef CONFIG_ALIGNMENT_TRAP
	ldr	ip, __cr_alignment
	ldr	ip, [ip]
	mcr	p15, 0, ip, c1, c0		@ update control register
#endif
	enable_irq

	get_thread_info tsk
	adr	tbl, sys_call_table		@ load syscall table pointer
	ldr	ip, [tsk, #TI_FLAGS]		@ check for syscall tracing

#if defined(CONFIG_OABI_COMPAT)
	/*
	 * If the swi argument is zero, this is an EABI call and we do nothing.
	 *
	 * If this is an old ABI call, get the syscall number into scno and
	 * get the old ABI syscall table address.
	 */
	bics	r10, r10, #0xff000000
	eorne	scno, r10, #__NR_OABI_SYSCALL_BASE
	ldrne	tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
	bic	scno, scno, #0xff000000		@ mask off SWI op-code
	eor	scno, scno, #__NR_SYSCALL_BASE	@ check OS number
#endif

	stmdb	sp!, {r4, r5}			@ push fifth and sixth args
	tst	ip, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	bne	__sys_trace

	cmp	scno, #NR_syscalls		@ check upper syscall limit
	adr	lr, ret_fast_syscall		@ return address
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine

	add	r1, sp, #S_OFF
2:	mov	why, #0				@ no longer a real syscall
	cmp	scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
	eor	r0, scno, #__NR_SYSCALL_BASE	@ put OS number back
	bcs	arm_syscall	
	b	sys_ni_syscall			@ not private func
ENDPROC(vector_swi)

	/*
	 * This is the really slow path.  We're going to be doing
	 * context switches, and waiting for our parent to respond.
	 */
__sys_trace:
	mov	r2, scno
	add	r1, sp, #S_OFF
	mov	r0, #0				@ trace entry [IP = 0]
	bl	syscall_trace

	adr	lr, __sys_trace_return		@ return address
	mov	scno, r0			@ syscall number (possibly new)
	add	r1, sp, #S_R0 + S_OFF		@ pointer to regs
	cmp	scno, #NR_syscalls		@ check upper syscall limit
	ldmccia	r1, {r0 - r3}			@ have to reload r0 - r3
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine
	b	2b

__sys_trace_return:
	str	r0, [sp, #S_R0 + S_OFF]!	@ save returned r0
	mov	r2, scno
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall

	.align	5
#ifdef CONFIG_ALIGNMENT_TRAP
	.type	__cr_alignment, #object
__cr_alignment:
	.word	cr_alignment
#endif
	.ltorg

/*
 * This is the syscall table declaration for native ABI syscalls.
 * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 */
#define ABI(native, compat) native
#ifdef CONFIG_AEABI
#define OBSOLETE(syscall) sys_ni_syscall
#else
#define OBSOLETE(syscall) syscall
#endif

	.type	sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

/*============================================================================
 * Special system call wrappers
 */
@ r0 = syscall number
@ r8 = syscall table
sys_syscall:
		bic	scno, r0, #__NR_OABI_SYSCALL_BASE
		cmp	scno, #__NR_syscall - __NR_SYSCALL_BASE
		cmpne	scno, #NR_syscalls	@ check range
		stmloia	sp, {r5, r6}		@ shuffle args
		movlo	r0, r1
		movlo	r1, r2
		movlo	r2, r3
		movlo	r3, r4
		ldrlo	pc, [tbl, scno, lsl #2]
		b	sys_ni_syscall
ENDPROC(sys_syscall)

sys_fork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_fork
ENDPROC(sys_fork_wrapper)

sys_vfork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_vfork
ENDPROC(sys_vfork_wrapper)

sys_execve_wrapper:
		add	r3, sp, #S_OFF
		b	sys_execve
ENDPROC(sys_execve_wrapper)

sys_clone_wrapper:
		add	ip, sp, #S_OFF
		str	ip, [sp, #4]
		b	sys_clone
ENDPROC(sys_clone_wrapper)

sys_sigsuspend_wrapper:
		add	r3, sp, #S_OFF
		b	sys_sigsuspend
ENDPROC(sys_sigsuspend_wrapper)

sys_rt_sigsuspend_wrapper:
		add	r2, sp, #S_OFF
		b	sys_rt_sigsuspend
ENDPROC(sys_rt_sigsuspend_wrapper)

sys_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_sigreturn
ENDPROC(sys_sigreturn_wrapper)

sys_rt_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_rt_sigreturn
ENDPROC(sys_rt_sigreturn_wrapper)

sys_sigaltstack_wrapper:
		ldr	r2, [sp, #S_OFF + S_SP]
		b	do_sigaltstack
ENDPROC(sys_sigaltstack_wrapper)

sys_statfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_statfs64
ENDPROC(sys_statfs64_wrapper)

sys_fstatfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_fstatfs64
ENDPROC(sys_fstatfs64_wrapper)

/*
 * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 * offset, we return EINVAL.
 */
sys_mmap2:
#if PAGE_SHIFT > 12
		tst	r5, #PGOFF_MASK
		moveq	r5, r5, lsr #PAGE_SHIFT - 12
		streq	r5, [sp, #4]
		beq	do_mmap2
		mov	r0, #-EINVAL
		mov	pc, lr
#else
		str	r5, [sp, #4]
		b	do_mmap2
#endif
ENDPROC(sys_mmap2)

ENTRY(pabort_ifar)
		mrc	p15, 0, r0, cr6, cr0, 2
ENTRY(pabort_noifar)
		mov	pc, lr
ENDPROC(pabort_ifar)
ENDPROC(pabort_noifar)

#ifdef CONFIG_OABI_COMPAT

/*
 * These are syscalls with argument register differences
 */

sys_oabi_pread64:
		stmia	sp, {r3, r4}
		b	sys_pread64
ENDPROC(sys_oabi_pread64)

sys_oabi_pwrite64:
		stmia	sp, {r3, r4}
		b	sys_pwrite64
ENDPROC(sys_oabi_pwrite64)

sys_oabi_truncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_truncate64
ENDPROC(sys_oabi_truncate64)

sys_oabi_ftruncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_ftruncate64
ENDPROC(sys_oabi_ftruncate64)

sys_oabi_readahead:
		str	r3, [sp]
		mov	r3, r2
		mov	r2, r1
		b	sys_readahead
ENDPROC(sys_oabi_readahead)

/*
 * Let's declare a second syscall table for old ABI binaries
 * using the compatibility syscall entries.
 */
#define ABI(native, compat) compat
#define OBSOLETE(syscall) syscall

	.type	sys_oabi_call_table, #object
ENTRY(sys_oabi_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/kernel/entry-common.S
	3	*
	4	* Copyright (C) 2000 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
1da177e4	10
1da177e4	11	#include <asm/unistd.h>
395a59d0	12	#include <asm/ftrace.h>
a09e64fb	13	#include <mach/entry-macro.S>
c4c5716e	14	#include <asm/unwind.h>
1da177e4 LT	15
	16	#include "entry-header.S"
	17
1da177e4 LT	18
	19	.align 5
	20	/*
	21	* This is the fast syscall return path. We do as little as
	22	* possible here, and this includes saving r0 back into the SVC
	23	* stack.
	24	*/
	25	ret_fast_syscall:
c4c5716e CM	26	UNWIND(.fnstart )
c4c5716e CM	27	UNWIND(.cantunwind )
1ec42c0c	28	disable_irq @ disable interrupts
1da177e4 LT	29	ldr r1, [tsk, #TI_FLAGS]
	30	tst r1, #_TIF_WORK_MASK
	31	bne fast_work_pending
f4dc9a4c	32
f80dff9d DW	33	/* perform architecture specific actions before user return */
	34	arch_ret_to_user r1, lr
	35
f4dc9a4c RK	36	@ fast_restore_user_regs
	37	ldr r1, [sp, #S_OFF + S_PSR] @ get calling cpsr
	38	ldr lr, [sp, #S_OFF + S_PC]! @ get pc
	39	msr spsr_cxsf, r1 @ save in spsr_svc
	40	ldmdb sp, {r1 - lr}^ @ get calling r1 - lr
	41	mov r0, r0
	42	add sp, sp, #S_FRAME_SIZE - S_PC
	43	movs pc, lr @ return & move spsr_svc into cpsr
c4c5716e	44	UNWIND(.fnend )
1da177e4 LT	45
	46	/*
	47	* Ok, we need to do extra processing, enter the slow path.
	48	*/
	49	fast_work_pending:
	50	str r0, [sp, #S_R0+S_OFF]! @ returned r0
	51	work_pending:
	52	tst r1, #_TIF_NEED_RESCHED
	53	bne work_resched
a583f1b5	54	tst r1, #_TIF_SIGPENDING
1da177e4 LT	55	beq no_work_pending
	56	mov r0, sp @ 'regs'
	57	mov r2, why @ 'syscall'
	58	bl do_notify_resume
a6c61e9d	59	b ret_slow_syscall @ Check work again
1da177e4 LT	60
	61	work_resched:
	62	bl schedule
	63	/*
	64	* "slow" syscall return path. "why" tells us if this was a real syscall.
	65	*/
	66	ENTRY(ret_to_user)
	67	ret_slow_syscall:
1ec42c0c	68	disable_irq @ disable interrupts
1da177e4 LT	69	ldr r1, [tsk, #TI_FLAGS]
	70	tst r1, #_TIF_WORK_MASK
	71	bne work_pending
	72	no_work_pending:
f80dff9d DW	73	/* perform architecture specific actions before user return */
	74	arch_ret_to_user r1, lr
	75
f4dc9a4c RK	76	@ slow_restore_user_regs
	77	ldr r1, [sp, #S_PSR] @ get calling cpsr
	78	ldr lr, [sp, #S_PC]! @ get pc
	79	msr spsr_cxsf, r1 @ save in spsr_svc
7b544c99	80	ldmdb sp, {r0 - lr}^ @ get calling r0 - lr
f4dc9a4c RK	81	mov r0, r0
	82	add sp, sp, #S_FRAME_SIZE - S_PC
	83	movs pc, lr @ return & move spsr_svc into cpsr
93ed3970	84	ENDPROC(ret_to_user)
1da177e4 LT	85
	86	/*
	87	* This is how we return from a fork.
	88	*/
	89	ENTRY(ret_from_fork)
	90	bl schedule_tail
	91	get_thread_info tsk
	92	ldr r1, [tsk, #TI_FLAGS] @ check for syscall tracing
	93	mov why, #1
	94	tst r1, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	95	beq ret_slow_syscall
	96	mov r1, sp
	97	mov r0, #1 @ trace exit [IP = 1]
	98	bl syscall_trace
	99	b ret_slow_syscall
93ed3970	100	ENDPROC(ret_from_fork)
1da177e4	101
fa1b4f91 AV	102	.equ NR_syscalls,0
fa1b4f91 AV	103	#define CALL(x) .equ NR_syscalls,NR_syscalls+1
1da177e4	104	#include "calls.S"
fa1b4f91 AV	105	#undef CALL
fa1b4f91 AV	106	#define CALL(x) .long x
1da177e4	107
606576ce	108	#ifdef CONFIG_FUNCTION_TRACER
014c257c AS	109	#ifdef CONFIG_DYNAMIC_FTRACE
	110	ENTRY(mcount)
	111	stmdb sp!, {r0-r3, lr}
	112	mov r0, lr
395a59d0	113	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	114
	115	.globl mcount_call
	116	mcount_call:
	117	bl ftrace_stub
d4cc510c	118	ldr lr, [fp, #-4] @ restore lr
014c257c AS	119	ldmia sp!, {r0-r3, pc}
	120
	121	ENTRY(ftrace_caller)
	122	stmdb sp!, {r0-r3, lr}
	123	ldr r1, [fp, #-4]
	124	mov r0, lr
395a59d0	125	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	126
	127	.globl ftrace_call
	128	ftrace_call:
	129	bl ftrace_stub
d4cc510c	130	ldr lr, [fp, #-4] @ restore lr
014c257c AS	131	ldmia sp!, {r0-r3, pc}
	132
	133	#else
	134
	135	ENTRY(mcount)
	136	stmdb sp!, {r0-r3, lr}
	137	ldr r0, =ftrace_trace_function
	138	ldr r2, [r0]
	139	adr r0, ftrace_stub
	140	cmp r0, r2
	141	bne trace
d4cc510c	142	ldr lr, [fp, #-4] @ restore lr
014c257c AS	143	ldmia sp!, {r0-r3, pc}
	144
	145	trace:
b3c960b2	146	ldr r1, [fp, #-4] @ lr of instrumented routine
014c257c	147	mov r0, lr
395a59d0	148	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	149	mov lr, pc
014c257c AS	150	mov pc, r2
d4cc510c	151	mov lr, r1 @ restore lr
014c257c AS	152	ldmia sp!, {r0-r3, pc}
	153
	154	#endif /* CONFIG_DYNAMIC_FTRACE */
	155
	156	.globl ftrace_stub
	157	ftrace_stub:
	158	mov pc, lr
	159
606576ce	160	#endif /* CONFIG_FUNCTION_TRACER */
014c257c	161
1da177e4 LT	162	/*=============================================================================
	163	* SWI handler
	164	*-----------------------------------------------------------------------------
	165	*/
	166
	167	/* If we're optimising for StrongARM the resulting code won't
	168	run on an ARM7 and we can save a couple of instructions.
	169	--pb */
	170	#ifdef CONFIG_CPU_ARM710
3f2829a3 NP	171	#define A710(code...) code
3f2829a3 NP	172	.Larm710bug:
1da177e4 LT	173	ldmia sp, {r0 - lr}^ @ Get calling r0 - lr
1da177e4 LT	174	mov r0, r0
1da177e4	175	add sp, sp, #S_FRAME_SIZE
60ac133a	176	subs pc, lr, #4
1da177e4	177	#else
3f2829a3	178	#define A710(code...)
1da177e4 LT	179	#endif
	180
	181	.align 5
	182	ENTRY(vector_swi)
f4dc9a4c RK	183	sub sp, sp, #S_FRAME_SIZE
	184	stmia sp, {r0 - r12} @ Calling r0 - r12
	185	add r8, sp, #S_PC
	186	stmdb r8, {sp, lr}^ @ Calling sp, lr
	187	mrs r8, spsr @ called from non-FIQ mode, so ok.
	188	str lr, [sp, #S_PC] @ Save calling PC
	189	str r8, [sp, #S_PSR] @ Save CPSR
	190	str r0, [sp, #S_OLD_R0] @ Save OLD_R0
1da177e4	191	zero_fp
e0f9f4a6 RK	192
	193	/*
	194	* Get the system call number.
	195	*/
3f2829a3	196
dd35afc2	197	#if defined(CONFIG_OABI_COMPAT)
3f2829a3	198
dd35afc2 NP	199	/*
	200	* If we have CONFIG_OABI_COMPAT then we need to look at the swi
	201	* value to determine if it is an EABI or an old ABI call.
	202	*/
	203	#ifdef CONFIG_ARM_THUMB
	204	tst r8, #PSR_T_BIT
	205	movne r10, #0 @ no thumb OABI emulation
	206	ldreq r10, [lr, #-4] @ get SWI instruction
	207	#else
	208	ldr r10, [lr, #-4] @ get SWI instruction
	209	A710( and ip, r10, #0x0f000000 @ check for SWI )
	210	A710( teq ip, #0x0f000000 )
	211	A710( bne .Larm710bug )
	212	#endif
	213
	214	#elif defined(CONFIG_AEABI)
	215
	216	/*
	217	* Pure EABI user space always put syscall number into scno (r7).
	218	*/
3f2829a3 NP	219	A710( ldr ip, [lr, #-4] @ get SWI instruction )
	220	A710( and ip, ip, #0x0f000000 @ check for SWI )
	221	A710( teq ip, #0x0f000000 )
	222	A710( bne .Larm710bug )
dd35afc2	223
3f2829a3	224	#elif defined(CONFIG_ARM_THUMB)
dd35afc2 NP	225
dd35afc2 NP	226	/* Legacy ABI only, possibly thumb mode. */
e0f9f4a6 RK	227	tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
	228	addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
	229	ldreq scno, [lr, #-4]
dd35afc2	230
e0f9f4a6	231	#else
dd35afc2 NP	232
dd35afc2 NP	233	/* Legacy ABI only. */
e0f9f4a6	234	ldr scno, [lr, #-4] @ get SWI instruction
3f2829a3 NP	235	A710( and ip, scno, #0x0f000000 @ check for SWI )
	236	A710( teq ip, #0x0f000000 )
	237	A710( bne .Larm710bug )
dd35afc2	238
e0f9f4a6	239	#endif
1da177e4 LT	240
	241	#ifdef CONFIG_ALIGNMENT_TRAP
	242	ldr ip, __cr_alignment
	243	ldr ip, [ip]
	244	mcr p15, 0, ip, c1, c0 @ update control register
	245	#endif
1ec42c0c	246	enable_irq
1da177e4	247
1da177e4	248	get_thread_info tsk
dd35afc2	249	adr tbl, sys_call_table @ load syscall table pointer
1da177e4	250	ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing
dd35afc2 NP	251
	252	#if defined(CONFIG_OABI_COMPAT)
	253	/*
	254	* If the swi argument is zero, this is an EABI call and we do nothing.
	255	*
	256	* If this is an old ABI call, get the syscall number into scno and
	257	* get the old ABI syscall table address.
	258	*/
	259	bics r10, r10, #0xff000000
	260	eorne scno, r10, #__NR_OABI_SYSCALL_BASE
	261	ldrne tbl, =sys_oabi_call_table
	262	#elif !defined(CONFIG_AEABI)
1da177e4	263	bic scno, scno, #0xff000000 @ mask off SWI op-code
e0f9f4a6	264	eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
3f2829a3	265	#endif
dd35afc2	266
3f2829a3	267	stmdb sp!, {r4, r5} @ push fifth and sixth args
1da177e4 LT	268	tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	269	bne __sys_trace
	270
1da177e4	271	cmp scno, #NR_syscalls @ check upper syscall limit
3f2829a3	272	adr lr, ret_fast_syscall @ return address
1da177e4 LT	273	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	274
	275	add r1, sp, #S_OFF
	276	2: mov why, #0 @ no longer a real syscall
e0f9f4a6 RK	277	cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
e0f9f4a6 RK	278	eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
1da177e4 LT	279	bcs arm_syscall
1da177e4 LT	280	b sys_ni_syscall @ not private func
93ed3970	281	ENDPROC(vector_swi)
1da177e4 LT	282
	283	/*
	284	* This is the really slow path. We're going to be doing
	285	* context switches, and waiting for our parent to respond.
	286	*/
	287	__sys_trace:
3f471126	288	mov r2, scno
1da177e4 LT	289	add r1, sp, #S_OFF
	290	mov r0, #0 @ trace entry [IP = 0]
	291	bl syscall_trace
	292
	293	adr lr, __sys_trace_return @ return address
3f471126	294	mov scno, r0 @ syscall number (possibly new)
1da177e4 LT	295	add r1, sp, #S_R0 + S_OFF @ pointer to regs
	296	cmp scno, #NR_syscalls @ check upper syscall limit
	297	ldmccia r1, {r0 - r3} @ have to reload r0 - r3
	298	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	299	b 2b
	300
	301	__sys_trace_return:
	302	str r0, [sp, #S_R0 + S_OFF]! @ save returned r0
3f471126	303	mov r2, scno
1da177e4 LT	304	mov r1, sp
	305	mov r0, #1 @ trace exit [IP = 1]
	306	bl syscall_trace
	307	b ret_slow_syscall
	308
	309	.align 5
	310	#ifdef CONFIG_ALIGNMENT_TRAP
	311	.type __cr_alignment, #object
	312	__cr_alignment:
	313	.word cr_alignment
dd35afc2 NP	314	#endif
	315	.ltorg
	316
	317	/*
	318	* This is the syscall table declaration for native ABI syscalls.
	319	* With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
	320	*/
	321	#define ABI(native, compat) native
	322	#ifdef CONFIG_AEABI
	323	#define OBSOLETE(syscall) sys_ni_syscall
	324	#else
	325	#define OBSOLETE(syscall) syscall
1da177e4 LT	326	#endif
	327
	328	.type sys_call_table, #object
	329	ENTRY(sys_call_table)
	330	#include "calls.S"
dd35afc2 NP	331	#undef ABI
dd35afc2 NP	332	#undef OBSOLETE
1da177e4 LT	333
	334	/*============================================================================
	335	* Special system call wrappers
	336	*/
	337	@ r0 = syscall number
567bd980	338	@ r8 = syscall table
1da177e4	339	sys_syscall:
5247593c	340	bic scno, r0, #__NR_OABI_SYSCALL_BASE
1da177e4 LT	341	cmp scno, #__NR_syscall - __NR_SYSCALL_BASE
	342	cmpne scno, #NR_syscalls @ check range
	343	stmloia sp, {r5, r6} @ shuffle args
	344	movlo r0, r1
	345	movlo r1, r2
	346	movlo r2, r3
	347	movlo r3, r4
	348	ldrlo pc, [tbl, scno, lsl #2]
	349	b sys_ni_syscall
93ed3970	350	ENDPROC(sys_syscall)
1da177e4 LT	351
	352	sys_fork_wrapper:
	353	add r0, sp, #S_OFF
	354	b sys_fork
93ed3970	355	ENDPROC(sys_fork_wrapper)
1da177e4 LT	356
	357	sys_vfork_wrapper:
	358	add r0, sp, #S_OFF
	359	b sys_vfork
93ed3970	360	ENDPROC(sys_vfork_wrapper)
1da177e4 LT	361
	362	sys_execve_wrapper:
	363	add r3, sp, #S_OFF
	364	b sys_execve
93ed3970	365	ENDPROC(sys_execve_wrapper)
1da177e4 LT	366
	367	sys_clone_wrapper:
	368	add ip, sp, #S_OFF
	369	str ip, [sp, #4]
	370	b sys_clone
93ed3970	371	ENDPROC(sys_clone_wrapper)
1da177e4 LT	372
	373	sys_sigsuspend_wrapper:
	374	add r3, sp, #S_OFF
	375	b sys_sigsuspend
93ed3970	376	ENDPROC(sys_sigsuspend_wrapper)
1da177e4 LT	377
	378	sys_rt_sigsuspend_wrapper:
	379	add r2, sp, #S_OFF
	380	b sys_rt_sigsuspend
93ed3970	381	ENDPROC(sys_rt_sigsuspend_wrapper)
1da177e4 LT	382
	383	sys_sigreturn_wrapper:
	384	add r0, sp, #S_OFF
	385	b sys_sigreturn
93ed3970	386	ENDPROC(sys_sigreturn_wrapper)
1da177e4 LT	387
	388	sys_rt_sigreturn_wrapper:
	389	add r0, sp, #S_OFF
	390	b sys_rt_sigreturn
93ed3970	391	ENDPROC(sys_rt_sigreturn_wrapper)
1da177e4 LT	392
	393	sys_sigaltstack_wrapper:
	394	ldr r2, [sp, #S_OFF + S_SP]
	395	b do_sigaltstack
93ed3970	396	ENDPROC(sys_sigaltstack_wrapper)
1da177e4	397
713c4815 NP	398	sys_statfs64_wrapper:
	399	teq r1, #88
	400	moveq r1, #84
	401	b sys_statfs64
93ed3970	402	ENDPROC(sys_statfs64_wrapper)
713c4815 NP	403
	404	sys_fstatfs64_wrapper:
	405	teq r1, #88
	406	moveq r1, #84
	407	b sys_fstatfs64
93ed3970	408	ENDPROC(sys_fstatfs64_wrapper)
713c4815	409
1da177e4 LT	410	/*
	411	* Note: off_4k (r5) is always units of 4K. If we can't do the requested
	412	* offset, we return EINVAL.
	413	*/
	414	sys_mmap2:
	415	#if PAGE_SHIFT > 12
	416	tst r5, #PGOFF_MASK
	417	moveq r5, r5, lsr #PAGE_SHIFT - 12
	418	streq r5, [sp, #4]
	419	beq do_mmap2
	420	mov r0, #-EINVAL
7999d8d7	421	mov pc, lr
1da177e4 LT	422	#else
	423	str r5, [sp, #4]
	424	b do_mmap2
	425	#endif
93ed3970	426	ENDPROC(sys_mmap2)
687ad019	427
48d7927b PB	428	ENTRY(pabort_ifar)
	429	mrc p15, 0, r0, cr6, cr0, 2
	430	ENTRY(pabort_noifar)
	431	mov pc, lr
93ed3970 CM	432	ENDPROC(pabort_ifar)
93ed3970 CM	433	ENDPROC(pabort_noifar)
48d7927b	434
687ad019	435	#ifdef CONFIG_OABI_COMPAT
dd35afc2	436
687ad019 NP	437	/*
	438	* These are syscalls with argument register differences
	439	*/
	440
	441	sys_oabi_pread64:
	442	stmia sp, {r3, r4}
	443	b sys_pread64
93ed3970	444	ENDPROC(sys_oabi_pread64)
687ad019 NP	445
	446	sys_oabi_pwrite64:
	447	stmia sp, {r3, r4}
	448	b sys_pwrite64
93ed3970	449	ENDPROC(sys_oabi_pwrite64)
687ad019 NP	450
	451	sys_oabi_truncate64:
	452	mov r3, r2
	453	mov r2, r1
	454	b sys_truncate64
93ed3970	455	ENDPROC(sys_oabi_truncate64)
687ad019 NP	456
	457	sys_oabi_ftruncate64:
	458	mov r3, r2
	459	mov r2, r1
	460	b sys_ftruncate64
93ed3970	461	ENDPROC(sys_oabi_ftruncate64)
687ad019 NP	462
	463	sys_oabi_readahead:
	464	str r3, [sp]
	465	mov r3, r2
	466	mov r2, r1
	467	b sys_readahead
93ed3970	468	ENDPROC(sys_oabi_readahead)
687ad019	469
dd35afc2 NP	470	/*
	471	* Let's declare a second syscall table for old ABI binaries
	472	* using the compatibility syscall entries.
	473	*/
	474	#define ABI(native, compat) compat
	475	#define OBSOLETE(syscall) syscall
	476
	477	.type sys_oabi_call_table, #object
	478	ENTRY(sys_oabi_call_table)
	479	#include "calls.S"
	480	#undef ABI
	481	#undef OBSOLETE
	482
687ad019 NP	483	#endif
687ad019 NP	484