[deliverable/linux.git] / arch / mips / kernel / mcount.S

/*
 * MIPS specific _mcount support
 *
 * This file is subject to the terms and conditions of the GNU General Public
 * License.  See the file "COPYING" in the main directory of this archive for
 * more details.
 *
 * Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
 * Copyright (C) 2010 DSLab, Lanzhou University, China
 * Author: Wu Zhangjin <wuzhangjin@gmail.com>
 */

#include <asm/regdef.h>
#include <asm/stackframe.h>
#include <asm/ftrace.h>

	.text
	.set noreorder
	.set noat

	.macro MCOUNT_SAVE_REGS
	PTR_SUBU	sp, PT_SIZE
	PTR_S	ra, PT_R31(sp)
	PTR_S	AT, PT_R1(sp)
	PTR_S	a0, PT_R4(sp)
	PTR_S	a1, PT_R5(sp)
	PTR_S	a2, PT_R6(sp)
	PTR_S	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_S	a4, PT_R8(sp)
	PTR_S	a5, PT_R9(sp)
	PTR_S	a6, PT_R10(sp)
	PTR_S	a7, PT_R11(sp)
#endif
	.endm

	.macro MCOUNT_RESTORE_REGS
	PTR_L	ra, PT_R31(sp)
	PTR_L	AT, PT_R1(sp)
	PTR_L	a0, PT_R4(sp)
	PTR_L	a1, PT_R5(sp)
	PTR_L	a2, PT_R6(sp)
	PTR_L	a3, PT_R7(sp)
#ifdef CONFIG_64BIT
	PTR_L	a4, PT_R8(sp)
	PTR_L	a5, PT_R9(sp)
	PTR_L	a6, PT_R10(sp)
	PTR_L	a7, PT_R11(sp)
#endif
	PTR_ADDIU	sp, PT_SIZE
	.endm

	.macro RETURN_BACK
	jr ra
	 move ra, AT
	.endm

/*
 * The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
 * the location of the parent's return address.
 */
#define MCOUNT_RA_ADDRESS_REG	$12

#ifdef CONFIG_DYNAMIC_FTRACE

NESTED(ftrace_caller, PT_SIZE, ra)
	.globl _mcount
_mcount:
	b	ftrace_stub
#ifdef CONFIG_32BIT
	 addiu sp,sp,8
#else
	 nop
#endif

	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
	MCOUNT_SAVE_REGS
#ifdef KBUILD_MCOUNT_RA_ADDRESS
	PTR_S	MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
#endif

	PTR_SUBU a0, ra, 8	/* arg1: self address */
	PTR_LA   t1, _stext
	sltu     t2, a0, t1	/* t2 = (a0 < _stext) */
	PTR_LA   t1, _etext
	sltu     t3, t1, a0	/* t3 = (a0 > _etext) */
	or       t1, t2, t3
	beqz     t1, ftrace_call
	 nop
#if defined(KBUILD_MCOUNT_RA_ADDRESS) && defined(CONFIG_32BIT)
	PTR_SUBU a0, a0, 16	/* arg1: adjust to module's recorded callsite */
#else
	PTR_SUBU a0, a0, 12
#endif

	.globl ftrace_call
ftrace_call:
	nop	/* a placeholder for the call to a real tracing function */
	 move	a1, AT		/* arg2: parent's return address */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	.globl ftrace_graph_call
ftrace_graph_call:
	nop
	 nop
#endif

	MCOUNT_RESTORE_REGS
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(ftrace_caller)

#else	/* ! CONFIG_DYNAMIC_FTRACE */

NESTED(_mcount, PT_SIZE, ra)
	PTR_LA	t1, ftrace_stub
	PTR_L	t2, ftrace_trace_function /* Prepare t2 for (1) */
	bne	t1, t2, static_trace
	 nop

#ifdef	CONFIG_FUNCTION_GRAPH_TRACER
	PTR_L	t3, ftrace_graph_return
	bne	t1, t3, ftrace_graph_caller
	 nop
	PTR_LA	t1, ftrace_graph_entry_stub
	PTR_L	t3, ftrace_graph_entry
	bne	t1, t3, ftrace_graph_caller
	 nop
