[deliverable/linux.git] / arch / x86 / boot / header.S

/*
 *	header.S
 *
 *	Copyright (C) 1991, 1992 Linus Torvalds
 *
 *	Based on bootsect.S and setup.S
 *	modified by more people than can be counted
 *
 *	Rewritten as a common file by H. Peter Anvin (Apr 2007)
 *
 * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
 * addresses must be multiplied by 16 to obtain their respective linear
 * addresses. To avoid confusion, linear addresses are written using leading
 * hex while segment addresses are written as segment:offset.
 *
 */

#include <asm/segment.h>
#include <generated/utsrelease.h>
#include <asm/boot.h>
#include <asm/e820.h>
#include <asm/page_types.h>
#include <asm/setup.h>
#include "boot.h"
#include "voffset.h"
#include "zoffset.h"

BOOTSEG		= 0x07C0		/* original address of boot-sector */
SYSSEG		= 0x1000		/* historical load address >> 4 */

#ifndef SVGA_MODE
#define SVGA_MODE ASK_VGA
#endif

#ifndef RAMDISK
#define RAMDISK 0
#endif

#ifndef ROOT_RDONLY
#define ROOT_RDONLY 1
#endif

	.code16
	.section ".bstext", "ax"

	.global bootsect_start
bootsect_start:
#ifdef CONFIG_EFI_STUB
	# "MZ", MS-DOS header
	.byte 0x4d
	.byte 0x5a
#endif

	# Normalize the start address
	ljmp	$BOOTSEG, $start2

start2:
	movw	%cs, %ax
	movw	%ax, %ds
	movw	%ax, %es
	movw	%ax, %ss
	xorw	%sp, %sp
	sti
	cld

	movw	$bugger_off_msg, %si

msg_loop:
	lodsb
	andb	%al, %al
	jz	bs_die
	movb	$0xe, %ah
	movw	$7, %bx
	int	$0x10
	jmp	msg_loop

bs_die:
	# Allow the user to press a key, then reboot
	xorw	%ax, %ax
	int	$0x16
	int	$0x19

	# int 0x19 should never return.  In case it does anyway,
	# invoke the BIOS reset code...
	ljmp	$0xf000,$0xfff0

#ifdef CONFIG_EFI_STUB
	.org	0x3c
	#
	# Offset to the PE header.
	#
	.long	pe_header
#endif /* CONFIG_EFI_STUB */

	.section ".bsdata", "a"
bugger_off_msg:
	.ascii	"Direct floppy boot is not supported. "
	.ascii	"Use a boot loader program instead.\r\n"
	.ascii	"\n"
	.ascii	"Remove disk and press any key to reboot ...\r\n"
	.byte	0

#ifdef CONFIG_EFI_STUB
pe_header:
	.ascii	"PE"
	.word 	0

coff_header:
#ifdef CONFIG_X86_32
	.word	0x14c				# i386
#else
	.word	0x8664				# x86-64
#endif
	.word	3				# nr_sections
	.long	0 				# TimeDateStamp
	.long	0				# PointerToSymbolTable
	.long	1				# NumberOfSymbols
	.word	section_table - optional_header	# SizeOfOptionalHeader
#ifdef CONFIG_X86_32
	.word	0x306				# Characteristics.
						# IMAGE_FILE_32BIT_MACHINE |
						# IMAGE_FILE_DEBUG_STRIPPED |
						# IMAGE_FILE_EXECUTABLE_IMAGE |
						# IMAGE_FILE_LINE_NUMS_STRIPPED
#else
	.word	0x206				# Characteristics
						# IMAGE_FILE_DEBUG_STRIPPED |
						# IMAGE_FILE_EXECUTABLE_IMAGE |
						# IMAGE_FILE_LINE_NUMS_STRIPPED
#endif

optional_header:
#ifdef CONFIG_X86_32
	.word	0x10b				# PE32 format
#else
	.word	0x20b 				# PE32+ format
#endif
	.byte	0x02				# MajorLinkerVersion
	.byte	0x14				# MinorLinkerVersion

	# Filled in by build.c
	.long	0				# SizeOfCode

	.long	0				# SizeOfInitializedData
	.long	0				# SizeOfUninitializedData

	# Filled in by build.c
	.long	0x0000				# AddressOfEntryPoint

	.long	0x0200				# BaseOfCode
