[deliverable/linux.git] / arch / powerpc / mm / slb_low.S

/*
 * Low-level SLB routines
 *
 * Copyright (C) 2004 David Gibson <dwg@au.ibm.com>, IBM
 *
 * Based on earlier C version:
 * Dave Engebretsen and Mike Corrigan {engebret|mikejc}@us.ibm.com
 *    Copyright (c) 2001 Dave Engebretsen
 * Copyright (C) 2002 Anton Blanchard <anton@au.ibm.com>, IBM
 *
 *  This program is free software; you can redistribute it and/or
 *  modify it under the terms of the GNU General Public License
 *  as published by the Free Software Foundation; either version
 *  2 of the License, or (at your option) any later version.
 */

#include <asm/processor.h>
#include <asm/ppc_asm.h>
#include <asm/asm-offsets.h>
#include <asm/cputable.h>
#include <asm/page.h>
#include <asm/mmu.h>
#include <asm/pgtable.h>
#include <asm/firmware.h>

/* void slb_allocate_realmode(unsigned long ea);
 *
 * Create an SLB entry for the given EA (user or kernel).
 * 	r3 = faulting address, r13 = PACA
 *	r9, r10, r11 are clobbered by this function
 * No other registers are examined or changed.
 */
_GLOBAL(slb_allocate_realmode)
	/* r3 = faulting address */

	srdi	r9,r3,60		/* get region */
	srdi	r10,r3,28		/* get esid */
	cmpldi	cr7,r9,0xc		/* cmp PAGE_OFFSET for later use */

	/* r3 = address, r10 = esid, cr7 = <> PAGE_OFFSET */
	blt	cr7,0f			/* user or kernel? */

	/* kernel address: proto-VSID = ESID */
	/* WARNING - MAGIC: we don't use the VSID 0xfffffffff, but
	 * this code will generate the protoVSID 0xfffffffff for the
	 * top segment.  That's ok, the scramble below will translate
	 * it to VSID 0, which is reserved as a bad VSID - one which
	 * will never have any pages in it.  */

	/* Check if hitting the linear mapping or some other kernel space
	*/
	bne	cr7,1f

	/* Linear mapping encoding bits, the "li" instruction below will
	 * be patched by the kernel at boot
	 */
_GLOBAL(slb_miss_kernel_load_linear)
	li	r11,0
BEGIN_FTR_SECTION
	b	slb_finish_load
END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
	b	slb_finish_load_1T

1:
#ifdef CONFIG_SPARSEMEM_VMEMMAP
	/* Check virtual memmap region. To be patches at kernel boot */
	cmpldi	cr0,r9,0xf
	bne	1f
_GLOBAL(slb_miss_kernel_load_vmemmap)
	li	r11,0
	b	6f
1:
#endif /* CONFIG_SPARSEMEM_VMEMMAP */

	/* vmalloc mapping gets the encoding from the PACA as the mapping
	 * can be demoted from 64K -> 4K dynamically on some machines
	 */
	clrldi	r11,r10,48
	cmpldi	r11,(VMALLOC_SIZE >> 28) - 1
	bgt	5f
	lhz	r11,PACAVMALLOCSLLP(r13)
	b	6f
5:
	/* IO mapping */
	_GLOBAL(slb_miss_kernel_load_io)
	li	r11,0
6:
BEGIN_FTR_SECTION
	b	slb_finish_load
END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
	b	slb_finish_load_1T

0:	/* user address: proto-VSID = context << 15 | ESID. First check
	 * if the address is within the boundaries of the user region
	 */
	srdi.	r9,r10,USER_ESID_BITS
	bne-	8f			/* invalid ea bits set */


	/* when using slices, we extract the psize off the slice bitmaps
	 * and then we need to get the sllp encoding off the mmu_psize_defs
	 * array.
	 *
	 * XXX This is a bit inefficient especially for the normal case,
	 * so we should try to implement a fast path for the standard page
	 * size using the old sllp value so we avoid the array. We cannot
	 * really do dynamic patching unfortunately as processes might flip
	 * between 4k and 64k standard page size
	 */
