[deliverable/linux.git] / arch / m68knommu / platform / 68360 / entry.S

/*
 *  linux/arch/m68knommu/platform/68360/entry.S
 *
 *  Copyright (C) 1991, 1992  Linus Torvalds
 *  Copyright (C) 2001 SED Systems, a Division of Calian Ltd.
 *
 * This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file README.legal in the main directory of this archive
 * for more details.
 *
 * Linux/m68k support by Hamish Macdonald
 * M68360 Port by SED Systems, and Lineo.
 */

#include <linux/sys.h>
#include <linux/linkage.h>
#include <asm/thread_info.h>
#include <asm/unistd.h>
#include <asm/errno.h>
#include <asm/setup.h>
#include <asm/segment.h>
#include <asm/traps.h>
#include <asm/asm-offsets.h>
#include <asm/entry.h>

.text

.globl system_call
.globl resume
.globl ret_from_exception
.globl ret_from_signal
.globl sys_call_table
.globl ret_from_interrupt
.globl bad_interrupt
.globl inthandler

badsys:
	movel	#-ENOSYS,%sp@(PT_OFF_D0)
	jra	ret_from_exception

do_trace:
	movel	#-ENOSYS,%sp@(PT_OFF_D0) /* needed for strace*/
	subql	#4,%sp
	SAVE_SWITCH_STACK
	jbsr	syscall_trace
	RESTORE_SWITCH_STACK
	addql	#4,%sp
	movel	%sp@(PT_OFF_ORIG_D0),%d1
	movel	#-ENOSYS,%d0
	cmpl	#NR_syscalls,%d1
	jcc	1f
	lsl	#2,%d1
	lea	sys_call_table, %a0
	jbsr	%a0@(%d1)

1:	movel	%d0,%sp@(PT_OFF_D0)	/* save the return value */
	subql	#4,%sp			/* dummy return address */
	SAVE_SWITCH_STACK
	jbsr	syscall_trace

ret_from_signal:
	RESTORE_SWITCH_STACK
	addql	#4,%sp
	jra	ret_from_exception

ENTRY(system_call)
	SAVE_ALL

	/* save top of frame*/
	pea	%sp@
	jbsr	set_esp0
	addql	#4,%sp

	btst	#PF_TRACESYS_BIT,%a2@(TASK_FLAGS+PF_TRACESYS_OFF)
	jne	do_trace
	cmpl	#NR_syscalls,%d0
	jcc	badsys
	lsl	#2,%d0
	lea	sys_call_table,%a0
	movel	%a0@(%d0), %a0
	jbsr	%a0@
	movel	%d0,%sp@(PT_OFF_D0)	/* save the return value*/

ret_from_exception:
	btst	#5,%sp@(PT_OFF_SR)	/* check if returning to kernel*/
	jeq	Luser_return		/* if so, skip resched, signals*/

Lkernel_return:
	RESTORE_ALL

Luser_return:
	/* only allow interrupts when we are really the last one on the*/
	/* kernel stack, otherwise stack overflow can occur during*/
	/* heavy interrupt load*/
	andw	#ALLOWINT,%sr

	movel	%sp,%d1			/* get thread_info pointer */
	andl	#-THREAD_SIZE,%d1
	movel	%d1,%a2
	move	%a2@(TI_FLAGS),%d1	/* thread_info->flags */
	andl	#_TIF_WORK_MASK,%d1
	jne	Lwork_to_do
	RESTORE_ALL

Lwork_to_do:
	movel	%a2@(TI_FLAGS),%d1	/* thread_info->flags */
	btst	#TIF_NEED_RESCHED,%d1
	jne	reschedule

Lsignal_return:
	subql	#4,%sp			/* dummy return address*/
	SAVE_SWITCH_STACK
	pea	%sp@(SWITCH_STACK_SIZE)
	clrl	%sp@-
	bsrw	do_signal
	addql	#8,%sp
	RESTORE_SWITCH_STACK
	addql	#4,%sp
Lreturn:
	RESTORE_ALL

/*
 * This is the main interrupt handler, responsible for calling do_IRQ()
 */
inthandler:
	SAVE_ALL
	movew	%sp@(PT_OFF_VECTOR), %d0
	and.l	#0x3ff, %d0
	lsr.l   #0x02,  %d0

	movel	%sp,%sp@-
	movel	%d0,%sp@- 		/*  put vector # on stack*/
	jbsr	do_IRQ			/*  process the IRQ*/