#ifdef CONFIG_X86_32
	.long	0				# data
#endif

extra_header_fields:
#ifdef CONFIG_X86_32
	.long	0				# ImageBase
#else
	.quad	0				# ImageBase
#endif
	.long	0x20				# SectionAlignment
	.long	0x20				# FileAlignment
	.word	0				# MajorOperatingSystemVersion
	.word	0				# MinorOperatingSystemVersion
	.word	0				# MajorImageVersion
	.word	0				# MinorImageVersion
	.word	0				# MajorSubsystemVersion
	.word	0				# MinorSubsystemVersion
	.long	0				# Win32VersionValue

	#
	# The size of the bzImage is written in tools/build.c
	#
	.long	0				# SizeOfImage

	.long	0x200				# SizeOfHeaders
	.long	0				# CheckSum
	.word	0xa				# Subsystem (EFI application)
	.word	0				# DllCharacteristics
#ifdef CONFIG_X86_32
	.long	0				# SizeOfStackReserve
	.long	0				# SizeOfStackCommit
	.long	0				# SizeOfHeapReserve
	.long	0				# SizeOfHeapCommit
#else
	.quad	0				# SizeOfStackReserve
	.quad	0				# SizeOfStackCommit
	.quad	0				# SizeOfHeapReserve
	.quad	0				# SizeOfHeapCommit
#endif
	.long	0				# LoaderFlags
	.long	0x6				# NumberOfRvaAndSizes

	.quad	0				# ExportTable
	.quad	0				# ImportTable
	.quad	0				# ResourceTable
	.quad	0				# ExceptionTable
	.quad	0				# CertificationTable
	.quad	0				# BaseRelocationTable

	# Section table
section_table:
	#
	# The offset & size fields are filled in by build.c.
	#
	.ascii	".setup"
	.byte	0
	.byte	0
	.long	0
	.long	0x0				# startup_{32,64}
	.long	0				# Size of initialized data
						# on disk
	.long	0x0				# startup_{32,64}
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x60500020			# Characteristics (section flags)

	#
	# The EFI application loader requires a relocation section
	# because EFI applications must be relocatable. The .reloc
	# offset & size fields are filled in by build.c.
	#
	.ascii	".reloc"
	.byte	0
	.byte	0
	.long	0
	.long	0
	.long	0				# SizeOfRawData
	.long	0				# PointerToRawData
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x42100040			# Characteristics (section flags)

	#
	# The offset & size fields are filled in by build.c.
	#
	.ascii	".text"
	.byte	0
	.byte	0
	.byte	0
	.long	0
	.long	0x0				# startup_{32,64}
	.long	0				# Size of initialized data
						# on disk
	.long	0x0				# startup_{32,64}
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x60500020			# Characteristics (section flags)

#endif /* CONFIG_EFI_STUB */

	# Kernel attributes; used by setup.  This is part 1 of the
	# header, from the old boot sector.

	.section ".header", "a"
	.globl	hdr
hdr:
setup_sects:	.byte 0			/* Filled in by build.c */
root_flags:	.word ROOT_RDONLY
syssize:	.long 0			/* Filled in by build.c */
ram_size:	.word 0			/* Obsolete */
vid_mode:	.word SVGA_MODE
root_dev:	.word 0			/* Filled in by build.c */
boot_flag:	.word 0xAA55

	# offset 512, entry point

	.globl	_start
_start:
		# Explicitly enter this as bytes, or the assembler
		# tries to generate a 3-byte jump here, which causes
		# everything else to push off to the wrong offset.
		.byte	0xeb		# short (2-byte) jump
		.byte	start_of_setup-1f
1:

	# Part 2 of the header, from the old setup.S

		.ascii	"HdrS"		# header signature
		.word	0x020a		# header version number (>= 0x0105)
					# or else old loadlin-1.5 will fail)
		.globl realmode_swtch