#ifdef CONFIG_PPC_MM_SLICES
	cmpldi	r10,16

	/* Get the slice index * 4 in r11 and matching slice size mask in r9 */
	ld	r9,PACALOWSLICESPSIZE(r13)
	sldi	r11,r10,2
	blt	5f
	ld	r9,PACAHIGHSLICEPSIZE(r13)
	srdi	r11,r10,(SLICE_HIGH_SHIFT - SLICE_LOW_SHIFT - 2)
	andi.	r11,r11,0x3c

5:	/* Extract the psize and multiply to get an array offset */
	srd	r9,r9,r11
	andi.	r9,r9,0xf
	mulli	r9,r9,MMUPSIZEDEFSIZE

	/* Now get to the array and obtain the sllp
	 */
	ld	r11,PACATOC(r13)
	ld	r11,mmu_psize_defs@got(r11)
	add	r11,r11,r9
	ld	r11,MMUPSIZESLLP(r11)
	ori	r11,r11,SLB_VSID_USER
#else
	/* paca context sllp already contains the SLB_VSID_USER bits */
	lhz	r11,PACACONTEXTSLLP(r13)
#endif /* CONFIG_PPC_MM_SLICES */

	ld	r9,PACACONTEXTID(r13)
BEGIN_FTR_SECTION
	cmpldi	r10,0x1000
END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
	rldimi	r10,r9,USER_ESID_BITS,0
BEGIN_FTR_SECTION
	bge	slb_finish_load_1T
END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
	b	slb_finish_load

8:	/* invalid EA */
	li	r10,0			/* BAD_VSID */
	li	r11,SLB_VSID_USER	/* flags don't much matter */
	b	slb_finish_load

#ifdef __DISABLED__

/* void slb_allocate_user(unsigned long ea);
 *
 * Create an SLB entry for the given EA (user or kernel).
 * 	r3 = faulting address, r13 = PACA
 *	r9, r10, r11 are clobbered by this function
 * No other registers are examined or changed.
 *
 * It is called with translation enabled in order to be able to walk the
 * page tables. This is not currently used.
 */
_GLOBAL(slb_allocate_user)
	/* r3 = faulting address */
	srdi	r10,r3,28		/* get esid */

	crset	4*cr7+lt		/* set "user" flag for later */

	/* check if we fit in the range covered by the pagetables*/
	srdi.	r9,r3,PGTABLE_EADDR_SIZE
	crnot	4*cr0+eq,4*cr0+eq
	beqlr

	/* now we need to get to the page tables in order to get the page
	 * size encoding from the PMD. In the future, we'll be able to deal
	 * with 1T segments too by getting the encoding from the PGD instead
	 */
	ld	r9,PACAPGDIR(r13)
	cmpldi	cr0,r9,0
	beqlr
	rlwinm	r11,r10,8,25,28
	ldx	r9,r9,r11		/* get pgd_t */
	cmpldi	cr0,r9,0
	beqlr
	rlwinm	r11,r10,3,17,28
	ldx	r9,r9,r11		/* get pmd_t */
	cmpldi	cr0,r9,0
	beqlr

	/* build vsid flags */
	andi.	r11,r9,SLB_VSID_LLP
	ori	r11,r11,SLB_VSID_USER

	/* get context to calculate proto-VSID */
	ld	r9,PACACONTEXTID(r13)
	rldimi	r10,r9,USER_ESID_BITS,0

	/* fall through slb_finish_load */

#endif /* __DISABLED__ */


/*
 * Finish loading of an SLB entry and return
 *
 * r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9, cr7 = <> PAGE_OFFSET
 */
slb_finish_load:
	ASM_VSID_SCRAMBLE(r10,r9,256M)
	rldimi	r11,r10,SLB_VSID_SHIFT,16	/* combine VSID and flags */

	/* r3 = EA, r11 = VSID data */
	/*
	 * Find a slot, round robin. Previously we tried to find a
	 * free slot first but that took too long. Unfortunately we
 	 * dont have any LRU information to help us choose a slot.
 	 */

