[deliverable/linux.git] / arch / s390 / kernel / head.S

/*
 * Copyright IBM Corp. 1999,2010
 *
 *    Author(s): Hartmut Penner <hp@de.ibm.com>
 *		 Martin Schwidefsky <schwidefsky@de.ibm.com>
 *		 Rob van der Heij <rvdhei@iae.nl>
 *		 Heiko Carstens <heiko.carstens@de.ibm.com>
 *
 * There are 5 different IPL methods
 *  1) load the image directly into ram at address 0 and do an PSW restart
 *  2) linload will load the image from address 0x10000 to memory 0x10000
 *     and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
 *  3) generate the tape ipl header, store the generated image on a tape
 *     and ipl from it
 *     In case of SL tape you need to IPL 5 times to get past VOL1 etc
 *  4) generate the vm reader ipl header, move the generated image to the
 *     VM reader (use option NOH!) and do a ipl from reader (VM only)
 *  5) direct call of start by the SALIPL loader
 *  We use the cpuid to distinguish between VM and native ipl
 *  params for kernel are pushed to 0x10400 (see setup.h)
 *
 */

#include <linux/init.h>
#include <linux/linkage.h>
#include <asm/asm-offsets.h>
#include <asm/thread_info.h>
#include <asm/page.h>

#ifdef CONFIG_64BIT
#define ARCH_OFFSET	4
#else
#define ARCH_OFFSET	0
#endif

__HEAD
#ifndef CONFIG_IPL
	.org   0
	.long  0x00080000,0x80000000+startup	# Just a restart PSW
#else
#ifdef CONFIG_IPL_TAPE
#define IPL_BS 1024
	.org   0
	.long  0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long  0x27000000,0x60000001		# by ipl to addresses 0-23.
	.long  0x02000000,0x20000000+IPL_BS	# (a PSW and two CCWs).
	.long  0x00000000,0x00000000		# external old psw
	.long  0x00000000,0x00000000		# svc old psw
	.long  0x00000000,0x00000000		# program check old psw
	.long  0x00000000,0x00000000		# machine check old psw
	.long  0x00000000,0x00000000		# io old psw
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x00000000,0x00000000
	.long  0x000a0000,0x00000058		# external new psw
	.long  0x000a0000,0x00000060		# svc new psw
	.long  0x000a0000,0x00000068		# program check new psw
	.long  0x000a0000,0x00000070		# machine check new psw
	.long  0x00080000,0x80000000+.Lioint	# io new psw

	.org   0x100
#
# subroutine for loading from tape
# Parameters:
#  R1 = device number
#  R2 = load address
.Lloader:
	st	%r14,.Lldret
	la	%r3,.Lorbread		# r3 = address of orb
	la	%r5,.Lirb		# r5 = address of irb
	st	%r2,.Lccwread+4 	# initialize CCW data addresses
	lctl	%c6,%c6,.Lcr6
	slr	%r2,%r2
.Lldlp:
	la	%r6,3			# 3 retries
.Lssch:
	ssch	0(%r3)			# load chunk of IPL_BS bytes
	bnz	.Llderr
.Lw4end:
	bas	%r14,.Lwait4io
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lrecov
	slr	%r7,%r7
	icm	%r7,3,10(%r5)		# get residual count
	lcr	%r7,%r7
	la	%r7,IPL_BS(%r7) 	# IPL_BS-residual=#bytes read
	ar	%r2,%r7 		# add to total size
	tm	8(%r5),0x01		# found a tape mark ?
	bnz	.Ldone
	l	%r0,.Lccwread+4 	# update CCW data addresses
	ar	%r0,%r7
	st	%r0,.Lccwread+4
	b	.Lldlp
.Ldone:
	l	%r14,.Lldret
	br	%r14			# r2 contains the total size
.Lrecov:
	bas	%r14,.Lsense		# do the sensing
	bct	%r6,.Lssch		# dec. retry count & branch
	b	.Llderr
#
# Sense subroutine
#
.Lsense:
	st	%r14,.Lsnsret
	la	%r7,.Lorbsense
	ssch	0(%r7)			# start sense command
	bnz	.Llderr
	bas	%r14,.Lwait4io
	l	%r14,.Lsnsret
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Llderr
	br	%r14
#
# Wait for interrupt subroutine
#
.Lwait4io:
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4io
	tsch	0(%r5)
	slr	%r0,%r0
	tm	8(%r5),0x82		# do we have a problem ?
	bnz	.Lwtexit
	tm	8(%r5),0x04		# got device end ?
	bz	.Lwait4io
.Lwtexit:
	br	%r14
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorbread:
	.long	0x00000000,0x0080ff00,.Lccwread
	.align	8
.Lorbsense:
	.long	0x00000000,0x0080ff00,.Lccwsense
	.align	8
.Lccwread:
	.long	0x02200000+IPL_BS,0x00000000
.Lccwsense:
	.long	0x04200001,0x00000000
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lldret:.long	0
.Lsnsret: .long 0
#endif	/* CONFIG_IPL_TAPE */

#ifdef CONFIG_IPL_VM
#define IPL_BS	0x730
	.org	0
	.long	0x00080000,0x80000000+iplstart	# The first 24 bytes are loaded
	.long	0x02000018,0x60000050		# by ipl to addresses 0-23.
	.long	0x02000068,0x60000050		# (a PSW and two CCWs).
	.fill	80-24,1,0x40			# bytes 24-79 are discarded !!
	.long	0x020000f0,0x60000050		# The next 160 byte are loaded
	.long	0x02000140,0x60000050		# to addresses 0x18-0xb7
	.long	0x02000190,0x60000050		# They form the continuation
	.long	0x020001e0,0x60000050		# of the CCW program started
	.long	0x02000230,0x60000050		# by ipl and load the range
	.long	0x02000280,0x60000050		# 0x0f0-0x730 from the image
	.long	0x020002d0,0x60000050		# to the range 0x0f0-0x730
	.long	0x02000320,0x60000050		# in memory. At the end of
	.long	0x02000370,0x60000050		# the channel program the PSW
	.long	0x020003c0,0x60000050		# at location 0 is loaded.
	.long	0x02000410,0x60000050		# Initial processing starts
	.long	0x02000460,0x60000050		# at 0xf0 = iplstart.
	.long	0x020004b0,0x60000050
	.long	0x02000500,0x60000050
	.long	0x02000550,0x60000050
	.long	0x020005a0,0x60000050
	.long	0x020005f0,0x60000050
	.long	0x02000640,0x60000050
	.long	0x02000690,0x60000050
	.long	0x020006e0,0x20000050

	.org	0xf0