realmode_swtch:	.word	0, 0		# default_switch, SETUPSEG
start_sys_seg:	.word	SYSSEG		# obsolete and meaningless, but just
					# in case something decided to "use" it
		.word	kernel_version-512 # pointing to kernel version string
					# above section of header is compatible
					# with loadlin-1.5 (header v1.5). Don't
					# change it.

type_of_loader:	.byte	0		# 0 means ancient bootloader, newer
					# bootloaders know to change this.
					# See Documentation/x86/boot.txt for
					# assigned ids

# flags, unused bits must be zero (RFU) bit within loadflags
loadflags:
LOADED_HIGH	= 1			# If set, the kernel is loaded high
CAN_USE_HEAP	= 0x80			# If set, the loader also has set
					# heap_end_ptr to tell how much
					# space behind setup.S can be used for
					# heap purposes.
					# Only the loader knows what is free
		.byte	LOADED_HIGH

setup_move_size: .word  0x8000		# size to move, when setup is not
					# loaded at 0x90000. We will move setup
					# to 0x90000 then just before jumping
					# into the kernel. However, only the
					# loader knows how much data behind
					# us also needs to be loaded.

code32_start:				# here loaders can put a different
					# start address for 32-bit code.
		.long	0x100000	# 0x100000 = default for big kernel

ramdisk_image:	.long	0		# address of loaded ramdisk image
					# Here the loader puts the 32-bit
					# address where it loaded the image.
					# This only will be read by the kernel.

ramdisk_size:	.long	0		# its size in bytes

bootsect_kludge:
		.long	0		# obsolete

heap_end_ptr:	.word	_end+STACK_SIZE-512
					# (Header version 0x0201 or later)
					# space from here (exclusive) down to
					# end of setup code can be used by setup
					# for local heap purposes.

ext_loader_ver:
		.byte	0		# Extended boot loader version
ext_loader_type:
		.byte	0		# Extended boot loader type

cmd_line_ptr:	.long	0		# (Header version 0x0202 or later)
					# If nonzero, a 32-bit pointer
					# to the kernel command line.
					# The command line should be
					# located between the start of
					# setup and the end of low
					# memory (0xa0000), or it may
					# get overwritten before it
					# gets read.  If this field is
					# used, there is no longer
					# anything magical about the
					# 0x90000 segment; the setup
					# can be located anywhere in
					# low memory 0x10000 or higher.

ramdisk_max:	.long 0x7fffffff
					# (Header version 0x0203 or later)
					# The highest safe address for
					# the contents of an initrd
					# The current kernel allows up to 4 GB,
					# but leave it at 2 GB to avoid
					# possible bootloader bugs.

kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN	#physical addr alignment
						#required for protected mode
						#kernel
#ifdef CONFIG_RELOCATABLE
relocatable_kernel:    .byte 1
#else
relocatable_kernel:    .byte 0
#endif
min_alignment:		.byte MIN_KERNEL_ALIGN_LG2	# minimum alignment
pad3:			.word 0

cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
                                                #added with boot protocol
                                                #version 2.06

hardware_subarch:	.long 0			# subarchitecture, added with 2.07
						# default to 0 for normal x86 PC

hardware_subarch_data:	.quad 0

payload_offset:		.long ZO_input_data
payload_length:		.long ZO_z_input_len

setup_data:		.quad 0			# 64-bit physical pointer to
						# single linked list of
						# struct setup_data

pref_address:		.quad LOAD_PHYSICAL_ADDR	# preferred load addr

#define ZO_INIT_SIZE	(ZO__end - ZO_startup_32 + ZO_z_extract_offset)
#define VO_INIT_SIZE	(VO__end - VO__text)
#if ZO_INIT_SIZE > VO_INIT_SIZE
#define INIT_SIZE ZO_INIT_SIZE
#else
#define INIT_SIZE VO_INIT_SIZE
#endif
init_size:		.long INIT_SIZE		# kernel initialization size

# End of setup header #####################################################

	.section ".entrytext", "ax"
start_of_setup:
#ifdef SAFE_RESET_DISK_CONTROLLER
# Reset the disk controller.
	movw	$0x0000, %ax		# Reset disk controller
	movb	$0x80, %dl		# All disks
	int	$0x13