7:	ld	r10,PACASTABRR(r13)
	addi	r10,r10,1
	/* This gets soft patched on boot. */
_GLOBAL(slb_compare_rr_to_size)
	cmpldi	r10,0

	blt+	4f
	li	r10,SLB_NUM_BOLTED

4:
	std	r10,PACASTABRR(r13)

3:
	rldimi	r3,r10,0,36		/* r3= EA[0:35] | entry */
	oris	r10,r3,SLB_ESID_V@h	/* r3 |= SLB_ESID_V */

	/* r3 = ESID data, r11 = VSID data */

	/*
	 * No need for an isync before or after this slbmte. The exception
	 * we enter with and the rfid we exit with are context synchronizing.
	 */
	slbmte	r11,r10

	/* we're done for kernel addresses */
	crclr	4*cr0+eq		/* set result to "success" */
	bgelr	cr7

	/* Update the slb cache */
	lhz	r3,PACASLBCACHEPTR(r13)	/* offset = paca->slb_cache_ptr */
	cmpldi	r3,SLB_CACHE_ENTRIES
	bge	1f

	/* still room in the slb cache */
	sldi	r11,r3,1		/* r11 = offset * sizeof(u16) */
	rldicl	r10,r10,36,28		/* get low 16 bits of the ESID */
	add	r11,r11,r13		/* r11 = (u16 *)paca + offset */
	sth	r10,PACASLBCACHE(r11)	/* paca->slb_cache[offset] = esid */
	addi	r3,r3,1			/* offset++ */
	b	2f
1:					/* offset >= SLB_CACHE_ENTRIES */
	li	r3,SLB_CACHE_ENTRIES+1
2:
	sth	r3,PACASLBCACHEPTR(r13)	/* paca->slb_cache_ptr = offset */
	crclr	4*cr0+eq		/* set result to "success" */
	blr

/*
 * Finish loading of a 1T SLB entry (for the kernel linear mapping) and return.
 *
 * r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9
 */
slb_finish_load_1T:
	srdi	r10,r10,40-28		/* get 1T ESID */
	ASM_VSID_SCRAMBLE(r10,r9,1T)
	rldimi	r11,r10,SLB_VSID_SHIFT_1T,16	/* combine VSID and flags */
	li	r10,MMU_SEGSIZE_1T
	rldimi	r11,r10,SLB_VSID_SSIZE_SHIFT,0	/* insert segment size */

	/* r3 = EA, r11 = VSID data */
	clrrdi	r3,r3,SID_SHIFT_1T	/* clear out non-ESID bits */
	b	7b
Commit	Line	Data
1da177e4	1	/*
1da177e4 LT	2	* Low-level SLB routines
	3	*
	4	* Copyright (C) 2004 David Gibson <dwg@au.ibm.com>, IBM
	5	*
	6	* Based on earlier C version:
	7	* Dave Engebretsen and Mike Corrigan {engebret\|mikejc}@us.ibm.com
	8	* Copyright (c) 2001 Dave Engebretsen
	9	* Copyright (C) 2002 Anton Blanchard <anton@au.ibm.com>, IBM
	10	*
	11	* This program is free software; you can redistribute it and/or
	12	* modify it under the terms of the GNU General Public License
	13	* as published by the Free Software Foundation; either version
	14	* 2 of the License, or (at your option) any later version.
	15	*/
	16
1da177e4	17	#include <asm/processor.h>
1da177e4	18	#include <asm/ppc_asm.h>
0013a854	19	#include <asm/asm-offsets.h>
1da177e4	20	#include <asm/cputable.h>
3c726f8d BH	21	#include <asm/page.h>
	22	#include <asm/mmu.h>
	23	#include <asm/pgtable.h>
3f639ee8	24	#include <asm/firmware.h>
1da177e4	25
3c726f8d	26	/* void slb_allocate_realmode(unsigned long ea);
1da177e4 LT	27	*
	28	* Create an SLB entry for the given EA (user or kernel).
	29	* r3 = faulting address, r13 = PACA
	30	* r9, r10, r11 are clobbered by this function
	31	* No other registers are examined or changed.
	32	*/
