[deliverable/linux.git] / arch / arm / mach-omap2 / sram242x.S

/*
 * linux/arch/arm/mach-omap2/sram242x.S
 *
 * Omap2 specific functions that need to be run in internal SRAM
 *
 * (C) Copyright 2004
 * Texas Instruments, <www.ti.com>
 * Richard Woodruff <r-woodruff2@ti.com>
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR /PURPOSE. See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 *
 * Richard Woodruff notes that any changes to this code must be carefully
 * audited and tested to ensure that they don't cause a TLB miss while
 * the SDRAM is inaccessible.  Such a situation will crash the system
 * since it will cause the ARM MMU to attempt to walk the page tables.
 * These crashes may be intermittent.
 */
#include <linux/linkage.h>
#include <asm/assembler.h>
#include <mach/io.h>
#include <mach/hardware.h>

#include "prm2xxx_3xxx.h"
#include "cm2xxx_3xxx.h"
#include "sdrc.h"

	.text

ENTRY(omap242x_sram_ddr_init)
	stmfd	sp!, {r0 - r12, lr}	@ save registers on stack

	mov	r12, r2			@ capture CS1 vs CS0
	mov	r8, r3			@ capture force parameter

	/* frequency shift down */
	ldr	r2, omap242x_sdi_cm_clksel2_pll	@ get address of dpllout reg
	mov	r3, #0x1		@ value for 1x operation
	str	r3, [r2]		@ go to L1-freq operation

	/* voltage shift down */
	mov r9, #0x1			@ set up for L1 voltage call
	bl voltage_shift		@ go drop voltage

	/* dll lock mode */
	ldr	r11, omap242x_sdi_sdrc_dlla_ctrl	@ addr of dlla ctrl
	ldr	r10, [r11]		@ get current val
	cmp	r12, #0x1		@ cs1 base (2422 es2.05/1)
	addeq	r11, r11, #0x8		@ if cs1 base, move to DLLB
	mvn	r9, #0x4		@ mask to get clear bit2
	and	r10, r10, r9		@ clear bit2 for lock mode.
	orr	r10, r10, #0x8		@ make sure DLL on (es2 bit pos)
	orr	r10, r10, #0x2		@ 90 degree phase for all below 133Mhz
	str	r10, [r11]		@ commit to DLLA_CTRL
	bl	i_dll_wait		@ wait for dll to lock

	/* get dll value */
	add	r11, r11, #0x4		@ get addr of status reg
	ldr	r10, [r11]		@ get locked value

	/* voltage shift up */
	mov r9, #0x0			@ shift back to L0-voltage
	bl voltage_shift		@ go raise voltage

	/* frequency shift up */
	mov	r3, #0x2		@ value for 2x operation
	str	r3, [r2]		@ go to L0-freq operation

	/* reset entry mode for dllctrl */
	sub	r11, r11, #0x4		@ move from status to ctrl
	cmp	r12, #0x1		@ normalize if cs1 based
	subeq	r11, r11, #0x8		@ possibly back to DLLA
	cmp	r8, #0x1		@ if forced unlock exit
	orreq	r1, r1, #0x4		@ make sure exit with unlocked value
	str	r1, [r11]		@ restore DLLA_CTRL high value
	add	r11, r11, #0x8		@ move to DLLB_CTRL addr
	str	r1, [r11]		@ set value DLLB_CTRL
	bl	i_dll_wait		@ wait for possible lock

	/* set up for return, DDR should be good */
	str r10, [r0]			@ write dll_status and return counter
	ldmfd	sp!, {r0 - r12, pc}	@ restore regs and return

	/* ensure the DLL has relocked */
i_dll_wait:
	mov	r4, #0x800		@ delay DLL relock, min 0x400 L3 clocks
i_dll_delay:
	subs	r4, r4, #0x1
	bne	i_dll_delay
	mov	pc, lr

	/*
	 * shift up or down voltage, use R9 as input to tell level.
	 * wait for it to finish, use 32k sync counter, 1tick=31uS.
	 */