#endif
	b	ftrace_stub
#ifdef CONFIG_32BIT
	 addiu sp, sp, 8
#else
	 nop
#endif

static_trace:
	MCOUNT_SAVE_REGS

	move	a0, ra		/* arg1: self return address */
	jalr	t2		/* (1) call *ftrace_trace_function */
	 move	a1, AT		/* arg2: parent's return address */

	MCOUNT_RESTORE_REGS
#ifdef CONFIG_32BIT
	addiu sp, sp, 8
#endif
	.globl ftrace_stub
ftrace_stub:
	RETURN_BACK
	END(_mcount)

#endif	/* ! CONFIG_DYNAMIC_FTRACE */

#ifdef CONFIG_FUNCTION_GRAPH_TRACER

NESTED(ftrace_graph_caller, PT_SIZE, ra)
#ifndef CONFIG_DYNAMIC_FTRACE
	MCOUNT_SAVE_REGS
#endif

	/* arg1: Get the location of the parent's return address */
#ifdef KBUILD_MCOUNT_RA_ADDRESS
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a0, PT_R12(sp)
#else
	move	a0, MCOUNT_RA_ADDRESS_REG
#endif
	bnez	a0, 1f	/* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
	 nop
#endif
	PTR_LA	a0, PT_R1(sp)	/* leaf func: the location in current stack */
1:

	/* arg2: Get self return address */
#ifdef CONFIG_DYNAMIC_FTRACE
	PTR_L	a1, PT_R31(sp)
#else
	move	a1, ra
#endif

	/* arg3: Get frame pointer of current stack */
#ifdef CONFIG_64BIT
	PTR_LA	a2, PT_SIZE(sp)
#else
	PTR_LA	a2, (PT_SIZE+8)(sp)
#endif

	jal	prepare_ftrace_return
	 nop
	MCOUNT_RESTORE_REGS
#ifndef CONFIG_DYNAMIC_FTRACE
#ifdef CONFIG_32BIT
	addiu sp, sp, 8
#endif
#endif
	RETURN_BACK
	END(ftrace_graph_caller)

	.align	2
	.globl	return_to_handler
return_to_handler:
	PTR_SUBU	sp, PT_SIZE
	PTR_S	v0, PT_R2(sp)

	jal	ftrace_return_to_handler
	 PTR_S	v1, PT_R3(sp)

	/* restore the real parent address: v0 -> ra */
	move	ra, v0

	PTR_L	v0, PT_R2(sp)
	PTR_L	v1, PT_R3(sp)
	jr	ra
	 PTR_ADDIU	sp, PT_SIZE
#endif /* CONFIG_FUNCTION_GRAPH_TRACER */

	.set at
	.set reorder
Commit	Line	Data
d2bb0762 WZ	1	/*
	2	* MIPS specific _mcount support
	3	*
	4	* This file is subject to the terms and conditions of the GNU General Public
	5	* License. See the file "COPYING" in the main directory of this archive for
	6	* more details.
	7	*
	8	* Copyright (C) 2009 Lemote Inc. & DSLab, Lanzhou University, China
042e571d	9	* Copyright (C) 2010 DSLab, Lanzhou University, China
f7a904df	10	* Author: Wu Zhangjin <wuzhangjin@gmail.com>
d2bb0762 WZ	11	*/
	12
	13	#include <asm/regdef.h>
	14	#include <asm/stackframe.h>
	15	#include <asm/ftrace.h>
	16
	17	.text
	18	.set noreorder
	19	.set noat
	20
	21	.macro MCOUNT_SAVE_REGS
	22	PTR_SUBU sp, PT_SIZE
	23	PTR_S ra, PT_R31(sp)
	24	PTR_S AT, PT_R1(sp)
	25	PTR_S a0, PT_R4(sp)
	26	PTR_S a1, PT_R5(sp)
	27	PTR_S a2, PT_R6(sp)
	28	PTR_S a3, PT_R7(sp)
	29	#ifdef CONFIG_64BIT
	30	PTR_S a4, PT_R8(sp)
	31	PTR_S a5, PT_R9(sp)
	32	PTR_S a6, PT_R10(sp)
	33	PTR_S a7, PT_R11(sp)
	34	#endif
	35	.endm
	36
	37	.macro MCOUNT_RESTORE_REGS
	38	PTR_L ra, PT_R31(sp)
	39	PTR_L AT, PT_R1(sp)
	40	PTR_L a0, PT_R4(sp)
	41	PTR_L a1, PT_R5(sp)
	42	PTR_L a2, PT_R6(sp)
	43	PTR_L a3, PT_R7(sp)
	44	#ifdef CONFIG_64BIT
	45	PTR_L a4, PT_R8(sp)
	46	PTR_L a5, PT_R9(sp)
	47	PTR_L a6, PT_R10(sp)
	48	PTR_L a7, PT_R11(sp)