3c726f8d BH	33	_GLOBAL(slb_allocate_realmode)
3c726f8d BH	34	/* r3 = faulting address */
1da177e4 LT	35
1da177e4 LT	36	srdi r9,r3,60 /* get region */
3c726f8d	37	srdi r10,r3,28 /* get esid */
b5666f70	38	cmpldi cr7,r9,0xc /* cmp PAGE_OFFSET for later use */
1da177e4	39
b5666f70	40	/* r3 = address, r10 = esid, cr7 = <> PAGE_OFFSET */
1da177e4 LT	41	blt cr7,0f /* user or kernel? */
	42
	43	/* kernel address: proto-VSID = ESID */
	44	/* WARNING - MAGIC: we don't use the VSID 0xfffffffff, but
	45	* this code will generate the protoVSID 0xfffffffff for the
	46	* top segment. That's ok, the scramble below will translate
	47	* it to VSID 0, which is reserved as a bad VSID - one which
	48	* will never have any pages in it. */
1da177e4	49
cec08e7a	50	/* Check if hitting the linear mapping or some other kernel space
3c726f8d BH	51	*/
	52	bne cr7,1f
	53
	54	/* Linear mapping encoding bits, the "li" instruction below will
	55	* be patched by the kernel at boot
	56	*/
	57	_GLOBAL(slb_miss_kernel_load_linear)
	58	li r11,0
1189be65	59	BEGIN_FTR_SECTION
3c726f8d	60	b slb_finish_load
44ae3ab3	61	END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
1189be65	62	b slb_finish_load_1T
3c726f8d	63
cec08e7a BH	64	1:
	65	#ifdef CONFIG_SPARSEMEM_VMEMMAP
	66	/* Check virtual memmap region. To be patches at kernel boot */
	67	cmpldi cr0,r9,0xf
	68	bne 1f
	69	_GLOBAL(slb_miss_kernel_load_vmemmap)
	70	li r11,0
	71	b 6f
	72	1:
	73	#endif /* CONFIG_SPARSEMEM_VMEMMAP */
	74
8d8997f3 BH	75	/* vmalloc mapping gets the encoding from the PACA as the mapping
8d8997f3 BH	76	* can be demoted from 64K -> 4K dynamically on some machines
3c726f8d	77	*/
bf72aeba PM	78	clrldi r11,r10,48
	79	cmpldi r11,(VMALLOC_SIZE >> 28) - 1
	80	bgt 5f
	81	lhz r11,PACAVMALLOCSLLP(r13)
1189be65	82	b 6f
bf72aeba	83	5:
8d8997f3 BH	84	/* IO mapping */
8d8997f3 BH	85	_GLOBAL(slb_miss_kernel_load_io)
3c726f8d	86	li r11,0
1189be65 PM	87	6:
1189be65 PM	88	BEGIN_FTR_SECTION
3c726f8d	89	b slb_finish_load
44ae3ab3	90	END_MMU_FTR_SECTION_IFCLR(MMU_FTR_1T_SEGMENT)
1189be65	91	b slb_finish_load_1T
3c726f8d BH	92
	93	0: /* user address: proto-VSID = context << 15 \| ESID. First check
	94	* if the address is within the boundaries of the user region
	95	*/
	96	srdi. r9,r10,USER_ESID_BITS
1da177e4 LT	97	bne- 8f /* invalid ea bits set */
1da177e4 LT	98
d0f13e3c BH	99
	100	/* when using slices, we extract the psize off the slice bitmaps
	101	* and then we need to get the sllp encoding off the mmu_psize_defs
	102	* array.
	103	*
	104	* XXX This is a bit inefficient especially for the normal case,
	105	* so we should try to implement a fast path for the standard page
	106	* size using the old sllp value so we avoid the array. We cannot
	107	* really do dynamic patching unfortunately as processes might flip
	108	* between 4k and 64k standard page size
	109	*/
	110	#ifdef CONFIG_PPC_MM_SLICES
7d24f0b8 DG	111	cmpldi r10,16
7d24f0b8 DG	112
d0f13e3c BH	113	/* Get the slice index * 4 in r11 and matching slice size mask in r9 */
	114	ld r9,PACALOWSLICESPSIZE(r13)
	115	sldi r11,r10,2
