[deliverable/linux.git] / arch / arm / kernel / vmlinux.lds.S

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 */

#include <asm-generic/vmlinux.lds.h>
#include <asm/thread_info.h>
#include <asm/memory.h>
	
OUTPUT_ARCH(arm)
ENTRY(stext)

#ifndef __ARMEB__
jiffies = jiffies_64;
#else
jiffies = jiffies_64 + 4;
#endif

SECTIONS
{
#ifdef CONFIG_XIP_KERNEL
	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
#else
	. = PAGE_OFFSET + TEXT_OFFSET;
#endif
	.text.head : {
		_stext = .;
		_sinittext = .;
		*(.text.head)
	}

	.init : {			/* Init code and data		*/
			INIT_TEXT
		_einittext = .;
		__proc_info_begin = .;
			*(.proc.info.init)
		__proc_info_end = .;
		__arch_info_begin = .;
			*(.arch.info.init)
		__arch_info_end = .;
		__tagtable_begin = .;
			*(.taglist.init)
		__tagtable_end = .;
		. = ALIGN(16);
		__setup_start = .;
			*(.init.setup)
		__setup_end = .;
		__early_begin = .;
			*(.early_param.init)
		__early_end = .;
		__initcall_start = .;
			INITCALLS
		__initcall_end = .;
		__con_initcall_start = .;
			*(.con_initcall.init)
		__con_initcall_end = .;
		__security_initcall_start = .;
			*(.security_initcall.init)
		__security_initcall_end = .;
#ifdef CONFIG_BLK_DEV_INITRD
		. = ALIGN(32);
		__initramfs_start = .;
			usr/built-in.o(.init.ramfs)
		__initramfs_end = .;
#endif
		. = ALIGN(4096);
		__per_cpu_start = .;
			*(.data.percpu.page_aligned)
			*(.data.percpu)
			*(.data.percpu.shared_aligned)
		__per_cpu_end = .;
#ifndef CONFIG_XIP_KERNEL
		__init_begin = _stext;
		INIT_DATA
		. = ALIGN(4096);
		__init_end = .;
#endif
	}

	/DISCARD/ : {			/* Exit code and data		*/
		EXIT_TEXT
		EXIT_DATA
		*(.exitcall.exit)
#ifndef CONFIG_MMU
		*(.fixup)
		*(__ex_table)
#endif
	}

	.text : {			/* Real text segment		*/
		_text = .;		/* Text and read-only data	*/
			__exception_text_start = .;
			*(.exception.text)
			__exception_text_end = .;
			TEXT_TEXT
			SCHED_TEXT
			LOCK_TEXT
			KPROBES_TEXT
#ifdef CONFIG_MMU
			*(.fixup)
#endif
			*(.gnu.warning)
			*(.rodata)
			*(.rodata.*)
			*(.glue_7)
			*(.glue_7t)
		*(.got)			/* Global offset table		*/
	}

	RODATA

	_etext = .;			/* End of text and rodata section */

#ifdef CONFIG_XIP_KERNEL
	__data_loc = ALIGN(4);		/* location in binary */
	. = PAGE_OFFSET + TEXT_OFFSET;
#else
	. = ALIGN(THREAD_SIZE);
	__data_loc = .;
#endif

	.data : AT(__data_loc) {
		_data = .;		/* address in memory */

		/*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary.
		 */
		*(.data.init_task)

#ifdef CONFIG_XIP_KERNEL
		. = ALIGN(4096);
		__init_begin = .;
		INIT_DATA
		. = ALIGN(4096);
		__init_end = .;
#endif

		. = ALIGN(4096);
		__nosave_begin = .;
		*(.data.nosave)
		. = ALIGN(4096);
		__nosave_end = .;

		/*
		 * then the cacheline aligned data
		 */
		. = ALIGN(32);
		*(.data.cacheline_aligned)

		/*
		 * The exception fixup table (might need resorting at runtime)
		 */
		. = ALIGN(32);
		__start___ex_table = .;
#ifdef CONFIG_MMU
		*(__ex_table)
#endif
		__stop___ex_table = .;

		/*
		 * and the usual data section
		 */
		DATA_DATA
		CONSTRUCTORS

		_edata = .;
	}
	_edata_loc = __data_loc + SIZEOF(.data);

	.bss : {
		__bss_start = .;	/* BSS				*/
		*(.bss)
		*(COMMON)
		_end = .;
	}
					/* Stabs debugging sections.	*/
	.stab 0 : { *(.stab) }
	.stabstr 0 : { *(.stabstr) }
	.stab.excl 0 : { *(.stab.excl) }
	.stab.exclstr 0 : { *(.stab.exclstr) }
	.stab.index 0 : { *(.stab.index) }
	.stab.indexstr 0 : { *(.stab.indexstr) }
	.comment 0 : { *(.comment) }
}