3:     	addql	#8,%sp			/*  pop parameters off stack*/
	bra	ret_from_interrupt

ret_from_interrupt:
	jeq	1f
2:
	RESTORE_ALL
1:
	moveb	%sp@(PT_OFF_SR), %d0
	and	#7, %d0
	jhi	2b
	/* check if we need to do software interrupts */

	movel	irq_stat+CPUSTAT_SOFTIRQ_PENDING,%d0
	jeq	ret_from_exception

	pea	ret_from_exception
	jra	do_softirq


/*
 * Handler for uninitialized and spurious interrupts.
 */
bad_interrupt:
	addql	#1,num_spurious
	rte

/*
 * Beware - when entering resume, prev (the current task) is
 * in a0, next (the new task) is in a1,so don't change these
 * registers until their contents are no longer needed.
 */
ENTRY(resume)
	movel	%a0,%d1				/* save prev thread in d1 */
	movew	%sr,%a0@(TASK_THREAD+THREAD_SR)	/* save sr */
	movel	%usp,%a2			/* save usp */
	movel	%a2,%a0@(TASK_THREAD+THREAD_USP)

	SAVE_SWITCH_STACK
	movel	%sp,%a0@(TASK_THREAD+THREAD_KSP) /* save kernel stack */
	movel	%a1@(TASK_THREAD+THREAD_KSP),%sp /* restore new thread stack */
	RESTORE_SWITCH_STACK

	movel	%a1@(TASK_THREAD+THREAD_USP),%a0 /* restore user stack */
	movel	%a0,%usp
	movew	%a1@(TASK_THREAD+THREAD_SR),%sr	/* restore thread status reg */
	rts
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/m68knommu/platform/68360/entry.S
	3	*
	4	* Copyright (C) 1991, 1992 Linus Torvalds
	5	* Copyright (C) 2001 SED Systems, a Division of Calian Ltd.
	6	*
	7	* This file is subject to the terms and conditions of the GNU General Public
	8	* License. See the file README.legal in the main directory of this archive
	9	* for more details.
	10	*
	11	* Linux/m68k support by Hamish Macdonald
	12	* M68360 Port by SED Systems, and Lineo.
	13	*/
	14
1da177e4 LT	15	#include <linux/sys.h>
	16	#include <linux/linkage.h>
	17	#include <asm/thread_info.h>
	18	#include <asm/unistd.h>
	19	#include <asm/errno.h>
	20	#include <asm/setup.h>
	21	#include <asm/segment.h>
	22	#include <asm/traps.h>
	23	#include <asm/asm-offsets.h>
	24	#include <asm/entry.h>
	25
	26	.text
	27
	28	.globl system_call
	29	.globl resume
	30	.globl ret_from_exception
	31	.globl ret_from_signal
	32	.globl sys_call_table
	33	.globl ret_from_interrupt
	34	.globl bad_interrupt
	35	.globl inthandler
	36
	37	badsys:
c84b564e	38	movel #-ENOSYS,%sp@(PT_OFF_D0)
1da177e4 LT	39	jra ret_from_exception
	40
	41	do_trace:
c84b564e	42	movel #-ENOSYS,%sp@(PT_OFF_D0) /* needed for strace*/
1da177e4 LT	43	subql #4,%sp
	44	SAVE_SWITCH_STACK
	45	jbsr syscall_trace
	46	RESTORE_SWITCH_STACK
	47	addql #4,%sp
c84b564e	48	movel %sp@(PT_OFF_ORIG_D0),%d1
1da177e4 LT	49	movel #-ENOSYS,%d0
	50	cmpl #NR_syscalls,%d1
	51	jcc 1f
	52	lsl #2,%d1
	53	lea sys_call_table, %a0
	54	jbsr %a0@(%d1)
	55
c84b564e	56	1: movel %d0,%sp@(PT_OFF_D0) /* save the return value */
1da177e4 LT	57	subql #4,%sp /* dummy return address */
	58	SAVE_SWITCH_STACK
	59	jbsr syscall_trace
	60
	61	ret_from_signal:
	62	RESTORE_SWITCH_STACK
	63	addql #4,%sp
	64	jra ret_from_exception
	65
	66	ENTRY(system_call)
	67	SAVE_ALL
	68
	69	/* save top of frame*/
	70	pea %sp@
	71	jbsr set_esp0
	72	addql #4,%sp
	73
	74	btst #PF_TRACESYS_BIT,%a2@(TASK_FLAGS+PF_TRACESYS_OFF)
	75	jne do_trace
	76	cmpl #NR_syscalls,%d0
	77	jcc badsys
	78	lsl #2,%d0
	79	lea sys_call_table,%a0
	80	movel %a0@(%d0), %a0
	81	jbsr %a0@