#
# subroutine for loading cards from the reader
#
.Lloader:
	la	%r3,.Lorb		# r2 = address of orb into r2
	la	%r5,.Lirb		# r4 = address of irb
	la	%r6,.Lccws
	la	%r7,20
.Linit:
	st	%r2,4(%r6)		# initialize CCW data addresses
	la	%r2,0x50(%r2)
	la	%r6,8(%r6)
	bct	7,.Linit

	lctl	%c6,%c6,.Lcr6		# set IO subclass mask
	slr	%r2,%r2
.Lldlp:
	ssch	0(%r3)			# load chunk of 1600 bytes
	bnz	.Llderr
.Lwait4irq:
	mvc	0x78(8),.Lnewpsw	# set up IO interrupt psw
	lpsw	.Lwaitpsw
.Lioint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwait4irq
	tsch	0(%r5)

	slr	%r0,%r0
	ic	%r0,8(%r5)		# get device status
	chi	%r0,8			# channel end ?
	be	.Lcont
	chi	%r0,12			# channel end + device end ?
	be	.Lcont

	l	%r0,4(%r5)
	s	%r0,8(%r3)		# r0/8 = number of ccws executed
	mhi	%r0,10			# *10 = number of bytes in ccws
	lh	%r3,10(%r5)		# get residual count
	sr	%r0,%r3 		# #ccws*80-residual=#bytes read
	ar	%r2,%r0

	br	%r14			# r2 contains the total size

.Lcont:
	ahi	%r2,0x640		# add 0x640 to total size
	la	%r6,.Lccws
	la	%r7,20
.Lincr:
	l	%r0,4(%r6)		# update CCW data addresses
	ahi	%r0,0x640
	st	%r0,4(%r6)
	ahi	%r6,8
	bct	7,.Lincr

	b	.Lldlp
.Llderr:
	lpsw	.Lcrash

	.align	8
.Lorb:	.long	0x00000000,0x0080ff00,.Lccws
.Lirb:	.long	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
.Lcr6:	.long	0xff000000
.Lloadp:.long	0,0
	.align	8
.Lcrash:.long	0x000a0000,0x00000000
.Lnewpsw:
	.long	0x00080000,0x80000000+.Lioint
.Lwaitpsw:
	.long	0x020a0000,0x80000000+.Lioint

	.align	8
.Lccws: .rept	19
	.long	0x02600050,0x00000000
	.endr
	.long	0x02200050,0x00000000
#endif	/* CONFIG_IPL_VM */

iplstart:
	lh	%r1,0xb8		# test if subchannel number
	bct	%r1,.Lnoload		#  is valid
	l	%r1,0xb8		# load ipl subchannel number
	la	%r2,IPL_BS		# load start address
	bas	%r14,.Lloader		# load rest of ipl image
	l	%r12,.Lparm		# pointer to parameter area
	st	%r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number

#
# load parameter file from ipl device
#
.Lagain1:
	l	%r2,.Linitrd		# ramdisk loc. is temp
	bas	%r14,.Lloader		# load parameter file
	ltr	%r2,%r2 		# got anything ?
	bz	.Lnopf
	chi	%r2,895
	bnh	.Lnotrunc
	la	%r2,895
.Lnotrunc:
	l	%r4,.Linitrd
	clc	0(3,%r4),.L_hdr		# if it is HDRx
	bz	.Lagain1		# skip dataset header
	clc	0(3,%r4),.L_eof		# if it is EOFx
	bz	.Lagain1		# skip dateset trailer
	la	%r5,0(%r4,%r2)
	lr	%r3,%r2
	la	%r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
	mvc	0(256,%r3),0(%r4)
	mvc	256(256,%r3),256(%r4)
	mvc	512(256,%r3),512(%r4)
	mvc	768(122,%r3),768(%r4)
	slr	%r0,%r0
	b	.Lcntlp
.Ldelspc:
	ic	%r0,0(%r2,%r3)
	chi	%r0,0x20		# is it a space ?
	be	.Lcntlp
	ahi	%r2,1
	b	.Leolp
.Lcntlp:
	brct	%r2,.Ldelspc
.Leolp:
	slr	%r0,%r0
	stc	%r0,0(%r2,%r3)		# terminate buffer
.Lnopf:

#
# load ramdisk from ipl device
#
.Lagain2:
	l	%r2,.Linitrd		# addr of ramdisk
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	bas	%r14,.Lloader		# load ramdisk
	st	%r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	ltr	%r2,%r2
	bnz	.Lrdcont
	st	%r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
.Lrdcont:
	l	%r2,.Linitrd

	clc	0(3,%r2),.L_hdr		# skip HDRx and EOFx
	bz	.Lagain2
	clc	0(3,%r2),.L_eof
	bz	.Lagain2

#ifdef CONFIG_IPL_VM
#
# reset files in VM reader
#
	stidp	__LC_SAVE_AREA		# store cpuid
	tm	__LC_SAVE_AREA,0xff	# running VM ?
	bno	.Lnoreset
	la	%r2,.Lreset
	lhi	%r3,26
	diag	%r2,%r3,8
	la	%r5,.Lirb
	stsch	0(%r5)			# check if irq is pending
	tm	30(%r5),0x0f		# by verifying if any of the
	bnz	.Lwaitforirq		# activity or status control
	tm	31(%r5),0xff		# bits is set in the schib
	bz	.Lnoreset
.Lwaitforirq:
	mvc	0x78(8),.Lrdrnewpsw	# set up IO interrupt psw
.Lwaitrdrirq:
	lpsw	.Lrdrwaitpsw
.Lrdrint:
	c	%r1,0xb8		# compare subchannel number
	bne	.Lwaitrdrirq
	la	%r5,.Lirb
	tsch	0(%r5)
.Lnoreset:
	b	.Lnoload

	.align	8
.Lrdrnewpsw:
	.long	0x00080000,0x80000000+.Lrdrint
