[deliverable/linux.git] / arch / arm / kernel / entry-common.S

/*
 *  linux/arch/arm/kernel/entry-common.S
 *
 *  Copyright (C) 2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <asm/assembler.h>
#include <asm/unistd.h>
#include <asm/ftrace.h>
#include <asm/unwind.h>

#ifdef CONFIG_NEED_RET_TO_USER
#include <mach/entry-macro.S>
#else
	.macro  arch_ret_to_user, tmp1, tmp2
	.endm
#endif

#include "entry-header.S"


	.align	5
/*
 * This is the fast syscall return path.  We do as little as
 * possible here, and this includes saving r0 back into the SVC
 * stack.
 */
ret_fast_syscall:
 UNWIND(.fnstart	)
 UNWIND(.cantunwind	)
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]		@ re-check for syscall tracing
	tst	r1, #_TIF_SYSCALL_WORK
	bne	__sys_trace_return
	tst	r1, #_TIF_WORK_MASK
	bne	fast_work_pending
	asm_trace_hardirqs_on

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr
	ct_user_enter

	restore_user_regs fast = 1, offset = S_OFF
 UNWIND(.fnend		)

/*
 * Ok, we need to do extra processing, enter the slow path.
 */
fast_work_pending:
	str	r0, [sp, #S_R0+S_OFF]!		@ returned r0
work_pending:
	mov	r0, sp				@ 'regs'
	mov	r2, why				@ 'syscall'
	bl	do_work_pending
	cmp	r0, #0
	beq	no_work_pending
	movlt	scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
	ldmia	sp, {r0 - r6}			@ have to reload r0 - r6
	b	local_restart			@ ... and off we go

/*
 * "slow" syscall return path.  "why" tells us if this was a real syscall.
 */
ENTRY(ret_to_user)
ret_slow_syscall:
	disable_irq				@ disable interrupts
ENTRY(ret_to_user_from_irq)
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	work_pending
no_work_pending:
	asm_trace_hardirqs_on

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr
	ct_user_enter save = 0

	restore_user_regs fast = 0, offset = 0
ENDPROC(ret_to_user_from_irq)
ENDPROC(ret_to_user)

/*
 * This is how we return from a fork.
 */
ENTRY(ret_from_fork)
	bl	schedule_tail
	cmp	r5, #0
	movne	r0, r4
	badrne	lr, 1f
	retne	r5
1:	get_thread_info tsk
	b	ret_slow_syscall
ENDPROC(ret_from_fork)

	.equ NR_syscalls,0
#define CALL(x) .equ NR_syscalls,NR_syscalls+1
#include "calls.S"

/*
 * Ensure that the system call table is equal to __NR_syscalls,
 * which is the value the rest of the system sees
 */
.ifne NR_syscalls - __NR_syscalls
.error "__NR_syscalls is not equal to the size of the syscall table"
.endif

#undef CALL
#define CALL(x) .long x

/*=============================================================================
 * SWI handler
 *-----------------------------------------------------------------------------
 */

	.align	5
ENTRY(vector_swi)
#ifdef CONFIG_CPU_V7M
	v7m_exception_entry
#else
	sub	sp, sp, #S_FRAME_SIZE
	stmia	sp, {r0 - r12}			@ Calling r0 - r12
 ARM(	add	r8, sp, #S_PC		)
 ARM(	stmdb	r8, {sp, lr}^		)	@ Calling sp, lr
 THUMB(	mov	r8, sp			)
 THUMB(	store_user_sp_lr r8, r10, S_SP	)	@ calling sp, lr
	mrs	r8, spsr			@ called from non-FIQ mode, so ok.
	str	lr, [sp, #S_PC]			@ Save calling PC
	str	r8, [sp, #S_PSR]		@ Save CPSR
	str	r0, [sp, #S_OLD_R0]		@ Save OLD_R0
#endif
	zero_fp
	alignment_trap r10, ip, __cr_alignment
	enable_irq
	ct_user_exit
	get_thread_info tsk

	/*
	 * Get the system call number.
	 */

#if defined(CONFIG_OABI_COMPAT)

	/*
	 * If we have CONFIG_OABI_COMPAT then we need to look at the swi
	 * value to determine if it is an EABI or an old ABI call.
	 */
#ifdef CONFIG_ARM_THUMB
	tst	r8, #PSR_T_BIT
	movne	r10, #0				@ no thumb OABI emulation
 USER(	ldreq	r10, [lr, #-4]		)	@ get SWI instruction
#else
 USER(	ldr	r10, [lr, #-4]		)	@ get SWI instruction
#endif
 ARM_BE8(rev	r10, r10)			@ little endian instruction

#elif defined(CONFIG_AEABI)

	/*
	 * Pure EABI user space always put syscall number into scno (r7).
	 */
#elif defined(CONFIG_ARM_THUMB)
	/* Legacy ABI only, possibly thumb mode. */
	tst	r8, #PSR_T_BIT			@ this is SPSR from save_user_regs
	addne	scno, r7, #__NR_SYSCALL_BASE	@ put OS number in
 USER(	ldreq	scno, [lr, #-4]		)

#else
	/* Legacy ABI only. */
 USER(	ldr	scno, [lr, #-4]		)	@ get SWI instruction
#endif

	adr	tbl, sys_call_table		@ load syscall table pointer

#if defined(CONFIG_OABI_COMPAT)
	/*
	 * If the swi argument is zero, this is an EABI call and we do nothing.
	 *
	 * If this is an old ABI call, get the syscall number into scno and
	 * get the old ABI syscall table address.
	 */
	bics	r10, r10, #0xff000000
	eorne	scno, r10, #__NR_OABI_SYSCALL_BASE
	ldrne	tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
	bic	scno, scno, #0xff000000		@ mask off SWI op-code
	eor	scno, scno, #__NR_SYSCALL_BASE	@ check OS number
#endif

local_restart:
	ldr	r10, [tsk, #TI_FLAGS]		@ check for syscall tracing
	stmdb	sp!, {r4, r5}			@ push fifth and sixth args

	tst	r10, #_TIF_SYSCALL_WORK		@ are we tracing syscalls?
	bne	__sys_trace

	cmp	scno, #NR_syscalls		@ check upper syscall limit
	badr	lr, ret_fast_syscall		@ return address
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine

	add	r1, sp, #S_OFF
2:	cmp	scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
	eor	r0, scno, #__NR_SYSCALL_BASE	@ put OS number back
	bcs	arm_syscall
	mov	why, #0				@ no longer a real syscall
	b	sys_ni_syscall			@ not private func

#if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
	/*
	 * We failed to handle a fault trying to access the page
	 * containing the swi instruction, but we're not really in a
	 * position to return -EFAULT. Instead, return back to the
	 * instruction and re-enter the user fault handling path trying
	 * to page it in. This will likely result in sending SEGV to the
	 * current task.
	 */
9001:
	sub	lr, lr, #4
	str	lr, [sp, #S_PC]
	b	ret_fast_syscall
#endif
ENDPROC(vector_swi)

	/*
	 * This is the really slow path.  We're going to be doing
	 * context switches, and waiting for our parent to respond.
	 */
__sys_trace:
	mov	r1, scno
	add	r0, sp, #S_OFF
	bl	syscall_trace_enter

	badr	lr, __sys_trace_return		@ return address
	mov	scno, r0			@ syscall number (possibly new)
	add	r1, sp, #S_R0 + S_OFF		@ pointer to regs
	cmp	scno, #NR_syscalls		@ check upper syscall limit
	ldmccia	r1, {r0 - r6}			@ have to reload r0 - r6
	stmccia	sp, {r4, r5}			@ and update the stack args
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine
	cmp	scno, #-1			@ skip the syscall?
	bne	2b
	add	sp, sp, #S_OFF			@ restore stack
	b	ret_slow_syscall

__sys_trace_return:
	str	r0, [sp, #S_R0 + S_OFF]!	@ save returned r0
	mov	r0, sp
	bl	syscall_trace_exit
	b	ret_slow_syscall

	.align	5
#ifdef CONFIG_ALIGNMENT_TRAP
	.type	__cr_alignment, #object
__cr_alignment:
	.word	cr_alignment
#endif
	.ltorg

/*
 * This is the syscall table declaration for native ABI syscalls.
 * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 */
#define ABI(native, compat) native
#ifdef CONFIG_AEABI
#define OBSOLETE(syscall) sys_ni_syscall
#else
#define OBSOLETE(syscall) syscall
#endif

	.type	sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

/*============================================================================
 * Special system call wrappers
 */
@ r0 = syscall number
@ r8 = syscall table
sys_syscall:
		bic	scno, r0, #__NR_OABI_SYSCALL_BASE
		cmp	scno, #__NR_syscall - __NR_SYSCALL_BASE
		cmpne	scno, #NR_syscalls	@ check range
		stmloia	sp, {r5, r6}		@ shuffle args
		movlo	r0, r1
		movlo	r1, r2
		movlo	r2, r3
		movlo	r3, r4
		ldrlo	pc, [tbl, scno, lsl #2]
		b	sys_ni_syscall
ENDPROC(sys_syscall)

sys_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		mov	why, #0		@ prevent syscall restart handling
		b	sys_sigreturn
ENDPROC(sys_sigreturn_wrapper)

sys_rt_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		mov	why, #0		@ prevent syscall restart handling
		b	sys_rt_sigreturn
ENDPROC(sys_rt_sigreturn_wrapper)

sys_statfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_statfs64
ENDPROC(sys_statfs64_wrapper)

sys_fstatfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_fstatfs64
ENDPROC(sys_fstatfs64_wrapper)

/*
 * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 * offset, we return EINVAL.
 */
sys_mmap2:
#if PAGE_SHIFT > 12
		tst	r5, #PGOFF_MASK
		moveq	r5, r5, lsr #PAGE_SHIFT - 12
		streq	r5, [sp, #4]
		beq	sys_mmap_pgoff
		mov	r0, #-EINVAL
		ret	lr
#else
		str	r5, [sp, #4]
		b	sys_mmap_pgoff
#endif
ENDPROC(sys_mmap2)

#ifdef CONFIG_OABI_COMPAT

/*
 * These are syscalls with argument register differences
 */

sys_oabi_pread64:
		stmia	sp, {r3, r4}
		b	sys_pread64
ENDPROC(sys_oabi_pread64)

sys_oabi_pwrite64:
		stmia	sp, {r3, r4}
		b	sys_pwrite64
ENDPROC(sys_oabi_pwrite64)

sys_oabi_truncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_truncate64
ENDPROC(sys_oabi_truncate64)

sys_oabi_ftruncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_ftruncate64
ENDPROC(sys_oabi_ftruncate64)

sys_oabi_readahead:
		str	r3, [sp]
		mov	r3, r2
		mov	r2, r1
		b	sys_readahead
ENDPROC(sys_oabi_readahead)

/*
 * Let's declare a second syscall table for old ABI binaries
 * using the compatibility syscall entries.
 */
#define ABI(native, compat) compat
#define OBSOLETE(syscall) syscall

	.type	sys_oabi_call_table, #object
ENTRY(sys_oabi_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/kernel/entry-common.S
	3	*
	4	* Copyright (C) 2000 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
1da177e4	10
6ebbf2ce	11	#include <asm/assembler.h>
1da177e4	12	#include <asm/unistd.h>
395a59d0	13	#include <asm/ftrace.h>
c4c5716e	14	#include <asm/unwind.h>
1da177e4	15
13a5045d RH	16	#ifdef CONFIG_NEED_RET_TO_USER
	17	#include <mach/entry-macro.S>
	18	#else
	19	.macro arch_ret_to_user, tmp1, tmp2
	20	.endm
	21	#endif
	22
1da177e4 LT	23	#include "entry-header.S"
1da177e4 LT	24
1da177e4 LT	25
	26	.align 5
	27	/*
	28	* This is the fast syscall return path. We do as little as
	29	* possible here, and this includes saving r0 back into the SVC
	30	* stack.
	31	*/
	32	ret_fast_syscall:
c4c5716e CM	33	UNWIND(.fnstart )
c4c5716e CM	34	UNWIND(.cantunwind )
1ec42c0c	35	disable_irq @ disable interrupts
1b979372 RK	36	ldr r1, [tsk, #TI_FLAGS] @ re-check for syscall tracing
	37	tst r1, #_TIF_SYSCALL_WORK
	38	bne __sys_trace_return
1da177e4 LT	39	tst r1, #_TIF_WORK_MASK
1da177e4 LT	40	bne fast_work_pending
d13e5edd	41	asm_trace_hardirqs_on
f4dc9a4c	42
f80dff9d DW	43	/* perform architecture specific actions before user return */
f80dff9d DW	44	arch_ret_to_user r1, lr
b0088480	45	ct_user_enter
f80dff9d	46
b86040a5	47	restore_user_regs fast = 1, offset = S_OFF
c4c5716e	48	UNWIND(.fnend )
1da177e4 LT	49
	50	/*
	51	* Ok, we need to do extra processing, enter the slow path.
	52	*/
	53	fast_work_pending:
	54	str r0, [sp, #S_R0+S_OFF]! @ returned r0
	55	work_pending:
1da177e4 LT	56	mov r0, sp @ 'regs'
1da177e4 LT	57	mov r2, why @ 'syscall'
0a267fa6	58	bl do_work_pending
66285217	59	cmp r0, #0
81783786	60	beq no_work_pending
66285217	61	movlt scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
81783786 AV	62	ldmia sp, {r0 - r6} @ have to reload r0 - r6
	63	b local_restart @ ... and off we go
	64
1da177e4 LT	65	/*
	66	* "slow" syscall return path. "why" tells us if this was a real syscall.
	67	*/
	68	ENTRY(ret_to_user)
	69	ret_slow_syscall:
1ec42c0c	70	disable_irq @ disable interrupts
9fc2552a	71	ENTRY(ret_to_user_from_irq)
1da177e4 LT	72	ldr r1, [tsk, #TI_FLAGS]
	73	tst r1, #_TIF_WORK_MASK
	74	bne work_pending
	75	no_work_pending:
d13e5edd	76	asm_trace_hardirqs_on
651e9499	77
f80dff9d DW	78	/* perform architecture specific actions before user return */
f80dff9d DW	79	arch_ret_to_user r1, lr
b0088480	80	ct_user_enter save = 0
f80dff9d	81
b86040a5	82	restore_user_regs fast = 0, offset = 0
9fc2552a	83	ENDPROC(ret_to_user_from_irq)
93ed3970	84	ENDPROC(ret_to_user)
1da177e4 LT	85
	86	/*
	87	* This is how we return from a fork.
	88	*/
	89	ENTRY(ret_from_fork)
	90	bl schedule_tail
9fff2fa0 AV	91	cmp r5, #0
9fff2fa0 AV	92	movne r0, r4
14327c66	93	badrne lr, 1f
6ebbf2ce	94	retne r5
68687c84	95	1: get_thread_info tsk
1da177e4	96	b ret_slow_syscall
93ed3970	97	ENDPROC(ret_from_fork)
1da177e4	98
fa1b4f91 AV	99	.equ NR_syscalls,0
fa1b4f91 AV	100	#define CALL(x) .equ NR_syscalls,NR_syscalls+1
1da177e4	101	#include "calls.S"
1f66e06f WF	102
	103	/*
	104	* Ensure that the system call table is equal to __NR_syscalls,
	105	* which is the value the rest of the system sees
	106	*/
	107	.ifne NR_syscalls - __NR_syscalls
	108	.error "__NR_syscalls is not equal to the size of the syscall table"
	109	.endif
	110
fa1b4f91 AV	111	#undef CALL
fa1b4f91 AV	112	#define CALL(x) .long x
1da177e4 LT	113
	114	/*=============================================================================
	115	* SWI handler
	116	*-----------------------------------------------------------------------------
	117	*/
	118
1da177e4 LT	119	.align 5
1da177e4 LT	120	ENTRY(vector_swi)
19c4d593 UKK	121	#ifdef CONFIG_CPU_V7M
	122	v7m_exception_entry
	123	#else
f4dc9a4c RK	124	sub sp, sp, #S_FRAME_SIZE
f4dc9a4c RK	125	stmia sp, {r0 - r12} @ Calling r0 - r12
b86040a5 CM	126	ARM( add r8, sp, #S_PC )
	127	ARM( stmdb r8, {sp, lr}^ ) @ Calling sp, lr
	128	THUMB( mov r8, sp )
	129	THUMB( store_user_sp_lr r8, r10, S_SP ) @ calling sp, lr
f4dc9a4c RK	130	mrs r8, spsr @ called from non-FIQ mode, so ok.
	131	str lr, [sp, #S_PC] @ Save calling PC
	132	str r8, [sp, #S_PSR] @ Save CPSR
	133	str r0, [sp, #S_OLD_R0] @ Save OLD_R0
19c4d593	134	#endif
1da177e4	135	zero_fp
195b58ad	136	alignment_trap r10, ip, __cr_alignment
1aa2b3b7 WD	137	enable_irq
	138	ct_user_exit
	139	get_thread_info tsk
	140
e0f9f4a6 RK	141	/*
	142	* Get the system call number.
	143	*/
3f2829a3	144
dd35afc2	145	#if defined(CONFIG_OABI_COMPAT)
3f2829a3	146
dd35afc2 NP	147	/*
	148	* If we have CONFIG_OABI_COMPAT then we need to look at the swi
	149	* value to determine if it is an EABI or an old ABI call.
	150	*/
	151	#ifdef CONFIG_ARM_THUMB
	152	tst r8, #PSR_T_BIT
	153	movne r10, #0 @ no thumb OABI emulation
1aa2b3b7	154	USER( ldreq r10, [lr, #-4] ) @ get SWI instruction
dd35afc2	155	#else
1aa2b3b7	156	USER( ldr r10, [lr, #-4] ) @ get SWI instruction
dd35afc2	157	#endif
457c2403	158	ARM_BE8(rev r10, r10) @ little endian instruction
dd35afc2 NP	159
	160	#elif defined(CONFIG_AEABI)
	161
	162	/*
	163	* Pure EABI user space always put syscall number into scno (r7).
	164	*/
3f2829a3	165	#elif defined(CONFIG_ARM_THUMB)
dd35afc2	166	/* Legacy ABI only, possibly thumb mode. */
e0f9f4a6 RK	167	tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
e0f9f4a6 RK	168	addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
1aa2b3b7	169	USER( ldreq scno, [lr, #-4] )
dd35afc2	170
e0f9f4a6	171	#else
dd35afc2	172	/* Legacy ABI only. */
1aa2b3b7	173	USER( ldr scno, [lr, #-4] ) @ get SWI instruction
e0f9f4a6	174	#endif
1da177e4	175
dd35afc2	176	adr tbl, sys_call_table @ load syscall table pointer
dd35afc2 NP	177
	178	#if defined(CONFIG_OABI_COMPAT)
	179	/*
	180	* If the swi argument is zero, this is an EABI call and we do nothing.
	181	*
	182	* If this is an old ABI call, get the syscall number into scno and
	183	* get the old ABI syscall table address.
	184	*/
	185	bics r10, r10, #0xff000000
	186	eorne scno, r10, #__NR_OABI_SYSCALL_BASE
	187	ldrne tbl, =sys_oabi_call_table
	188	#elif !defined(CONFIG_AEABI)
1da177e4	189	bic scno, scno, #0xff000000 @ mask off SWI op-code
e0f9f4a6	190	eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
3f2829a3	191	#endif
dd35afc2	192
81783786	193	local_restart:
70c70d97	194	ldr r10, [tsk, #TI_FLAGS] @ check for syscall tracing
3f2829a3	195	stmdb sp!, {r4, r5} @ push fifth and sixth args
70c70d97	196
29ef73b7	197	tst r10, #_TIF_SYSCALL_WORK @ are we tracing syscalls?
1da177e4 LT	198	bne __sys_trace
1da177e4 LT	199
1da177e4	200	cmp scno, #NR_syscalls @ check upper syscall limit
14327c66	201	badr lr, ret_fast_syscall @ return address
1da177e4 LT	202	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	203
	204	add r1, sp, #S_OFF
d95bc250	205	2: cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
e0f9f4a6	206	eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
377747c4	207	bcs arm_syscall
d95bc250	208	mov why, #0 @ no longer a real syscall
1da177e4	209	b sys_ni_syscall @ not private func
1aa2b3b7 WD	210
	211	#if defined(CONFIG_OABI_COMPAT) \|\| !defined(CONFIG_AEABI)
	212	/*
	213	* We failed to handle a fault trying to access the page
	214	* containing the swi instruction, but we're not really in a
	215	* position to return -EFAULT. Instead, return back to the
	216	* instruction and re-enter the user fault handling path trying
	217	* to page it in. This will likely result in sending SEGV to the
	218	* current task.
	219	*/
	220	9001:
	221	sub lr, lr, #4
	222	str lr, [sp, #S_PC]
	223	b ret_fast_syscall
	224	#endif
93ed3970	225	ENDPROC(vector_swi)
1da177e4 LT	226
	227	/*
	228	* This is the really slow path. We're going to be doing
	229	* context switches, and waiting for our parent to respond.
	230	*/
	231	__sys_trace:
ad722541 WD	232	mov r1, scno
	233	add r0, sp, #S_OFF
	234	bl syscall_trace_enter
1da177e4	235
14327c66	236	badr lr, __sys_trace_return @ return address
3f471126	237	mov scno, r0 @ syscall number (possibly new)
1da177e4 LT	238	add r1, sp, #S_R0 + S_OFF @ pointer to regs
1da177e4 LT	239	cmp scno, #NR_syscalls @ check upper syscall limit
c7aa00db WD	240	ldmccia r1, {r0 - r6} @ have to reload r0 - r6
c7aa00db WD	241	stmccia sp, {r4, r5} @ and update the stack args
1da177e4	242	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
ad75b514 KC	243	cmp scno, #-1 @ skip the syscall?
	244	bne 2b
	245	add sp, sp, #S_OFF @ restore stack
	246	b ret_slow_syscall
1da177e4 LT	247
	248	__sys_trace_return:
	249	str r0, [sp, #S_R0 + S_OFF]! @ save returned r0
ad722541 WD	250	mov r0, sp
ad722541 WD	251	bl syscall_trace_exit
1da177e4 LT	252	b ret_slow_syscall
	253
	254	.align 5
	255	#ifdef CONFIG_ALIGNMENT_TRAP
	256	.type __cr_alignment, #object
	257	__cr_alignment:
	258	.word cr_alignment
dd35afc2 NP	259	#endif
	260	.ltorg
	261
	262	/*
	263	* This is the syscall table declaration for native ABI syscalls.
	264	* With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
	265	*/
	266	#define ABI(native, compat) native
	267	#ifdef CONFIG_AEABI
	268	#define OBSOLETE(syscall) sys_ni_syscall
	269	#else
	270	#define OBSOLETE(syscall) syscall
1da177e4 LT	271	#endif
	272
	273	.type sys_call_table, #object
	274	ENTRY(sys_call_table)
	275	#include "calls.S"
dd35afc2 NP	276	#undef ABI
dd35afc2 NP	277	#undef OBSOLETE
1da177e4 LT	278
	279	/*============================================================================
	280	* Special system call wrappers
	281	*/
	282	@ r0 = syscall number
567bd980	283	@ r8 = syscall table
1da177e4	284	sys_syscall:
5247593c	285	bic scno, r0, #__NR_OABI_SYSCALL_BASE
1da177e4 LT	286	cmp scno, #__NR_syscall - __NR_SYSCALL_BASE
	287	cmpne scno, #NR_syscalls @ check range
	288	stmloia sp, {r5, r6} @ shuffle args
	289	movlo r0, r1
	290	movlo r1, r2
	291	movlo r2, r3
	292	movlo r3, r4
	293	ldrlo pc, [tbl, scno, lsl #2]
	294	b sys_ni_syscall
93ed3970	295	ENDPROC(sys_syscall)
1da177e4	296
1da177e4 LT	297	sys_sigreturn_wrapper:
1da177e4 LT	298	add r0, sp, #S_OFF
653d48b2	299	mov why, #0 @ prevent syscall restart handling
1da177e4	300	b sys_sigreturn
93ed3970	301	ENDPROC(sys_sigreturn_wrapper)
1da177e4 LT	302
	303	sys_rt_sigreturn_wrapper:
	304	add r0, sp, #S_OFF
653d48b2	305	mov why, #0 @ prevent syscall restart handling
1da177e4	306	b sys_rt_sigreturn
93ed3970	307	ENDPROC(sys_rt_sigreturn_wrapper)
1da177e4	308
713c4815 NP	309	sys_statfs64_wrapper:
	310	teq r1, #88
	311	moveq r1, #84
	312	b sys_statfs64
93ed3970	313	ENDPROC(sys_statfs64_wrapper)
713c4815 NP	314
	315	sys_fstatfs64_wrapper:
	316	teq r1, #88
	317	moveq r1, #84
	318	b sys_fstatfs64
93ed3970	319	ENDPROC(sys_fstatfs64_wrapper)
713c4815	320
1da177e4 LT	321	/*
	322	* Note: off_4k (r5) is always units of 4K. If we can't do the requested
	323	* offset, we return EINVAL.
	324	*/
	325	sys_mmap2:
	326	#if PAGE_SHIFT > 12
	327	tst r5, #PGOFF_MASK
	328	moveq r5, r5, lsr #PAGE_SHIFT - 12
	329	streq r5, [sp, #4]
f8b72560	330	beq sys_mmap_pgoff
1da177e4	331	mov r0, #-EINVAL
6ebbf2ce	332	ret lr
1da177e4 LT	333	#else
1da177e4 LT	334	str r5, [sp, #4]
f8b72560	335	b sys_mmap_pgoff
1da177e4	336	#endif
93ed3970	337	ENDPROC(sys_mmap2)
687ad019 NP	338
687ad019 NP	339	#ifdef CONFIG_OABI_COMPAT
dd35afc2	340
687ad019 NP	341	/*
	342	* These are syscalls with argument register differences
	343	*/
	344
	345	sys_oabi_pread64:
	346	stmia sp, {r3, r4}
	347	b sys_pread64
93ed3970	348	ENDPROC(sys_oabi_pread64)
687ad019 NP	349
	350	sys_oabi_pwrite64:
	351	stmia sp, {r3, r4}
	352	b sys_pwrite64
93ed3970	353	ENDPROC(sys_oabi_pwrite64)
687ad019 NP	354
	355	sys_oabi_truncate64:
	356	mov r3, r2
	357	mov r2, r1
	358	b sys_truncate64
93ed3970	359	ENDPROC(sys_oabi_truncate64)
687ad019 NP	360
	361	sys_oabi_ftruncate64:
	362	mov r3, r2
	363	mov r2, r1
	364	b sys_ftruncate64
93ed3970	365	ENDPROC(sys_oabi_ftruncate64)
687ad019 NP	366
	367	sys_oabi_readahead:
	368	str r3, [sp]
	369	mov r3, r2
	370	mov r2, r1
	371	b sys_readahead
93ed3970	372	ENDPROC(sys_oabi_readahead)
687ad019	373
dd35afc2 NP	374	/*
	375	* Let's declare a second syscall table for old ABI binaries
	376	* using the compatibility syscall entries.
	377	*/
	378	#define ABI(native, compat) compat
	379	#define OBSOLETE(syscall) syscall
	380
	381	.type sys_oabi_call_table, #object
	382	ENTRY(sys_oabi_call_table)
	383	#include "calls.S"
	384	#undef ABI
	385	#undef OBSOLETE
	386
687ad019 NP	387	#endif
687ad019 NP	388