[deliverable/linux.git] / arch / sparc / kernel / rtrap_64.S

/*
 * rtrap.S: Preparing for return from trap on Sparc V9.
 *
 * Copyright (C) 1997,1998 Jakub Jelinek (jj@sunsite.mff.cuni.cz)
 * Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
 */


#include <asm/asi.h>
#include <asm/pstate.h>
#include <asm/ptrace.h>
#include <asm/spitfire.h>
#include <asm/head.h>
#include <asm/visasm.h>
#include <asm/processor.h>

#define		RTRAP_PSTATE		(PSTATE_TSO|PSTATE_PEF|PSTATE_PRIV|PSTATE_IE)
#define		RTRAP_PSTATE_IRQOFF	(PSTATE_TSO|PSTATE_PEF|PSTATE_PRIV)
#define		RTRAP_PSTATE_AG_IRQOFF	(PSTATE_TSO|PSTATE_PEF|PSTATE_PRIV|PSTATE_AG)

		.text
		.align			32
__handle_softirq:
		call			do_softirq
		 nop
		ba,a,pt			%xcc, __handle_softirq_continue
		 nop
__handle_preemption:
		call			schedule
		 wrpr			%g0, RTRAP_PSTATE, %pstate
		ba,pt			%xcc, __handle_preemption_continue
		 wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate

__handle_user_windows:
		call			fault_in_user_windows
		 wrpr			%g0, RTRAP_PSTATE, %pstate
		wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate
		/* Redo sched+sig checks */
		ldx			[%g6 + TI_FLAGS], %l0
		andcc			%l0, _TIF_NEED_RESCHED, %g0

		be,pt			%xcc, 1f
		 nop
		call			schedule
		 wrpr			%g0, RTRAP_PSTATE, %pstate
		wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate
		ldx			[%g6 + TI_FLAGS], %l0