voltage_shift:
	ldr	r4, omap242x_sdi_prcm_voltctrl	@ get addr of volt ctrl.
	ldr	r5, [r4]		@ get value.
	ldr	r6, prcm_mask_val	@ get value of mask
	and	r5, r5, r6		@ apply mask to clear bits
	orr	r5, r5, r9		@ bulld value for L0/L1-volt operation.
	str	r5, [r4]		@ set up for change.
	mov	r3, #0x4000		@ get val for force
	orr	r5, r5, r3		@ build value for force
	str	r5, [r4]		@ Force transition to L1

	ldr	r3, omap242x_sdi_timer_32ksynct_cr	@ get addr of counter
	ldr	r5, [r3]		@ get value
	add	r5, r5, #0x3		@ give it at most 93uS
volt_delay:
	ldr	r7, [r3]		@ get timer value
	cmp	r5, r7			@ time up?
	bhi	volt_delay		@ not yet->branch
	mov	pc, lr			@ back to caller.

omap242x_sdi_cm_clksel2_pll:
	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL2)
omap242x_sdi_sdrc_dlla_ctrl:
	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
omap242x_sdi_prcm_voltctrl:
	.word OMAP2420_PRCM_VOLTCTRL
prcm_mask_val:
	.word 0xFFFF3FFC
omap242x_sdi_timer_32ksynct_cr:
	.word OMAP2_L4_IO_ADDRESS(OMAP2420_32KSYNCT_BASE + 0x010)
ENTRY(omap242x_sram_ddr_init_sz)
	.word	. - omap242x_sram_ddr_init

/*
 * Reprograms memory timings.
 * r0 = [PRCM_FULL | PRCM_HALF] r1 = SDRC_DLLA_CTRL value r2 = [DDR | SDR]
 * PRCM_FULL = 2, PRCM_HALF = 1, DDR = 1, SDR = 0
 */
ENTRY(omap242x_sram_reprogram_sdrc)
	stmfd	sp!, {r0 - r10, lr}	@ save registers on stack
	mov	r3, #0x0		@ clear for mrc call
	mcr	p15, 0, r3, c7, c10, 4	@ memory barrier, finish ARM SDR/DDR
	nop
	nop
	ldr	r6, omap242x_srs_sdrc_rfr_ctrl	@ get addr of refresh reg
	ldr	r5, [r6]		@ get value
	mov	r5, r5, lsr #8		@ isolate rfr field and drop burst

	cmp	r0, #0x1		@ going to half speed?
	movne	r9, #0x0		@ if up set flag up for pre up, hi volt

	blne	voltage_shift_c		@ adjust voltage

	cmp	r0, #0x1		@ going to half speed (post branch link)
	moveq	r5, r5, lsr #1		@ divide by 2 if to half
	movne	r5, r5, lsl #1		@ mult by 2 if to full
	mov	r5, r5, lsl #8		@ put rfr field back into place
	add	r5, r5, #0x1		@ turn on burst of 1
	ldr	r4, omap242x_srs_cm_clksel2_pll	@ get address of out reg
	ldr	r3, [r4]		@ get curr value
	orr	r3, r3, #0x3
	bic	r3, r3, #0x3		@ clear lower bits
	orr	r3, r3, r0		@ new state value
	str	r3, [r4]		@ set new state (pll/x, x=1 or 2)
	nop
	nop

	moveq	r9, #0x1		@ if speed down, post down, drop volt
	bleq	voltage_shift_c

	mcr	p15, 0, r3, c7, c10, 4	@ memory barrier
	str	r5, [r6]		@ set new RFR_1 value
	add	r6, r6, #0x30		@ get RFR_2 addr
	str	r5, [r6]		@ set RFR_2
	nop
	cmp	r2, #0x1		@ (SDR or DDR) do we need to adjust DLL
	bne	freq_out		@ leave if SDR, no DLL function

	/* With DDR, we need to take care of the DLL for the frequency change */
	ldr	r2, omap242x_srs_sdrc_dlla_ctrl	@ addr of dlla ctrl
	str	r1, [r2]		@ write out new SDRC_DLLA_CTRL
	add	r2, r2, #0x8		@ addr to SDRC_DLLB_CTRL
	str	r1, [r2]		@ commit to SDRC_DLLB_CTRL
	mov	r1, #0x2000		@ wait DLL relock, min 0x400 L3 clocks