.Lrdrwaitpsw:
	.long	0x020a0000,0x80000000+.Lrdrint
#endif

#
# everything loaded, go for it
#
.Lnoload:
	l	%r1,.Lstartup
	br	%r1

.Linitrd:.long _end			# default address of initrd
.Lparm:	.long  PARMAREA
.Lstartup: .long startup
.Lreset:.byte	0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	.byte	0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	.byte	0xc8,0xd6,0xd3,0xc4	# "change rdr all keep nohold"
.L_eof: .long	0xc5d6c600	 /* C'EOF' */
.L_hdr: .long	0xc8c4d900	 /* C'HDR' */

#endif	/* CONFIG_IPL */

#
# SALIPL loader support. Based on a patch by Rob van der Heij.
# This entry point is called directly from the SALIPL loader and
# doesn't need a builtin ipl record.
#
	.org	0x800
ENTRY(start)
	stm	%r0,%r15,0x07b0		# store registers
	basr	%r12,%r0
.base:
	l	%r11,.parm
	l	%r8,.cmd		# pointer to command buffer

	ltr	%r9,%r9			# do we have SALIPL parameters?
	bp	.sk8x8

	mvc	0(64,%r8),0x00b0	# copy saved registers
	xc	64(240-64,%r8),0(%r8)	# remainder of buffer
	tr	0(64,%r8),.lowcase
	b	.gotr
.sk8x8:
	mvc	0(240,%r8),0(%r9)	# copy iplparms into buffer
.gotr:
	slr	%r0,%r0
	st	%r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	st	%r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	j	startup 		# continue with startup
.cmd:	.long	COMMAND_LINE		# address of command line buffer
.parm:	.long	PARMAREA
.lowcase:
	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f

	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87	# .abcdefg
	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf	# hi
	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97	# .jklmnop
	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf	# qr
	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7	# ..stuvwx
	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef	# yz
	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff

#
# startup-code at 0x10000, running in absolute addressing mode
# this is called either by the ipl loader or directly by PSW restart
# or linload or SALIPL
#
	.org	0x10000
ENTRY(startup)
	j	.Lep_startup_normal
	.org	0x10008
#
# This is a list of s390 kernel entry points. At address 0x1000f the number of
# valid entry points is stored.
#
# IMPORTANT: Do not change this table, it is s390 kernel ABI!
#
	.ascii	"S390EP"
	.byte	0x00,0x01
#
# kdump startup-code at 0x10010, running in 64 bit absolute addressing mode
#
	.org	0x10010
ENTRY(startup_kdump)
	j	.Lep_startup_kdump
.Lep_startup_normal:
	basr	%r13,0			# get base
.LPG0:
	xc	0x200(256),0x200	# partially clear lowcore
	xc	0x300(256),0x300
	xc	0xe00(256),0xe00
	stck	__LC_LAST_UPDATE_CLOCK
	spt	5f-.LPG0(%r13)
	mvc	__LC_LAST_UPDATE_TIMER(8),5f-.LPG0(%r13)
#ifndef CONFIG_MARCH_G5
	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
	xc	__LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
	.insn	s,0xb2b10000,__LC_STFL_FAC_LIST	# store facility list
	tm	__LC_STFL_FAC_LIST,0x01	# stfle available ?
	jz	0f
	la	%r0,0
	.insn	s,0xb2b00000,__LC_STFL_FAC_LIST	# store facility list extended
0:	l	%r0,__LC_STFL_FAC_LIST
	n	%r0,2f+8-.LPG0(%r13)
	cl	%r0,2f+8-.LPG0(%r13)
	jne	1f
	l	%r0,__LC_STFL_FAC_LIST+4
	n	%r0,2f+12-.LPG0(%r13)
	cl	%r0,2f+12-.LPG0(%r13)
	je	3f
1:	l	%r15,.Lstack-.LPG0(%r13)
	ahi	%r15,-96
	la	%r2,.Lals_string-.LPG0(%r13)
	l	%r3,.Lsclp_print-.LPG0(%r13)
	basr	%r14,%r3
	lpsw	2f-.LPG0(%r13)		# machine type not good enough, crash
.Lals_string:
	.asciz	"The Linux kernel requires more recent processor hardware"
.Lsclp_print:
	.long	_sclp_print_early
.Lstack:
	.long	0x8000 + (1<<(PAGE_SHIFT+THREAD_ORDER))
	.align 16
2:	.long	0x000a0000,0x8badcccc
#if defined(CONFIG_64BIT)
#if defined(CONFIG_MARCH_Z196)
	.long 0xc100efe3, 0xf46c0000
#elif defined(CONFIG_MARCH_Z10)
	.long 0xc100efe3, 0xf0680000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0xc100efc3, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0xc0002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0xc0000000, 0x00000000
#endif
#else
#if defined(CONFIG_MARCH_Z196)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z10)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z9_109)
	.long 0x8100c880, 0x00000000
#elif defined(CONFIG_MARCH_Z990)
	.long 0x80002000, 0x00000000
#elif defined(CONFIG_MARCH_Z900)
	.long 0x80000000, 0x00000000
#endif
#endif
3:
#endif

#ifdef CONFIG_64BIT
	mvi	__LC_AR_MODE_ID,1	# set esame flag
	slr	%r0,%r0 		# set cpuid to zero
	lhi	%r1,2			# mode 2 = esame (dump)
	sigp	%r1,%r0,0x12		# switch to esame mode
	sam64				# switch to 64 bit mode
	larl	%r13,4f
	lmh	%r0,%r15,0(%r13)	# clear high-order half
	jg	startup_continue
4:	.fill	16,4,0x0
#else
	mvi	__LC_AR_MODE_ID,0	# set ESA flag (mode 0)
	l	%r13,4f-.LPG0(%r13)
	b	0(%r13)
	.align	8
4:	.long	startup_continue
#endif
	.align	8
5:	.long	0x7fffffff,0xffffffff

#include "head_kdump.S"

#
# params at 10400 (setup.h)
#
	.org	PARMAREA
	.long	0,0			# IPL_DEVICE
	.long	0,0			# INITRD_START
	.long	0,0			# INITRD_SIZE
	.long	0,0			# OLDMEM_BASE
	.long	0,0			# OLDMEM_SIZE

	.org	COMMAND_LINE
	.byte	"root=/dev/ram0 ro"
	.byte	0

	.org	0x11000
