[deliverable/linux.git] / arch / arm / kernel / vmlinux.lds.S

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 */

#include <asm-generic/vmlinux.lds.h>
#include <linux/config.h>
#include <asm/thread_info.h>
#include <asm/memory.h>
	
OUTPUT_ARCH(arm)
ENTRY(stext)

#ifndef __ARMEB__
jiffies = jiffies_64;
#else
jiffies = jiffies_64 + 4;
#endif

SECTIONS
{
#ifdef CONFIG_XIP_KERNEL
	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
#else
	. = PAGE_OFFSET + TEXT_OFFSET;
#endif
	.init : {			/* Init code and data		*/
		_stext = .;
			_sinittext = .;
			*(.init.text)
			_einittext = .;
		__proc_info_begin = .;
			*(.proc.info.init)
		__proc_info_end = .;
		__arch_info_begin = .;
			*(.arch.info.init)
		__arch_info_end = .;
		__tagtable_begin = .;
			*(.taglist.init)
		__tagtable_end = .;
		. = ALIGN(16);
		__setup_start = .;
			*(.init.setup)
		__setup_end = .;
		__early_begin = .;
			*(.early_param.init)
		__early_end = .;
		__initcall_start = .;
			*(.initcall1.init)
			*(.initcall2.init)
			*(.initcall3.init)
			*(.initcall4.init)
			*(.initcall5.init)
			*(.initcall6.init)
			*(.initcall7.init)
		__initcall_end = .;
		__con_initcall_start = .;
			*(.con_initcall.init)
		__con_initcall_end = .;
		__security_initcall_start = .;
			*(.security_initcall.init)
		__security_initcall_end = .;
		. = ALIGN(32);
		__initramfs_start = .;
			usr/built-in.o(.init.ramfs)
		__initramfs_end = .;
		. = ALIGN(64);
		__per_cpu_start = .;
			*(.data.percpu)
		__per_cpu_end = .;
#ifndef CONFIG_XIP_KERNEL
		__init_begin = _stext;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif
	}

	/DISCARD/ : {			/* Exit code and data		*/
		*(.exit.text)
		*(.exit.data)
		*(.exitcall.exit)
	}

	.text : {			/* Real text segment		*/
		_text = .;		/* Text and read-only data	*/
			*(.text)
			SCHED_TEXT
			LOCK_TEXT
			*(.fixup)
			*(.gnu.warning)
			*(.rodata)
			*(.rodata.*)
			*(.glue_7)
			*(.glue_7t)
		*(.got)			/* Global offset table		*/
	}

	RODATA

	_etext = .;			/* End of text and rodata section */

#ifdef CONFIG_XIP_KERNEL
	__data_loc = ALIGN(4);		/* location in binary */
	. = PAGE_OFFSET + TEXT_OFFSET;
#else
	. = ALIGN(THREAD_SIZE);
	__data_loc = .;
#endif

	.data : AT(__data_loc) {
		__data_start = .;	/* address in memory */

		/*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary.
		 */
		*(.init.task)

#ifdef CONFIG_XIP_KERNEL
		. = ALIGN(4096);
		__init_begin = .;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif

		. = ALIGN(4096);
		__nosave_begin = .;
		*(.data.nosave)
		. = ALIGN(4096);
		__nosave_end = .;

		/*
		 * then the cacheline aligned data
		 */
		. = ALIGN(32);
		*(.data.cacheline_aligned)

		/*
		 * The exception fixup table (might need resorting at runtime)
		 */
		. = ALIGN(32);
		__start___ex_table = .;
		*(__ex_table)
		__stop___ex_table = .;

		/*
		 * and the usual data section
		 */
		*(.data)
		CONSTRUCTORS

		_edata = .;
	}

	.bss : {
		__bss_start = .;	/* BSS				*/
		*(.bss)
		*(COMMON)
		_end = .;
	}
					/* Stabs debugging sections.	*/
	.stab 0 : { *(.stab) }
	.stabstr 0 : { *(.stabstr) }
	.stab.excl 0 : { *(.stab.excl) }
	.stab.exclstr 0 : { *(.stab.exclstr) }
	.stab.index 0 : { *(.stab.index) }
	.stab.indexstr 0 : { *(.stab.indexstr) }
	.comment 0 : { *(.comment) }
}

/*
 * These must never be empty
 * If you have to comment these two assert statements out, your
 * binutils is too old (for other reasons as well)
 */
ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
Commit	Line	Data
1da177e4 LT	1	/* ld script to make ARM Linux kernel
	2	* taken from the i386 version by Russell King
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	4	*/
	5
	6	#include <asm-generic/vmlinux.lds.h>
	7	#include <linux/config.h>
4f7a1812	8	#include <asm/thread_info.h>
37d07b72	9	#include <asm/memory.h>
1da177e4 LT	10
	11	OUTPUT_ARCH(arm)
	12	ENTRY(stext)
37d07b72	13
1da177e4 LT	14	#ifndef __ARMEB__
	15	jiffies = jiffies_64;
	16	#else
	17	jiffies = jiffies_64 + 4;
	18	#endif
