[deliverable/linux.git] / arch / arm / kernel / entry-common.S

/*
 *  linux/arch/arm/kernel/entry-common.S
 *
 *  Copyright (C) 2000 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */

#include <asm/unistd.h>
#include <asm/ftrace.h>
#include <mach/entry-macro.S>
#include <asm/unwind.h>

#include "entry-header.S"


	.align	5
/*
 * This is the fast syscall return path.  We do as little as
 * possible here, and this includes saving r0 back into the SVC
 * stack.
 */
ret_fast_syscall:
 UNWIND(.fnstart	)
 UNWIND(.cantunwind	)
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	fast_work_pending

	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	restore_user_regs fast = 1, offset = S_OFF
 UNWIND(.fnend		)

/*
 * Ok, we need to do extra processing, enter the slow path.
 */
fast_work_pending:
	str	r0, [sp, #S_R0+S_OFF]!		@ returned r0
work_pending:
	tst	r1, #_TIF_NEED_RESCHED
	bne	work_resched
	tst	r1, #_TIF_SIGPENDING
	beq	no_work_pending
	mov	r0, sp				@ 'regs'
	mov	r2, why				@ 'syscall'
	bl	do_notify_resume
	b	ret_slow_syscall		@ Check work again

work_resched:
	bl	schedule
/*
 * "slow" syscall return path.  "why" tells us if this was a real syscall.
 */
ENTRY(ret_to_user)
ret_slow_syscall:
	disable_irq				@ disable interrupts
	ldr	r1, [tsk, #TI_FLAGS]
	tst	r1, #_TIF_WORK_MASK
	bne	work_pending
no_work_pending:
	/* perform architecture specific actions before user return */
	arch_ret_to_user r1, lr

	restore_user_regs fast = 0, offset = 0
ENDPROC(ret_to_user)

/*
 * This is how we return from a fork.
 */
ENTRY(ret_from_fork)
	bl	schedule_tail
	get_thread_info tsk
	ldr	r1, [tsk, #TI_FLAGS]		@ check for syscall tracing
	mov	why, #1
	tst	r1, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	beq	ret_slow_syscall
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall
ENDPROC(ret_from_fork)

	.equ NR_syscalls,0
#define CALL(x) .equ NR_syscalls,NR_syscalls+1
#include "calls.S"
#undef CALL
#define CALL(x) .long x

#ifdef CONFIG_FUNCTION_TRACER
#ifdef CONFIG_DYNAMIC_FTRACE
ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl mcount_call
mcount_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

ENTRY(ftrace_caller)
	stmdb sp!, {r0-r3, lr}
	ldr r1, [fp, #-4]
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE

	.globl ftrace_call
ftrace_call:
	bl ftrace_stub
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

#else

ENTRY(mcount)
	stmdb sp!, {r0-r3, lr}
	ldr r0, =ftrace_trace_function
	ldr r2, [r0]
	adr r0, ftrace_stub
	cmp r0, r2
	bne trace
	ldr lr, [fp, #-4]			@ restore lr
	ldmia sp!, {r0-r3, pc}

trace:
	ldr r1, [fp, #-4]			@ lr of instrumented routine
	mov r0, lr
	sub r0, r0, #MCOUNT_INSN_SIZE
	mov lr, pc
	mov pc, r2
	mov lr, r1				@ restore lr
	ldmia sp!, {r0-r3, pc}

#endif /* CONFIG_DYNAMIC_FTRACE */

	.globl ftrace_stub
ftrace_stub:
	mov pc, lr

#endif /* CONFIG_FUNCTION_TRACER */

/*=============================================================================
 * SWI handler
 *-----------------------------------------------------------------------------
 */

	/* If we're optimising for StrongARM the resulting code won't 
	   run on an ARM7 and we can save a couple of instructions.  
								--pb */
#ifdef CONFIG_CPU_ARM710
#define A710(code...) code
.Larm710bug:
	ldmia	sp, {r0 - lr}^			@ Get calling r0 - lr
	mov	r0, r0
	add	sp, sp, #S_FRAME_SIZE
	subs	pc, lr, #4
#else
#define A710(code...)
#endif

	.align	5
ENTRY(vector_swi)
	sub	sp, sp, #S_FRAME_SIZE
	stmia	sp, {r0 - r12}			@ Calling r0 - r12
 ARM(	add	r8, sp, #S_PC		)
 ARM(	stmdb	r8, {sp, lr}^		)	@ Calling sp, lr
 THUMB(	mov	r8, sp			)
 THUMB(	store_user_sp_lr r8, r10, S_SP	)	@ calling sp, lr
	mrs	r8, spsr			@ called from non-FIQ mode, so ok.
	str	lr, [sp, #S_PC]			@ Save calling PC
	str	r8, [sp, #S_PSR]		@ Save CPSR
	str	r0, [sp, #S_OLD_R0]		@ Save OLD_R0
	zero_fp

	/*
	 * Get the system call number.
	 */

#if defined(CONFIG_OABI_COMPAT)

	/*
	 * If we have CONFIG_OABI_COMPAT then we need to look at the swi
	 * value to determine if it is an EABI or an old ABI call.
	 */
#ifdef CONFIG_ARM_THUMB
	tst	r8, #PSR_T_BIT
	movne	r10, #0				@ no thumb OABI emulation
	ldreq	r10, [lr, #-4]			@ get SWI instruction
#else
	ldr	r10, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, r10, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)
#endif
#ifdef CONFIG_CPU_ENDIAN_BE8
	rev	r10, r10			@ little endian instruction
#endif

#elif defined(CONFIG_AEABI)

	/*
	 * Pure EABI user space always put syscall number into scno (r7).
	 */
  A710(	ldr	ip, [lr, #-4]			@ get SWI instruction	)
  A710(	and	ip, ip, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#elif defined(CONFIG_ARM_THUMB)

	/* Legacy ABI only, possibly thumb mode. */
	tst	r8, #PSR_T_BIT			@ this is SPSR from save_user_regs
	addne	scno, r7, #__NR_SYSCALL_BASE	@ put OS number in
	ldreq	scno, [lr, #-4]

#else

	/* Legacy ABI only. */
	ldr	scno, [lr, #-4]			@ get SWI instruction
  A710(	and	ip, scno, #0x0f000000		@ check for SWI		)
  A710(	teq	ip, #0x0f000000						)
  A710(	bne	.Larm710bug						)

#endif

#ifdef CONFIG_ALIGNMENT_TRAP
	ldr	ip, __cr_alignment
	ldr	ip, [ip]
	mcr	p15, 0, ip, c1, c0		@ update control register
#endif
	enable_irq

	get_thread_info tsk
	adr	tbl, sys_call_table		@ load syscall table pointer
	ldr	ip, [tsk, #TI_FLAGS]		@ check for syscall tracing

#if defined(CONFIG_OABI_COMPAT)
	/*
	 * If the swi argument is zero, this is an EABI call and we do nothing.
	 *
	 * If this is an old ABI call, get the syscall number into scno and
	 * get the old ABI syscall table address.
	 */
	bics	r10, r10, #0xff000000
	eorne	scno, r10, #__NR_OABI_SYSCALL_BASE
	ldrne	tbl, =sys_oabi_call_table
#elif !defined(CONFIG_AEABI)
	bic	scno, scno, #0xff000000		@ mask off SWI op-code
	eor	scno, scno, #__NR_SYSCALL_BASE	@ check OS number
#endif

	stmdb	sp!, {r4, r5}			@ push fifth and sixth args
	tst	ip, #_TIF_SYSCALL_TRACE		@ are we tracing syscalls?
	bne	__sys_trace

	cmp	scno, #NR_syscalls		@ check upper syscall limit
	adr	lr, BSYM(ret_fast_syscall)	@ return address
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine

	add	r1, sp, #S_OFF
2:	mov	why, #0				@ no longer a real syscall
	cmp	scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
	eor	r0, scno, #__NR_SYSCALL_BASE	@ put OS number back
	bcs	arm_syscall	
	b	sys_ni_syscall			@ not private func
ENDPROC(vector_swi)

	/*
	 * This is the really slow path.  We're going to be doing
	 * context switches, and waiting for our parent to respond.
	 */
__sys_trace:
	mov	r2, scno
	add	r1, sp, #S_OFF
	mov	r0, #0				@ trace entry [IP = 0]
	bl	syscall_trace

	adr	lr, BSYM(__sys_trace_return)	@ return address
	mov	scno, r0			@ syscall number (possibly new)
	add	r1, sp, #S_R0 + S_OFF		@ pointer to regs
	cmp	scno, #NR_syscalls		@ check upper syscall limit
	ldmccia	r1, {r0 - r3}			@ have to reload r0 - r3
	ldrcc	pc, [tbl, scno, lsl #2]		@ call sys_* routine
	b	2b

__sys_trace_return:
	str	r0, [sp, #S_R0 + S_OFF]!	@ save returned r0
	mov	r2, scno
	mov	r1, sp
	mov	r0, #1				@ trace exit [IP = 1]
	bl	syscall_trace
	b	ret_slow_syscall

	.align	5
#ifdef CONFIG_ALIGNMENT_TRAP
	.type	__cr_alignment, #object
__cr_alignment:
	.word	cr_alignment
#endif
	.ltorg

/*
 * This is the syscall table declaration for native ABI syscalls.
 * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 */
#define ABI(native, compat) native
#ifdef CONFIG_AEABI
#define OBSOLETE(syscall) sys_ni_syscall
#else
#define OBSOLETE(syscall) syscall
#endif

	.type	sys_call_table, #object
ENTRY(sys_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

/*============================================================================
 * Special system call wrappers
 */
@ r0 = syscall number
@ r8 = syscall table
sys_syscall:
		bic	scno, r0, #__NR_OABI_SYSCALL_BASE
		cmp	scno, #__NR_syscall - __NR_SYSCALL_BASE
		cmpne	scno, #NR_syscalls	@ check range
		stmloia	sp, {r5, r6}		@ shuffle args
		movlo	r0, r1
		movlo	r1, r2
		movlo	r2, r3
		movlo	r3, r4
		ldrlo	pc, [tbl, scno, lsl #2]
		b	sys_ni_syscall
ENDPROC(sys_syscall)

sys_fork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_fork
ENDPROC(sys_fork_wrapper)

sys_vfork_wrapper:
		add	r0, sp, #S_OFF
		b	sys_vfork
ENDPROC(sys_vfork_wrapper)

sys_execve_wrapper:
		add	r3, sp, #S_OFF
		b	sys_execve
ENDPROC(sys_execve_wrapper)

sys_clone_wrapper:
		add	ip, sp, #S_OFF
		str	ip, [sp, #4]
		b	sys_clone
ENDPROC(sys_clone_wrapper)

sys_sigsuspend_wrapper:
		add	r3, sp, #S_OFF
		b	sys_sigsuspend
ENDPROC(sys_sigsuspend_wrapper)

sys_rt_sigsuspend_wrapper:
		add	r2, sp, #S_OFF
		b	sys_rt_sigsuspend
ENDPROC(sys_rt_sigsuspend_wrapper)

sys_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_sigreturn
ENDPROC(sys_sigreturn_wrapper)

sys_rt_sigreturn_wrapper:
		add	r0, sp, #S_OFF
		b	sys_rt_sigreturn
ENDPROC(sys_rt_sigreturn_wrapper)

sys_sigaltstack_wrapper:
		ldr	r2, [sp, #S_OFF + S_SP]
		b	do_sigaltstack
ENDPROC(sys_sigaltstack_wrapper)

sys_statfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_statfs64
ENDPROC(sys_statfs64_wrapper)

sys_fstatfs64_wrapper:
		teq	r1, #88
		moveq	r1, #84
		b	sys_fstatfs64
ENDPROC(sys_fstatfs64_wrapper)

/*
 * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 * offset, we return EINVAL.
 */
sys_mmap2:
#if PAGE_SHIFT > 12
		tst	r5, #PGOFF_MASK
		moveq	r5, r5, lsr #PAGE_SHIFT - 12
		streq	r5, [sp, #4]
		beq	do_mmap2
		mov	r0, #-EINVAL
		mov	pc, lr
#else
		str	r5, [sp, #4]
		b	do_mmap2
#endif
ENDPROC(sys_mmap2)

ENTRY(pabort_ifar)
		mrc	p15, 0, r0, cr6, cr0, 2
ENTRY(pabort_noifar)
		mov	pc, lr
ENDPROC(pabort_ifar)
ENDPROC(pabort_noifar)

#ifdef CONFIG_OABI_COMPAT

/*
 * These are syscalls with argument register differences
 */

sys_oabi_pread64:
		stmia	sp, {r3, r4}
		b	sys_pread64
ENDPROC(sys_oabi_pread64)

sys_oabi_pwrite64:
		stmia	sp, {r3, r4}
		b	sys_pwrite64
ENDPROC(sys_oabi_pwrite64)

sys_oabi_truncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_truncate64
ENDPROC(sys_oabi_truncate64)

sys_oabi_ftruncate64:
		mov	r3, r2
		mov	r2, r1
		b	sys_ftruncate64
ENDPROC(sys_oabi_ftruncate64)

sys_oabi_readahead:
		str	r3, [sp]
		mov	r3, r2
		mov	r2, r1
		b	sys_readahead
ENDPROC(sys_oabi_readahead)

/*
 * Let's declare a second syscall table for old ABI binaries
 * using the compatibility syscall entries.
 */
#define ABI(native, compat) compat
#define OBSOLETE(syscall) syscall

	.type	sys_oabi_call_table, #object
ENTRY(sys_oabi_call_table)
#include "calls.S"
#undef ABI
#undef OBSOLETE

#endif
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/kernel/entry-common.S
	3	*
	4	* Copyright (C) 2000 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
1da177e4	10
1da177e4	11	#include <asm/unistd.h>
395a59d0	12	#include <asm/ftrace.h>
a09e64fb	13	#include <mach/entry-macro.S>
c4c5716e	14	#include <asm/unwind.h>
1da177e4 LT	15
	16	#include "entry-header.S"
	17
1da177e4 LT	18
	19	.align 5
	20	/*
	21	* This is the fast syscall return path. We do as little as
	22	* possible here, and this includes saving r0 back into the SVC
	23	* stack.
	24	*/
	25	ret_fast_syscall:
c4c5716e CM	26	UNWIND(.fnstart )
c4c5716e CM	27	UNWIND(.cantunwind )
1ec42c0c	28	disable_irq @ disable interrupts
1da177e4 LT	29	ldr r1, [tsk, #TI_FLAGS]
	30	tst r1, #_TIF_WORK_MASK
	31	bne fast_work_pending
f4dc9a4c	32
f80dff9d DW	33	/* perform architecture specific actions before user return */
	34	arch_ret_to_user r1, lr
	35
b86040a5	36	restore_user_regs fast = 1, offset = S_OFF
c4c5716e	37	UNWIND(.fnend )
1da177e4 LT	38
	39	/*
	40	* Ok, we need to do extra processing, enter the slow path.
	41	*/
	42	fast_work_pending:
	43	str r0, [sp, #S_R0+S_OFF]! @ returned r0
	44	work_pending:
	45	tst r1, #_TIF_NEED_RESCHED
	46	bne work_resched
a583f1b5	47	tst r1, #_TIF_SIGPENDING
1da177e4 LT	48	beq no_work_pending
	49	mov r0, sp @ 'regs'
	50	mov r2, why @ 'syscall'
	51	bl do_notify_resume
a6c61e9d	52	b ret_slow_syscall @ Check work again
1da177e4 LT	53
	54	work_resched:
	55	bl schedule
	56	/*
	57	* "slow" syscall return path. "why" tells us if this was a real syscall.
	58	*/
	59	ENTRY(ret_to_user)
	60	ret_slow_syscall:
1ec42c0c	61	disable_irq @ disable interrupts
1da177e4 LT	62	ldr r1, [tsk, #TI_FLAGS]
	63	tst r1, #_TIF_WORK_MASK
	64	bne work_pending
	65	no_work_pending:
f80dff9d DW	66	/* perform architecture specific actions before user return */
	67	arch_ret_to_user r1, lr
	68
b86040a5	69	restore_user_regs fast = 0, offset = 0
93ed3970	70	ENDPROC(ret_to_user)
1da177e4 LT	71
	72	/*
	73	* This is how we return from a fork.
	74	*/
	75	ENTRY(ret_from_fork)
	76	bl schedule_tail
	77	get_thread_info tsk
	78	ldr r1, [tsk, #TI_FLAGS] @ check for syscall tracing
	79	mov why, #1
	80	tst r1, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	81	beq ret_slow_syscall
	82	mov r1, sp
	83	mov r0, #1 @ trace exit [IP = 1]
	84	bl syscall_trace
	85	b ret_slow_syscall
93ed3970	86	ENDPROC(ret_from_fork)
1da177e4	87
fa1b4f91 AV	88	.equ NR_syscalls,0
fa1b4f91 AV	89	#define CALL(x) .equ NR_syscalls,NR_syscalls+1
1da177e4	90	#include "calls.S"
fa1b4f91 AV	91	#undef CALL
fa1b4f91 AV	92	#define CALL(x) .long x
1da177e4	93
606576ce	94	#ifdef CONFIG_FUNCTION_TRACER
014c257c AS	95	#ifdef CONFIG_DYNAMIC_FTRACE
	96	ENTRY(mcount)
	97	stmdb sp!, {r0-r3, lr}
	98	mov r0, lr
395a59d0	99	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	100
	101	.globl mcount_call
	102	mcount_call:
	103	bl ftrace_stub
d4cc510c	104	ldr lr, [fp, #-4] @ restore lr
014c257c AS	105	ldmia sp!, {r0-r3, pc}
	106
	107	ENTRY(ftrace_caller)
	108	stmdb sp!, {r0-r3, lr}
	109	ldr r1, [fp, #-4]
	110	mov r0, lr
395a59d0	111	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	112
	113	.globl ftrace_call
	114	ftrace_call:
	115	bl ftrace_stub
d4cc510c	116	ldr lr, [fp, #-4] @ restore lr
014c257c AS	117	ldmia sp!, {r0-r3, pc}
	118
	119	#else
	120
	121	ENTRY(mcount)
	122	stmdb sp!, {r0-r3, lr}
	123	ldr r0, =ftrace_trace_function
	124	ldr r2, [r0]
	125	adr r0, ftrace_stub
	126	cmp r0, r2
	127	bne trace
d4cc510c	128	ldr lr, [fp, #-4] @ restore lr
014c257c AS	129	ldmia sp!, {r0-r3, pc}
	130
	131	trace:
b3c960b2	132	ldr r1, [fp, #-4] @ lr of instrumented routine
014c257c	133	mov r0, lr
395a59d0	134	sub r0, r0, #MCOUNT_INSN_SIZE
014c257c AS	135	mov lr, pc
014c257c AS	136	mov pc, r2
d4cc510c	137	mov lr, r1 @ restore lr
014c257c AS	138	ldmia sp!, {r0-r3, pc}
	139
	140	#endif /* CONFIG_DYNAMIC_FTRACE */
	141
	142	.globl ftrace_stub
	143	ftrace_stub:
	144	mov pc, lr
	145
606576ce	146	#endif /* CONFIG_FUNCTION_TRACER */
014c257c	147
1da177e4 LT	148	/*=============================================================================
	149	* SWI handler
	150	*-----------------------------------------------------------------------------
	151	*/
	152
	153	/* If we're optimising for StrongARM the resulting code won't
	154	run on an ARM7 and we can save a couple of instructions.
	155	--pb */
	156	#ifdef CONFIG_CPU_ARM710
3f2829a3 NP	157	#define A710(code...) code
3f2829a3 NP	158	.Larm710bug:
1da177e4 LT	159	ldmia sp, {r0 - lr}^ @ Get calling r0 - lr
1da177e4 LT	160	mov r0, r0
1da177e4	161	add sp, sp, #S_FRAME_SIZE
60ac133a	162	subs pc, lr, #4
1da177e4	163	#else
3f2829a3	164	#define A710(code...)
1da177e4 LT	165	#endif
	166
	167	.align 5
	168	ENTRY(vector_swi)
f4dc9a4c RK	169	sub sp, sp, #S_FRAME_SIZE
f4dc9a4c RK	170	stmia sp, {r0 - r12} @ Calling r0 - r12
b86040a5 CM	171	ARM( add r8, sp, #S_PC )
	172	ARM( stmdb r8, {sp, lr}^ ) @ Calling sp, lr
	173	THUMB( mov r8, sp )
	174	THUMB( store_user_sp_lr r8, r10, S_SP ) @ calling sp, lr
f4dc9a4c RK	175	mrs r8, spsr @ called from non-FIQ mode, so ok.
	176	str lr, [sp, #S_PC] @ Save calling PC
	177	str r8, [sp, #S_PSR] @ Save CPSR
	178	str r0, [sp, #S_OLD_R0] @ Save OLD_R0
1da177e4	179	zero_fp
e0f9f4a6 RK	180
	181	/*
	182	* Get the system call number.
	183	*/
3f2829a3	184
dd35afc2	185	#if defined(CONFIG_OABI_COMPAT)
3f2829a3	186
dd35afc2 NP	187	/*
	188	* If we have CONFIG_OABI_COMPAT then we need to look at the swi
	189	* value to determine if it is an EABI or an old ABI call.
	190	*/
	191	#ifdef CONFIG_ARM_THUMB
	192	tst r8, #PSR_T_BIT
	193	movne r10, #0 @ no thumb OABI emulation
	194	ldreq r10, [lr, #-4] @ get SWI instruction
	195	#else
	196	ldr r10, [lr, #-4] @ get SWI instruction
	197	A710( and ip, r10, #0x0f000000 @ check for SWI )
	198	A710( teq ip, #0x0f000000 )
	199	A710( bne .Larm710bug )
	200	#endif
26584853 CM	201	#ifdef CONFIG_CPU_ENDIAN_BE8
	202	rev r10, r10 @ little endian instruction
	203	#endif
dd35afc2 NP	204
	205	#elif defined(CONFIG_AEABI)
	206
	207	/*
	208	* Pure EABI user space always put syscall number into scno (r7).
	209	*/
3f2829a3 NP	210	A710( ldr ip, [lr, #-4] @ get SWI instruction )
	211	A710( and ip, ip, #0x0f000000 @ check for SWI )
	212	A710( teq ip, #0x0f000000 )
	213	A710( bne .Larm710bug )
dd35afc2	214
3f2829a3	215	#elif defined(CONFIG_ARM_THUMB)
dd35afc2 NP	216
dd35afc2 NP	217	/* Legacy ABI only, possibly thumb mode. */
e0f9f4a6 RK	218	tst r8, #PSR_T_BIT @ this is SPSR from save_user_regs
	219	addne scno, r7, #__NR_SYSCALL_BASE @ put OS number in
	220	ldreq scno, [lr, #-4]
dd35afc2	221
e0f9f4a6	222	#else
dd35afc2 NP	223
dd35afc2 NP	224	/* Legacy ABI only. */
e0f9f4a6	225	ldr scno, [lr, #-4] @ get SWI instruction
3f2829a3 NP	226	A710( and ip, scno, #0x0f000000 @ check for SWI )
	227	A710( teq ip, #0x0f000000 )
	228	A710( bne .Larm710bug )
dd35afc2	229
e0f9f4a6	230	#endif
1da177e4 LT	231
	232	#ifdef CONFIG_ALIGNMENT_TRAP
	233	ldr ip, __cr_alignment
	234	ldr ip, [ip]
	235	mcr p15, 0, ip, c1, c0 @ update control register
	236	#endif
1ec42c0c	237	enable_irq
1da177e4	238
1da177e4	239	get_thread_info tsk
dd35afc2	240	adr tbl, sys_call_table @ load syscall table pointer
1da177e4	241	ldr ip, [tsk, #TI_FLAGS] @ check for syscall tracing
dd35afc2 NP	242
	243	#if defined(CONFIG_OABI_COMPAT)
	244	/*
	245	* If the swi argument is zero, this is an EABI call and we do nothing.
	246	*
	247	* If this is an old ABI call, get the syscall number into scno and
	248	* get the old ABI syscall table address.
	249	*/
	250	bics r10, r10, #0xff000000
	251	eorne scno, r10, #__NR_OABI_SYSCALL_BASE
	252	ldrne tbl, =sys_oabi_call_table
	253	#elif !defined(CONFIG_AEABI)
1da177e4	254	bic scno, scno, #0xff000000 @ mask off SWI op-code
e0f9f4a6	255	eor scno, scno, #__NR_SYSCALL_BASE @ check OS number
3f2829a3	256	#endif
dd35afc2	257
3f2829a3	258	stmdb sp!, {r4, r5} @ push fifth and sixth args
1da177e4 LT	259	tst ip, #_TIF_SYSCALL_TRACE @ are we tracing syscalls?
	260	bne __sys_trace
	261
1da177e4	262	cmp scno, #NR_syscalls @ check upper syscall limit
b86040a5	263	adr lr, BSYM(ret_fast_syscall) @ return address
1da177e4 LT	264	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	265
	266	add r1, sp, #S_OFF
	267	2: mov why, #0 @ no longer a real syscall
e0f9f4a6 RK	268	cmp scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
e0f9f4a6 RK	269	eor r0, scno, #__NR_SYSCALL_BASE @ put OS number back
1da177e4 LT	270	bcs arm_syscall
1da177e4 LT	271	b sys_ni_syscall @ not private func
93ed3970	272	ENDPROC(vector_swi)
1da177e4 LT	273
	274	/*
	275	* This is the really slow path. We're going to be doing
	276	* context switches, and waiting for our parent to respond.
	277	*/
	278	__sys_trace:
3f471126	279	mov r2, scno
1da177e4 LT	280	add r1, sp, #S_OFF
	281	mov r0, #0 @ trace entry [IP = 0]
	282	bl syscall_trace
	283
b86040a5	284	adr lr, BSYM(__sys_trace_return) @ return address
3f471126	285	mov scno, r0 @ syscall number (possibly new)
1da177e4 LT	286	add r1, sp, #S_R0 + S_OFF @ pointer to regs
	287	cmp scno, #NR_syscalls @ check upper syscall limit
	288	ldmccia r1, {r0 - r3} @ have to reload r0 - r3
	289	ldrcc pc, [tbl, scno, lsl #2] @ call sys_* routine
	290	b 2b
	291
	292	__sys_trace_return:
	293	str r0, [sp, #S_R0 + S_OFF]! @ save returned r0
3f471126	294	mov r2, scno
1da177e4 LT	295	mov r1, sp
	296	mov r0, #1 @ trace exit [IP = 1]
	297	bl syscall_trace
	298	b ret_slow_syscall
	299
	300	.align 5
	301	#ifdef CONFIG_ALIGNMENT_TRAP
	302	.type __cr_alignment, #object
	303	__cr_alignment:
	304	.word cr_alignment
dd35afc2 NP	305	#endif
	306	.ltorg
	307
	308	/*
	309	* This is the syscall table declaration for native ABI syscalls.
	310	* With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
	311	*/
	312	#define ABI(native, compat) native
	313	#ifdef CONFIG_AEABI
	314	#define OBSOLETE(syscall) sys_ni_syscall
	315	#else
	316	#define OBSOLETE(syscall) syscall
1da177e4 LT	317	#endif
	318
	319	.type sys_call_table, #object
	320	ENTRY(sys_call_table)
	321	#include "calls.S"
dd35afc2 NP	322	#undef ABI
dd35afc2 NP	323	#undef OBSOLETE
1da177e4 LT	324
	325	/*============================================================================
	326	* Special system call wrappers
	327	*/
	328	@ r0 = syscall number
567bd980	329	@ r8 = syscall table
1da177e4	330	sys_syscall:
5247593c	331	bic scno, r0, #__NR_OABI_SYSCALL_BASE
1da177e4 LT	332	cmp scno, #__NR_syscall - __NR_SYSCALL_BASE
	333	cmpne scno, #NR_syscalls @ check range
	334	stmloia sp, {r5, r6} @ shuffle args
	335	movlo r0, r1
	336	movlo r1, r2
	337	movlo r2, r3
	338	movlo r3, r4
	339	ldrlo pc, [tbl, scno, lsl #2]
	340	b sys_ni_syscall
93ed3970	341	ENDPROC(sys_syscall)
1da177e4 LT	342
	343	sys_fork_wrapper:
	344	add r0, sp, #S_OFF
	345	b sys_fork
93ed3970	346	ENDPROC(sys_fork_wrapper)
1da177e4 LT	347
	348	sys_vfork_wrapper:
	349	add r0, sp, #S_OFF
	350	b sys_vfork
93ed3970	351	ENDPROC(sys_vfork_wrapper)
1da177e4 LT	352
	353	sys_execve_wrapper:
	354	add r3, sp, #S_OFF
	355	b sys_execve
93ed3970	356	ENDPROC(sys_execve_wrapper)
1da177e4 LT	357
	358	sys_clone_wrapper:
	359	add ip, sp, #S_OFF
	360	str ip, [sp, #4]
	361	b sys_clone
93ed3970	362	ENDPROC(sys_clone_wrapper)
1da177e4 LT	363
	364	sys_sigsuspend_wrapper:
	365	add r3, sp, #S_OFF
	366	b sys_sigsuspend
93ed3970	367	ENDPROC(sys_sigsuspend_wrapper)
1da177e4 LT	368
	369	sys_rt_sigsuspend_wrapper:
	370	add r2, sp, #S_OFF
	371	b sys_rt_sigsuspend
93ed3970	372	ENDPROC(sys_rt_sigsuspend_wrapper)
1da177e4 LT	373
	374	sys_sigreturn_wrapper:
	375	add r0, sp, #S_OFF
	376	b sys_sigreturn
93ed3970	377	ENDPROC(sys_sigreturn_wrapper)
1da177e4 LT	378
	379	sys_rt_sigreturn_wrapper:
	380	add r0, sp, #S_OFF
	381	b sys_rt_sigreturn
93ed3970	382	ENDPROC(sys_rt_sigreturn_wrapper)
1da177e4 LT	383
	384	sys_sigaltstack_wrapper:
	385	ldr r2, [sp, #S_OFF + S_SP]
	386	b do_sigaltstack
93ed3970	387	ENDPROC(sys_sigaltstack_wrapper)
1da177e4	388
713c4815 NP	389	sys_statfs64_wrapper:
	390	teq r1, #88
	391	moveq r1, #84
	392	b sys_statfs64
93ed3970	393	ENDPROC(sys_statfs64_wrapper)
713c4815 NP	394
	395	sys_fstatfs64_wrapper:
	396	teq r1, #88
	397	moveq r1, #84
	398	b sys_fstatfs64
93ed3970	399	ENDPROC(sys_fstatfs64_wrapper)
713c4815	400
1da177e4 LT	401	/*
	402	* Note: off_4k (r5) is always units of 4K. If we can't do the requested
	403	* offset, we return EINVAL.
	404	*/
	405	sys_mmap2:
	406	#if PAGE_SHIFT > 12
	407	tst r5, #PGOFF_MASK
	408	moveq r5, r5, lsr #PAGE_SHIFT - 12
	409	streq r5, [sp, #4]
	410	beq do_mmap2
	411	mov r0, #-EINVAL
7999d8d7	412	mov pc, lr
1da177e4 LT	413	#else
	414	str r5, [sp, #4]
	415	b do_mmap2
	416	#endif
93ed3970	417	ENDPROC(sys_mmap2)
687ad019	418
48d7927b PB	419	ENTRY(pabort_ifar)
	420	mrc p15, 0, r0, cr6, cr0, 2
	421	ENTRY(pabort_noifar)
	422	mov pc, lr
93ed3970 CM	423	ENDPROC(pabort_ifar)
93ed3970 CM	424	ENDPROC(pabort_noifar)
48d7927b	425
687ad019	426	#ifdef CONFIG_OABI_COMPAT
dd35afc2	427
687ad019 NP	428	/*
	429	* These are syscalls with argument register differences
	430	*/
	431
	432	sys_oabi_pread64:
	433	stmia sp, {r3, r4}
	434	b sys_pread64
93ed3970	435	ENDPROC(sys_oabi_pread64)
687ad019 NP	436
	437	sys_oabi_pwrite64:
	438	stmia sp, {r3, r4}
	439	b sys_pwrite64
93ed3970	440	ENDPROC(sys_oabi_pwrite64)
687ad019 NP	441
	442	sys_oabi_truncate64:
	443	mov r3, r2
	444	mov r2, r1
	445	b sys_truncate64
93ed3970	446	ENDPROC(sys_oabi_truncate64)
687ad019 NP	447
	448	sys_oabi_ftruncate64:
	449	mov r3, r2
	450	mov r2, r1
	451	b sys_ftruncate64
93ed3970	452	ENDPROC(sys_oabi_ftruncate64)
687ad019 NP	453
	454	sys_oabi_readahead:
	455	str r3, [sp]
	456	mov r3, r2
	457	mov r2, r1
	458	b sys_readahead
93ed3970	459	ENDPROC(sys_oabi_readahead)
687ad019	460
dd35afc2 NP	461	/*
	462	* Let's declare a second syscall table for old ABI binaries
	463	* using the compatibility syscall entries.
	464	*/
	465	#define ABI(native, compat) compat
	466	#define OBSOLETE(syscall) syscall
	467
	468	.type sys_oabi_call_table, #object
	469	ENTRY(sys_oabi_call_table)
	470	#include "calls.S"
	471	#undef ABI
	472	#undef OBSOLETE
	473
687ad019 NP	474	#endif
687ad019 NP	475