Commit	Line	Data
1da177e4	1	/*
1844c9bc	2	* Copyright IBM Corp. 1999,2010
0ad775db HC	3	*
	4	* Author(s): Hartmut Penner <hp@de.ibm.com>
	5	* Martin Schwidefsky <schwidefsky@de.ibm.com>
	6	* Rob van der Heij <rvdhei@iae.nl>
	7	* Heiko Carstens <heiko.carstens@de.ibm.com>
1da177e4 LT	8	*
	9	* There are 5 different IPL methods
	10	* 1) load the image directly into ram at address 0 and do an PSW restart
	11	* 2) linload will load the image from address 0x10000 to memory 0x10000
	12	* and start the code thru LPSW 0x0008000080010000 (VM only, deprecated)
	13	* 3) generate the tape ipl header, store the generated image on a tape
	14	* and ipl from it
	15	* In case of SL tape you need to IPL 5 times to get past VOL1 etc
	16	* 4) generate the vm reader ipl header, move the generated image to the
	17	* VM reader (use option NOH!) and do a ipl from reader (VM only)
	18	* 5) direct call of start by the SALIPL loader
	19	* We use the cpuid to distinguish between VM and native ipl
	20	* params for kernel are pushed to 0x10400 (see setup.h)
0ad775db	21	*
1da177e4 LT	22	*/
1da177e4 LT	23
2133bb8d	24	#include <linux/init.h>
144d634a	25	#include <linux/linkage.h>
0013a854	26	#include <asm/asm-offsets.h>
1da177e4 LT	27	#include <asm/thread_info.h>
	28	#include <asm/page.h>
	29
347a8dc3	30	#ifdef CONFIG_64BIT
0ad775db HC	31	#define ARCH_OFFSET 4
	32	#else
	33	#define ARCH_OFFSET 0
	34	#endif
	35
2133bb8d	36	__HEAD
1da177e4	37	#ifndef CONFIG_IPL
25d83cbf HC	38	.org 0
25d83cbf HC	39	.long 0x00080000,0x80000000+startup # Just a restart PSW
1da177e4 LT	40	#else
	41	#ifdef CONFIG_IPL_TAPE
	42	#define IPL_BS 1024
25d83cbf HC	43	.org 0
	44	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	45	.long 0x27000000,0x60000001 # by ipl to addresses 0-23.
	46	.long 0x02000000,0x20000000+IPL_BS # (a PSW and two CCWs).
	47	.long 0x00000000,0x00000000 # external old psw
	48	.long 0x00000000,0x00000000 # svc old psw
	49	.long 0x00000000,0x00000000 # program check old psw
	50	.long 0x00000000,0x00000000 # machine check old psw
	51	.long 0x00000000,0x00000000 # io old psw
	52	.long 0x00000000,0x00000000
	53	.long 0x00000000,0x00000000
	54	.long 0x00000000,0x00000000
	55	.long 0x000a0000,0x00000058 # external new psw
	56	.long 0x000a0000,0x00000060 # svc new psw
	57	.long 0x000a0000,0x00000068 # program check new psw
	58	.long 0x000a0000,0x00000070 # machine check new psw
	59	.long 0x00080000,0x80000000+.Lioint # io new psw
1da177e4	60
25d83cbf	61	.org 0x100
1da177e4 LT	62	#
1da177e4 LT	63	# subroutine for loading from tape
98a1708d	64	# Parameters:
1da177e4 LT	65	# R1 = device number
1da177e4 LT	66	# R2 = load address
25d83cbf HC	67	.Lloader:
	68	st %r14,.Lldret
	69	la %r3,.Lorbread # r3 = address of orb
	70	la %r5,.Lirb # r5 = address of irb
	71	st %r2,.Lccwread+4 # initialize CCW data addresses
	72	lctl %c6,%c6,.Lcr6
	73	slr %r2,%r2
1da177e4	74	.Lldlp:
25d83cbf	75	la %r6,3 # 3 retries
1da177e4	76	.Lssch:
25d83cbf HC	77	ssch 0(%r3) # load chunk of IPL_BS bytes
25d83cbf HC	78	bnz .Llderr
1da177e4	79	.Lw4end:
25d83cbf HC	80	bas %r14,.Lwait4io
	81	tm 8(%r5),0x82 # do we have a problem ?
	82	bnz .Lrecov
	83	slr %r7,%r7
	84	icm %r7,3,10(%r5) # get residual count
	85	lcr %r7,%r7
	86	la %r7,IPL_BS(%r7) # IPL_BS-residual=#bytes read
	87	ar %r2,%r7 # add to total size
	88	tm 8(%r5),0x01 # found a tape mark ?
	89	bnz .Ldone
	90	l %r0,.Lccwread+4 # update CCW data addresses
	91	ar %r0,%r7
	92	st %r0,.Lccwread+4
	93	b .Lldlp
1da177e4	94	.Ldone:
25d83cbf HC	95	l %r14,.Lldret
25d83cbf HC	96	br %r14 # r2 contains the total size
1da177e4	97	.Lrecov:
25d83cbf HC	98	bas %r14,.Lsense # do the sensing
	99	bct %r6,.Lssch # dec. retry count & branch
	100	b .Llderr
1da177e4 LT	101	#
	102	# Sense subroutine
	103	#
	104	.Lsense:
25d83cbf HC	105	st %r14,.Lsnsret
	106	la %r7,.Lorbsense
	107	ssch 0(%r7) # start sense command
	108	bnz .Llderr
	109	bas %r14,.Lwait4io
	110	l %r14,.Lsnsret
	111	tm 8(%r5),0x82 # do we have a problem ?
	112	bnz .Llderr
	113	br %r14
1da177e4 LT	114	#
	115	# Wait for interrupt subroutine
	116	#
	117	.Lwait4io:
25d83cbf	118	lpsw .Lwaitpsw
1da177e4	119	.Lioint:
25d83cbf HC	120	c %r1,0xb8 # compare subchannel number
	121	bne .Lwait4io
	122	tsch 0(%r5)
	123	slr %r0,%r0
	124	tm 8(%r5),0x82 # do we have a problem ?
	125	bnz .Lwtexit
	126	tm 8(%r5),0x04 # got device end ?
	127	bz .Lwait4io