dll_wait:
	subs	r1, r1, #0x1
	bne	dll_wait
freq_out:
	ldmfd	sp!, {r0 - r10, pc}	@ restore regs and return

    /*
     * shift up or down voltage, use R9 as input to tell level.
     *	wait for it to finish, use 32k sync counter, 1tick=31uS.
     */
voltage_shift_c:
	ldr	r10, omap242x_srs_prcm_voltctrl	@ get addr of volt ctrl
	ldr	r8, [r10]		@ get value
	ldr	r7, ddr_prcm_mask_val	@ get value of mask
	and	r8, r8, r7		@ apply mask to clear bits
	orr	r8, r8, r9		@ bulld value for L0/L1-volt operation.
	str	r8, [r10]		@ set up for change.
	mov	r7, #0x4000		@ get val for force
	orr	r8, r8, r7		@ build value for force
	str	r8, [r10]		@ Force transition to L1

	ldr	r10, omap242x_srs_timer_32ksynct	@ get addr of counter
	ldr	r8, [r10]		@ get value
	add	r8, r8, #0x2		@ give it at most 62uS (min 31+)
volt_delay_c:
	ldr	r7, [r10]		@ get timer value
	cmp	r8, r7			@ time up?
	bhi	volt_delay_c		@ not yet->branch
	mov	pc, lr			@ back to caller

omap242x_srs_cm_clksel2_pll:
	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL2)
omap242x_srs_sdrc_dlla_ctrl:
	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
omap242x_srs_sdrc_rfr_ctrl:
	.word OMAP242X_SDRC_REGADDR(SDRC_RFR_CTRL_0)
omap242x_srs_prcm_voltctrl:
	.word OMAP2420_PRCM_VOLTCTRL
ddr_prcm_mask_val:
	.word 0xFFFF3FFC
omap242x_srs_timer_32ksynct:
	.word OMAP2_L4_IO_ADDRESS(OMAP2420_32KSYNCT_BASE + 0x010)

ENTRY(omap242x_sram_reprogram_sdrc_sz)
	.word	. - omap242x_sram_reprogram_sdrc

/*
 * Set dividers and pll. Also recalculate DLL value for DDR and unlock mode.
 */
ENTRY(omap242x_sram_set_prcm)
	stmfd	sp!, {r0-r12, lr}	@ regs to stack
	adr	r4, pbegin		@ addr of preload start
	adr	r8, pend		@ addr of preload end
	mcrr	p15, 1, r8, r4, c12	@ preload into icache
pbegin:
	/* move into fast relock bypass */
	ldr	r8, omap242x_ssp_pll_ctl	@ get addr
	ldr	r5, [r8]		@ get val
	mvn	r6, #0x3		@ clear mask
	and	r5, r5, r6		@ clear field
	orr	r7, r5, #0x2		@ fast relock val
	str	r7, [r8]		@ go to fast relock
	ldr	r4, omap242x_ssp_pll_stat	@ addr of stat
block:
	/* wait for bypass */
	ldr	r8, [r4]		@ stat value
	and	r8, r8, #0x3		@ mask for stat
	cmp	r8, #0x1		@ there yet
	bne	block			@ loop if not

	/* set new dpll dividers _after_ in bypass */
	ldr	r4, omap242x_ssp_pll_div	@ get addr
	str	r0, [r4]		@ set dpll ctrl val

	ldr	r4, omap242x_ssp_set_config	@ get addr
	mov	r8, #1			@ valid cfg msk
	str	r8, [r4]		@ make dividers take

	mov	r4, #100		@ dead spin a bit