7d24f0b8	116	blt 5f
d0f13e3c BH	117	ld r9,PACAHIGHSLICEPSIZE(r13)
	118	srdi r11,r10,(SLICE_HIGH_SHIFT - SLICE_LOW_SHIFT - 2)
	119	andi. r11,r11,0x3c
7d24f0b8	120
d0f13e3c BH	121	5: /* Extract the psize and multiply to get an array offset */
	122	srd r9,r9,r11
	123	andi. r9,r9,0xf
	124	mulli r9,r9,MMUPSIZEDEFSIZE
c594adad	125
d0f13e3c BH	126	/* Now get to the array and obtain the sllp
	127	*/
	128	ld r11,PACATOC(r13)
	129	ld r11,mmu_psize_defs@got(r11)
	130	add r11,r11,r9
	131	ld r11,MMUPSIZESLLP(r11)
	132	ori r11,r11,SLB_VSID_USER
	133	#else
	134	/* paca context sllp already contains the SLB_VSID_USER bits */
bf72aeba	135	lhz r11,PACACONTEXTSLLP(r13)
d0f13e3c BH	136	#endif /* CONFIG_PPC_MM_SLICES */
d0f13e3c BH	137
3c726f8d	138	ld r9,PACACONTEXTID(r13)
1189be65 PM	139	BEGIN_FTR_SECTION
1189be65 PM	140	cmpldi r10,0x1000
44ae3ab3	141	END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
3c726f8d	142	rldimi r10,r9,USER_ESID_BITS,0
1189be65 PM	143	BEGIN_FTR_SECTION
1189be65 PM	144	bge slb_finish_load_1T
44ae3ab3	145	END_MMU_FTR_SECTION_IFSET(MMU_FTR_1T_SEGMENT)
3c726f8d BH	146	b slb_finish_load
	147
	148	8: /* invalid EA */
	149	li r10,0 /* BAD_VSID */
	150	li r11,SLB_VSID_USER /* flags don't much matter */
	151	b slb_finish_load
	152
	153	#ifdef __DISABLED__
	154
	155	/* void slb_allocate_user(unsigned long ea);
	156	*
	157	* Create an SLB entry for the given EA (user or kernel).
	158	* r3 = faulting address, r13 = PACA
	159	* r9, r10, r11 are clobbered by this function
	160	* No other registers are examined or changed.
	161	*
	162	* It is called with translation enabled in order to be able to walk the
	163	* page tables. This is not currently used.
	164	*/
	165	_GLOBAL(slb_allocate_user)
	166	/* r3 = faulting address */
	167	srdi r10,r3,28 /* get esid */
	168
	169	crset 4cr7+lt / set "user" flag for later */
	170
	171	/* check if we fit in the range covered by the pagetables*/
	172	srdi. r9,r3,PGTABLE_EADDR_SIZE
	173	crnot 4cr0+eq,4cr0+eq
	174	beqlr
1da177e4	175
3c726f8d BH	176	/* now we need to get to the page tables in order to get the page
	177	* size encoding from the PMD. In the future, we'll be able to deal
	178	* with 1T segments too by getting the encoding from the PGD instead
	179	*/
	180	ld r9,PACAPGDIR(r13)
	181	cmpldi cr0,r9,0
	182	beqlr
	183	rlwinm r11,r10,8,25,28
	184	ldx r9,r9,r11 /* get pgd_t */
	185	cmpldi cr0,r9,0
	186	beqlr
	187	rlwinm r11,r10,3,17,28
	188	ldx r9,r9,r11 /* get pmd_t */
	189	cmpldi cr0,r9,0
	190	beqlr
	191
	192	/* build vsid flags */
	193	andi. r11,r9,SLB_VSID_LLP
	194	ori r11,r11,SLB_VSID_USER
	195
	196	/* get context to calculate proto-VSID */