1da177e4	128	.Lwtexit:
25d83cbf	129	br %r14
1da177e4	130	.Llderr:
25d83cbf	131	lpsw .Lcrash
1da177e4	132
25d83cbf	133	.align 8
1da177e4	134	.Lorbread:
25d83cbf HC	135	.long 0x00000000,0x0080ff00,.Lccwread
25d83cbf HC	136	.align 8
1da177e4	137	.Lorbsense:
25d83cbf HC	138	.long 0x00000000,0x0080ff00,.Lccwsense
25d83cbf HC	139	.align 8
1da177e4	140	.Lccwread:
25d83cbf	141	.long 0x02200000+IPL_BS,0x00000000
1da177e4	142	.Lccwsense:
25d83cbf	143	.long 0x04200001,0x00000000
1da177e4	144	.Lwaitpsw:
25d83cbf	145	.long 0x020a0000,0x80000000+.Lioint
1da177e4	146
25d83cbf HC	147	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	148	.Lcr6: .long 0xff000000
	149	.align 8
	150	.Lcrash:.long 0x000a0000,0x00000000
	151	.Lldret:.long 0
1da177e4	152	.Lsnsret: .long 0
25d83cbf	153	#endif /* CONFIG_IPL_TAPE */
1da177e4 LT	154
1da177e4 LT	155	#ifdef CONFIG_IPL_VM
25d83cbf HC	156	#define IPL_BS 0x730
	157	.org 0
	158	.long 0x00080000,0x80000000+iplstart # The first 24 bytes are loaded
	159	.long 0x02000018,0x60000050 # by ipl to addresses 0-23.
	160	.long 0x02000068,0x60000050 # (a PSW and two CCWs).
	161	.fill 80-24,1,0x40 # bytes 24-79 are discarded !!
	162	.long 0x020000f0,0x60000050 # The next 160 byte are loaded
	163	.long 0x02000140,0x60000050 # to addresses 0x18-0xb7
	164	.long 0x02000190,0x60000050 # They form the continuation
	165	.long 0x020001e0,0x60000050 # of the CCW program started
	166	.long 0x02000230,0x60000050 # by ipl and load the range
	167	.long 0x02000280,0x60000050 # 0x0f0-0x730 from the image
	168	.long 0x020002d0,0x60000050 # to the range 0x0f0-0x730
	169	.long 0x02000320,0x60000050 # in memory. At the end of
	170	.long 0x02000370,0x60000050 # the channel program the PSW
	171	.long 0x020003c0,0x60000050 # at location 0 is loaded.
	172	.long 0x02000410,0x60000050 # Initial processing starts
	173	.long 0x02000460,0x60000050 # at 0xf0 = iplstart.
	174	.long 0x020004b0,0x60000050
	175	.long 0x02000500,0x60000050
	176	.long 0x02000550,0x60000050
	177	.long 0x020005a0,0x60000050
	178	.long 0x020005f0,0x60000050
	179	.long 0x02000640,0x60000050
	180	.long 0x02000690,0x60000050
	181	.long 0x020006e0,0x20000050
1da177e4	182
25d83cbf	183	.org 0xf0
1da177e4 LT	184	#
	185	# subroutine for loading cards from the reader
	186	#
25d83cbf HC	187	.Lloader:
	188	la %r3,.Lorb # r2 = address of orb into r2
	189	la %r5,.Lirb # r4 = address of irb
	190	la %r6,.Lccws
	191	la %r7,20
1da177e4	192	.Linit:
25d83cbf HC	193	st %r2,4(%r6) # initialize CCW data addresses
	194	la %r2,0x50(%r2)
	195	la %r6,8(%r6)
	196	bct 7,.Linit
1da177e4	197
25d83cbf HC	198	lctl %c6,%c6,.Lcr6 # set IO subclass mask
25d83cbf HC	199	slr %r2,%r2
1da177e4	200	.Lldlp:
25d83cbf HC	201	ssch 0(%r3) # load chunk of 1600 bytes
25d83cbf HC	202	bnz .Llderr
1da177e4	203	.Lwait4irq:
25d83cbf HC	204	mvc 0x78(8),.Lnewpsw # set up IO interrupt psw
25d83cbf HC	205	lpsw .Lwaitpsw
1da177e4	206	.Lioint:
25d83cbf HC	207	c %r1,0xb8 # compare subchannel number
	208	bne .Lwait4irq
	209	tsch 0(%r5)
1da177e4	210
25d83cbf HC	211	slr %r0,%r0
	212	ic %r0,8(%r5) # get device status
	213	chi %r0,8 # channel end ?
	214	be .Lcont
	215	chi %r0,12 # channel end + device end ?
	216	be .Lcont
1da177e4	217
25d83cbf HC	218	l %r0,4(%r5)
	219	s %r0,8(%r3) # r0/8 = number of ccws executed
	220	mhi %r0,10 # *10 = number of bytes in ccws
	221	lh %r3,10(%r5) # get residual count
	222	sr %r0,%r3 # #ccws*80-residual=#bytes read
	223	ar %r2,%r0
	224
	225	br %r14 # r2 contains the total size
1da177e4 LT	226
1da177e4 LT	227	.Lcont:
25d83cbf HC	228	ahi %r2,0x640 # add 0x640 to total size
	229	la %r6,.Lccws
	230	la %r7,20
1da177e4	231	.Lincr:
25d83cbf HC	232	l %r0,4(%r6) # update CCW data addresses
	233	ahi %r0,0x640
	234	st %r0,4(%r6)
	235	ahi %r6,8
	236	bct 7,.Lincr
1da177e4	237
25d83cbf	238	b .Lldlp
1da177e4	239	.Llderr:
25d83cbf	240	lpsw .Lcrash
1da177e4	241
25d83cbf HC	242	.align 8
	243	.Lorb: .long 0x00000000,0x0080ff00,.Lccws
	244	.Lirb: .long 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
	245	.Lcr6: .long 0xff000000
	246	.Lloadp:.long 0,0
	247	.align 8
	248	.Lcrash:.long 0x000a0000,0x00000000