37d07b72	19
9d4f13e5 RK	20	SECTIONS
9d4f13e5 RK	21	{
37d07b72	22	#ifdef CONFIG_XIP_KERNEL
9d4f13e5	23	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
37d07b72	24	#else
9d4f13e5	25	. = PAGE_OFFSET + TEXT_OFFSET;
37d07b72	26	#endif
1da177e4 LT	27	.init : { /* Init code and data */
	28	_stext = .;
	29	_sinittext = .;
	30	*(.init.text)
	31	_einittext = .;
	32	__proc_info_begin = .;
02b7dd12	33	*(.proc.info.init)
1da177e4 LT	34	__proc_info_end = .;
1da177e4 LT	35	__arch_info_begin = .;
9d0fd1eb	36	*(.arch.info.init)
1da177e4 LT	37	__arch_info_end = .;
1da177e4 LT	38	__tagtable_begin = .;
9506057f	39	*(.taglist.init)
1da177e4 LT	40	__tagtable_end = .;
	41	. = ALIGN(16);
	42	__setup_start = .;
	43	*(.init.setup)
	44	__setup_end = .;
	45	__early_begin = .;
bfe6815e	46	*(.early_param.init)
1da177e4 LT	47	__early_end = .;
	48	__initcall_start = .;
	49	*(.initcall1.init)
	50	*(.initcall2.init)
	51	*(.initcall3.init)
	52	*(.initcall4.init)
	53	*(.initcall5.init)
	54	*(.initcall6.init)
	55	*(.initcall7.init)
	56	__initcall_end = .;
	57	__con_initcall_start = .;
	58	*(.con_initcall.init)
	59	__con_initcall_end = .;
	60	__security_initcall_start = .;
	61	*(.security_initcall.init)
	62	__security_initcall_end = .;
	63	. = ALIGN(32);
	64	__initramfs_start = .;
	65	usr/built-in.o(.init.ramfs)
	66	__initramfs_end = .;
	67	. = ALIGN(64);
	68	__per_cpu_start = .;
	69	*(.data.percpu)
	70	__per_cpu_end = .;
	71	#ifndef CONFIG_XIP_KERNEL
	72	__init_begin = _stext;
	73	*(.init.data)
	74	. = ALIGN(4096);
	75	__init_end = .;
	76	#endif
	77	}
	78
	79	/DISCARD/ : { /* Exit code and data */
	80	*(.exit.text)
	81	*(.exit.data)
	82	*(.exitcall.exit)
	83	}
	84
	85	.text : { /* Real text segment */
	86	_text = .; /* Text and read-only data */
	87	*(.text)
	88	SCHED_TEXT
	89	LOCK_TEXT
	90	*(.fixup)
	91	*(.gnu.warning)
	92	*(.rodata)
	93	(.rodata.)
	94	*(.glue_7)
	95	*(.glue_7t)
	96	(.got) / Global offset table */
	97	}
	98
1da177e4 LT	99	RODATA
	100
	101	_etext = .; /* End of text and rodata section */
	102
	103	#ifdef CONFIG_XIP_KERNEL
	104	__data_loc = ALIGN(4); /* location in binary */
9d4f13e5	105	. = PAGE_OFFSET + TEXT_OFFSET;
1da177e4	106	#else
4f7a1812	107	. = ALIGN(THREAD_SIZE);
1da177e4 LT	108	__data_loc = .;
	109	#endif
	110
	111	.data : AT(__data_loc) {
	112	__data_start = .; /* address in memory */
	113
	114	/*
	115	* first, the init task union, aligned
	116	* to an 8192 byte boundary.
	117	*/
	118	*(.init.task)
	119
	120	#ifdef CONFIG_XIP_KERNEL
	121	. = ALIGN(4096);
	122	__init_begin = .;
	123	*(.init.data)
	124	. = ALIGN(4096);
	125	__init_end = .;
	126	#endif
	127
	128	. = ALIGN(4096);
	129	__nosave_begin = .;
	130	*(.data.nosave)
	131	. = ALIGN(4096);
	132	__nosave_end = .;
	133
	134	/*
	135	* then the cacheline aligned data
	136	*/
	137	. = ALIGN(32);
	138	*(.data.cacheline_aligned)
	139
13b1f64c NP	140	/*
	141	* The exception fixup table (might need resorting at runtime)
	142	*/
	143	. = ALIGN(32);
	144	__start___ex_table = .;
	145	*(__ex_table)
	146	__stop___ex_table = .;
	147
1da177e4 LT	148	/*
	149	* and the usual data section
	150	*/
	151	*(.data)
	152	CONSTRUCTORS
	153
	154	_edata = .;
	155	}
	156
	157	.bss : {
	158	__bss_start = .; /* BSS */
	159	*(.bss)
	160	*(COMMON)
	161	_end = .;
	162	}
	163	/* Stabs debugging sections. */
	164	.stab 0 : { *(.stab) }
	165	.stabstr 0 : { *(.stabstr) }
	166	.stab.excl 0 : { *(.stab.excl) }
	167	.stab.exclstr 0 : { *(.stab.exclstr) }
	168	.stab.index 0 : { *(.stab.index) }
	169	.stab.indexstr 0 : { *(.stab.indexstr) }
	170	.comment 0 : { *(.comment) }
	171	}
	172
728f5c07 RK	173	/*
	174	* These must never be empty
	175	* If you have to comment these two assert statements out, your
	176	* binutils is too old (for other reasons as well)
	177	*/
1da177e4 LT	178	ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
1da177e4 LT	179	ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")