wait_a_bit:
	subs	r4, r4, #1		@ dec loop
	bne	wait_a_bit		@ delay done?

	/* check if staying in bypass */
	cmp	r2, #0x1		@ stay in bypass?
	beq	pend			@ jump over dpll relock

	/* relock DPLL with new vals */
	ldr	r5, omap242x_ssp_pll_stat	@ get addr
	ldr	r4, omap242x_ssp_pll_ctl	@ get addr
	orr	r8, r7, #0x3		@ val for lock dpll
	str	r8, [r4]		@ set val
	mov	r0, #1000		@ dead spin a bit
wait_more:
	subs	r0, r0, #1		@ dec loop
	bne	wait_more		@ delay done?
wait_lock:
	ldr	r8, [r5]		@ get lock val
	and	r8, r8, #3		@ isolate field
	cmp	r8, #2			@ locked?
	bne	wait_lock		@ wait if not
pend:
	/* update memory timings & briefly lock dll */
	ldr	r4, omap242x_ssp_sdrc_rfr	@ get addr
	str	r1, [r4]		@ update refresh timing
	ldr	r11, omap242x_ssp_dlla_ctrl	@ get addr of DLLA ctrl
	ldr	r10, [r11]		@ get current val
	mvn	r9, #0x4		@ mask to get clear bit2
	and	r10, r10, r9		@ clear bit2 for lock mode
	orr	r10, r10, #0x8		@ make sure DLL on (es2 bit pos)
	str	r10, [r11]		@ commit to DLLA_CTRL
	add	r11, r11, #0x8		@ move to dllb
	str	r10, [r11]		@ hit DLLB also

	mov	r4, #0x800		@ relock time (min 0x400 L3 clocks)
wait_dll_lock:
	subs	r4, r4, #0x1
	bne	wait_dll_lock
	nop
	ldmfd	sp!, {r0-r12, pc}	@ restore regs and return

omap242x_ssp_set_config:
	.word OMAP2420_PRCM_CLKCFG_CTRL
omap242x_ssp_pll_ctl:
	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKEN)
omap242x_ssp_pll_stat:
	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_IDLEST)
omap242x_ssp_pll_div:
	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL1)
omap242x_ssp_sdrc_rfr:
	.word OMAP242X_SDRC_REGADDR(SDRC_RFR_CTRL_0)
omap242x_ssp_dlla_ctrl:
	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)

ENTRY(omap242x_sram_set_prcm_sz)
	.word	. - omap242x_sram_set_prcm
Commit	Line	Data
1dbae815	1	/*
c2d43e39	2	* linux/arch/arm/mach-omap2/sram242x.S
1dbae815 TL	3	*
	4	* Omap2 specific functions that need to be run in internal SRAM
	5	*
	6	* (C) Copyright 2004
	7	* Texas Instruments, <www.ti.com>
	8	* Richard Woodruff <r-woodruff2@ti.com>
	9	*
	10	* This program is free software; you can redistribute it and/or
	11	* modify it under the terms of the GNU General Public License as
	12	* published by the Free Software Foundation; either version 2 of
	13	* the License, or (at your option) any later version.
	14	*
	15	* This program is distributed in the hope that it will be useful,
	16	* but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	* MERCHANTABILITY or FITNESS FOR A PARTICULAR /PURPOSE. See the
	18	* GNU General Public License for more details.
	19	*
	20	* You should have received a copy of the GNU General Public License
	21	* along with this program; if not, write to the Free Software
	22	* Foundation, Inc., 59 Temple Place, Suite 330, Boston,
	23	* MA 02111-1307 USA
1124d2f9 PW	24	*
	25	* Richard Woodruff notes that any changes to this code must be carefully
	26	* audited and tested to ensure that they don't cause a TLB miss while
	27	* the SDRAM is inaccessible. Such a situation will crash the system
	28	* since it will cause the ARM MMU to attempt to walk the page tables.
	29	* These crashes may be intermittent.
1dbae815	30	*/
1dbae815 TL	31	#include <linux/linkage.h>
1dbae815 TL	32	#include <asm/assembler.h>
a09e64fb RK	33	#include <mach/io.h>
a09e64fb RK	34	#include <mach/hardware.h>
1dbae815	35
59fb659b PW	36	#include "prm2xxx_3xxx.h"
59fb659b PW	37	#include "cm2xxx_3xxx.h"
c2d43e39	38	#include "sdrc.h"
1dbae815 TL	39
	40	.text
	41