1da177e4	249	.Lnewpsw:
25d83cbf	250	.long 0x00080000,0x80000000+.Lioint
1da177e4	251	.Lwaitpsw:
25d83cbf	252	.long 0x020a0000,0x80000000+.Lioint
1da177e4	253
25d83cbf HC	254	.align 8
	255	.Lccws: .rept 19
	256	.long 0x02600050,0x00000000
	257	.endr
	258	.long 0x02200050,0x00000000
	259	#endif /* CONFIG_IPL_VM */
1da177e4 LT	260
1da177e4 LT	261	iplstart:
25d83cbf HC	262	lh %r1,0xb8 # test if subchannel number
	263	bct %r1,.Lnoload # is valid
	264	l %r1,0xb8 # load ipl subchannel number
	265	la %r2,IPL_BS # load start address
	266	bas %r14,.Lloader # load rest of ipl image
	267	l %r12,.Lparm # pointer to parameter area
	268	st %r1,IPL_DEVICE+ARCH_OFFSET-PARMAREA(%r12) # save ipl device number
1da177e4 LT	269
	270	#
	271	# load parameter file from ipl device
	272	#
	273	.Lagain1:
25d83cbf HC	274	l %r2,.Linitrd # ramdisk loc. is temp
	275	bas %r14,.Lloader # load parameter file
	276	ltr %r2,%r2 # got anything ?
	277	bz .Lnopf
	278	chi %r2,895
	279	bnh .Lnotrunc
	280	la %r2,895
1da177e4	281	.Lnotrunc:
25d83cbf HC	282	l %r4,.Linitrd
	283	clc 0(3,%r4),.L_hdr # if it is HDRx
	284	bz .Lagain1 # skip dataset header
	285	clc 0(3,%r4),.L_eof # if it is EOFx
	286	bz .Lagain1 # skip dateset trailer
	287	la %r5,0(%r4,%r2)
	288	lr %r3,%r2
61fd330d	289	la %r3,COMMAND_LINE-PARMAREA(%r12) # load adr. of command line
25d83cbf HC	290	mvc 0(256,%r3),0(%r4)
	291	mvc 256(256,%r3),256(%r4)
	292	mvc 512(256,%r3),512(%r4)
	293	mvc 768(122,%r3),768(%r4)
	294	slr %r0,%r0
	295	b .Lcntlp
1da177e4	296	.Ldelspc:
25d83cbf HC	297	ic %r0,0(%r2,%r3)
	298	chi %r0,0x20 # is it a space ?
	299	be .Lcntlp
	300	ahi %r2,1
	301	b .Leolp
1da177e4	302	.Lcntlp:
25d83cbf	303	brct %r2,.Ldelspc
1da177e4	304	.Leolp:
25d83cbf HC	305	slr %r0,%r0
25d83cbf HC	306	stc %r0,0(%r2,%r3) # terminate buffer
1da177e4 LT	307	.Lnopf:
	308
	309	#
	310	# load ramdisk from ipl device
25d83cbf	311	#
1da177e4	312	.Lagain2:
25d83cbf HC	313	l %r2,.Linitrd # addr of ramdisk
	314	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12)
	315	bas %r14,.Lloader # load ramdisk
	316	st %r2,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r12) # store size of rd
	317	ltr %r2,%r2
	318	bnz .Lrdcont
	319	st %r2,INITRD_START+ARCH_OFFSET-PARMAREA(%r12) # no ramdisk found
1da177e4	320	.Lrdcont:
25d83cbf	321	l %r2,.Linitrd
1da177e4	322
25d83cbf HC	323	clc 0(3,%r2),.L_hdr # skip HDRx and EOFx
	324	bz .Lagain2
	325	clc 0(3,%r2),.L_eof
	326	bz .Lagain2
1da177e4 LT	327
	328	#ifdef CONFIG_IPL_VM
	329	#
	330	# reset files in VM reader
	331	#
94038a99 MS	332	stidp __LC_SAVE_AREA # store cpuid
94038a99 MS	333	tm __LC_SAVE_AREA,0xff # running VM ?
25d83cbf HC	334	bno .Lnoreset
	335	la %r2,.Lreset
	336	lhi %r3,26
	337	diag %r2,%r3,8
	338	la %r5,.Lirb
	339	stsch 0(%r5) # check if irq is pending
	340	tm 30(%r5),0x0f # by verifying if any of the
	341	bnz .Lwaitforirq # activity or status control
	342	tm 31(%r5),0xff # bits is set in the schib
	343	bz .Lnoreset
350e3ade	344	.Lwaitforirq:
25d83cbf	345	mvc 0x78(8),.Lrdrnewpsw # set up IO interrupt psw
2b071886	346	.Lwaitrdrirq:
25d83cbf	347	lpsw .Lrdrwaitpsw
2b071886	348	.Lrdrint:
25d83cbf HC	349	c %r1,0xb8 # compare subchannel number
	350	bne .Lwaitrdrirq
	351	la %r5,.Lirb
	352	tsch 0(%r5)
1da177e4	353	.Lnoreset:
25d83cbf	354	b .Lnoload
2b071886	355
25d83cbf	356	.align 8
2b071886	357	.Lrdrnewpsw:
25d83cbf	358	.long 0x00080000,0x80000000+.Lrdrint
2b071886	359	.Lrdrwaitpsw:
25d83cbf	360	.long 0x020a0000,0x80000000+.Lrdrint
1da177e4	361	#endif
2b071886	362
1da177e4 LT	363	#
	364	# everything loaded, go for it
	365	#
	366	.Lnoload:
25d83cbf HC	367	l %r1,.Lstartup
25d83cbf HC	368	br %r1
1da177e4	369
e033b9a0	370	.Linitrd:.long _end # default address of initrd
1da177e4 LT	371	.Lparm: .long PARMAREA
1da177e4 LT	372	.Lstartup: .long startup
25d83cbf HC	373	.Lreset:.byte 0xc3,0xc8,0xc1,0xd5,0xc7,0xc5,0x40,0xd9,0xc4,0xd9,0x40
	374	.byte 0xc1,0xd3,0xd3,0x40,0xd2,0xc5,0xc5,0xd7,0x40,0xd5,0xd6
	375	.byte 0xc8,0xd6,0xd3,0xc4 # "change rdr all keep nohold"
	376	.L_eof: .long 0xc5d6c600 /* C'EOF' */
	377	.L_hdr: .long 0xc8c4d900 /* C'HDR' */