d2bb0762	49	#endif
ad8c3969 DD	50	PTR_ADDIU sp, PT_SIZE
ad8c3969 DD	51	.endm
d2bb0762 WZ	52
	53	.macro RETURN_BACK
	54	jr ra
	55	move ra, AT
	56	.endm
	57
56b49cd3 WZ	58	/*
	59	* The -mmcount-ra-address option of gcc 4.5 uses register $12 to pass
	60	* the location of the parent's return address.
	61	*/
	62	#define MCOUNT_RA_ADDRESS_REG $12
	63
538f1952 WZ	64	#ifdef CONFIG_DYNAMIC_FTRACE
	65
	66	NESTED(ftrace_caller, PT_SIZE, ra)
	67	.globl _mcount
	68	_mcount:
	69	b ftrace_stub
ad8c3969 DD	70	#ifdef CONFIG_32BIT
	71	addiu sp,sp,8
	72	#else
	73	nop
	74	#endif
58b69401 AC	75
58b69401 AC	76	/* When tracing is activated, it calls ftrace_caller+8 (aka here) */
538f1952	77	MCOUNT_SAVE_REGS
7326c4e5	78	#ifdef KBUILD_MCOUNT_RA_ADDRESS
56b49cd3	79	PTR_S MCOUNT_RA_ADDRESS_REG, PT_R12(sp)
7326c4e5	80	#endif
538f1952	81
05f22639	82	PTR_SUBU a0, ra, 8 /* arg1: self address */
dce0e7d5 PG	83	PTR_LA t1, _stext
	84	sltu t2, a0, t1 /* t2 = (a0 < _stext) */
	85	PTR_LA t1, _etext
	86	sltu t3, t1, a0 /* t3 = (a0 > _etext) */
	87	or t1, t2, t3
	88	beqz t1, ftrace_call
	89	nop
	90	#if defined(KBUILD_MCOUNT_RA_ADDRESS) && defined(CONFIG_32BIT)
	91	PTR_SUBU a0, a0, 16 /* arg1: adjust to module's recorded callsite */
	92	#else
	93	PTR_SUBU a0, a0, 12
	94	#endif
	95
538f1952 WZ	96	.globl ftrace_call
	97	ftrace_call:
	98	nop /* a placeholder for the call to a real tracing function */
042e571d	99	move a1, AT /* arg2: parent's return address */
538f1952	100
e17ff5fe WZ	101	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	102	.globl ftrace_graph_call
	103	ftrace_graph_call:
	104	nop
	105	nop
	106	#endif
	107
538f1952 WZ	108	MCOUNT_RESTORE_REGS
	109	.globl ftrace_stub
	110	ftrace_stub:
	111	RETURN_BACK
	112	END(ftrace_caller)
	113
	114	#else /* ! CONFIG_DYNAMIC_FTRACE */
	115
d2bb0762	116	NESTED(_mcount, PT_SIZE, ra)
fc49a3be WZ	117	PTR_LA t1, ftrace_stub
	118	PTR_L t2, ftrace_trace_function /* Prepare t2 for (1) */
	119	bne t1, t2, static_trace
d2bb0762	120	nop
29c5d346 WZ	121
29c5d346 WZ	122	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
fc49a3be WZ	123	PTR_L t3, ftrace_graph_return
fc49a3be WZ	124	bne t1, t3, ftrace_graph_caller
29c5d346	125	nop
fc49a3be WZ	126	PTR_LA t1, ftrace_graph_entry_stub
	127	PTR_L t3, ftrace_graph_entry
	128	bne t1, t3, ftrace_graph_caller