c2d43e39	42	ENTRY(omap242x_sram_ddr_init)
1dbae815 TL	43	stmfd sp!, {r0 - r12, lr} @ save registers on stack
	44
	45	mov r12, r2 @ capture CS1 vs CS0
	46	mov r8, r3 @ capture force parameter
	47
	48	/* frequency shift down */
c2d43e39	49	ldr r2, omap242x_sdi_cm_clksel2_pll @ get address of dpllout reg
1dbae815 TL	50	mov r3, #0x1 @ value for 1x operation
	51	str r3, [r2] @ go to L1-freq operation
	52
	53	/* voltage shift down */
	54	mov r9, #0x1 @ set up for L1 voltage call
	55	bl voltage_shift @ go drop voltage
	56
	57	/* dll lock mode */
c2d43e39	58	ldr r11, omap242x_sdi_sdrc_dlla_ctrl @ addr of dlla ctrl
1dbae815 TL	59	ldr r10, [r11] @ get current val
	60	cmp r12, #0x1 @ cs1 base (2422 es2.05/1)
	61	addeq r11, r11, #0x8 @ if cs1 base, move to DLLB
	62	mvn r9, #0x4 @ mask to get clear bit2
	63	and r10, r10, r9 @ clear bit2 for lock mode.
	64	orr r10, r10, #0x8 @ make sure DLL on (es2 bit pos)
	65	orr r10, r10, #0x2 @ 90 degree phase for all below 133Mhz
	66	str r10, [r11] @ commit to DLLA_CTRL
	67	bl i_dll_wait @ wait for dll to lock
	68
	69	/* get dll value */
	70	add r11, r11, #0x4 @ get addr of status reg
	71	ldr r10, [r11] @ get locked value
	72
	73	/* voltage shift up */
	74	mov r9, #0x0 @ shift back to L0-voltage
	75	bl voltage_shift @ go raise voltage
	76
	77	/* frequency shift up */
	78	mov r3, #0x2 @ value for 2x operation
	79	str r3, [r2] @ go to L0-freq operation
	80
	81	/* reset entry mode for dllctrl */
	82	sub r11, r11, #0x4 @ move from status to ctrl
	83	cmp r12, #0x1 @ normalize if cs1 based
	84	subeq r11, r11, #0x8 @ possibly back to DLLA
	85	cmp r8, #0x1 @ if forced unlock exit
	86	orreq r1, r1, #0x4 @ make sure exit with unlocked value
	87	str r1, [r11] @ restore DLLA_CTRL high value
	88	add r11, r11, #0x8 @ move to DLLB_CTRL addr
	89	str r1, [r11] @ set value DLLB_CTRL
	90	bl i_dll_wait @ wait for possible lock
	91
	92	/* set up for return, DDR should be good */
	93	str r10, [r0] @ write dll_status and return counter
	94	ldmfd sp!, {r0 - r12, pc} @ restore regs and return
	95
	96	/* ensure the DLL has relocked */
	97	i_dll_wait:
	98	mov r4, #0x800 @ delay DLL relock, min 0x400 L3 clocks
	99	i_dll_delay:
	100	subs r4, r4, #0x1
	101	bne i_dll_delay
	102	mov pc, lr
	103
	104	/*
	105	* shift up or down voltage, use R9 as input to tell level.
	106	* wait for it to finish, use 32k sync counter, 1tick=31uS.
	107	*/
	108	voltage_shift:
c2d43e39	109	ldr r4, omap242x_sdi_prcm_voltctrl @ get addr of volt ctrl.
1dbae815 TL	110	ldr r5, [r4] @ get value.
	111	ldr r6, prcm_mask_val @ get value of mask
	112	and r5, r5, r6 @ apply mask to clear bits
	113	orr r5, r5, r9 @ bulld value for L0/L1-volt operation.
	114	str r5, [r4] @ set up for change.
	115	mov r3, #0x4000 @ get val for force
	116	orr r5, r5, r3 @ build value for force
	117	str r5, [r4] @ Force transition to L1
	118