319e76a1	197	ld r9,PACACONTEXTID(r13)
3c726f8d BH	198	rldimi r10,r9,USER_ESID_BITS,0
	199
	200	/* fall through slb_finish_load */
	201
	202	#endif /* __DISABLED__ */
1da177e4	203
1da177e4	204
3c726f8d BH	205	/*
	206	* Finish loading of an SLB entry and return
	207	*
b5666f70	208	* r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9, cr7 = <> PAGE_OFFSET
3c726f8d BH	209	*/
3c726f8d BH	210	slb_finish_load:
1189be65	211	ASM_VSID_SCRAMBLE(r10,r9,256M)
3c726f8d BH	212	rldimi r11,r10,SLB_VSID_SHIFT,16 /* combine VSID and flags */
	213
	214	/* r3 = EA, r11 = VSID data */
	215	/*
	216	* Find a slot, round robin. Previously we tried to find a
	217	* free slot first but that took too long. Unfortunately we
	218	* dont have any LRU information to help us choose a slot.
	219	*/
3c726f8d	220
1189be65	221	7: ld r10,PACASTABRR(r13)
3c726f8d	222	addi r10,r10,1
584f8b71 MN	223	/* This gets soft patched on boot. */
	224	_GLOBAL(slb_compare_rr_to_size)
	225	cmpldi r10,0
3c726f8d BH	226
	227	blt+ 4f
	228	li r10,SLB_NUM_BOLTED
	229
	230	4:
	231	std r10,PACASTABRR(r13)
	232
	233	3:
	234	rldimi r3,r10,0,36 /* r3= EA[0:35] \| entry */
	235	oris r10,r3,SLB_ESID_V@h /* r3 \|= SLB_ESID_V */
	236
	237	/* r3 = ESID data, r11 = VSID data */
1da177e4 LT	238
	239	/*
	240	* No need for an isync before or after this slbmte. The exception
	241	* we enter with and the rfid we exit with are context synchronizing.
	242	*/
	243	slbmte r11,r10
	244
3c726f8d BH	245	/* we're done for kernel addresses */
	246	crclr 4cr0+eq / set result to "success" */
	247	bgelr cr7
1da177e4 LT	248
	249	/* Update the slb cache */
	250	lhz r3,PACASLBCACHEPTR(r13) /* offset = paca->slb_cache_ptr */
	251	cmpldi r3,SLB_CACHE_ENTRIES
	252	bge 1f
	253
	254	/* still room in the slb cache */
	255	sldi r11,r3,1 /* r11 = offset * sizeof(u16) */
	256	rldicl r10,r10,36,28 /* get low 16 bits of the ESID */
	257	add r11,r11,r13 /* r11 = (u16 )paca + offset /
	258	sth r10,PACASLBCACHE(r11) /* paca->slb_cache[offset] = esid */
	259	addi r3,r3,1 /* offset++ */
	260	b 2f
	261	1: /* offset >= SLB_CACHE_ENTRIES */
	262	li r3,SLB_CACHE_ENTRIES+1
	263	2:
	264	sth r3,PACASLBCACHEPTR(r13) /* paca->slb_cache_ptr = offset */
3c726f8d	265	crclr 4cr0+eq / set result to "success" */
1da177e4 LT	266	blr
1da177e4 LT	267
1189be65 PM	268	/*
1189be65 PM	269	* Finish loading of a 1T SLB entry (for the kernel linear mapping) and return.
1189be65 PM	270	*
	271	* r3 = EA, r10 = proto-VSID, r11 = flags, clobbers r9
	272	*/
	273	slb_finish_load_1T:
	274	srdi r10,r10,40-28 /* get 1T ESID */
	275	ASM_VSID_SCRAMBLE(r10,r9,1T)
	276	rldimi r11,r10,SLB_VSID_SHIFT_1T,16 /* combine VSID and flags */
	277	li r10,MMU_SEGSIZE_1T
	278	rldimi r11,r10,SLB_VSID_SSIZE_SHIFT,0 /* insert segment size */
	279
	280	/* r3 = EA, r11 = VSID data */
	281	clrrdi r3,r3,SID_SHIFT_1T /* clear out non-ESID bits */
	282	b 7b
	283