29c5d346 WZ	129	nop
29c5d346 WZ	130	#endif
d2bb0762	131	b ftrace_stub
8a574cfa MC	132	#ifdef CONFIG_32BIT
	133	addiu sp, sp, 8
	134	#else
d2bb0762	135	nop
8a574cfa	136	#endif
d2bb0762 WZ	137
	138	static_trace:
	139	MCOUNT_SAVE_REGS
	140
042e571d	141	move a0, ra /* arg1: self return address */
fc49a3be	142	jalr t2 /* (1) call ftrace_trace_function /
042e571d	143	move a1, AT /* arg2: parent's return address */
d2bb0762 WZ	144
d2bb0762 WZ	145	MCOUNT_RESTORE_REGS
8a574cfa MC	146	#ifdef CONFIG_32BIT
	147	addiu sp, sp, 8
	148	#endif
d2bb0762 WZ	149	.globl ftrace_stub
	150	ftrace_stub:
	151	RETURN_BACK
	152	END(_mcount)
	153
538f1952 WZ	154	#endif /* ! CONFIG_DYNAMIC_FTRACE */
538f1952 WZ	155
29c5d346 WZ	156	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	157
	158	NESTED(ftrace_graph_caller, PT_SIZE, ra)
cbe555b0	159	#ifndef CONFIG_DYNAMIC_FTRACE
29c5d346	160	MCOUNT_SAVE_REGS
e17ff5fe	161	#endif
7326c4e5	162
cbe555b0	163	/* arg1: Get the location of the parent's return address */
7326c4e5	164	#ifdef KBUILD_MCOUNT_RA_ADDRESS
cbe555b0 WZ	165	#ifdef CONFIG_DYNAMIC_FTRACE
	166	PTR_L a0, PT_R12(sp)
	167	#else
56b49cd3	168	move a0, MCOUNT_RA_ADDRESS_REG
cbe555b0	169	#endif
56b49cd3	170	bnez a0, 1f /* non-leaf func: stored in MCOUNT_RA_ADDRESS_REG */
7326c4e5	171	nop
cbe555b0 WZ	172	#endif
	173	PTR_LA a0, PT_R1(sp) /* leaf func: the location in current stack */
	174	1:
	175
	176	/* arg2: Get self return address */
	177	#ifdef CONFIG_DYNAMIC_FTRACE
	178	PTR_L a1, PT_R31(sp)
7326c4e5	179	#else
cbe555b0	180	move a1, ra
7326c4e5	181	#endif
cbe555b0 WZ	182
cbe555b0 WZ	183	/* arg3: Get frame pointer of current stack */
046199ca	184	#ifdef CONFIG_64BIT
65ab2826	185	PTR_LA a2, PT_SIZE(sp)
046199ca	186	#else
65ab2826	187	PTR_LA a2, (PT_SIZE+8)(sp)
046199ca	188	#endif
29c5d346	189
cbe555b0 WZ	190	jal prepare_ftrace_return
cbe555b0 WZ	191	nop
29c5d346	192	MCOUNT_RESTORE_REGS
8a574cfa MC	193	#ifndef CONFIG_DYNAMIC_FTRACE
	194	#ifdef CONFIG_32BIT
	195	addiu sp, sp, 8
	196	#endif
	197	#endif
29c5d346 WZ	198	RETURN_BACK
	199	END(ftrace_graph_caller)
	200
	201	.align 2
	202	.globl return_to_handler
	203	return_to_handler:
	204	PTR_SUBU sp, PT_SIZE
	205	PTR_S v0, PT_R2(sp)
	206
	207	jal ftrace_return_to_handler
	208	PTR_S v1, PT_R3(sp)
	209
	210	/* restore the real parent address: v0 -> ra */
	211	move ra, v0
	212
	213	PTR_L v0, PT_R2(sp)
	214	PTR_L v1, PT_R3(sp)
	215	jr ra
	216	PTR_ADDIU sp, PT_SIZE
	217	#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
	218
d2bb0762 WZ	219	.set at
d2bb0762 WZ	220	.set reorder