#endif

# Force %es = %ds
	movw	%ds, %ax
	movw	%ax, %es
	cld

# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
# which happened to work by accident for the old code.  Recalculate the stack
# pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
# stack behind its own code, so we can't blindly put it directly past the heap.

	movw	%ss, %dx
	cmpw	%ax, %dx	# %ds == %ss?
	movw	%sp, %dx
	je	2f		# -> assume %sp is reasonably set

	# Invalid %ss, make up a new stack
	movw	$_end, %dx
	testb	$CAN_USE_HEAP, loadflags
	jz	1f
	movw	heap_end_ptr, %dx
1:	addw	$STACK_SIZE, %dx
	jnc	2f
	xorw	%dx, %dx	# Prevent wraparound

2:	# Now %dx should point to the end of our stack space
	andw	$~3, %dx	# dword align (might as well...)
	jnz	3f
	movw	$0xfffc, %dx	# Make sure we're not zero
3:	movw	%ax, %ss
	movzwl	%dx, %esp	# Clear upper half of %esp
	sti			# Now we should have a working stack

# We will have entered with %cs = %ds+0x20, normalize %cs so
# it is on par with the other segments.
	pushw	%ds
	pushw	$6f
	lretw
6:

# Check signature at end of setup
	cmpl	$0x5a5aaa55, setup_sig
	jne	setup_bad

# Zero the bss
	movw	$__bss_start, %di
	movw	$_end+3, %cx
	xorl	%eax, %eax
	subw	%di, %cx
	shrw	$2, %cx
	rep; stosl

# Jump to C code (should not return)
	calll	main

# Setup corrupt somehow...
setup_bad:
	movl	$setup_corrupt, %eax
	calll	puts
	# Fall through...

	.globl	die
	.type	die, @function
die:
	hlt
	jmp	die

	.size	die, .-die

	.section ".initdata", "a"
setup_corrupt:
	.byte	7
	.string	"No setup signature found...\n"

	.data
dummy:	.long	0
Commit	Line	Data
62607313 PA	1	/*
	2	* header.S
	3	*
	4	* Copyright (C) 1991, 1992 Linus Torvalds
	5	*
	6	* Based on bootsect.S and setup.S
	7	* modified by more people than can be counted
	8	*
	9	* Rewritten as a common file by H. Peter Anvin (Apr 2007)
	10	*
	11	* BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
	12	* addresses must be multiplied by 16 to obtain their respective linear
	13	* addresses. To avoid confusion, linear addresses are written using leading
	14	* hex while segment addresses are written as segment:offset.
	15	*
	16	*/
	17
	18	#include <asm/segment.h>
273b281f	19	#include <generated/utsrelease.h>
62607313 PA	20	#include <asm/boot.h>
62607313 PA	21	#include <asm/e820.h>
0341c14d	22	#include <asm/page_types.h>
62607313 PA	23	#include <asm/setup.h>
62607313 PA	24	#include "boot.h"
77d1a499 PA	25	#include "voffset.h"
77d1a499 PA	26	#include "zoffset.h"
62607313	27
62607313	28	BOOTSEG = 0x07C0 /* original address of boot-sector */
5e47c478	29	SYSSEG = 0x1000 /* historical load address >> 4 */
62607313 PA	30
	31	#ifndef SVGA_MODE
	32	#define SVGA_MODE ASK_VGA
	33	#endif
	34
	35	#ifndef RAMDISK
	36	#define RAMDISK 0
	37	#endif
	38
	39	#ifndef ROOT_RDONLY
	40	#define ROOT_RDONLY 1
	41	#endif
	42
	43	.code16
	44	.section ".bstext", "ax"
	45
	46	.global bootsect_start
	47	bootsect_start:
291f3632 MF	48	#ifdef CONFIG_EFI_STUB
	49	# "MZ", MS-DOS header
	50	.byte 0x4d
	51	.byte 0x5a
	52	#endif