1da177e4	378
25d83cbf	379	#endif /* CONFIG_IPL */
1da177e4 LT	380
	381	#
	382	# SALIPL loader support. Based on a patch by Rob van der Heij.
	383	# This entry point is called directly from the SALIPL loader and
	384	# doesn't need a builtin ipl record.
	385	#
25d83cbf	386	.org 0x800
144d634a	387	ENTRY(start)
25d83cbf HC	388	stm %r0,%r15,0x07b0 # store registers
25d83cbf HC	389	basr %r12,%r0
1da177e4	390	.base:
25d83cbf HC	391	l %r11,.parm
25d83cbf HC	392	l %r8,.cmd # pointer to command buffer
1da177e4	393
25d83cbf HC	394	ltr %r9,%r9 # do we have SALIPL parameters?
25d83cbf HC	395	bp .sk8x8
1da177e4	396
25d83cbf HC	397	mvc 0(64,%r8),0x00b0 # copy saved registers
	398	xc 64(240-64,%r8),0(%r8) # remainder of buffer
	399	tr 0(64,%r8),.lowcase
	400	b .gotr
1da177e4	401	.sk8x8:
25d83cbf	402	mvc 0(240,%r8),0(%r9) # copy iplparms into buffer
1da177e4	403	.gotr:
25d83cbf HC	404	slr %r0,%r0
	405	st %r0,INITRD_SIZE+ARCH_OFFSET-PARMAREA(%r11)
	406	st %r0,INITRD_START+ARCH_OFFSET-PARMAREA(%r11)
	407	j startup # continue with startup
25d83cbf HC	408	.cmd: .long COMMAND_LINE # address of command line buffer
25d83cbf HC	409	.parm: .long PARMAREA
1da177e4	410	.lowcase:
25d83cbf	411	.byte 0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07
1da177e4	412	.byte 0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f
25d83cbf	413	.byte 0x10,0x11,0x12,0x13,0x14,0x15,0x16,0x17
1da177e4	414	.byte 0x18,0x19,0x1a,0x1b,0x1c,0x1d,0x1e,0x1f
25d83cbf	415	.byte 0x20,0x21,0x22,0x23,0x24,0x25,0x26,0x27
1da177e4	416	.byte 0x28,0x29,0x2a,0x2b,0x2c,0x2d,0x2e,0x2f
25d83cbf	417	.byte 0x30,0x31,0x32,0x33,0x34,0x35,0x36,0x37
1da177e4	418	.byte 0x38,0x39,0x3a,0x3b,0x3c,0x3d,0x3e,0x3f
25d83cbf	419	.byte 0x40,0x41,0x42,0x43,0x44,0x45,0x46,0x47
1da177e4	420	.byte 0x48,0x49,0x4a,0x4b,0x4c,0x4d,0x4e,0x4f
25d83cbf	421	.byte 0x50,0x51,0x52,0x53,0x54,0x55,0x56,0x57
1da177e4	422	.byte 0x58,0x59,0x5a,0x5b,0x5c,0x5d,0x5e,0x5f
25d83cbf	423	.byte 0x60,0x61,0x62,0x63,0x64,0x65,0x66,0x67
1da177e4	424	.byte 0x68,0x69,0x6a,0x6b,0x6c,0x6d,0x6e,0x6f
25d83cbf	425	.byte 0x70,0x71,0x72,0x73,0x74,0x75,0x76,0x77
1da177e4 LT	426	.byte 0x78,0x79,0x7a,0x7b,0x7c,0x7d,0x7e,0x7f
1da177e4 LT	427
25d83cbf	428	.byte 0x80,0x81,0x82,0x83,0x84,0x85,0x86,0x87
1da177e4	429	.byte 0x88,0x89,0x8a,0x8b,0x8c,0x8d,0x8e,0x8f
25d83cbf	430	.byte 0x90,0x91,0x92,0x93,0x94,0x95,0x96,0x97
1da177e4	431	.byte 0x98,0x99,0x9a,0x9b,0x9c,0x9d,0x9e,0x9f
25d83cbf	432	.byte 0xa0,0xa1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7
1da177e4	433	.byte 0xa8,0xa9,0xaa,0xab,0xac,0xad,0xae,0xaf
25d83cbf	434	.byte 0xb0,0xb1,0xb2,0xb3,0xb4,0xb5,0xb6,0xb7
1da177e4	435	.byte 0xb8,0xb9,0xba,0xbb,0xbc,0xbd,0xbe,0xbf
25d83cbf	436	.byte 0xc0,0x81,0x82,0x83,0x84,0x85,0x86,0x87 # .abcdefg
1da177e4	437	.byte 0x88,0x89,0xca,0xcb,0xcc,0xcd,0xce,0xcf # hi
25d83cbf	438	.byte 0xd0,0x91,0x92,0x93,0x94,0x95,0x96,0x97 # .jklmnop
1da177e4 LT	439	.byte 0x98,0x99,0xda,0xdb,0xdc,0xdd,0xde,0xdf # qr
	440	.byte 0xe0,0xe1,0xa2,0xa3,0xa4,0xa5,0xa6,0xa7 # ..stuvwx
	441	.byte 0xa8,0xa9,0xea,0xeb,0xec,0xed,0xee,0xef # yz
25d83cbf	442	.byte 0xf0,0xf1,0xf2,0xf3,0xf4,0xf5,0xf6,0xf7
1da177e4 LT	443	.byte 0xf8,0xf9,0xfa,0xfb,0xfc,0xfd,0xfe,0xff
1da177e4 LT	444
e37f50e1 MS	445	#
	446	# startup-code at 0x10000, running in absolute addressing mode
	447	# this is called either by the ipl loader or directly by PSW restart
	448	# or linload or SALIPL
	449	#
	450	.org 0x10000