/*
 * These must never be empty
 * If you have to comment these two assert statements out, your
 * binutils is too old (for other reasons as well)
 */
ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
Commit	Line	Data
1da177e4 LT	1	/* ld script to make ARM Linux kernel
	2	* taken from the i386 version by Russell King
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	4	*/
	5
	6	#include <asm-generic/vmlinux.lds.h>
4f7a1812	7	#include <asm/thread_info.h>
37d07b72	8	#include <asm/memory.h>
1da177e4 LT	9
	10	OUTPUT_ARCH(arm)
	11	ENTRY(stext)
37d07b72	12
1da177e4 LT	13	#ifndef __ARMEB__
	14	jiffies = jiffies_64;
	15	#else
	16	jiffies = jiffies_64 + 4;
	17	#endif
37d07b72	18
9d4f13e5 RK	19	SECTIONS
9d4f13e5 RK	20	{
37d07b72	21	#ifdef CONFIG_XIP_KERNEL
9d4f13e5	22	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
37d07b72	23	#else
9d4f13e5	24	. = PAGE_OFFSET + TEXT_OFFSET;
37d07b72	25	#endif
08fdffd4	26	.text.head : {
1da177e4	27	_stext = .;
08fdffd4 RK	28	_sinittext = .;
	29	*(.text.head)
	30	}
	31
	32	.init : { /* Init code and data */
01ba2bdc	33	INIT_TEXT
08fdffd4	34	_einittext = .;
1da177e4	35	__proc_info_begin = .;
02b7dd12	36	*(.proc.info.init)
1da177e4 LT	37	__proc_info_end = .;
1da177e4 LT	38	__arch_info_begin = .;
9d0fd1eb	39	*(.arch.info.init)
1da177e4 LT	40	__arch_info_end = .;
1da177e4 LT	41	__tagtable_begin = .;
9506057f	42	*(.taglist.init)
1da177e4 LT	43	__tagtable_end = .;
	44	. = ALIGN(16);
	45	__setup_start = .;
	46	*(.init.setup)
	47	__setup_end = .;
	48	__early_begin = .;
bfe6815e	49	*(.early_param.init)
1da177e4 LT	50	__early_end = .;
1da177e4 LT	51	__initcall_start = .;
61ce1efe	52	INITCALLS
1da177e4 LT	53	__initcall_end = .;
	54	__con_initcall_start = .;
	55	*(.con_initcall.init)
	56	__con_initcall_end = .;
	57	__security_initcall_start = .;
	58	*(.security_initcall.init)
	59	__security_initcall_end = .;
67d38229	60	#ifdef CONFIG_BLK_DEV_INITRD
1da177e4 LT	61	. = ALIGN(32);
	62	__initramfs_start = .;
	63	usr/built-in.o(.init.ramfs)
	64	__initramfs_end = .;
67d38229	65	#endif
b6e3590f	66	. = ALIGN(4096);
1da177e4	67	__per_cpu_start = .;
74e79045	68	*(.data.percpu.page_aligned)
1da177e4	69	*(.data.percpu)
5fb7dc37	70	*(.data.percpu.shared_aligned)
1da177e4 LT	71	__per_cpu_end = .;
	72	#ifndef CONFIG_XIP_KERNEL
	73	__init_begin = _stext;
01ba2bdc	74	INIT_DATA
1da177e4 LT	75	. = ALIGN(4096);
	76	__init_end = .;
	77	#endif
	78	}
	79
	80	/DISCARD/ : { /* Exit code and data */
01ba2bdc SR	81	EXIT_TEXT
01ba2bdc SR	82	EXIT_DATA
1da177e4	83	*(.exitcall.exit)
9641c7cc RK	84	#ifndef CONFIG_MMU
	85	*(.fixup)
	86	*(__ex_table)
	87	#endif
1da177e4 LT	88	}
	89
	90	.text : { /* Real text segment */
	91	_text = .; /* Text and read-only data */
7ab3f8d5 RK	92	__exception_text_start = .;
	93	*(.exception.text)
	94	__exception_text_end = .;
7664709b	95	TEXT_TEXT
1da177e4 LT	96	SCHED_TEXT
1da177e4 LT	97	LOCK_TEXT
785d3cd2	98	KPROBES_TEXT
9641c7cc	99	#ifdef CONFIG_MMU
1da177e4	100	*(.fixup)
9641c7cc	101	#endif
1da177e4 LT	102	*(.gnu.warning)
	103	*(.rodata)
	104	(.rodata.)
	105	*(.glue_7)
	106	*(.glue_7t)
	107	(.got) / Global offset table */
	108	}
	109
1da177e4 LT	110	RODATA
	111
	112	_etext = .; /* End of text and rodata section */
	113
	114	#ifdef CONFIG_XIP_KERNEL
	115	__data_loc = ALIGN(4); /* location in binary */
9d4f13e5	116	. = PAGE_OFFSET + TEXT_OFFSET;
1da177e4	117	#else
4f7a1812	118	. = ALIGN(THREAD_SIZE);
1da177e4 LT	119	__data_loc = .;
	120	#endif
	121
	122	.data : AT(__data_loc) {
37efe642	123	_data = .; /* address in memory */
1da177e4 LT	124
	125	/*
	126	* first, the init task union, aligned
	127	* to an 8192 byte boundary.
	128	*/
4efb4482	129	*(.data.init_task)
1da177e4 LT	130
	131	#ifdef CONFIG_XIP_KERNEL
	132	. = ALIGN(4096);
	133	__init_begin = .;
01ba2bdc	134	INIT_DATA
1da177e4 LT	135	. = ALIGN(4096);
	136	__init_end = .;
	137	#endif
	138
	139	. = ALIGN(4096);
	140	__nosave_begin = .;
	141	*(.data.nosave)
	142	. = ALIGN(4096);
	143	__nosave_end = .;
	144
	145	/*
	146	* then the cacheline aligned data
	147	*/
	148	. = ALIGN(32);
	149	*(.data.cacheline_aligned)
	150
13b1f64c NP	151	/*
	152	* The exception fixup table (might need resorting at runtime)
	153	*/
	154	. = ALIGN(32);
	155	__start___ex_table = .;
9641c7cc	156	#ifdef CONFIG_MMU
13b1f64c	157	*(__ex_table)
9641c7cc	158	#endif
13b1f64c NP	159	__stop___ex_table = .;
13b1f64c NP	160
1da177e4 LT	161	/*
	162	* and the usual data section
	163	*/
ca967258	164	DATA_DATA
1da177e4 LT	165	CONSTRUCTORS
	166
	167	_edata = .;
	168	}
e98ff7f6	169	_edata_loc = __data_loc + SIZEOF(.data);
1da177e4 LT	170
	171	.bss : {
	172	__bss_start = .; /* BSS */
	173	*(.bss)
	174	*(COMMON)
	175	_end = .;
	176	}
	177	/* Stabs debugging sections. */
	178	.stab 0 : { *(.stab) }
	179	.stabstr 0 : { *(.stabstr) }
	180	.stab.excl 0 : { *(.stab.excl) }
	181	.stab.exclstr 0 : { *(.stab.exclstr) }
	182	.stab.index 0 : { *(.stab.index) }
	183	.stab.indexstr 0 : { *(.stab.indexstr) }
	184	.comment 0 : { *(.comment) }
	185	}
	186
728f5c07 RK	187	/*
	188	* These must never be empty
	189	* If you have to comment these two assert statements out, your
	190	* binutils is too old (for other reasons as well)
	191	*/
1da177e4 LT	192	ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
1da177e4 LT	193	ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")