c2d43e39	119	ldr r3, omap242x_sdi_timer_32ksynct_cr @ get addr of counter
1dbae815 TL	120	ldr r5, [r3] @ get value
	121	add r5, r5, #0x3 @ give it at most 93uS
	122	volt_delay:
	123	ldr r7, [r3] @ get timer value
	124	cmp r5, r7 @ time up?
	125	bhi volt_delay @ not yet->branch
	126	mov pc, lr @ back to caller.
	127
c2d43e39	128	omap242x_sdi_cm_clksel2_pll:
44595982	129	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL2)
c2d43e39	130	omap242x_sdi_sdrc_dlla_ctrl:
44595982	131	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
c2d43e39	132	omap242x_sdi_prcm_voltctrl:
8e3bd351	133	.word OMAP2420_PRCM_VOLTCTRL
1dbae815 TL	134	prcm_mask_val:
1dbae815 TL	135	.word 0xFFFF3FFC
c2d43e39	136	omap242x_sdi_timer_32ksynct_cr:
233fd64e	137	.word OMAP2_L4_IO_ADDRESS(OMAP2420_32KSYNCT_BASE + 0x010)
c2d43e39 TL	138	ENTRY(omap242x_sram_ddr_init_sz)
c2d43e39 TL	139	.word . - omap242x_sram_ddr_init
1dbae815 TL	140
	141	/*
	142	* Reprograms memory timings.
	143	* r0 = [PRCM_FULL \| PRCM_HALF] r1 = SDRC_DLLA_CTRL value r2 = [DDR \| SDR]
	144	* PRCM_FULL = 2, PRCM_HALF = 1, DDR = 1, SDR = 0
	145	*/
c2d43e39	146	ENTRY(omap242x_sram_reprogram_sdrc)
1dbae815 TL	147	stmfd sp!, {r0 - r10, lr} @ save registers on stack
	148	mov r3, #0x0 @ clear for mrc call
	149	mcr p15, 0, r3, c7, c10, 4 @ memory barrier, finish ARM SDR/DDR
	150	nop
	151	nop
c2d43e39	152	ldr r6, omap242x_srs_sdrc_rfr_ctrl @ get addr of refresh reg
1dbae815 TL	153	ldr r5, [r6] @ get value
	154	mov r5, r5, lsr #8 @ isolate rfr field and drop burst
	155
	156	cmp r0, #0x1 @ going to half speed?
	157	movne r9, #0x0 @ if up set flag up for pre up, hi volt
	158
	159	blne voltage_shift_c @ adjust voltage
	160
	161	cmp r0, #0x1 @ going to half speed (post branch link)
	162	moveq r5, r5, lsr #1 @ divide by 2 if to half
	163	movne r5, r5, lsl #1 @ mult by 2 if to full
	164	mov r5, r5, lsl #8 @ put rfr field back into place
	165	add r5, r5, #0x1 @ turn on burst of 1
c2d43e39	166	ldr r4, omap242x_srs_cm_clksel2_pll @ get address of out reg
1dbae815 TL	167	ldr r3, [r4] @ get curr value
	168	orr r3, r3, #0x3
	169	bic r3, r3, #0x3 @ clear lower bits
	170	orr r3, r3, r0 @ new state value
	171	str r3, [r4] @ set new state (pll/x, x=1 or 2)
	172	nop
	173	nop
	174
	175	moveq r9, #0x1 @ if speed down, post down, drop volt
	176	bleq voltage_shift_c
	177
	178	mcr p15, 0, r3, c7, c10, 4 @ memory barrier
	179	str r5, [r6] @ set new RFR_1 value
	180	add r6, r6, #0x30 @ get RFR_2 addr
	181	str r5, [r6] @ set RFR_2
	182	nop
	183	cmp r2, #0x1 @ (SDR or DDR) do we need to adjust DLL
	184	bne freq_out @ leave if SDR, no DLL function
	185
	186	/* With DDR, we need to take care of the DLL for the frequency change */