62607313 PA	53
	54	# Normalize the start address
	55	ljmp $BOOTSEG, $start2
	56
	57	start2:
	58	movw %cs, %ax
	59	movw %ax, %ds
	60	movw %ax, %es
	61	movw %ax, %ss
	62	xorw %sp, %sp
	63	sti
	64	cld
	65
	66	movw $bugger_off_msg, %si
	67
	68	msg_loop:
	69	lodsb
	70	andb %al, %al
	71	jz bs_die
	72	movb $0xe, %ah
	73	movw $7, %bx
	74	int $0x10
	75	jmp msg_loop
	76
	77	bs_die:
	78	# Allow the user to press a key, then reboot
	79	xorw %ax, %ax
	80	int $0x16
	81	int $0x19
	82
	83	# int 0x19 should never return. In case it does anyway,
	84	# invoke the BIOS reset code...
	85	ljmp $0xf000,$0xfff0
	86
291f3632 MF	87	#ifdef CONFIG_EFI_STUB
	88	.org 0x3c
	89	#
	90	# Offset to the PE header.
	91	#
	92	.long pe_header
	93	#endif /* CONFIG_EFI_STUB */
	94
62607313 PA	95	.section ".bsdata", "a"
62607313 PA	96	bugger_off_msg:
743628e8 JJ	97	.ascii "Direct floppy boot is not supported. "
743628e8 JJ	98	.ascii "Use a boot loader program instead.\r\n"
62607313	99	.ascii "\n"
743628e8	100	.ascii "Remove disk and press any key to reboot ...\r\n"
62607313 PA	101	.byte 0
62607313 PA	102
291f3632 MF	103	#ifdef CONFIG_EFI_STUB
	104	pe_header:
	105	.ascii "PE"
	106	.word 0
	107
	108	coff_header:
	109	#ifdef CONFIG_X86_32
	110	.word 0x14c # i386
	111	#else
	112	.word 0x8664 # x86-64
	113	#endif
743628e8	114	.word 3 # nr_sections
291f3632 MF	115	.long 0 # TimeDateStamp
	116	.long 0 # PointerToSymbolTable
	117	.long 1 # NumberOfSymbols
	118	.word section_table - optional_header # SizeOfOptionalHeader
	119	#ifdef CONFIG_X86_32
	120	.word 0x306 # Characteristics.
	121	# IMAGE_FILE_32BIT_MACHINE \|
	122	# IMAGE_FILE_DEBUG_STRIPPED \|
	123	# IMAGE_FILE_EXECUTABLE_IMAGE \|
	124	# IMAGE_FILE_LINE_NUMS_STRIPPED
	125	#else
	126	.word 0x206 # Characteristics
	127	# IMAGE_FILE_DEBUG_STRIPPED \|
	128	# IMAGE_FILE_EXECUTABLE_IMAGE \|
	129	# IMAGE_FILE_LINE_NUMS_STRIPPED
	130	#endif
	131
	132	optional_header:
	133	#ifdef CONFIG_X86_32
	134	.word 0x10b # PE32 format
	135	#else
	136	.word 0x20b # PE32+ format
	137	#endif
	138	.byte 0x02 # MajorLinkerVersion
	139	.byte 0x14 # MinorLinkerVersion
	140
	141	# Filled in by build.c
	142	.long 0 # SizeOfCode
	143
	144	.long 0 # SizeOfInitializedData
	145	.long 0 # SizeOfUninitializedData
	146
	147	# Filled in by build.c
	148	.long 0x0000 # AddressOfEntryPoint
	149
e31be363	150	.long 0x0200 # BaseOfCode
291f3632 MF	151	#ifdef CONFIG_X86_32
	152	.long 0 # data
	153	#endif
	154
	155	extra_header_fields:
	156	#ifdef CONFIG_X86_32
	157	.long 0 # ImageBase
	158	#else
	159	.quad 0 # ImageBase
	160	#endif
