[deliverable/linux.git] / arch / arm / lib / csumpartial.S

/*
 *  linux/arch/arm/lib/csumpartial.S
 *
 *  Copyright (C) 1995-1998 Russell King
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License version 2 as
 * published by the Free Software Foundation.
 */
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <asm/export.h>

		.text

/*
 * Function: __u32 csum_partial(const char *src, int len, __u32 sum)
 * Params  : r0 = buffer, r1 = len, r2 = checksum
 * Returns : r0 = new checksum
 */

buf	.req	r0
len	.req	r1
sum	.req	r2
td0	.req	r3
td1	.req	r4	@ save before use
td2	.req	r5	@ save before use
td3	.req	lr

.Lzero:		mov	r0, sum
		add	sp, sp, #4
		ldr	pc, [sp], #4

		/*
		 * Handle 0 to 7 bytes, with any alignment of source and
		 * destination pointers.  Note that when we get here, C = 0
		 */
.Lless8:		teq	len, #0			@ check for zero count
		beq	.Lzero

		/* we must have at least one byte. */
		tst	buf, #1			@ odd address?
		movne	sum, sum, ror #8
		ldrneb	td0, [buf], #1
		subne	len, len, #1
		adcnes	sum, sum, td0, put_byte_1

.Lless4:		tst	len, #6
		beq	.Lless8_byte

		/* we are now half-word aligned */

.Lless8_wordlp:
#if __LINUX_ARM_ARCH__ >= 4
		ldrh	td0, [buf], #2
		sub	len, len, #2
#else
		ldrb	td0, [buf], #1
		ldrb	td3, [buf], #1
		sub	len, len, #2
#ifndef __ARMEB__
		orr	td0, td0, td3, lsl #8
#else
		orr	td0, td3, td0, lsl #8
#endif
#endif
		adcs	sum, sum, td0
		tst	len, #6
		bne	.Lless8_wordlp

.Lless8_byte:	tst	len, #1			@ odd number of bytes
		ldrneb	td0, [buf], #1		@ include last byte
		adcnes	sum, sum, td0, put_byte_0	@ update checksum

.Ldone:		adc	r0, sum, #0		@ collect up the last carry
		ldr	td0, [sp], #4
		tst	td0, #1			@ check buffer alignment
		movne	r0, r0, ror #8		@ rotate checksum by 8 bits
		ldr	pc, [sp], #4		@ return

.Lnot_aligned:	tst	buf, #1			@ odd address
		ldrneb	td0, [buf], #1		@ make even
		subne	len, len, #1
		adcnes	sum, sum, td0, put_byte_1	@ update checksum

		tst	buf, #2			@ 32-bit aligned?
#if __LINUX_ARM_ARCH__ >= 4
		ldrneh	td0, [buf], #2		@ make 32-bit aligned
		subne	len, len, #2
#else
		ldrneb	td0, [buf], #1
		ldrneb	ip, [buf], #1
		subne	len, len, #2
#ifndef __ARMEB__
		orrne	td0, td0, ip, lsl #8
#else
		orrne	td0, ip, td0, lsl #8
#endif
#endif
		adcnes	sum, sum, td0		@ update checksum
		ret	lr

ENTRY(csum_partial)
		stmfd	sp!, {buf, lr}
		cmp	len, #8			@ Ensure that we have at least
		blo	.Lless8			@ 8 bytes to copy.

		tst	buf, #1
		movne	sum, sum, ror #8

		adds	sum, sum, #0		@ C = 0
		tst	buf, #3			@ Test destination alignment
		blne	.Lnot_aligned		@ align destination, return here

1:		bics	ip, len, #31
		beq	3f

		stmfd	sp!, {r4 - r5}
2:		ldmia	buf!, {td0, td1, td2, td3}
		adcs	sum, sum, td0
		adcs	sum, sum, td1
		adcs	sum, sum, td2
		adcs	sum, sum, td3
		ldmia	buf!, {td0, td1, td2, td3}
		adcs	sum, sum, td0
		adcs	sum, sum, td1
		adcs	sum, sum, td2
		adcs	sum, sum, td3
		sub	ip, ip, #32
		teq	ip, #0
		bne	2b
		ldmfd	sp!, {r4 - r5}

3:		tst	len, #0x1c		@ should not change C
		beq	.Lless4

4:		ldr	td0, [buf], #4
		sub	len, len, #4
		adcs	sum, sum, td0
		tst	len, #0x1c
		bne	4b
		b	.Lless4
ENDPROC(csum_partial)
EXPORT_SYMBOL(csum_partial)
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/arm/lib/csumpartial.S
	3	*
	4	* Copyright (C) 1995-1998 Russell King
	5	*
	6	* This program is free software; you can redistribute it and/or modify
	7	* it under the terms of the GNU General Public License version 2 as
	8	* published by the Free Software Foundation.
	9	*/
	10	#include <linux/linkage.h>
	11	#include <asm/assembler.h>
