[deliverable/linux.git] / arch / arm / kernel / vmlinux.lds.S

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
 */

#include <asm-generic/vmlinux.lds.h>
#include <asm/thread_info.h>
#include <asm/memory.h>
	
OUTPUT_ARCH(arm)
ENTRY(stext)

#ifndef __ARMEB__
jiffies = jiffies_64;
#else
jiffies = jiffies_64 + 4;
#endif

SECTIONS
{
#ifdef CONFIG_XIP_KERNEL
	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
#else
	. = PAGE_OFFSET + TEXT_OFFSET;
#endif
	.init : {			/* Init code and data		*/
		_stext = .;
			_sinittext = .;
			*(.init.text)
			_einittext = .;
		__proc_info_begin = .;
			*(.proc.info.init)
		__proc_info_end = .;
		__arch_info_begin = .;
			*(.arch.info.init)
		__arch_info_end = .;
		__tagtable_begin = .;
			*(.taglist.init)
		__tagtable_end = .;
		. = ALIGN(16);
		__setup_start = .;
			*(.init.setup)
		__setup_end = .;
		__early_begin = .;
			*(.early_param.init)
		__early_end = .;
		__initcall_start = .;
			INITCALLS
		__initcall_end = .;
		__con_initcall_start = .;
			*(.con_initcall.init)
		__con_initcall_end = .;
		__security_initcall_start = .;
			*(.security_initcall.init)
		__security_initcall_end = .;
#ifdef CONFIG_BLK_DEV_INITRD
		. = ALIGN(32);
		__initramfs_start = .;
			usr/built-in.o(.init.ramfs)
		__initramfs_end = .;
#endif
		. = ALIGN(64);
		__per_cpu_start = .;
			*(.data.percpu)
		__per_cpu_end = .;
#ifndef CONFIG_XIP_KERNEL
		__init_begin = _stext;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif
	}

	/DISCARD/ : {			/* Exit code and data		*/
		*(.exit.text)
		*(.exit.data)
		*(.exitcall.exit)
#ifndef CONFIG_MMU
		*(.fixup)
		*(__ex_table)
#endif
	}

	.text : {			/* Real text segment		*/
		_text = .;		/* Text and read-only data	*/
			*(.text)
			SCHED_TEXT
			LOCK_TEXT
#ifdef CONFIG_MMU
			*(.fixup)
#endif
			*(.gnu.warning)
			*(.rodata)
			*(.rodata.*)
			*(.glue_7)
			*(.glue_7t)
		*(.got)			/* Global offset table		*/
	}

	RODATA

	_etext = .;			/* End of text and rodata section */

#ifdef CONFIG_XIP_KERNEL
	__data_loc = ALIGN(4);		/* location in binary */
	. = PAGE_OFFSET + TEXT_OFFSET;
#else
	. = ALIGN(THREAD_SIZE);
	__data_loc = .;
#endif

	.data : AT(__data_loc) {
		__data_start = .;	/* address in memory */

		/*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary.
		 */
		*(.init.task)

#ifdef CONFIG_XIP_KERNEL
		. = ALIGN(4096);
		__init_begin = .;
		*(.init.data)
		. = ALIGN(4096);
		__init_end = .;
#endif

		. = ALIGN(4096);
		__nosave_begin = .;
		*(.data.nosave)
		. = ALIGN(4096);
		__nosave_end = .;

		/*
		 * then the cacheline aligned data
		 */
		. = ALIGN(32);
		*(.data.cacheline_aligned)

		/*
		 * The exception fixup table (might need resorting at runtime)
		 */
		. = ALIGN(32);
		__start___ex_table = .;
#ifdef CONFIG_MMU
		*(__ex_table)
#endif
		__stop___ex_table = .;

		/*
		 * and the usual data section
		 */
		*(.data)
		CONSTRUCTORS

		_edata = .;
	}
	_edata_loc = __data_loc + SIZEOF(.data);

	.bss : {
		__bss_start = .;	/* BSS				*/
		*(.bss)
		*(COMMON)
		_end = .;
	}
					/* Stabs debugging sections.	*/
	.stab 0 : { *(.stab) }
	.stabstr 0 : { *(.stabstr) }
	.stab.excl 0 : { *(.stab.excl) }
	.stab.exclstr 0 : { *(.stab.exclstr) }
	.stab.index 0 : { *(.stab.index) }
	.stab.indexstr 0 : { *(.stab.indexstr) }
	.comment 0 : { *(.comment) }
}

/*
 * These must never be empty
 * If you have to comment these two assert statements out, your
 * binutils is too old (for other reasons as well)
 */
ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
Commit	Line	Data
1da177e4 LT	1	/* ld script to make ARM Linux kernel
	2	* taken from the i386 version by Russell King
	3	* Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
	4	*/
	5
	6	#include <asm-generic/vmlinux.lds.h>
4f7a1812	7	#include <asm/thread_info.h>
37d07b72	8	#include <asm/memory.h>
1da177e4 LT	9
	10	OUTPUT_ARCH(arm)
	11	ENTRY(stext)
37d07b72	12
1da177e4 LT	13	#ifndef __ARMEB__
	14	jiffies = jiffies_64;
	15	#else
	16	jiffies = jiffies_64 + 4;
	17	#endif