c2d43e39	187	ldr r2, omap242x_srs_sdrc_dlla_ctrl @ addr of dlla ctrl
1dbae815 TL	188	str r1, [r2] @ write out new SDRC_DLLA_CTRL
	189	add r2, r2, #0x8 @ addr to SDRC_DLLB_CTRL
	190	str r1, [r2] @ commit to SDRC_DLLB_CTRL
	191	mov r1, #0x2000 @ wait DLL relock, min 0x400 L3 clocks
	192	dll_wait:
	193	subs r1, r1, #0x1
	194	bne dll_wait
	195	freq_out:
	196	ldmfd sp!, {r0 - r10, pc} @ restore regs and return
	197
	198	/*
	199	* shift up or down voltage, use R9 as input to tell level.
	200	* wait for it to finish, use 32k sync counter, 1tick=31uS.
	201	*/
	202	voltage_shift_c:
c2d43e39	203	ldr r10, omap242x_srs_prcm_voltctrl @ get addr of volt ctrl
1dbae815 TL	204	ldr r8, [r10] @ get value
	205	ldr r7, ddr_prcm_mask_val @ get value of mask
	206	and r8, r8, r7 @ apply mask to clear bits
	207	orr r8, r8, r9 @ bulld value for L0/L1-volt operation.
	208	str r8, [r10] @ set up for change.
	209	mov r7, #0x4000 @ get val for force
	210	orr r8, r8, r7 @ build value for force
	211	str r8, [r10] @ Force transition to L1
	212
c2d43e39	213	ldr r10, omap242x_srs_timer_32ksynct @ get addr of counter
1dbae815 TL	214	ldr r8, [r10] @ get value
	215	add r8, r8, #0x2 @ give it at most 62uS (min 31+)
	216	volt_delay_c:
	217	ldr r7, [r10] @ get timer value
	218	cmp r8, r7 @ time up?
	219	bhi volt_delay_c @ not yet->branch
	220	mov pc, lr @ back to caller
	221
c2d43e39	222	omap242x_srs_cm_clksel2_pll:
44595982	223	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL2)
c2d43e39	224	omap242x_srs_sdrc_dlla_ctrl:
44595982	225	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
c2d43e39	226	omap242x_srs_sdrc_rfr_ctrl:
44595982	227	.word OMAP242X_SDRC_REGADDR(SDRC_RFR_CTRL_0)
c2d43e39	228	omap242x_srs_prcm_voltctrl:
8e3bd351	229	.word OMAP2420_PRCM_VOLTCTRL
1dbae815 TL	230	ddr_prcm_mask_val:
1dbae815 TL	231	.word 0xFFFF3FFC
c2d43e39	232	omap242x_srs_timer_32ksynct:
233fd64e	233	.word OMAP2_L4_IO_ADDRESS(OMAP2420_32KSYNCT_BASE + 0x010)
1dbae815	234
c2d43e39 TL	235	ENTRY(omap242x_sram_reprogram_sdrc_sz)
c2d43e39 TL	236	.word . - omap242x_sram_reprogram_sdrc
1dbae815 TL	237
	238	/*
	239	* Set dividers and pll. Also recalculate DLL value for DDR and unlock mode.
	240	*/
c2d43e39	241	ENTRY(omap242x_sram_set_prcm)
1dbae815 TL	242	stmfd sp!, {r0-r12, lr} @ regs to stack
	243	adr r4, pbegin @ addr of preload start
	244	adr r8, pend @ addr of preload end
	245	mcrr p15, 1, r8, r4, c12 @ preload into icache
	246	pbegin:
	247	/* move into fast relock bypass */
c2d43e39	248	ldr r8, omap242x_ssp_pll_ctl @ get addr
1dbae815 TL	249	ldr r5, [r8] @ get val
	250	mvn r6, #0x3 @ clear mask
	251	and r5, r5, r6 @ clear field
	252	orr r7, r5, #0x2 @ fast relock val
	253	str r7, [r8] @ go to fast relock