743628e8 JJ	161	.long 0x20 # SectionAlignment
743628e8 JJ	162	.long 0x20 # FileAlignment
291f3632 MF	163	.word 0 # MajorOperatingSystemVersion
	164	.word 0 # MinorOperatingSystemVersion
	165	.word 0 # MajorImageVersion
	166	.word 0 # MinorImageVersion
	167	.word 0 # MajorSubsystemVersion
	168	.word 0 # MinorSubsystemVersion
	169	.long 0 # Win32VersionValue
	170
	171	#
	172	# The size of the bzImage is written in tools/build.c
	173	#
	174	.long 0 # SizeOfImage
	175
	176	.long 0x200 # SizeOfHeaders
	177	.long 0 # CheckSum
	178	.word 0xa # Subsystem (EFI application)
	179	.word 0 # DllCharacteristics
	180	#ifdef CONFIG_X86_32
	181	.long 0 # SizeOfStackReserve
	182	.long 0 # SizeOfStackCommit
	183	.long 0 # SizeOfHeapReserve
	184	.long 0 # SizeOfHeapCommit
	185	#else
	186	.quad 0 # SizeOfStackReserve
	187	.quad 0 # SizeOfStackCommit
	188	.quad 0 # SizeOfHeapReserve
	189	.quad 0 # SizeOfHeapCommit
	190	#endif
	191	.long 0 # LoaderFlags
e47bb0bd	192	.long 0x6 # NumberOfRvaAndSizes
291f3632 MF	193
	194	.quad 0 # ExportTable
	195	.quad 0 # ImportTable
	196	.quad 0 # ResourceTable
	197	.quad 0 # ExceptionTable
	198	.quad 0 # CertificationTable
	199	.quad 0 # BaseRelocationTable
	200
	201	# Section table
	202	section_table:
743628e8 JJ	203	#
	204	# The offset & size fields are filled in by build.c.
	205	#
	206	.ascii ".setup"
291f3632 MF	207	.byte 0
	208	.byte 0
	209	.long 0
	210	.long 0x0 # startup_{32,64}
	211	.long 0 # Size of initialized data
	212	# on disk
	213	.long 0x0 # startup_{32,64}
	214	.long 0 # PointerToRelocations
	215	.long 0 # PointerToLineNumbers
	216	.word 0 # NumberOfRelocations
	217	.word 0 # NumberOfLineNumbers
	218	.long 0x60500020 # Characteristics (section flags)
	219
	220	#
	221	# The EFI application loader requires a relocation section
743628e8 JJ	222	# because EFI applications must be relocatable. The .reloc
743628e8 JJ	223	# offset & size fields are filled in by build.c.
291f3632 MF	224	#
	225	.ascii ".reloc"
	226	.byte 0
	227	.byte 0
2e064b1e JJ	228	.long 0
	229	.long 0
	230	.long 0 # SizeOfRawData
	231	.long 0 # PointerToRawData
291f3632 MF	232	.long 0 # PointerToRelocations
	233	.long 0 # PointerToLineNumbers
	234	.word 0 # NumberOfRelocations
	235	.word 0 # NumberOfLineNumbers
	236	.long 0x42100040 # Characteristics (section flags)
743628e8 JJ	237
	238	#
	239	# The offset & size fields are filled in by build.c.
	240	#
	241	.ascii ".text"
	242	.byte 0
	243	.byte 0
	244	.byte 0
	245	.long 0
	246	.long 0x0 # startup_{32,64}
	247	.long 0 # Size of initialized data
	248	# on disk
	249	.long 0x0 # startup_{32,64}
	250	.long 0 # PointerToRelocations
	251	.long 0 # PointerToLineNumbers
	252	.word 0 # NumberOfRelocations
	253	.word 0 # NumberOfLineNumbers
	254	.long 0x60500020 # Characteristics (section flags)
	255
291f3632	256	#endif /* CONFIG_EFI_STUB */
62607313 PA	257
	258	# Kernel attributes; used by setup. This is part 1 of the
	259	# header, from the old boot sector.
	260
	261	.section ".header", "a"
	262	.globl hdr
	263	hdr:
5e47c478	264	setup_sects: .byte 0 /* Filled in by build.c */
62607313	265	root_flags: .word ROOT_RDONLY
5e47c478 PA	266	syssize: .long 0 /* Filled in by build.c */
5e47c478 PA	267	ram_size: .word 0 /* Obsolete */
62607313	268	vid_mode: .word SVGA_MODE
5e47c478	269	root_dev: .word 0 /* Filled in by build.c */
62607313 PA	270	boot_flag: .word 0xAA55
	271
	272	# offset 512, entry point
	273
	274	.globl _start
	275	_start:
	276	# Explicitly enter this as bytes, or the assembler
	277	# tries to generate a 3-byte jump here, which causes
	278	# everything else to push off to the wrong offset.
	279	.byte 0xeb # short (2-byte) jump
	280	.byte start_of_setup-1f
	281	1:
	282
	283	# Part 2 of the header, from the old setup.S
	284
	285	.ascii "HdrS" # header signature