144d634a	451	ENTRY(startup)
60a0c68d MH	452	j .Lep_startup_normal
	453	.org 0x10008
	454	#
	455	# This is a list of s390 kernel entry points. At address 0x1000f the number of
	456	# valid entry points is stored.
	457	#
	458	# IMPORTANT: Do not change this table, it is s390 kernel ABI!
	459	#
	460	.ascii "S390EP"
	461	.byte 0x00,0x01
	462	#
	463	# kdump startup-code at 0x10010, running in 64 bit absolute addressing mode
	464	#
	465	.org 0x10010
	466	ENTRY(startup_kdump)
	467	j .Lep_startup_kdump
	468	.Lep_startup_normal:
1844c9bc	469	basr %r13,0 # get base
e37f50e1	470	.LPG0:
866ba284 MS	471	xc 0x200(256),0x200 # partially clear lowcore
866ba284 MS	472	xc 0x300(256),0x300
60a0c68d	473	xc 0xe00(256),0xe00
1844c9bc MS	474	stck __LC_LAST_UPDATE_CLOCK
	475	spt 5f-.LPG0(%r13)
	476	mvc __LC_LAST_UPDATE_TIMER(8),5f-.LPG0(%r13)
e37f50e1	477	#ifndef CONFIG_MARCH_G5
8c4caa4f MS	478	# check capabilities against MARCH_{G5,Z900,Z990,Z9_109,Z10}
8c4caa4f MS	479	xc __LC_STFL_FAC_LIST(8),__LC_STFL_FAC_LIST
88381011	480	.insn s,0xb2b10000,__LC_STFL_FAC_LIST # store facility list
8c4caa4f MS	481	tm __LC_STFL_FAC_LIST,0x01 # stfle available ?
	482	jz 0f
	483	la %r0,0
	484	.insn s,0xb2b00000,__LC_STFL_FAC_LIST # store facility list extended
	485	0: l %r0,__LC_STFL_FAC_LIST
	486	n %r0,2f+8-.LPG0(%r13)
	487	cl %r0,2f+8-.LPG0(%r13)
	488	jne 1f
	489	l %r0,__LC_STFL_FAC_LIST+4
	490	n %r0,2f+12-.LPG0(%r13)
	491	cl %r0,2f+12-.LPG0(%r13)
	492	je 3f
d90cbd46	493	1: l %r15,.Lstack-.LPG0(%r13)
d90cbd46 HC	494	ahi %r15,-96
	495	la %r2,.Lals_string-.LPG0(%r13)
	496	l %r3,.Lsclp_print-.LPG0(%r13)
	497	basr %r14,%r3
	498	lpsw 2f-.LPG0(%r13) # machine type not good enough, crash
	499	.Lals_string:
	500	.asciz "The Linux kernel requires more recent processor hardware"
	501	.Lsclp_print:
	502	.long _sclp_print_early
	503	.Lstack:
1844c9bc	504	.long 0x8000 + (1<<(PAGE_SHIFT+THREAD_ORDER))
e37f50e1	505	.align 16
8c4caa4f MS	506	2: .long 0x000a0000,0x8badcccc
8c4caa4f MS	507	#if defined(CONFIG_64BIT)
f861e405 HC	508	#if defined(CONFIG_MARCH_Z196)
	509	.long 0xc100efe3, 0xf46c0000
	510	#elif defined(CONFIG_MARCH_Z10)
8c4caa4f MS	511	.long 0xc100efe3, 0xf0680000
	512	#elif defined(CONFIG_MARCH_Z9_109)
	513	.long 0xc100efc3, 0x00000000
	514	#elif defined(CONFIG_MARCH_Z990)
	515	.long 0xc0002000, 0x00000000
	516	#elif defined(CONFIG_MARCH_Z900)
	517	.long 0xc0000000, 0x00000000
	518	#endif
	519	#else
f861e405 HC	520	#if defined(CONFIG_MARCH_Z196)
	521	.long 0x8100c880, 0x00000000
	522	#elif defined(CONFIG_MARCH_Z10)
8c4caa4f	523	.long 0x8100c880, 0x00000000
e37f50e1	524	#elif defined(CONFIG_MARCH_Z9_109)
8c4caa4f	525	.long 0x8100c880, 0x00000000
e37f50e1	526	#elif defined(CONFIG_MARCH_Z990)
8c4caa4f	527	.long 0x80002000, 0x00000000
e37f50e1	528	#elif defined(CONFIG_MARCH_Z900)
8c4caa4f MS	529	.long 0x80000000, 0x00000000
8c4caa4f MS	530	#endif
e37f50e1	531	#endif
8c4caa4f	532	3:
e37f50e1 MS	533	#endif
e37f50e1 MS	534
1844c9bc MS	535	#ifdef CONFIG_64BIT
	536	mvi __LC_AR_MODE_ID,1 # set esame flag
	537	slr %r0,%r0 # set cpuid to zero
	538	lhi %r1,2 # mode 2 = esame (dump)
	539	sigp %r1,%r0,0x12 # switch to esame mode
	540	sam64 # switch to 64 bit mode
06c0dd72 MS	541	larl %r13,4f
06c0dd72 MS	542	lmh %r0,%r15,0(%r13) # clear high-order half
1844c9bc	543	jg startup_continue
06c0dd72	544	4: .fill 16,4,0x0
1844c9bc MS	545	#else
1844c9bc MS	546	mvi __LC_AR_MODE_ID,0 # set ESA flag (mode 0)
b6112ccb	547	l %r13,4f-.LPG0(%r13)
e37f50e1	548	b 0(%r13)
1844c9bc	549	.align 8
b6112ccb	550	4: .long startup_continue
1844c9bc	551	#endif
ab96e798	552	.align 8
1844c9bc	553	5: .long 0x7fffffff,0xffffffff
e37f50e1	554
60a0c68d MH	555	#include "head_kdump.S"
60a0c68d MH	556
e37f50e1 MS	557	#
	558	# params at 10400 (setup.h)
	559	#
	560	.org PARMAREA
	561	.long 0,0 # IPL_DEVICE
	562	.long 0,0 # INITRD_START
	563	.long 0,0 # INITRD_SIZE
60a0c68d MH	564	.long 0,0 # OLDMEM_BASE
60a0c68d MH	565	.long 0,0 # OLDMEM_SIZE
e37f50e1 MS	566
	567	.org COMMAND_LINE
	568	.byte "root=/dev/ram0 ro"
	569	.byte 0
	570
1844c9bc	571	.org 0x11000