c84b564e	82	movel %d0,%sp@(PT_OFF_D0) /* save the return value*/
1da177e4 LT	83
1da177e4 LT	84	ret_from_exception:
c84b564e	85	btst #5,%sp@(PT_OFF_SR) /* check if returning to kernel*/
1da177e4 LT	86	jeq Luser_return /* if so, skip resched, signals*/
	87
	88	Lkernel_return:
	89	RESTORE_ALL
	90
	91	Luser_return:
	92	/* only allow interrupts when we are really the last one on the*/
	93	/* kernel stack, otherwise stack overflow can occur during*/
	94	/* heavy interrupt load*/
	95	andw #ALLOWINT,%sr
	96
	97	movel %sp,%d1 /* get thread_info pointer */
8410a546	98	andl #-THREAD_SIZE,%d1
1da177e4 LT	99	movel %d1,%a2
	100	move %a2@(TI_FLAGS),%d1 /* thread_info->flags */
	101	andl #_TIF_WORK_MASK,%d1
	102	jne Lwork_to_do
	103	RESTORE_ALL
	104
	105	Lwork_to_do:
	106	movel %a2@(TI_FLAGS),%d1 /* thread_info->flags */
	107	btst #TIF_NEED_RESCHED,%d1
	108	jne reschedule
	109
	110	Lsignal_return:
	111	subql #4,%sp /* dummy return address*/
	112	SAVE_SWITCH_STACK
	113	pea %sp@(SWITCH_STACK_SIZE)
	114	clrl %sp@-
	115	bsrw do_signal
	116	addql #8,%sp
	117	RESTORE_SWITCH_STACK
	118	addql #4,%sp
	119	Lreturn:
	120	RESTORE_ALL
	121
	122	/*
2502b667	123	* This is the main interrupt handler, responsible for calling do_IRQ()
1da177e4 LT	124	*/
	125	inthandler:
	126	SAVE_ALL
c84b564e	127	movew %sp@(PT_OFF_VECTOR), %d0
1da177e4 LT	128	and.l #0x3ff, %d0
	129	lsr.l #0x02, %d0
	130
	131	movel %sp,%sp@-
	132	movel %d0,%sp@- /* put vector # on stack*/
2502b667	133	jbsr do_IRQ /* process the IRQ*/
1da177e4 LT	134	3: addql #8,%sp /* pop parameters off stack*/
	135	bra ret_from_interrupt
	136
	137	ret_from_interrupt:
1da177e4 LT	138	jeq 1f
	139	2:
	140	RESTORE_ALL
	141	1:
c84b564e	142	moveb %sp@(PT_OFF_SR), %d0
1da177e4 LT	143	and #7, %d0
	144	jhi 2b
	145	/* check if we need to do software interrupts */
	146
	147	movel irq_stat+CPUSTAT_SOFTIRQ_PENDING,%d0
	148	jeq ret_from_exception
	149
	150	pea ret_from_exception
	151	jra do_softirq
	152
	153
	154	/*
	155	* Handler for uninitialized and spurious interrupts.
	156	*/
	157	bad_interrupt:
	158	addql #1,num_spurious
	159	rte
	160
	161	/*
	162	* Beware - when entering resume, prev (the current task) is
	163	* in a0, next (the new task) is in a1,so don't change these
	164	* registers until their contents are no longer needed.
	165	*/
	166	ENTRY(resume)
	167	movel %a0,%d1 /* save prev thread in d1 */
	168	movew %sr,%a0@(TASK_THREAD+THREAD_SR) /* save sr */
	169	movel %usp,%a2 /* save usp */
	170	movel %a2,%a0@(TASK_THREAD+THREAD_USP)
	171
	172	SAVE_SWITCH_STACK
	173	movel %sp,%a0@(TASK_THREAD+THREAD_KSP) /* save kernel stack */
	174	movel %a1@(TASK_THREAD+THREAD_KSP),%sp /* restore new thread stack */
	175	RESTORE_SWITCH_STACK
	176
	177	movel %a1@(TASK_THREAD+THREAD_USP),%a0 /* restore user stack */
	178	movel %a0,%usp
	179	movew %a1@(TASK_THREAD+THREAD_SR),%sr /* restore thread status reg */
	180	rts
	181