37ba7ab5	286	.word 0x020a # header version number (>= 0x0105)
62607313 PA	287	# or else old loadlin-1.5 will fail)
	288	.globl realmode_swtch
	289	realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
5e47c478 PA	290	start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
5e47c478 PA	291	# in case something decided to "use" it
62607313 PA	292	.word kernel_version-512 # pointing to kernel version string
	293	# above section of header is compatible
	294	# with loadlin-1.5 (header v1.5). Don't
	295	# change it.
	296
5e47c478 PA	297	type_of_loader: .byte 0 # 0 means ancient bootloader, newer
5e47c478 PA	298	# bootloaders know to change this.
395cf969	299	# See Documentation/x86/boot.txt for
62607313 PA	300	# assigned ids
	301
	302	# flags, unused bits must be zero (RFU) bit within loadflags
	303	loadflags:
	304	LOADED_HIGH = 1 # If set, the kernel is loaded high
	305	CAN_USE_HEAP = 0x80 # If set, the loader also has set
	306	# heap_end_ptr to tell how much
	307	# space behind setup.S can be used for
	308	# heap purposes.
	309	# Only the loader knows what is free
62607313	310	.byte LOADED_HIGH
62607313 PA	311
	312	setup_move_size: .word 0x8000 # size to move, when setup is not
	313	# loaded at 0x90000. We will move setup
	314	# to 0x90000 then just before jumping
	315	# into the kernel. However, only the
	316	# loader knows how much data behind
	317	# us also needs to be loaded.
	318
	319	code32_start: # here loaders can put a different
	320	# start address for 32-bit code.
62607313	321	.long 0x100000 # 0x100000 = default for big kernel
62607313 PA	322
	323	ramdisk_image: .long 0 # address of loaded ramdisk image
	324	# Here the loader puts the 32-bit
	325	# address where it loaded the image.
	326	# This only will be read by the kernel.
	327
	328	ramdisk_size: .long 0 # its size in bytes
	329
	330	bootsect_kludge:
	331	.long 0 # obsolete
	332
6b6815c6 PA	333	heap_end_ptr: .word _end+STACK_SIZE-512
6b6815c6 PA	334	# (Header version 0x0201 or later)
62607313 PA	335	# space from here (exclusive) down to
	336	# end of setup code can be used by setup
	337	# for local heap purposes.
	338
5031296c PA	339	ext_loader_ver:
	340	.byte 0 # Extended boot loader version
	341	ext_loader_type:
	342	.byte 0 # Extended boot loader type
	343
62607313 PA	344	cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
	345	# If nonzero, a 32-bit pointer
	346	# to the kernel command line.
	347	# The command line should be
	348	# located between the start of
	349	# setup and the end of low
	350	# memory (0xa0000), or it may
	351	# get overwritten before it
	352	# gets read. If this field is
	353	# used, there is no longer
	354	# anything magical about the
	355	# 0x90000 segment; the setup
	356	# can be located anywhere in
	357	# low memory 0x10000 or higher.
	358
cf8fa920	359	ramdisk_max: .long 0x7fffffff
62607313 PA	360	# (Header version 0x0203 or later)
	361	# The highest safe address for
	362	# the contents of an initrd
cf8fa920 PA	363	# The current kernel allows up to 4 GB,
	364	# but leave it at 2 GB to avoid
	365	# possible bootloader bugs.
62607313 PA	366
	367	kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
	368	#required for protected mode
	369	#kernel
	370	#ifdef CONFIG_RELOCATABLE
	371	relocatable_kernel: .byte 1
	372	#else
	373	relocatable_kernel: .byte 0
	374	#endif