c2d43e39	254	ldr r4, omap242x_ssp_pll_stat @ addr of stat
1dbae815 TL	255	block:
	256	/* wait for bypass */
	257	ldr r8, [r4] @ stat value
	258	and r8, r8, #0x3 @ mask for stat
	259	cmp r8, #0x1 @ there yet
	260	bne block @ loop if not
	261
	262	/* set new dpll dividers _after_ in bypass */
c2d43e39	263	ldr r4, omap242x_ssp_pll_div @ get addr
1dbae815 TL	264	str r0, [r4] @ set dpll ctrl val
1dbae815 TL	265
c2d43e39	266	ldr r4, omap242x_ssp_set_config @ get addr
1dbae815 TL	267	mov r8, #1 @ valid cfg msk
	268	str r8, [r4] @ make dividers take
	269
	270	mov r4, #100 @ dead spin a bit
	271	wait_a_bit:
	272	subs r4, r4, #1 @ dec loop
	273	bne wait_a_bit @ delay done?
	274
	275	/* check if staying in bypass */
	276	cmp r2, #0x1 @ stay in bypass?
	277	beq pend @ jump over dpll relock
	278
	279	/* relock DPLL with new vals */
c2d43e39 TL	280	ldr r5, omap242x_ssp_pll_stat @ get addr
c2d43e39 TL	281	ldr r4, omap242x_ssp_pll_ctl @ get addr
1dbae815 TL	282	orr r8, r7, #0x3 @ val for lock dpll
	283	str r8, [r4] @ set val
	284	mov r0, #1000 @ dead spin a bit
	285	wait_more:
	286	subs r0, r0, #1 @ dec loop
	287	bne wait_more @ delay done?
	288	wait_lock:
	289	ldr r8, [r5] @ get lock val
	290	and r8, r8, #3 @ isolate field
	291	cmp r8, #2 @ locked?
	292	bne wait_lock @ wait if not
	293	pend:
	294	/* update memory timings & briefly lock dll */
c2d43e39	295	ldr r4, omap242x_ssp_sdrc_rfr @ get addr
1dbae815	296	str r1, [r4] @ update refresh timing
c2d43e39	297	ldr r11, omap242x_ssp_dlla_ctrl @ get addr of DLLA ctrl
1dbae815 TL	298	ldr r10, [r11] @ get current val
	299	mvn r9, #0x4 @ mask to get clear bit2
	300	and r10, r10, r9 @ clear bit2 for lock mode
	301	orr r10, r10, #0x8 @ make sure DLL on (es2 bit pos)
	302	str r10, [r11] @ commit to DLLA_CTRL
	303	add r11, r11, #0x8 @ move to dllb
	304	str r10, [r11] @ hit DLLB also
	305
	306	mov r4, #0x800 @ relock time (min 0x400 L3 clocks)
	307	wait_dll_lock:
	308	subs r4, r4, #0x1
	309	bne wait_dll_lock
	310	nop
	311	ldmfd sp!, {r0-r12, pc} @ restore regs and return
	312
c2d43e39	313	omap242x_ssp_set_config:
8e3bd351	314	.word OMAP2420_PRCM_CLKCFG_CTRL
c2d43e39 TL	315	omap242x_ssp_pll_ctl:
	316	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKEN)
	317	omap242x_ssp_pll_stat:
	318	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_IDLEST)
	319	omap242x_ssp_pll_div:
	320	.word OMAP2420_CM_REGADDR(PLL_MOD, CM_CLKSEL1)
	321	omap242x_ssp_sdrc_rfr:
44595982	322	.word OMAP242X_SDRC_REGADDR(SDRC_RFR_CTRL_0)
c2d43e39	323	omap242x_ssp_dlla_ctrl:
44595982	324	.word OMAP242X_SDRC_REGADDR(SDRC_DLLA_CTRL)
1dbae815	325
c2d43e39 TL	326	ENTRY(omap242x_sram_set_prcm_sz)
c2d43e39 TL	327	.word . - omap242x_sram_set_prcm