1:		andcc			%l0, _TIF_DO_NOTIFY_RESUME_MASK, %g0
		be,pt			%xcc, __handle_user_windows_continue
		 nop
		mov			%l5, %o1
		add			%sp, PTREGS_OFF, %o0
		mov			%l0, %o2

		call			do_notify_resume
		 wrpr			%g0, RTRAP_PSTATE, %pstate
		wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate
		/* Signal delivery can modify pt_regs tstate, so we must
		 * reload it.
		 */
		ldx			[%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
		sethi			%hi(0xf << 20), %l4
		and			%l1, %l4, %l4
		ba,pt			%xcc, __handle_user_windows_continue

		 andn			%l1, %l4, %l1
__handle_userfpu:
		rd			%fprs, %l5
		andcc			%l5, FPRS_FEF, %g0
		sethi			%hi(TSTATE_PEF), %o0
		be,a,pn			%icc, __handle_userfpu_continue
		 andn			%l1, %o0, %l1
		ba,a,pt			%xcc, __handle_userfpu_continue

__handle_signal:
		mov			%l5, %o1
		add			%sp, PTREGS_OFF, %o0
		mov			%l0, %o2
		call			do_notify_resume
		 wrpr			%g0, RTRAP_PSTATE, %pstate
		wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate

		/* Signal delivery can modify pt_regs tstate, so we must
		 * reload it.
		 */
		ldx			[%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
		sethi			%hi(0xf << 20), %l4
		and			%l1, %l4, %l4
		ba,pt			%xcc, __handle_signal_continue
		 andn			%l1, %l4, %l1

		/* When returning from a NMI (%pil==15) interrupt we want to
		 * avoid running softirqs, doing IRQ tracing, preempting, etc.
		 */
		.globl			rtrap_nmi
rtrap_nmi:	ldx			[%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
		sethi			%hi(0xf << 20), %l4
		and			%l1, %l4, %l4
		andn			%l1, %l4, %l1
		srl			%l4, 20, %l4
		ba,pt			%xcc, rtrap_no_irq_enable
		 wrpr			%l4, %pil

		.align			64
		.globl			rtrap_irq, rtrap, irqsz_patchme, rtrap_xcall
rtrap_irq:
rtrap:
#ifndef CONFIG_SMP
		sethi			%hi(__cpu_data), %l0
		lduw			[%l0 + %lo(__cpu_data)], %l1
#else
		sethi			%hi(__cpu_data), %l0
		or			%l0, %lo(__cpu_data), %l0
		lduw			[%l0 + %g5], %l1
#endif
		cmp			%l1, 0

		/* mm/ultra.S:xcall_report_regs KNOWS about this load. */
		bne,pn			%icc, __handle_softirq
		 ldx			[%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
__handle_softirq_continue:
rtrap_xcall:
		sethi			%hi(0xf << 20), %l4
		and			%l1, %l4, %l4
		andn			%l1, %l4, %l1
		srl			%l4, 20, %l4
#ifdef CONFIG_TRACE_IRQFLAGS
		brnz,pn			%l4, rtrap_no_irq_enable
		 nop
		call			trace_hardirqs_on
		 nop
		/* Do not actually set the %pil here.  We will do that
		 * below after we clear PSTATE_IE in the %pstate register.
		 * If we re-enable interrupts here, we can recurse down
		 * the hardirq stack potentially endlessly, causing a
		 * stack overflow.
		 *
		 * It is tempting to put this test and trace_hardirqs_on
		 * call at the 'rt_continue' label, but that will not work
		 * as that path hits unconditionally and we do not want to
		 * execute this in NMI return paths, for example.
		 */
#endif
rtrap_no_irq_enable:
		andcc			%l1, TSTATE_PRIV, %l3
		bne,pn			%icc, to_kernel
		 nop

		/* We must hold IRQs off and atomically test schedule+signal
		 * state, then hold them off all the way back to userspace.
		 * If we are returning to kernel, none of this matters.  Note
		 * that we are disabling interrupts via PSTATE_IE, not using
		 * %pil.
		 *
		 * If we do not do this, there is a window where we would do
		 * the tests, later the signal/resched event arrives but we do
		 * not process it since we are still in kernel mode.  It would
		 * take until the next local IRQ before the signal/resched
		 * event would be handled.
		 *
		 * This also means that if we have to deal with user
		 * windows, we have to redo all of these sched+signal checks
		 * with IRQs disabled.
		 */
to_user:	wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate
		wrpr			0, %pil
__handle_preemption_continue:
		ldx			[%g6 + TI_FLAGS], %l0
		sethi			%hi(_TIF_USER_WORK_MASK), %o0
		or			%o0, %lo(_TIF_USER_WORK_MASK), %o0
		andcc			%l0, %o0, %g0
		sethi			%hi(TSTATE_PEF), %o0
		be,pt			%xcc, user_nowork
		 andcc			%l1, %o0, %g0
		andcc			%l0, _TIF_NEED_RESCHED, %g0
		bne,pn			%xcc, __handle_preemption
		 andcc			%l0, _TIF_DO_NOTIFY_RESUME_MASK, %g0
		bne,pn			%xcc, __handle_signal
__handle_signal_continue:
		 ldub			[%g6 + TI_WSAVED], %o2
		brnz,pn			%o2, __handle_user_windows
		 nop
__handle_user_windows_continue:
		sethi			%hi(TSTATE_PEF), %o0
		andcc			%l1, %o0, %g0

		/* This fpdepth clear is necessary for non-syscall rtraps only */
user_nowork:
		bne,pn			%xcc, __handle_userfpu
		 stb			%g0, [%g6 + TI_FPDEPTH]
__handle_userfpu_continue:

rt_continue:	ldx			[%sp + PTREGS_OFF + PT_V9_G1], %g1
		ldx			[%sp + PTREGS_OFF + PT_V9_G2], %g2

		ldx			[%sp + PTREGS_OFF + PT_V9_G3], %g3
		ldx			[%sp + PTREGS_OFF + PT_V9_G4], %g4
		ldx			[%sp + PTREGS_OFF + PT_V9_G5], %g5
		brz,pt			%l3, 1f
		mov			%g6, %l2

		/* Must do this before thread reg is clobbered below.  */
		LOAD_PER_CPU_BASE(%g5, %g6, %i0, %i1, %i2)
1:
		ldx			[%sp + PTREGS_OFF + PT_V9_G6], %g6
		ldx			[%sp + PTREGS_OFF + PT_V9_G7], %g7

		/* Normal globals are restored, go to trap globals.  */
661:		wrpr			%g0, RTRAP_PSTATE_AG_IRQOFF, %pstate
		nop
		.section		.sun4v_2insn_patch, "ax"
		.word			661b
		wrpr			%g0, RTRAP_PSTATE_IRQOFF, %pstate
		SET_GL(1)
		.previous

		mov			%l2, %g6

		ldx			[%sp + PTREGS_OFF + PT_V9_I0], %i0
		ldx			[%sp + PTREGS_OFF + PT_V9_I1], %i1

		ldx			[%sp + PTREGS_OFF + PT_V9_I2], %i2
		ldx			[%sp + PTREGS_OFF + PT_V9_I3], %i3
		ldx			[%sp + PTREGS_OFF + PT_V9_I4], %i4
		ldx			[%sp + PTREGS_OFF + PT_V9_I5], %i5
		ldx			[%sp + PTREGS_OFF + PT_V9_I6], %i6
		ldx			[%sp + PTREGS_OFF + PT_V9_I7], %i7
		ldx			[%sp + PTREGS_OFF + PT_V9_TPC], %l2
		ldx			[%sp + PTREGS_OFF + PT_V9_TNPC], %o2

		ld			[%sp + PTREGS_OFF + PT_V9_Y], %o3
		wr			%o3, %g0, %y
		wrpr			%l4, 0x0, %pil
		wrpr			%g0, 0x1, %tl
		andn			%l1, TSTATE_SYSCALL, %l1
		wrpr			%l1, %g0, %tstate
		wrpr			%l2, %g0, %tpc
		wrpr			%o2, %g0, %tnpc

		brnz,pn			%l3, kern_rtt
		 mov			PRIMARY_CONTEXT, %l7

661:		ldxa			[%l7 + %l7] ASI_DMMU, %l0
		.section		.sun4v_1insn_patch, "ax"
		.word			661b
		ldxa			[%l7 + %l7] ASI_MMU, %l0
		.previous

		sethi			%hi(sparc64_kern_pri_nuc_bits), %l1
		ldx			[%l1 + %lo(sparc64_kern_pri_nuc_bits)], %l1
		or			%l0, %l1, %l0

661:		stxa			%l0, [%l7] ASI_DMMU
		.section		.sun4v_1insn_patch, "ax"
		.word			661b
		stxa			%l0, [%l7] ASI_MMU
		.previous

		sethi			%hi(KERNBASE), %l7
		flush			%l7
		rdpr			%wstate, %l1
		rdpr			%otherwin, %l2
		srl			%l1, 3, %l1

		wrpr			%l2, %g0, %canrestore
		wrpr			%l1, %g0, %wstate
		brnz,pt			%l2, user_rtt_restore
		 wrpr			%g0, %g0, %otherwin

		ldx			[%g6 + TI_FLAGS], %g3
		wr			%g0, ASI_AIUP, %asi
		rdpr			%cwp, %g1
		andcc			%g3, _TIF_32BIT, %g0
		sub			%g1, 1, %g1
		bne,pt			%xcc, user_rtt_fill_32bit
		 wrpr			%g1, %cwp
		ba,a,pt			%xcc, user_rtt_fill_64bit

user_rtt_fill_fixup:
		rdpr	%cwp, %g1
		add	%g1, 1, %g1
		wrpr	%g1, 0x0, %cwp

		rdpr	%wstate, %g2
		sll	%g2, 3, %g2
		wrpr	%g2, 0x0, %wstate

		/* We know %canrestore and %otherwin are both zero.  */

		sethi	%hi(sparc64_kern_pri_context), %g2
		ldx	[%g2 + %lo(sparc64_kern_pri_context)], %g2
		mov	PRIMARY_CONTEXT, %g1

661:		stxa	%g2, [%g1] ASI_DMMU
		.section .sun4v_1insn_patch, "ax"
		.word	661b
		stxa	%g2, [%g1] ASI_MMU
		.previous

		sethi	%hi(KERNBASE), %g1
		flush	%g1

		or	%g4, FAULT_CODE_WINFIXUP, %g4
		stb	%g4, [%g6 + TI_FAULT_CODE]
		stx	%g5, [%g6 + TI_FAULT_ADDR]

		mov	%g6, %l1
		wrpr	%g0, 0x0, %tl

661:		nop
		.section		.sun4v_1insn_patch, "ax"
		.word			661b
		SET_GL(0)
		.previous

		wrpr	%g0, RTRAP_PSTATE, %pstate

		mov	%l1, %g6
		ldx	[%g6 + TI_TASK], %g4
		LOAD_PER_CPU_BASE(%g5, %g6, %g1, %g2, %g3)
		call	do_sparc64_fault
		 add	%sp, PTREGS_OFF, %o0
		ba,pt	%xcc, rtrap
		 nop

user_rtt_pre_restore:
		add			%g1, 1, %g1
		wrpr			%g1, 0x0, %cwp

user_rtt_restore:
		restore
		rdpr			%canrestore, %g1
		wrpr			%g1, 0x0, %cleanwin
		retry
		nop

kern_rtt:	rdpr			%canrestore, %g1
		brz,pn			%g1, kern_rtt_fill
		 nop
kern_rtt_restore:
		stw			%g0, [%sp + PTREGS_OFF + PT_V9_MAGIC]
		restore
		retry

to_kernel:
#ifdef CONFIG_PREEMPT
		ldsw			[%g6 + TI_PRE_COUNT], %l5
		brnz			%l5, kern_fpucheck
		 ldx			[%g6 + TI_FLAGS], %l5
		andcc			%l5, _TIF_NEED_RESCHED, %g0
		be,pt			%xcc, kern_fpucheck
		 nop
		cmp			%l4, 0
		bne,pn			%xcc, kern_fpucheck
		 sethi			%hi(PREEMPT_ACTIVE), %l6
		stw			%l6, [%g6 + TI_PRE_COUNT]
		call			schedule
		 nop
		ba,pt			%xcc, rtrap
		 stw			%g0, [%g6 + TI_PRE_COUNT]
#endif
kern_fpucheck:	ldub			[%g6 + TI_FPDEPTH], %l5
		brz,pt			%l5, rt_continue
		 srl			%l5, 1, %o0
		add			%g6, TI_FPSAVED, %l6
		ldub			[%l6 + %o0], %l2
		sub			%l5, 2, %l5

		add			%g6, TI_GSR, %o1
		andcc			%l2, (FPRS_FEF|FPRS_DU), %g0
		be,pt			%icc, 2f
		 and			%l2, FPRS_DL, %l6
		andcc			%l2, FPRS_FEF, %g0
		be,pn			%icc, 5f
		 sll			%o0, 3, %o5
		rd			%fprs, %g1

		wr			%g1, FPRS_FEF, %fprs
		ldx			[%o1 + %o5], %g1
		add			%g6, TI_XFSR, %o1
		sll			%o0, 8, %o2
		add			%g6, TI_FPREGS, %o3
		brz,pn			%l6, 1f
		 add			%g6, TI_FPREGS+0x40, %o4

		membar			#Sync
		ldda			[%o3 + %o2] ASI_BLK_P, %f0
		ldda			[%o4 + %o2] ASI_BLK_P, %f16
		membar			#Sync
1:		andcc			%l2, FPRS_DU, %g0
		be,pn			%icc, 1f
		 wr			%g1, 0, %gsr
		add			%o2, 0x80, %o2
		membar			#Sync
		ldda			[%o3 + %o2] ASI_BLK_P, %f32
		ldda			[%o4 + %o2] ASI_BLK_P, %f48
1:		membar			#Sync
		ldx			[%o1 + %o5], %fsr
2:		stb			%l5, [%g6 + TI_FPDEPTH]
		ba,pt			%xcc, rt_continue
		 nop
5:		wr			%g0, FPRS_FEF, %fprs
		sll			%o0, 8, %o2

		add			%g6, TI_FPREGS+0x80, %o3
		add			%g6, TI_FPREGS+0xc0, %o4
		membar			#Sync
		ldda			[%o3 + %o2] ASI_BLK_P, %f32
		ldda			[%o4 + %o2] ASI_BLK_P, %f48
		membar			#Sync
		wr			%g0, FPRS_DU, %fprs
		ba,pt			%xcc, rt_continue
		 stb			%l5, [%g6 + TI_FPDEPTH]
Commit	Line	Data
b00dc837	1	/*
1da177e4 LT	2	* rtrap.S: Preparing for return from trap on Sparc V9.
	3	*
	4	* Copyright (C) 1997,1998 Jakub Jelinek (jj@sunsite.mff.cuni.cz)
	5	* Copyright (C) 1997 David S. Miller (davem@caip.rutgers.edu)
	6	*/
	7
1da177e4 LT	8
	9	#include <asm/asi.h>
	10	#include <asm/pstate.h>
	11	#include <asm/ptrace.h>
	12	#include <asm/spitfire.h>
	13	#include <asm/head.h>
	14	#include <asm/visasm.h>
	15	#include <asm/processor.h>
	16
64f2dde3 DM	17	#define RTRAP_PSTATE (PSTATE_TSO\|PSTATE_PEF\|PSTATE_PRIV\|PSTATE_IE)
	18	#define RTRAP_PSTATE_IRQOFF (PSTATE_TSO\|PSTATE_PEF\|PSTATE_PRIV)
	19	#define RTRAP_PSTATE_AG_IRQOFF (PSTATE_TSO\|PSTATE_PEF\|PSTATE_PRIV\|PSTATE_AG)
1da177e4	20
1da177e4 LT	21	.text
	22	.align 32
	23	__handle_softirq:
	24	call do_softirq
	25	nop
	26	ba,a,pt %xcc, __handle_softirq_continue
	27	nop
	28	__handle_preemption:
	29	call schedule
	30	wrpr %g0, RTRAP_PSTATE, %pstate
	31	ba,pt %xcc, __handle_preemption_continue
	32	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
	33
	34	__handle_user_windows:
	35	call fault_in_user_windows
	36	wrpr %g0, RTRAP_PSTATE, %pstate
	37	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
	38	/* Redo sched+sig checks */
	39	ldx [%g6 + TI_FLAGS], %l0
	40	andcc %l0, _TIF_NEED_RESCHED, %g0
	41
	42	be,pt %xcc, 1f
	43	nop
	44	call schedule
	45	wrpr %g0, RTRAP_PSTATE, %pstate
	46	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
	47	ldx [%g6 + TI_FLAGS], %l0
	48
e35a8925	49	1: andcc %l0, _TIF_DO_NOTIFY_RESUME_MASK, %g0
1da177e4 LT	50	be,pt %xcc, __handle_user_windows_continue
1da177e4 LT	51	nop
2d7d5f05	52	mov %l5, %o1
2d7d5f05	53	add %sp, PTREGS_OFF, %o0
7697daaa	54	mov %l0, %o2
1da177e4 LT	55
	56	call do_notify_resume
	57	wrpr %g0, RTRAP_PSTATE, %pstate
	58	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
1da177e4 LT	59	/* Signal delivery can modify pt_regs tstate, so we must
	60	* reload it.
	61	*/
	62	ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
	63	sethi %hi(0xf << 20), %l4
	64	and %l1, %l4, %l4
	65	ba,pt %xcc, __handle_user_windows_continue
	66
	67	andn %l1, %l4, %l1
1da177e4 LT	68	__handle_userfpu:
	69	rd %fprs, %l5
	70	andcc %l5, FPRS_FEF, %g0
	71	sethi %hi(TSTATE_PEF), %o0
	72	be,a,pn %icc, __handle_userfpu_continue
	73	andn %l1, %o0, %l1
	74	ba,a,pt %xcc, __handle_userfpu_continue
	75
	76	__handle_signal:
2d7d5f05	77	mov %l5, %o1
2d7d5f05	78	add %sp, PTREGS_OFF, %o0
7697daaa	79	mov %l0, %o2
1da177e4 LT	80	call do_notify_resume
	81	wrpr %g0, RTRAP_PSTATE, %pstate
	82	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
1da177e4 LT	83
	84	/* Signal delivery can modify pt_regs tstate, so we must
	85	* reload it.
	86	*/
	87	ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
	88	sethi %hi(0xf << 20), %l4
	89	and %l1, %l4, %l4
	90	ba,pt %xcc, __handle_signal_continue
	91	andn %l1, %l4, %l1
	92
5565736e DM	93	/* When returning from a NMI (%pil==15) interrupt we want to
	94	* avoid running softirqs, doing IRQ tracing, preempting, etc.
	95	*/
	96	.globl rtrap_nmi
	97	rtrap_nmi: ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
	98	sethi %hi(0xf << 20), %l4
	99	and %l1, %l4, %l4
	100	andn %l1, %l4, %l1
	101	srl %l4, 20, %l4
	102	ba,pt %xcc, rtrap_no_irq_enable
	103	wrpr %l4, %pil
	104
1da177e4	105	.align 64
7697daaa	106	.globl rtrap_irq, rtrap, irqsz_patchme, rtrap_xcall
1da177e4	107	rtrap_irq:
1da177e4	108	rtrap:
d7ce78fd	109	#ifndef CONFIG_SMP
dd17c8f7 RR	110	sethi %hi(__cpu_data), %l0
dd17c8f7 RR	111	lduw [%l0 + %lo(__cpu_data)], %l1
d7ce78fd	112	#else
dd17c8f7 RR	113	sethi %hi(__cpu_data), %l0
dd17c8f7 RR	114	or %l0, %lo(__cpu_data), %l0
d7ce78fd DM	115	lduw [%l0 + %g5], %l1
d7ce78fd DM	116	#endif
1da177e4 LT	117	cmp %l1, 0
	118
	119	/* mm/ultra.S:xcall_report_regs KNOWS about this load. */
	120	bne,pn %icc, __handle_softirq
	121	ldx [%sp + PTREGS_OFF + PT_V9_TSTATE], %l1
	122	__handle_softirq_continue:
	123	rtrap_xcall:
	124	sethi %hi(0xf << 20), %l4
1da177e4	125	and %l1, %l4, %l4
10e26723 DM	126	andn %l1, %l4, %l1
	127	srl %l4, 20, %l4
	128	#ifdef CONFIG_TRACE_IRQFLAGS
	129	brnz,pn %l4, rtrap_no_irq_enable
	130	nop
	131	call trace_hardirqs_on
	132	nop
28a1f533 DM	133	/* Do not actually set the %pil here. We will do that
	134	* below after we clear PSTATE_IE in the %pstate register.
	135	* If we re-enable interrupts here, we can recurse down
	136	* the hardirq stack potentially endlessly, causing a
	137	* stack overflow.
	138	*
	139	* It is tempting to put this test and trace_hardirqs_on
	140	* call at the 'rt_continue' label, but that will not work
	141	* as that path hits unconditionally and we do not want to
	142	* execute this in NMI return paths, for example.
	143	*/
10e26723	144	#endif
5565736e	145	rtrap_no_irq_enable:
10e26723	146	andcc %l1, TSTATE_PRIV, %l3
1da177e4	147	bne,pn %icc, to_kernel
10e26723	148	nop
1da177e4 LT	149
	150	/* We must hold IRQs off and atomically test schedule+signal
	151	* state, then hold them off all the way back to userspace.
10e26723 DM	152	* If we are returning to kernel, none of this matters. Note
	153	* that we are disabling interrupts via PSTATE_IE, not using
	154	* %pil.
1da177e4 LT	155	*
	156	* If we do not do this, there is a window where we would do
	157	* the tests, later the signal/resched event arrives but we do
	158	* not process it since we are still in kernel mode. It would
	159	* take until the next local IRQ before the signal/resched
	160	* event would be handled.
	161	*
c7d5a005 DM	162	* This also means that if we have to deal with user
	163	* windows, we have to redo all of these sched+signal checks
	164	* with IRQs disabled.
1da177e4 LT	165	*/
	166	to_user: wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
	167	wrpr 0, %pil
	168	__handle_preemption_continue:
	169	ldx [%g6 + TI_FLAGS], %l0
	170	sethi %hi(_TIF_USER_WORK_MASK), %o0
	171	or %o0, %lo(_TIF_USER_WORK_MASK), %o0
	172	andcc %l0, %o0, %g0
	173	sethi %hi(TSTATE_PEF), %o0
	174	be,pt %xcc, user_nowork
	175	andcc %l1, %o0, %g0
	176	andcc %l0, _TIF_NEED_RESCHED, %g0
	177	bne,pn %xcc, __handle_preemption
e35a8925	178	andcc %l0, _TIF_DO_NOTIFY_RESUME_MASK, %g0
1da177e4 LT	179	bne,pn %xcc, __handle_signal
	180	__handle_signal_continue:
	181	ldub [%g6 + TI_WSAVED], %o2
	182	brnz,pn %o2, __handle_user_windows
	183	nop
	184	__handle_user_windows_continue:
1da177e4	185	sethi %hi(TSTATE_PEF), %o0
c7d5a005	186	andcc %l1, %o0, %g0
1da177e4 LT	187
	188	/* This fpdepth clear is necessary for non-syscall rtraps only */
	189	user_nowork:
	190	bne,pn %xcc, __handle_userfpu
	191	stb %g0, [%g6 + TI_FPDEPTH]
	192	__handle_userfpu_continue:
	193
	194	rt_continue: ldx [%sp + PTREGS_OFF + PT_V9_G1], %g1
	195	ldx [%sp + PTREGS_OFF + PT_V9_G2], %g2
	196
	197	ldx [%sp + PTREGS_OFF + PT_V9_G3], %g3
	198	ldx [%sp + PTREGS_OFF + PT_V9_G4], %g4
	199	ldx [%sp + PTREGS_OFF + PT_V9_G5], %g5
56fb4df6	200	brz,pt %l3, 1f
314981ac DM	201	mov %g6, %l2
314981ac DM	202
56fb4df6	203	/* Must do this before thread reg is clobbered below. */
ffe483d5	204	LOAD_PER_CPU_BASE(%g5, %g6, %i0, %i1, %i2)
74bf4312 DM	205	1:
74bf4312 DM	206	ldx [%sp + PTREGS_OFF + PT_V9_G6], %g6
1da177e4	207	ldx [%sp + PTREGS_OFF + PT_V9_G7], %g7
936f482a DM	208
	209	/* Normal globals are restored, go to trap globals. */
	210	661: wrpr %g0, RTRAP_PSTATE_AG_IRQOFF, %pstate
af02bec6 DM	211	nop
af02bec6 DM	212	.section .sun4v_2insn_patch, "ax"
936f482a	213	.word 661b
af02bec6	214	wrpr %g0, RTRAP_PSTATE_IRQOFF, %pstate
936f482a DM	215	SET_GL(1)
	216	.previous
	217
314981ac DM	218	mov %l2, %g6
314981ac DM	219
1da177e4 LT	220	ldx [%sp + PTREGS_OFF + PT_V9_I0], %i0
	221	ldx [%sp + PTREGS_OFF + PT_V9_I1], %i1
	222
	223	ldx [%sp + PTREGS_OFF + PT_V9_I2], %i2
	224	ldx [%sp + PTREGS_OFF + PT_V9_I3], %i3
	225	ldx [%sp + PTREGS_OFF + PT_V9_I4], %i4
	226	ldx [%sp + PTREGS_OFF + PT_V9_I5], %i5
	227	ldx [%sp + PTREGS_OFF + PT_V9_I6], %i6
	228	ldx [%sp + PTREGS_OFF + PT_V9_I7], %i7
	229	ldx [%sp + PTREGS_OFF + PT_V9_TPC], %l2
	230	ldx [%sp + PTREGS_OFF + PT_V9_TNPC], %o2
	231
	232	ld [%sp + PTREGS_OFF + PT_V9_Y], %o3
	233	wr %o3, %g0, %y
1da177e4 LT	234	wrpr %l4, 0x0, %pil
1da177e4 LT	235	wrpr %g0, 0x1, %tl
28e61036	236	andn %l1, TSTATE_SYSCALL, %l1
1da177e4 LT	237	wrpr %l1, %g0, %tstate
	238	wrpr %l2, %g0, %tpc
	239	wrpr %o2, %g0, %tnpc
	240
	241	brnz,pn %l3, kern_rtt
	242	mov PRIMARY_CONTEXT, %l7
8b11bd12 DM	243
	244	661: ldxa [%l7 + %l7] ASI_DMMU, %l0
	245	.section .sun4v_1insn_patch, "ax"
	246	.word 661b
	247	ldxa [%l7 + %l7] ASI_MMU, %l0
	248	.previous
	249
0835ae0f DM	250	sethi %hi(sparc64_kern_pri_nuc_bits), %l1
0835ae0f DM	251	ldx [%l1 + %lo(sparc64_kern_pri_nuc_bits)], %l1
1da177e4	252	or %l0, %l1, %l0
8b11bd12 DM	253
	254	661: stxa %l0, [%l7] ASI_DMMU
	255	.section .sun4v_1insn_patch, "ax"
	256	.word 661b
	257	stxa %l0, [%l7] ASI_MMU
	258	.previous
	259
4da808c3 DM	260	sethi %hi(KERNBASE), %l7
4da808c3 DM	261	flush %l7
1da177e4 LT	262	rdpr %wstate, %l1
	263	rdpr %otherwin, %l2
	264	srl %l1, 3, %l1
	265
	266	wrpr %l2, %g0, %canrestore
	267	wrpr %l1, %g0, %wstate
314ef685 DM	268	brnz,pt %l2, user_rtt_restore
	269	wrpr %g0, %g0, %otherwin
	270
	271	ldx [%g6 + TI_FLAGS], %g3
	272	wr %g0, ASI_AIUP, %asi
	273	rdpr %cwp, %g1
	274	andcc %g3, _TIF_32BIT, %g0
	275	sub %g1, 1, %g1
	276	bne,pt %xcc, user_rtt_fill_32bit
	277	wrpr %g1, %cwp
	278	ba,a,pt %xcc, user_rtt_fill_64bit
	279
	280	user_rtt_fill_fixup:
	281	rdpr %cwp, %g1
	282	add %g1, 1, %g1
	283	wrpr %g1, 0x0, %cwp
	284
	285	rdpr %wstate, %g2
	286	sll %g2, 3, %g2
	287	wrpr %g2, 0x0, %wstate
	288
	289	/* We know %canrestore and %otherwin are both zero. */
	290
	291	sethi %hi(sparc64_kern_pri_context), %g2
	292	ldx [%g2 + %lo(sparc64_kern_pri_context)], %g2
	293	mov PRIMARY_CONTEXT, %g1
8b11bd12 DM	294
	295	661: stxa %g2, [%g1] ASI_DMMU
	296	.section .sun4v_1insn_patch, "ax"
	297	.word 661b
	298	stxa %g2, [%g1] ASI_MMU
	299	.previous
	300
314ef685 DM	301	sethi %hi(KERNBASE), %g1
	302	flush %g1
	303
	304	or %g4, FAULT_CODE_WINFIXUP, %g4
	305	stb %g4, [%g6 + TI_FAULT_CODE]
	306	stx %g5, [%g6 + TI_FAULT_ADDR]
	307
	308	mov %g6, %l1
	309	wrpr %g0, 0x0, %tl
936f482a DM	310
936f482a DM	311	661: nop
df7d6aec	312	.section .sun4v_1insn_patch, "ax"
936f482a DM	313	.word 661b
	314	SET_GL(0)
	315	.previous
	316
fc504928 DM	317	wrpr %g0, RTRAP_PSTATE, %pstate
fc504928 DM	318
314ef685 DM	319	mov %l1, %g6
	320	ldx [%g6 + TI_TASK], %g4
	321	LOAD_PER_CPU_BASE(%g5, %g6, %g1, %g2, %g3)
	322	call do_sparc64_fault
	323	add %sp, PTREGS_OFF, %o0
	324	ba,pt %xcc, rtrap
	325	nop
	326
	327	user_rtt_pre_restore:
	328	add %g1, 1, %g1
	329	wrpr %g1, 0x0, %cwp
	330
	331	user_rtt_restore:
1da177e4 LT	332	restore
	333	rdpr %canrestore, %g1
	334	wrpr %g1, 0x0, %cleanwin
	335	retry
	336	nop
	337
314ef685 DM	338	kern_rtt: rdpr %canrestore, %g1
	339	brz,pn %g1, kern_rtt_fill
	340	nop
	341	kern_rtt_restore:
ada44a04	342	stw %g0, [%sp + PTREGS_OFF + PT_V9_MAGIC]
314ef685	343	restore
1da177e4	344	retry
314ef685	345
1da177e4 LT	346	to_kernel:
	347	#ifdef CONFIG_PREEMPT
	348	ldsw [%g6 + TI_PRE_COUNT], %l5
	349	brnz %l5, kern_fpucheck
	350	ldx [%g6 + TI_FLAGS], %l5
	351	andcc %l5, _TIF_NEED_RESCHED, %g0
	352	be,pt %xcc, kern_fpucheck
10e26723 DM	353	nop
10e26723 DM	354	cmp %l4, 0
1da177e4 LT	355	bne,pn %xcc, kern_fpucheck
	356	sethi %hi(PREEMPT_ACTIVE), %l6
	357	stw %l6, [%g6 + TI_PRE_COUNT]
	358	call schedule
	359	nop
	360	ba,pt %xcc, rtrap
	361	stw %g0, [%g6 + TI_PRE_COUNT]
	362	#endif
	363	kern_fpucheck: ldub [%g6 + TI_FPDEPTH], %l5
	364	brz,pt %l5, rt_continue
	365	srl %l5, 1, %o0
	366	add %g6, TI_FPSAVED, %l6
	367	ldub [%l6 + %o0], %l2
	368	sub %l5, 2, %l5
	369
	370	add %g6, TI_GSR, %o1
	371	andcc %l2, (FPRS_FEF\|FPRS_DU), %g0
	372	be,pt %icc, 2f
	373	and %l2, FPRS_DL, %l6
	374	andcc %l2, FPRS_FEF, %g0
	375	be,pn %icc, 5f
	376	sll %o0, 3, %o5
	377	rd %fprs, %g1
	378
	379	wr %g1, FPRS_FEF, %fprs
	380	ldx [%o1 + %o5], %g1
	381	add %g6, TI_XFSR, %o1
1da177e4 LT	382	sll %o0, 8, %o2
	383	add %g6, TI_FPREGS, %o3
	384	brz,pn %l6, 1f
	385	add %g6, TI_FPREGS+0x40, %o4
	386
ba639933	387	membar #Sync
1da177e4 LT	388	ldda [%o3 + %o2] ASI_BLK_P, %f0
1da177e4 LT	389	ldda [%o4 + %o2] ASI_BLK_P, %f16
ba639933	390	membar #Sync
1da177e4 LT	391	1: andcc %l2, FPRS_DU, %g0
	392	be,pn %icc, 1f
	393	wr %g1, 0, %gsr
	394	add %o2, 0x80, %o2
ba639933	395	membar #Sync
1da177e4 LT	396	ldda [%o3 + %o2] ASI_BLK_P, %f32
1da177e4 LT	397	ldda [%o4 + %o2] ASI_BLK_P, %f48
1da177e4 LT	398	1: membar #Sync
	399	ldx [%o1 + %o5], %fsr
	400	2: stb %l5, [%g6 + TI_FPDEPTH]
	401	ba,pt %xcc, rt_continue
	402	nop
	403	5: wr %g0, FPRS_FEF, %fprs
1da177e4 LT	404	sll %o0, 8, %o2
	405
	406	add %g6, TI_FPREGS+0x80, %o3
	407	add %g6, TI_FPREGS+0xc0, %o4
ba639933	408	membar #Sync
1da177e4 LT	409	ldda [%o3 + %o2] ASI_BLK_P, %f32
	410	ldda [%o4 + %o2] ASI_BLK_P, %f48
	411	membar #Sync
	412	wr %g0, FPRS_DU, %fprs
	413	ba,pt %xcc, rt_continue
	414	stb %l5, [%g6 + TI_FPDEPTH]