37d07b72	18
9d4f13e5 RK	19	SECTIONS
9d4f13e5 RK	20	{
37d07b72	21	#ifdef CONFIG_XIP_KERNEL
9d4f13e5	22	. = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
37d07b72	23	#else
9d4f13e5	24	. = PAGE_OFFSET + TEXT_OFFSET;
37d07b72	25	#endif
1da177e4 LT	26	.init : { /* Init code and data */
	27	_stext = .;
	28	_sinittext = .;
	29	*(.init.text)
	30	_einittext = .;
	31	__proc_info_begin = .;
02b7dd12	32	*(.proc.info.init)
1da177e4 LT	33	__proc_info_end = .;
1da177e4 LT	34	__arch_info_begin = .;
9d0fd1eb	35	*(.arch.info.init)
1da177e4 LT	36	__arch_info_end = .;
1da177e4 LT	37	__tagtable_begin = .;
9506057f	38	*(.taglist.init)
1da177e4 LT	39	__tagtable_end = .;
	40	. = ALIGN(16);
	41	__setup_start = .;
	42	*(.init.setup)
	43	__setup_end = .;
	44	__early_begin = .;
bfe6815e	45	*(.early_param.init)
1da177e4 LT	46	__early_end = .;
1da177e4 LT	47	__initcall_start = .;
61ce1efe	48	INITCALLS
1da177e4 LT	49	__initcall_end = .;
	50	__con_initcall_start = .;
	51	*(.con_initcall.init)
	52	__con_initcall_end = .;
	53	__security_initcall_start = .;
	54	*(.security_initcall.init)
	55	__security_initcall_end = .;
67d38229	56	#ifdef CONFIG_BLK_DEV_INITRD
1da177e4 LT	57	. = ALIGN(32);
	58	__initramfs_start = .;
	59	usr/built-in.o(.init.ramfs)
	60	__initramfs_end = .;
67d38229	61	#endif
1da177e4 LT	62	. = ALIGN(64);
	63	__per_cpu_start = .;
	64	*(.data.percpu)
	65	__per_cpu_end = .;
	66	#ifndef CONFIG_XIP_KERNEL
	67	__init_begin = _stext;
	68	*(.init.data)
	69	. = ALIGN(4096);
	70	__init_end = .;
	71	#endif
	72	}
	73
	74	/DISCARD/ : { /* Exit code and data */
	75	*(.exit.text)
	76	*(.exit.data)
	77	*(.exitcall.exit)
9641c7cc RK	78	#ifndef CONFIG_MMU
	79	*(.fixup)
	80	*(__ex_table)
	81	#endif
1da177e4 LT	82	}
	83
	84	.text : { /* Real text segment */
	85	_text = .; /* Text and read-only data */
	86	*(.text)
	87	SCHED_TEXT
	88	LOCK_TEXT
9641c7cc	89	#ifdef CONFIG_MMU
1da177e4	90	*(.fixup)
9641c7cc	91	#endif
1da177e4 LT	92	*(.gnu.warning)
	93	*(.rodata)
	94	(.rodata.)
	95	*(.glue_7)
	96	*(.glue_7t)
	97	(.got) / Global offset table */
	98	}
	99
1da177e4 LT	100	RODATA
	101
	102	_etext = .; /* End of text and rodata section */
	103
	104	#ifdef CONFIG_XIP_KERNEL
	105	__data_loc = ALIGN(4); /* location in binary */
9d4f13e5	106	. = PAGE_OFFSET + TEXT_OFFSET;
1da177e4	107	#else
4f7a1812	108	. = ALIGN(THREAD_SIZE);
1da177e4 LT	109	__data_loc = .;
	110	#endif
	111
	112	.data : AT(__data_loc) {
	113	__data_start = .; /* address in memory */
	114
	115	/*
	116	* first, the init task union, aligned
	117	* to an 8192 byte boundary.
	118	*/
	119	*(.init.task)
	120
	121	#ifdef CONFIG_XIP_KERNEL
	122	. = ALIGN(4096);
	123	__init_begin = .;
	124	*(.init.data)
	125	. = ALIGN(4096);
	126	__init_end = .;
	127	#endif
	128
	129	. = ALIGN(4096);
	130	__nosave_begin = .;
	131	*(.data.nosave)
	132	. = ALIGN(4096);
	133	__nosave_end = .;
	134
	135	/*
	136	* then the cacheline aligned data
	137	*/
	138	. = ALIGN(32);
	139	*(.data.cacheline_aligned)
	140
13b1f64c NP	141	/*
	142	* The exception fixup table (might need resorting at runtime)
	143	*/
	144	. = ALIGN(32);
	145	__start___ex_table = .;
9641c7cc	146	#ifdef CONFIG_MMU
13b1f64c	147	*(__ex_table)
9641c7cc	148	#endif
13b1f64c NP	149	__stop___ex_table = .;
13b1f64c NP	150
1da177e4 LT	151	/*
	152	* and the usual data section
	153	*/
	154	*(.data)
	155	CONSTRUCTORS
	156
	157	_edata = .;
	158	}
e98ff7f6	159	_edata_loc = __data_loc + SIZEOF(.data);
1da177e4 LT	160
	161	.bss : {
	162	__bss_start = .; /* BSS */
	163	*(.bss)
	164	*(COMMON)
	165	_end = .;
	166	}
	167	/* Stabs debugging sections. */
	168	.stab 0 : { *(.stab) }
	169	.stabstr 0 : { *(.stabstr) }
	170	.stab.excl 0 : { *(.stab.excl) }
	171	.stab.exclstr 0 : { *(.stab.exclstr) }
	172	.stab.index 0 : { *(.stab.index) }
	173	.stab.indexstr 0 : { *(.stab.indexstr) }
	174	.comment 0 : { *(.comment) }
	175	}
	176
728f5c07 RK	177	/*
	178	* These must never be empty
	179	* If you have to comment these two assert statements out, your
	180	* binutils is too old (for other reasons as well)
	181	*/
1da177e4 LT	182	ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
1da177e4 LT	183	ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")