Commit | Line | Data |
---|---|---|
9703d9d7 CM |
1 | /* |
2 | * Low-level CPU initialisation | |
3 | * Based on arch/arm/kernel/head.S | |
4 | * | |
5 | * Copyright (C) 1994-2002 Russell King | |
6 | * Copyright (C) 2003-2012 ARM Ltd. | |
7 | * Authors: Catalin Marinas <catalin.marinas@arm.com> | |
8 | * Will Deacon <will.deacon@arm.com> | |
9 | * | |
10 | * This program is free software; you can redistribute it and/or modify | |
11 | * it under the terms of the GNU General Public License version 2 as | |
12 | * published by the Free Software Foundation. | |
13 | * | |
14 | * This program is distributed in the hope that it will be useful, | |
15 | * but WITHOUT ANY WARRANTY; without even the implied warranty of | |
16 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
17 | * GNU General Public License for more details. | |
18 | * | |
19 | * You should have received a copy of the GNU General Public License | |
20 | * along with this program. If not, see <http://www.gnu.org/licenses/>. | |
21 | */ | |
22 | ||
23 | #include <linux/linkage.h> | |
24 | #include <linux/init.h> | |
021f6537 | 25 | #include <linux/irqchip/arm-gic-v3.h> |
9703d9d7 CM |
26 | |
27 | #include <asm/assembler.h> | |
28 | #include <asm/ptrace.h> | |
29 | #include <asm/asm-offsets.h> | |
c218bca7 | 30 | #include <asm/cache.h> |
0359b0e2 | 31 | #include <asm/cputype.h> |
9703d9d7 CM |
32 | #include <asm/memory.h> |
33 | #include <asm/thread_info.h> | |
34 | #include <asm/pgtable-hwdef.h> | |
35 | #include <asm/pgtable.h> | |
36 | #include <asm/page.h> | |
f35a9205 | 37 | #include <asm/virt.h> |
9703d9d7 | 38 | |
9703d9d7 CM |
39 | #define KERNEL_RAM_VADDR (PAGE_OFFSET + TEXT_OFFSET) |
40 | ||
4190312b AB |
41 | #if (TEXT_OFFSET & 0xfff) != 0 |
42 | #error TEXT_OFFSET must be at least 4KB aligned | |
43 | #elif (PAGE_OFFSET & 0x1fffff) != 0 | |
da57a369 | 44 | #error PAGE_OFFSET must be at least 2MB aligned |
4190312b | 45 | #elif TEXT_OFFSET > 0x1fffff |
da57a369 | 46 | #error TEXT_OFFSET must be less than 2MB |
9703d9d7 CM |
47 | #endif |
48 | ||
bd00cd5f MR |
49 | .macro pgtbl, ttb0, ttb1, virt_to_phys |
50 | ldr \ttb1, =swapper_pg_dir | |
51 | ldr \ttb0, =idmap_pg_dir | |
52 | add \ttb1, \ttb1, \virt_to_phys | |
53 | add \ttb0, \ttb0, \virt_to_phys | |
9703d9d7 CM |
54 | .endm |
55 | ||
56 | #ifdef CONFIG_ARM64_64K_PAGES | |
57 | #define BLOCK_SHIFT PAGE_SHIFT | |
58 | #define BLOCK_SIZE PAGE_SIZE | |
383c2799 | 59 | #define TABLE_SHIFT PMD_SHIFT |
9703d9d7 CM |
60 | #else |
61 | #define BLOCK_SHIFT SECTION_SHIFT | |
62 | #define BLOCK_SIZE SECTION_SIZE | |
383c2799 | 63 | #define TABLE_SHIFT PUD_SHIFT |
9703d9d7 CM |
64 | #endif |
65 | ||
66 | #define KERNEL_START KERNEL_RAM_VADDR | |
67 | #define KERNEL_END _end | |
68 | ||
69 | /* | |
70 | * Initial memory map attributes. | |
71 | */ | |
72 | #ifndef CONFIG_SMP | |
73 | #define PTE_FLAGS PTE_TYPE_PAGE | PTE_AF | |
74 | #define PMD_FLAGS PMD_TYPE_SECT | PMD_SECT_AF | |
75 | #else | |
76 | #define PTE_FLAGS PTE_TYPE_PAGE | PTE_AF | PTE_SHARED | |
77 | #define PMD_FLAGS PMD_TYPE_SECT | PMD_SECT_AF | PMD_SECT_S | |
78 | #endif | |
79 | ||
80 | #ifdef CONFIG_ARM64_64K_PAGES | |
81 | #define MM_MMUFLAGS PTE_ATTRINDX(MT_NORMAL) | PTE_FLAGS | |
9703d9d7 CM |
82 | #else |
83 | #define MM_MMUFLAGS PMD_ATTRINDX(MT_NORMAL) | PMD_FLAGS | |
9703d9d7 CM |
84 | #endif |
85 | ||
86 | /* | |
87 | * Kernel startup entry point. | |
88 | * --------------------------- | |
89 | * | |
90 | * The requirements are: | |
91 | * MMU = off, D-cache = off, I-cache = on or off, | |
92 | * x0 = physical address to the FDT blob. | |
93 | * | |
94 | * This code is mostly position independent so you call this at | |
95 | * __pa(PAGE_OFFSET + TEXT_OFFSET). | |
96 | * | |
97 | * Note that the callee-saved registers are used for storing variables | |
98 | * that are useful before the MMU is enabled. The allocations are described | |
99 | * in the entry routines. | |
100 | */ | |
101 | __HEAD | |
102 | ||
103 | /* | |
104 | * DO NOT MODIFY. Image header expected by Linux boot-loaders. | |
105 | */ | |
3c7f2550 MS |
106 | #ifdef CONFIG_EFI |
107 | efi_head: | |
108 | /* | |
109 | * This add instruction has no meaningful effect except that | |
110 | * its opcode forms the magic "MZ" signature required by UEFI. | |
111 | */ | |
112 | add x13, x18, #0x16 | |
113 | b stext | |
114 | #else | |
9703d9d7 CM |
115 | b stext // branch to kernel start, magic |
116 | .long 0 // reserved | |
3c7f2550 | 117 | #endif |
a2c1d73b MR |
118 | .quad _kernel_offset_le // Image load offset from start of RAM, little-endian |
119 | .quad _kernel_size_le // Effective size of kernel image, little-endian | |
120 | .quad _kernel_flags_le // Informative flags, little-endian | |
4370eec0 RF |
121 | .quad 0 // reserved |
122 | .quad 0 // reserved | |
123 | .quad 0 // reserved | |
124 | .byte 0x41 // Magic number, "ARM\x64" | |
125 | .byte 0x52 | |
126 | .byte 0x4d | |
127 | .byte 0x64 | |
3c7f2550 MS |
128 | #ifdef CONFIG_EFI |
129 | .long pe_header - efi_head // Offset to the PE header. | |
130 | #else | |
4370eec0 | 131 | .word 0 // reserved |
3c7f2550 MS |
132 | #endif |
133 | ||
134 | #ifdef CONFIG_EFI | |
95b39596 AB |
135 | .globl stext_offset |
136 | .set stext_offset, stext - efi_head | |
3c7f2550 MS |
137 | .align 3 |
138 | pe_header: | |
139 | .ascii "PE" | |
140 | .short 0 | |
141 | coff_header: | |
142 | .short 0xaa64 // AArch64 | |
143 | .short 2 // nr_sections | |
144 | .long 0 // TimeDateStamp | |
145 | .long 0 // PointerToSymbolTable | |
146 | .long 1 // NumberOfSymbols | |
147 | .short section_table - optional_header // SizeOfOptionalHeader | |
148 | .short 0x206 // Characteristics. | |
149 | // IMAGE_FILE_DEBUG_STRIPPED | | |
150 | // IMAGE_FILE_EXECUTABLE_IMAGE | | |
151 | // IMAGE_FILE_LINE_NUMS_STRIPPED | |
152 | optional_header: | |
153 | .short 0x20b // PE32+ format | |
154 | .byte 0x02 // MajorLinkerVersion | |
155 | .byte 0x14 // MinorLinkerVersion | |
c16173fa | 156 | .long _end - stext // SizeOfCode |
3c7f2550 MS |
157 | .long 0 // SizeOfInitializedData |
158 | .long 0 // SizeOfUninitializedData | |
159 | .long efi_stub_entry - efi_head // AddressOfEntryPoint | |
95b39596 | 160 | .long stext_offset // BaseOfCode |
3c7f2550 MS |
161 | |
162 | extra_header_fields: | |
163 | .quad 0 // ImageBase | |
ea6bc80d | 164 | .long 0x1000 // SectionAlignment |
a352ea3e | 165 | .long PECOFF_FILE_ALIGNMENT // FileAlignment |
3c7f2550 MS |
166 | .short 0 // MajorOperatingSystemVersion |
167 | .short 0 // MinorOperatingSystemVersion | |
168 | .short 0 // MajorImageVersion | |
169 | .short 0 // MinorImageVersion | |
170 | .short 0 // MajorSubsystemVersion | |
171 | .short 0 // MinorSubsystemVersion | |
172 | .long 0 // Win32VersionValue | |
173 | ||
c16173fa | 174 | .long _end - efi_head // SizeOfImage |
3c7f2550 MS |
175 | |
176 | // Everything before the kernel image is considered part of the header | |
95b39596 | 177 | .long stext_offset // SizeOfHeaders |
3c7f2550 MS |
178 | .long 0 // CheckSum |
179 | .short 0xa // Subsystem (EFI application) | |
180 | .short 0 // DllCharacteristics | |
181 | .quad 0 // SizeOfStackReserve | |
182 | .quad 0 // SizeOfStackCommit | |
183 | .quad 0 // SizeOfHeapReserve | |
184 | .quad 0 // SizeOfHeapCommit | |
185 | .long 0 // LoaderFlags | |
186 | .long 0x6 // NumberOfRvaAndSizes | |
187 | ||
188 | .quad 0 // ExportTable | |
189 | .quad 0 // ImportTable | |
190 | .quad 0 // ResourceTable | |
191 | .quad 0 // ExceptionTable | |
192 | .quad 0 // CertificationTable | |
193 | .quad 0 // BaseRelocationTable | |
194 | ||
195 | // Section table | |
196 | section_table: | |
197 | ||
198 | /* | |
199 | * The EFI application loader requires a relocation section | |
200 | * because EFI applications must be relocatable. This is a | |
201 | * dummy section as far as we are concerned. | |
202 | */ | |
203 | .ascii ".reloc" | |
204 | .byte 0 | |
205 | .byte 0 // end of 0 padding of section name | |
206 | .long 0 | |
207 | .long 0 | |
208 | .long 0 // SizeOfRawData | |
209 | .long 0 // PointerToRawData | |
210 | .long 0 // PointerToRelocations | |
211 | .long 0 // PointerToLineNumbers | |
212 | .short 0 // NumberOfRelocations | |
213 | .short 0 // NumberOfLineNumbers | |
214 | .long 0x42100040 // Characteristics (section flags) | |
215 | ||
216 | ||
217 | .ascii ".text" | |
218 | .byte 0 | |
219 | .byte 0 | |
220 | .byte 0 // end of 0 padding of section name | |
c16173fa | 221 | .long _end - stext // VirtualSize |
95b39596 | 222 | .long stext_offset // VirtualAddress |
3c7f2550 | 223 | .long _edata - stext // SizeOfRawData |
95b39596 | 224 | .long stext_offset // PointerToRawData |
3c7f2550 MS |
225 | |
226 | .long 0 // PointerToRelocations (0 for executables) | |
227 | .long 0 // PointerToLineNumbers (0 for executables) | |
228 | .short 0 // NumberOfRelocations (0 for executables) | |
229 | .short 0 // NumberOfLineNumbers (0 for executables) | |
230 | .long 0xe0500020 // Characteristics (section flags) | |
ea6bc80d AB |
231 | |
232 | /* | |
233 | * EFI will load stext onwards at the 4k section alignment | |
234 | * described in the PE/COFF header. To ensure that instruction | |
235 | * sequences using an adrp and a :lo12: immediate will function | |
236 | * correctly at this alignment, we must ensure that stext is | |
237 | * placed at a 4k boundary in the Image to begin with. | |
238 | */ | |
239 | .align 12 | |
3c7f2550 | 240 | #endif |
9703d9d7 CM |
241 | |
242 | ENTRY(stext) | |
243 | mov x21, x0 // x21=FDT | |
828e9834 | 244 | bl el2_setup // Drop to EL1, w20=cpu_boot_mode |
f35a9205 | 245 | bl __calc_phys_offset // x24=PHYS_OFFSET, x28=PHYS_OFFSET-PAGE_OFFSET |
828e9834 | 246 | bl set_cpu_boot_mode_flag |
9703d9d7 CM |
247 | mrs x22, midr_el1 // x22=cpuid |
248 | mov x0, x22 | |
249 | bl lookup_processor_type | |
250 | mov x23, x0 // x23=current cpu_table | |
251 | cbz x23, __error_p // invalid processor (x23=0)? | |
9703d9d7 CM |
252 | bl __vet_fdt |
253 | bl __create_page_tables // x25=TTBR0, x26=TTBR1 | |
254 | /* | |
255 | * The following calls CPU specific code in a position independent | |
256 | * manner. See arch/arm64/mm/proc.S for details. x23 = base of | |
257 | * cpu_info structure selected by lookup_processor_type above. | |
258 | * On return, the CPU will be ready for the MMU to be turned on and | |
259 | * the TCR will have been set. | |
260 | */ | |
261 | ldr x27, __switch_data // address to jump to after | |
262 | // MMU has been enabled | |
263 | adr lr, __enable_mmu // return (PIC) address | |
264 | ldr x12, [x23, #CPU_INFO_SETUP] | |
265 | add x12, x12, x28 // __virt_to_phys | |
266 | br x12 // initialise processor | |
267 | ENDPROC(stext) | |
268 | ||
269 | /* | |
270 | * If we're fortunate enough to boot at EL2, ensure that the world is | |
271 | * sane before dropping to EL1. | |
828e9834 ML |
272 | * |
273 | * Returns either BOOT_CPU_MODE_EL1 or BOOT_CPU_MODE_EL2 in x20 if | |
274 | * booted in EL1 or EL2 respectively. | |
9703d9d7 CM |
275 | */ |
276 | ENTRY(el2_setup) | |
277 | mrs x0, CurrentEL | |
974c8e45 | 278 | cmp x0, #CurrentEL_EL2 |
9cf71728 ML |
279 | b.ne 1f |
280 | mrs x0, sctlr_el2 | |
281 | CPU_BE( orr x0, x0, #(1 << 25) ) // Set the EE bit for EL2 | |
282 | CPU_LE( bic x0, x0, #(1 << 25) ) // Clear the EE bit for EL2 | |
283 | msr sctlr_el2, x0 | |
284 | b 2f | |
285 | 1: mrs x0, sctlr_el1 | |
286 | CPU_BE( orr x0, x0, #(3 << 24) ) // Set the EE and E0E bits for EL1 | |
287 | CPU_LE( bic x0, x0, #(3 << 24) ) // Clear the EE and E0E bits for EL1 | |
288 | msr sctlr_el1, x0 | |
828e9834 | 289 | mov w20, #BOOT_CPU_MODE_EL1 // This cpu booted in EL1 |
9cf71728 | 290 | isb |
9703d9d7 CM |
291 | ret |
292 | ||
293 | /* Hyp configuration. */ | |
9cf71728 | 294 | 2: mov x0, #(1 << 31) // 64-bit EL1 |
9703d9d7 CM |
295 | msr hcr_el2, x0 |
296 | ||
297 | /* Generic timers. */ | |
298 | mrs x0, cnthctl_el2 | |
299 | orr x0, x0, #3 // Enable EL1 physical timers | |
300 | msr cnthctl_el2, x0 | |
1f75ff0a | 301 | msr cntvoff_el2, xzr // Clear virtual offset |
9703d9d7 | 302 | |
021f6537 MZ |
303 | #ifdef CONFIG_ARM_GIC_V3 |
304 | /* GICv3 system register access */ | |
305 | mrs x0, id_aa64pfr0_el1 | |
306 | ubfx x0, x0, #24, #4 | |
307 | cmp x0, #1 | |
308 | b.ne 3f | |
309 | ||
72c58395 | 310 | mrs_s x0, ICC_SRE_EL2 |
021f6537 MZ |
311 | orr x0, x0, #ICC_SRE_EL2_SRE // Set ICC_SRE_EL2.SRE==1 |
312 | orr x0, x0, #ICC_SRE_EL2_ENABLE // Set ICC_SRE_EL2.Enable==1 | |
72c58395 | 313 | msr_s ICC_SRE_EL2, x0 |
021f6537 | 314 | isb // Make sure SRE is now set |
72c58395 | 315 | msr_s ICH_HCR_EL2, xzr // Reset ICC_HCR_EL2 to defaults |
021f6537 MZ |
316 | |
317 | 3: | |
318 | #endif | |
319 | ||
9703d9d7 CM |
320 | /* Populate ID registers. */ |
321 | mrs x0, midr_el1 | |
322 | mrs x1, mpidr_el1 | |
323 | msr vpidr_el2, x0 | |
324 | msr vmpidr_el2, x1 | |
325 | ||
326 | /* sctlr_el1 */ | |
327 | mov x0, #0x0800 // Set/clear RES{1,0} bits | |
9cf71728 ML |
328 | CPU_BE( movk x0, #0x33d0, lsl #16 ) // Set EE and E0E on BE systems |
329 | CPU_LE( movk x0, #0x30d0, lsl #16 ) // Clear EE and E0E on LE systems | |
9703d9d7 CM |
330 | msr sctlr_el1, x0 |
331 | ||
332 | /* Coprocessor traps. */ | |
333 | mov x0, #0x33ff | |
334 | msr cptr_el2, x0 // Disable copro. traps to EL2 | |
335 | ||
336 | #ifdef CONFIG_COMPAT | |
337 | msr hstr_el2, xzr // Disable CP15 traps to EL2 | |
338 | #endif | |
339 | ||
7dbfbe5b MZ |
340 | /* Stage-2 translation */ |
341 | msr vttbr_el2, xzr | |
342 | ||
712c6ff4 MZ |
343 | /* Hypervisor stub */ |
344 | adr x0, __hyp_stub_vectors | |
345 | msr vbar_el2, x0 | |
346 | ||
9703d9d7 CM |
347 | /* spsr */ |
348 | mov x0, #(PSR_F_BIT | PSR_I_BIT | PSR_A_BIT | PSR_D_BIT |\ | |
349 | PSR_MODE_EL1h) | |
350 | msr spsr_el2, x0 | |
351 | msr elr_el2, lr | |
828e9834 | 352 | mov w20, #BOOT_CPU_MODE_EL2 // This CPU booted in EL2 |
9703d9d7 CM |
353 | eret |
354 | ENDPROC(el2_setup) | |
355 | ||
828e9834 ML |
356 | /* |
357 | * Sets the __boot_cpu_mode flag depending on the CPU boot mode passed | |
358 | * in x20. See arch/arm64/include/asm/virt.h for more info. | |
359 | */ | |
360 | ENTRY(set_cpu_boot_mode_flag) | |
361 | ldr x1, =__boot_cpu_mode // Compute __boot_cpu_mode | |
362 | add x1, x1, x28 | |
363 | cmp w20, #BOOT_CPU_MODE_EL2 | |
364 | b.ne 1f | |
365 | add x1, x1, #4 | |
d0488597 WD |
366 | 1: str w20, [x1] // This CPU has booted in EL1 |
367 | dmb sy | |
368 | dc ivac, x1 // Invalidate potentially stale cache line | |
828e9834 ML |
369 | ret |
370 | ENDPROC(set_cpu_boot_mode_flag) | |
371 | ||
f35a9205 MZ |
372 | /* |
373 | * We need to find out the CPU boot mode long after boot, so we need to | |
374 | * store it in a writable variable. | |
375 | * | |
376 | * This is not in .bss, because we set it sufficiently early that the boot-time | |
377 | * zeroing of .bss would clobber it. | |
378 | */ | |
c218bca7 | 379 | .pushsection .data..cacheline_aligned |
f35a9205 | 380 | ENTRY(__boot_cpu_mode) |
c218bca7 | 381 | .align L1_CACHE_SHIFT |
f35a9205 MZ |
382 | .long BOOT_CPU_MODE_EL2 |
383 | .long 0 | |
384 | .popsection | |
385 | ||
9703d9d7 | 386 | #ifdef CONFIG_SMP |
9703d9d7 CM |
387 | .align 3 |
388 | 1: .quad . | |
389 | .quad secondary_holding_pen_release | |
390 | ||
391 | /* | |
392 | * This provides a "holding pen" for platforms to hold all secondary | |
393 | * cores are held until we're ready for them to initialise. | |
394 | */ | |
395 | ENTRY(secondary_holding_pen) | |
828e9834 ML |
396 | bl el2_setup // Drop to EL1, w20=cpu_boot_mode |
397 | bl __calc_phys_offset // x24=PHYS_OFFSET, x28=PHYS_OFFSET-PAGE_OFFSET | |
398 | bl set_cpu_boot_mode_flag | |
9703d9d7 | 399 | mrs x0, mpidr_el1 |
0359b0e2 JM |
400 | ldr x1, =MPIDR_HWID_BITMASK |
401 | and x0, x0, x1 | |
9703d9d7 CM |
402 | adr x1, 1b |
403 | ldp x2, x3, [x1] | |
404 | sub x1, x1, x2 | |
405 | add x3, x3, x1 | |
406 | pen: ldr x4, [x3] | |
407 | cmp x4, x0 | |
408 | b.eq secondary_startup | |
409 | wfe | |
410 | b pen | |
411 | ENDPROC(secondary_holding_pen) | |
652af899 MR |
412 | |
413 | /* | |
414 | * Secondary entry point that jumps straight into the kernel. Only to | |
415 | * be used where CPUs are brought online dynamically by the kernel. | |
416 | */ | |
417 | ENTRY(secondary_entry) | |
652af899 | 418 | bl el2_setup // Drop to EL1 |
85cc00ea LP |
419 | bl __calc_phys_offset // x24=PHYS_OFFSET, x28=PHYS_OFFSET-PAGE_OFFSET |
420 | bl set_cpu_boot_mode_flag | |
652af899 MR |
421 | b secondary_startup |
422 | ENDPROC(secondary_entry) | |
9703d9d7 CM |
423 | |
424 | ENTRY(secondary_startup) | |
425 | /* | |
426 | * Common entry point for secondary CPUs. | |
427 | */ | |
428 | mrs x22, midr_el1 // x22=cpuid | |
429 | mov x0, x22 | |
430 | bl lookup_processor_type | |
431 | mov x23, x0 // x23=current cpu_table | |
432 | cbz x23, __error_p // invalid processor (x23=0)? | |
433 | ||
bd00cd5f | 434 | pgtbl x25, x26, x28 // x25=TTBR0, x26=TTBR1 |
9703d9d7 CM |
435 | ldr x12, [x23, #CPU_INFO_SETUP] |
436 | add x12, x12, x28 // __virt_to_phys | |
437 | blr x12 // initialise processor | |
438 | ||
439 | ldr x21, =secondary_data | |
440 | ldr x27, =__secondary_switched // address to jump to after enabling the MMU | |
441 | b __enable_mmu | |
442 | ENDPROC(secondary_startup) | |
443 | ||
444 | ENTRY(__secondary_switched) | |
445 | ldr x0, [x21] // get secondary_data.stack | |
446 | mov sp, x0 | |
447 | mov x29, #0 | |
448 | b secondary_start_kernel | |
449 | ENDPROC(__secondary_switched) | |
450 | #endif /* CONFIG_SMP */ | |
451 | ||
452 | /* | |
453 | * Setup common bits before finally enabling the MMU. Essentially this is just | |
454 | * loading the page table pointer and vector base registers. | |
455 | * | |
456 | * On entry to this code, x0 must contain the SCTLR_EL1 value for turning on | |
457 | * the MMU. | |
458 | */ | |
459 | __enable_mmu: | |
460 | ldr x5, =vectors | |
461 | msr vbar_el1, x5 | |
462 | msr ttbr0_el1, x25 // load TTBR0 | |
463 | msr ttbr1_el1, x26 // load TTBR1 | |
464 | isb | |
465 | b __turn_mmu_on | |
466 | ENDPROC(__enable_mmu) | |
467 | ||
468 | /* | |
469 | * Enable the MMU. This completely changes the structure of the visible memory | |
470 | * space. You will not be able to trace execution through this. | |
471 | * | |
472 | * x0 = system control register | |
473 | * x27 = *virtual* address to jump to upon completion | |
474 | * | |
475 | * other registers depend on the function called upon completion | |
909a4069 MR |
476 | * |
477 | * We align the entire function to the smallest power of two larger than it to | |
478 | * ensure it fits within a single block map entry. Otherwise were PHYS_OFFSET | |
479 | * close to the end of a 512MB or 1GB block we might require an additional | |
480 | * table to map the entire function. | |
9703d9d7 | 481 | */ |
909a4069 | 482 | .align 4 |
9703d9d7 CM |
483 | __turn_mmu_on: |
484 | msr sctlr_el1, x0 | |
485 | isb | |
486 | br x27 | |
487 | ENDPROC(__turn_mmu_on) | |
488 | ||
489 | /* | |
490 | * Calculate the start of physical memory. | |
491 | */ | |
492 | __calc_phys_offset: | |
493 | adr x0, 1f | |
494 | ldp x1, x2, [x0] | |
495 | sub x28, x0, x1 // x28 = PHYS_OFFSET - PAGE_OFFSET | |
496 | add x24, x2, x28 // x24 = PHYS_OFFSET | |
497 | ret | |
498 | ENDPROC(__calc_phys_offset) | |
499 | ||
500 | .align 3 | |
501 | 1: .quad . | |
502 | .quad PAGE_OFFSET | |
503 | ||
504 | /* | |
b4a0d8b3 | 505 | * Macro to create a table entry to the next page. |
9703d9d7 | 506 | * |
b4a0d8b3 CM |
507 | * tbl: page table address |
508 | * virt: virtual address | |
509 | * shift: #imm page table shift | |
510 | * ptrs: #imm pointers per table page | |
511 | * | |
512 | * Preserves: virt | |
513 | * Corrupts: tmp1, tmp2 | |
514 | * Returns: tbl -> next level table page address | |
9703d9d7 | 515 | */ |
b4a0d8b3 CM |
516 | .macro create_table_entry, tbl, virt, shift, ptrs, tmp1, tmp2 |
517 | lsr \tmp1, \virt, #\shift | |
518 | and \tmp1, \tmp1, #\ptrs - 1 // table index | |
519 | add \tmp2, \tbl, #PAGE_SIZE | |
520 | orr \tmp2, \tmp2, #PMD_TYPE_TABLE // address of next table and entry type | |
521 | str \tmp2, [\tbl, \tmp1, lsl #3] | |
522 | add \tbl, \tbl, #PAGE_SIZE // next level table page | |
c79b954b JL |
523 | .endm |
524 | ||
525 | /* | |
526 | * Macro to populate the PGD (and possibily PUD) for the corresponding | |
527 | * block entry in the next level (tbl) for the given virtual address. | |
528 | * | |
b4a0d8b3 CM |
529 | * Preserves: tbl, next, virt |
530 | * Corrupts: tmp1, tmp2 | |
c79b954b | 531 | */ |
b4a0d8b3 CM |
532 | .macro create_pgd_entry, tbl, virt, tmp1, tmp2 |
533 | create_table_entry \tbl, \virt, PGDIR_SHIFT, PTRS_PER_PGD, \tmp1, \tmp2 | |
383c2799 CM |
534 | #if SWAPPER_PGTABLE_LEVELS == 3 |
535 | create_table_entry \tbl, \virt, TABLE_SHIFT, PTRS_PER_PTE, \tmp1, \tmp2 | |
b4a0d8b3 | 536 | #endif |
9703d9d7 CM |
537 | .endm |
538 | ||
539 | /* | |
540 | * Macro to populate block entries in the page table for the start..end | |
541 | * virtual range (inclusive). | |
542 | * | |
543 | * Preserves: tbl, flags | |
544 | * Corrupts: phys, start, end, pstate | |
545 | */ | |
ea8c2e11 | 546 | .macro create_block_map, tbl, flags, phys, start, end |
9703d9d7 | 547 | lsr \phys, \phys, #BLOCK_SHIFT |
9703d9d7 CM |
548 | lsr \start, \start, #BLOCK_SHIFT |
549 | and \start, \start, #PTRS_PER_PTE - 1 // table index | |
9703d9d7 | 550 | orr \phys, \flags, \phys, lsl #BLOCK_SHIFT // table entry |
9703d9d7 CM |
551 | lsr \end, \end, #BLOCK_SHIFT |
552 | and \end, \end, #PTRS_PER_PTE - 1 // table end index | |
9703d9d7 | 553 | 9999: str \phys, [\tbl, \start, lsl #3] // store the entry |
9703d9d7 CM |
554 | add \start, \start, #1 // next entry |
555 | add \phys, \phys, #BLOCK_SIZE // next block | |
556 | cmp \start, \end | |
557 | b.ls 9999b | |
9703d9d7 CM |
558 | .endm |
559 | ||
560 | /* | |
561 | * Setup the initial page tables. We only setup the barest amount which is | |
562 | * required to get the kernel running. The following sections are required: | |
563 | * - identity mapping to enable the MMU (low address, TTBR0) | |
564 | * - first few MB of the kernel linear mapping to jump to once the MMU has | |
565 | * been enabled, including the FDT blob (TTBR1) | |
bf4b558e | 566 | * - pgd entry for fixed mappings (TTBR1) |
9703d9d7 CM |
567 | */ |
568 | __create_page_tables: | |
bd00cd5f | 569 | pgtbl x25, x26, x28 // idmap_pg_dir and swapper_pg_dir addresses |
c218bca7 CM |
570 | mov x27, lr |
571 | ||
572 | /* | |
573 | * Invalidate the idmap and swapper page tables to avoid potential | |
574 | * dirty cache lines being evicted. | |
575 | */ | |
576 | mov x0, x25 | |
577 | add x1, x26, #SWAPPER_DIR_SIZE | |
578 | bl __inval_cache_range | |
9703d9d7 CM |
579 | |
580 | /* | |
581 | * Clear the idmap and swapper page tables. | |
582 | */ | |
583 | mov x0, x25 | |
584 | add x6, x26, #SWAPPER_DIR_SIZE | |
585 | 1: stp xzr, xzr, [x0], #16 | |
586 | stp xzr, xzr, [x0], #16 | |
587 | stp xzr, xzr, [x0], #16 | |
588 | stp xzr, xzr, [x0], #16 | |
589 | cmp x0, x6 | |
590 | b.lo 1b | |
591 | ||
592 | ldr x7, =MM_MMUFLAGS | |
593 | ||
594 | /* | |
595 | * Create the identity mapping. | |
596 | */ | |
b4a0d8b3 | 597 | mov x0, x25 // idmap_pg_dir |
ea8c2e11 CM |
598 | ldr x3, =KERNEL_START |
599 | add x3, x3, x28 // __pa(KERNEL_START) | |
b4a0d8b3 | 600 | create_pgd_entry x0, x3, x5, x6 |
ea8c2e11 CM |
601 | ldr x6, =KERNEL_END |
602 | mov x5, x3 // __pa(KERNEL_START) | |
603 | add x6, x6, x28 // __pa(KERNEL_END) | |
604 | create_block_map x0, x7, x3, x5, x6 | |
9703d9d7 CM |
605 | |
606 | /* | |
607 | * Map the kernel image (starting with PHYS_OFFSET). | |
608 | */ | |
b4a0d8b3 | 609 | mov x0, x26 // swapper_pg_dir |
9703d9d7 | 610 | mov x5, #PAGE_OFFSET |
b4a0d8b3 | 611 | create_pgd_entry x0, x5, x3, x6 |
ea8c2e11 | 612 | ldr x6, =KERNEL_END |
9703d9d7 CM |
613 | mov x3, x24 // phys offset |
614 | create_block_map x0, x7, x3, x5, x6 | |
615 | ||
616 | /* | |
617 | * Map the FDT blob (maximum 2MB; must be within 512MB of | |
618 | * PHYS_OFFSET). | |
619 | */ | |
620 | mov x3, x21 // FDT phys address | |
621 | and x3, x3, #~((1 << 21) - 1) // 2MB aligned | |
622 | mov x6, #PAGE_OFFSET | |
623 | sub x5, x3, x24 // subtract PHYS_OFFSET | |
624 | tst x5, #~((1 << 29) - 1) // within 512MB? | |
625 | csel x21, xzr, x21, ne // zero the FDT pointer | |
626 | b.ne 1f | |
627 | add x5, x5, x6 // __va(FDT blob) | |
628 | add x6, x5, #1 << 21 // 2MB for the FDT blob | |
629 | sub x6, x6, #1 // inclusive range | |
630 | create_block_map x0, x7, x3, x5, x6 | |
631 | 1: | |
c218bca7 CM |
632 | /* |
633 | * Since the page tables have been populated with non-cacheable | |
634 | * accesses (MMU disabled), invalidate the idmap and swapper page | |
635 | * tables again to remove any speculatively loaded cache lines. | |
636 | */ | |
637 | mov x0, x25 | |
638 | add x1, x26, #SWAPPER_DIR_SIZE | |
639 | bl __inval_cache_range | |
640 | ||
641 | mov lr, x27 | |
9703d9d7 CM |
642 | ret |
643 | ENDPROC(__create_page_tables) | |
644 | .ltorg | |
645 | ||
646 | .align 3 | |
647 | .type __switch_data, %object | |
648 | __switch_data: | |
649 | .quad __mmap_switched | |
9703d9d7 | 650 | .quad __bss_start // x6 |
bd00cd5f | 651 | .quad __bss_stop // x7 |
9703d9d7 CM |
652 | .quad processor_id // x4 |
653 | .quad __fdt_pointer // x5 | |
654 | .quad memstart_addr // x6 | |
655 | .quad init_thread_union + THREAD_START_SP // sp | |
656 | ||
657 | /* | |
658 | * The following fragment of code is executed with the MMU on in MMU mode, and | |
659 | * uses absolute addresses; this is not position independent. | |
660 | */ | |
661 | __mmap_switched: | |
662 | adr x3, __switch_data + 8 | |
663 | ||
9703d9d7 | 664 | ldp x6, x7, [x3], #16 |
9703d9d7 CM |
665 | 1: cmp x6, x7 |
666 | b.hs 2f | |
667 | str xzr, [x6], #8 // Clear BSS | |
668 | b 1b | |
669 | 2: | |
670 | ldp x4, x5, [x3], #16 | |
671 | ldr x6, [x3], #8 | |
672 | ldr x16, [x3] | |
673 | mov sp, x16 | |
674 | str x22, [x4] // Save processor ID | |
675 | str x21, [x5] // Save FDT pointer | |
676 | str x24, [x6] // Save PHYS_OFFSET | |
677 | mov x29, #0 | |
678 | b start_kernel | |
679 | ENDPROC(__mmap_switched) | |
680 | ||
681 | /* | |
682 | * Exception handling. Something went wrong and we can't proceed. We ought to | |
683 | * tell the user, but since we don't have any guarantee that we're even | |
684 | * running on the right architecture, we do virtually nothing. | |
685 | */ | |
686 | __error_p: | |
687 | ENDPROC(__error_p) | |
688 | ||
689 | __error: | |
690 | 1: nop | |
691 | b 1b | |
692 | ENDPROC(__error) | |
693 | ||
694 | /* | |
695 | * This function gets the processor ID in w0 and searches the cpu_table[] for | |
696 | * a match. It returns a pointer to the struct cpu_info it found. The | |
697 | * cpu_table[] must end with an empty (all zeros) structure. | |
698 | * | |
699 | * This routine can be called via C code and it needs to work with the MMU | |
700 | * both disabled and enabled (the offset is calculated automatically). | |
701 | */ | |
702 | ENTRY(lookup_processor_type) | |
703 | adr x1, __lookup_processor_type_data | |
704 | ldp x2, x3, [x1] | |
705 | sub x1, x1, x2 // get offset between VA and PA | |
706 | add x3, x3, x1 // convert VA to PA | |
707 | 1: | |
708 | ldp w5, w6, [x3] // load cpu_id_val and cpu_id_mask | |
709 | cbz w5, 2f // end of list? | |
710 | and w6, w6, w0 | |
711 | cmp w5, w6 | |
712 | b.eq 3f | |
713 | add x3, x3, #CPU_INFO_SZ | |
714 | b 1b | |
715 | 2: | |
716 | mov x3, #0 // unknown processor | |
717 | 3: | |
718 | mov x0, x3 | |
719 | ret | |
720 | ENDPROC(lookup_processor_type) | |
721 | ||
722 | .align 3 | |
723 | .type __lookup_processor_type_data, %object | |
724 | __lookup_processor_type_data: | |
725 | .quad . | |
726 | .quad cpu_table | |
727 | .size __lookup_processor_type_data, . - __lookup_processor_type_data | |
728 | ||
729 | /* | |
730 | * Determine validity of the x21 FDT pointer. | |
731 | * The dtb must be 8-byte aligned and live in the first 512M of memory. | |
732 | */ | |
733 | __vet_fdt: | |
734 | tst x21, #0x7 | |
735 | b.ne 1f | |
736 | cmp x21, x24 | |
737 | b.lt 1f | |
738 | mov x0, #(1 << 29) | |
739 | add x0, x0, x24 | |
740 | cmp x21, x0 | |
741 | b.ge 1f | |
742 | ret | |
743 | 1: | |
744 | mov x21, #0 | |
745 | ret | |
746 | ENDPROC(__vet_fdt) |