37ba7ab5	375	min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
62607313 PA	376	pad3: .word 0
	377
	378	cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
	379	#added with boot protocol
	380	#version 2.06
	381
a24e7851 RR	382	hardware_subarch: .long 0 # subarchitecture, added with 2.07
	383	# default to 0 for normal x86 PC
	384
	385	hardware_subarch_data: .quad 0
	386
77d1a499 PA	387	payload_offset: .long ZO_input_data
77d1a499 PA	388	payload_length: .long ZO_z_input_len
099e1377	389
8b664aa6 HY	390	setup_data: .quad 0 # 64-bit physical pointer to
	391	# single linked list of
	392	# struct setup_data
	393
37ba7ab5 PA	394	pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
37ba7ab5 PA	395
c6ac4c18	396	#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
37ba7ab5 PA	397	#define VO_INIT_SIZE (VO__end - VO__text)
	398	#if ZO_INIT_SIZE > VO_INIT_SIZE
	399	#define INIT_SIZE ZO_INIT_SIZE
	400	#else
	401	#define INIT_SIZE VO_INIT_SIZE
	402	#endif
	403	init_size: .long INIT_SIZE # kernel initialization size
	404
62607313 PA	405	# End of setup header #####################################################
62607313 PA	406
7a734e7d	407	.section ".entrytext", "ax"
62607313 PA	408	start_of_setup:
	409	#ifdef SAFE_RESET_DISK_CONTROLLER
	410	# Reset the disk controller.
	411	movw $0x0000, %ax # Reset disk controller
	412	movb $0x80, %dl # All disks
	413	int $0x13
	414	#endif
	415
62607313 PA	416	# Force %es = %ds
	417	movw %ds, %ax
	418	movw %ax, %es
	419	cld
	420
16252da6 JR	421	# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
	422	# which happened to work by accident for the old code. Recalculate the stack
	423	# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
	424	# stack behind its own code, so we can't blindly put it directly past the heap.
6b6815c6	425
6b6815c6 PA	426	movw %ss, %dx
	427	cmpw %ax, %dx # %ds == %ss?
	428	movw %sp, %dx
16252da6 JR	429	je 2f # -> assume %sp is reasonably set
	430
	431	# Invalid %ss, make up a new stack
	432	movw $_end, %dx
	433	testb $CAN_USE_HEAP, loadflags
	434	jz 1f
	435	movw heap_end_ptr, %dx
	436	1: addw $STACK_SIZE, %dx
	437	jnc 2f
	438	xorw %dx, %dx # Prevent wraparound
6b6815c6	439
16252da6	440	2: # Now %dx should point to the end of our stack space
6b6815c6 PA	441	andw $~3, %dx # dword align (might as well...)
	442	jnz 3f
	443	movw $0xfffc, %dx # Make sure we're not zero
16252da6	444	3: movw %ax, %ss
6b6815c6 PA	445	movzwl %dx, %esp # Clear upper half of %esp
	446	sti # Now we should have a working stack
	447
	448	# We will have entered with %cs = %ds+0x20, normalize %cs so
	449	# it is on par with the other segments.
	450	pushw %ds
	451	pushw $6f
	452	lretw
	453	6:
62607313 PA	454
	455	# Check signature at end of setup
	456	cmpl $0x5a5aaa55, setup_sig
	457	jne setup_bad
	458
	459	# Zero the bss
	460	movw $__bss_start, %di
	461	movw $_end+3, %cx
	462	xorl %eax, %eax
	463	subw %di, %cx
	464	shrw $2, %cx
	465	rep; stosl
	466
	467	# Jump to C code (should not return)
	468	calll main
	469
	470	# Setup corrupt somehow...
	471	setup_bad:
	472	movl $setup_corrupt, %eax
	473	calll puts
	474	# Fall through...
	475
	476	.globl die
	477	.type die, @function
	478	die:
	479	hlt
	480	jmp die
	481
bbc15f46	482	.size die, .-die
62607313 PA	483
	484	.section ".initdata", "a"
	485	setup_corrupt:
	486	.byte 7
8b608d2f	487	.string "No setup signature found...\n"
291f3632 MF	488
	489	.data
	490	dummy: .long 0