4dd1837d	12	#include <asm/export.h>
1da177e4 LT	13
	14	.text
	15
	16	/*
	17	* Function: __u32 csum_partial(const char *src, int len, __u32 sum)
	18	* Params : r0 = buffer, r1 = len, r2 = checksum
	19	* Returns : r0 = new checksum
	20	*/
	21
	22	buf .req r0
	23	len .req r1
	24	sum .req r2
	25	td0 .req r3
	26	td1 .req r4 @ save before use
	27	td2 .req r5 @ save before use
	28	td3 .req lr
	29
8adbb371	30	.Lzero: mov r0, sum
1da177e4 LT	31	add sp, sp, #4
	32	ldr pc, [sp], #4
	33
	34	/*
	35	* Handle 0 to 7 bytes, with any alignment of source and
	36	* destination pointers. Note that when we get here, C = 0
	37	*/
8adbb371 NP	38	.Lless8: teq len, #0 @ check for zero count
8adbb371 NP	39	beq .Lzero
1da177e4 LT	40
	41	/* we must have at least one byte. */
	42	tst buf, #1 @ odd address?
af36bef0	43	movne sum, sum, ror #8
1da177e4 LT	44	ldrneb td0, [buf], #1
	45	subne len, len, #1
	46	adcnes sum, sum, td0, put_byte_1
	47
8adbb371 NP	48	.Lless4: tst len, #6
8adbb371 NP	49	beq .Lless8_byte
1da177e4 LT	50
	51	/* we are now half-word aligned */
	52
8adbb371	53	.Lless8_wordlp:
1da177e4 LT	54	#if __LINUX_ARM_ARCH__ >= 4
	55	ldrh td0, [buf], #2
	56	sub len, len, #2
	57	#else
	58	ldrb td0, [buf], #1
	59	ldrb td3, [buf], #1
	60	sub len, len, #2
	61	#ifndef __ARMEB__
	62	orr td0, td0, td3, lsl #8
	63	#else
	64	orr td0, td3, td0, lsl #8
	65	#endif
	66	#endif
	67	adcs sum, sum, td0
	68	tst len, #6
8adbb371	69	bne .Lless8_wordlp
1da177e4	70
8adbb371	71	.Lless8_byte: tst len, #1 @ odd number of bytes
1da177e4 LT	72	ldrneb td0, [buf], #1 @ include last byte
	73	adcnes sum, sum, td0, put_byte_0 @ update checksum
	74
8adbb371	75	.Ldone: adc r0, sum, #0 @ collect up the last carry
1da177e4 LT	76	ldr td0, [sp], #4
	77	tst td0, #1 @ check buffer alignment
	78	movne r0, r0, ror #8 @ rotate checksum by 8 bits
	79	ldr pc, [sp], #4 @ return
	80
8adbb371	81	.Lnot_aligned: tst buf, #1 @ odd address
1da177e4 LT	82	ldrneb td0, [buf], #1 @ make even
	83	subne len, len, #1
	84	adcnes sum, sum, td0, put_byte_1 @ update checksum
	85
	86	tst buf, #2 @ 32-bit aligned?
	87	#if __LINUX_ARM_ARCH__ >= 4
	88	ldrneh td0, [buf], #2 @ make 32-bit aligned
	89	subne len, len, #2
	90	#else
	91	ldrneb td0, [buf], #1
	92	ldrneb ip, [buf], #1
	93	subne len, len, #2
	94	#ifndef __ARMEB__
	95	orrne td0, td0, ip, lsl #8
	96	#else
	97	orrne td0, ip, td0, lsl #8
	98	#endif
	99	#endif
	100	adcnes sum, sum, td0 @ update checksum
6ebbf2ce	101	ret lr
1da177e4 LT	102
	103	ENTRY(csum_partial)
	104	stmfd sp!, {buf, lr}
	105	cmp len, #8 @ Ensure that we have at least
8adbb371	106	blo .Lless8 @ 8 bytes to copy.
1da177e4	107
af36bef0 RK	108	tst buf, #1
	109	movne sum, sum, ror #8
	110
1da177e4 LT	111	adds sum, sum, #0 @ C = 0
1da177e4 LT	112	tst buf, #3 @ Test destination alignment
8adbb371	113	blne .Lnot_aligned @ align destination, return here
1da177e4 LT	114
	115	1: bics ip, len, #31
	116	beq 3f
	117
	118	stmfd sp!, {r4 - r5}
	119	2: ldmia buf!, {td0, td1, td2, td3}
	120	adcs sum, sum, td0
	121	adcs sum, sum, td1
	122	adcs sum, sum, td2
	123	adcs sum, sum, td3
	124	ldmia buf!, {td0, td1, td2, td3}
	125	adcs sum, sum, td0
	126	adcs sum, sum, td1
	127	adcs sum, sum, td2
	128	adcs sum, sum, td3
	129	sub ip, ip, #32
	130	teq ip, #0
	131	bne 2b
	132	ldmfd sp!, {r4 - r5}
	133
	134	3: tst len, #0x1c @ should not change C
8adbb371	135	beq .Lless4
1da177e4 LT	136
	137	4: ldr td0, [buf], #4
	138	sub len, len, #4
	139	adcs sum, sum, td0
	140	tst len, #0x1c
	141	bne 4b
8adbb371	142	b .Lless4
93ed3970	143	ENDPROC(csum_partial)
4dd1837d	144	EXPORT_SYMBOL(csum_partial)