[deliverable/linux.git] / arch / x86 / boot / header.S

/*
 *	header.S
 *
 *	Copyright (C) 1991, 1992 Linus Torvalds
 *
 *	Based on bootsect.S and setup.S
 *	modified by more people than can be counted
 *
 *	Rewritten as a common file by H. Peter Anvin (Apr 2007)
 *
 * BIG FAT NOTE: We're in real mode using 64k segments.  Therefore segment
 * addresses must be multiplied by 16 to obtain their respective linear
 * addresses. To avoid confusion, linear addresses are written using leading
 * hex while segment addresses are written as segment:offset.
 *
 */

#include <asm/segment.h>
#include <generated/utsrelease.h>
#include <asm/boot.h>
#include <asm/e820.h>
#include <asm/page_types.h>
#include <asm/setup.h>
#include <asm/bootparam.h>
#include "boot.h"
#include "voffset.h"
#include "zoffset.h"

BOOTSEG		= 0x07C0		/* original address of boot-sector */
SYSSEG		= 0x1000		/* historical load address >> 4 */

#ifndef SVGA_MODE
#define SVGA_MODE ASK_VGA
#endif

#ifndef ROOT_RDONLY
#define ROOT_RDONLY 1
#endif

	.code16
	.section ".bstext", "ax"

	.global bootsect_start
bootsect_start:
#ifdef CONFIG_EFI_STUB
	# "MZ", MS-DOS header
	.byte 0x4d
	.byte 0x5a
#endif

	# Normalize the start address
	ljmp	$BOOTSEG, $start2

start2:
	movw	%cs, %ax
	movw	%ax, %ds
	movw	%ax, %es
	movw	%ax, %ss
	xorw	%sp, %sp
	sti
	cld

	movw	$bugger_off_msg, %si

msg_loop:
	lodsb
	andb	%al, %al
	jz	bs_die
	movb	$0xe, %ah
	movw	$7, %bx
	int	$0x10
	jmp	msg_loop

bs_die:
	# Allow the user to press a key, then reboot
	xorw	%ax, %ax
	int	$0x16
	int	$0x19

	# int 0x19 should never return.  In case it does anyway,
	# invoke the BIOS reset code...
	ljmp	$0xf000,$0xfff0

#ifdef CONFIG_EFI_STUB
	.org	0x3c
	#
	# Offset to the PE header.
	#
	.long	pe_header
#endif /* CONFIG_EFI_STUB */

	.section ".bsdata", "a"
bugger_off_msg:
	.ascii	"Use a boot loader.\r\n"
	.ascii	"\n"
	.ascii	"Remove disk and press any key to reboot...\r\n"
	.byte	0

#ifdef CONFIG_EFI_STUB
pe_header:
	.ascii	"PE"
	.word 	0

coff_header:
#ifdef CONFIG_X86_32
	.word	0x14c				# i386
#else
	.word	0x8664				# x86-64
#endif
	.word	4				# nr_sections
	.long	0 				# TimeDateStamp
	.long	0				# PointerToSymbolTable
	.long	1				# NumberOfSymbols
	.word	section_table - optional_header	# SizeOfOptionalHeader
#ifdef CONFIG_X86_32
	.word	0x306				# Characteristics.
						# IMAGE_FILE_32BIT_MACHINE |
						# IMAGE_FILE_DEBUG_STRIPPED |
						# IMAGE_FILE_EXECUTABLE_IMAGE |
						# IMAGE_FILE_LINE_NUMS_STRIPPED
#else
	.word	0x206				# Characteristics
						# IMAGE_FILE_DEBUG_STRIPPED |
						# IMAGE_FILE_EXECUTABLE_IMAGE |
						# IMAGE_FILE_LINE_NUMS_STRIPPED
#endif

optional_header:
#ifdef CONFIG_X86_32
	.word	0x10b				# PE32 format
#else
	.word	0x20b 				# PE32+ format
#endif
	.byte	0x02				# MajorLinkerVersion
	.byte	0x14				# MinorLinkerVersion

	# Filled in by build.c
	.long	0				# SizeOfCode

	.long	0				# SizeOfInitializedData
	.long	0				# SizeOfUninitializedData

	# Filled in by build.c
	.long	0x0000				# AddressOfEntryPoint

	.long	0x0200				# BaseOfCode
#ifdef CONFIG_X86_32
	.long	0				# data
#endif

extra_header_fields:
#ifdef CONFIG_X86_32
	.long	0				# ImageBase
#else
	.quad	0				# ImageBase
#endif
	.long	0x20				# SectionAlignment
	.long	0x20				# FileAlignment
	.word	0				# MajorOperatingSystemVersion
	.word	0				# MinorOperatingSystemVersion
	.word	0				# MajorImageVersion
	.word	0				# MinorImageVersion
	.word	0				# MajorSubsystemVersion
	.word	0				# MinorSubsystemVersion
	.long	0				# Win32VersionValue

	#
	# The size of the bzImage is written in tools/build.c
	#
	.long	0				# SizeOfImage

	.long	0x200				# SizeOfHeaders
	.long	0				# CheckSum
	.word	0xa				# Subsystem (EFI application)
	.word	0				# DllCharacteristics
#ifdef CONFIG_X86_32
	.long	0				# SizeOfStackReserve
	.long	0				# SizeOfStackCommit
	.long	0				# SizeOfHeapReserve
	.long	0				# SizeOfHeapCommit
#else
	.quad	0				# SizeOfStackReserve
	.quad	0				# SizeOfStackCommit
	.quad	0				# SizeOfHeapReserve
	.quad	0				# SizeOfHeapCommit
#endif
	.long	0				# LoaderFlags
	.long	0x6				# NumberOfRvaAndSizes

	.quad	0				# ExportTable
	.quad	0				# ImportTable
	.quad	0				# ResourceTable
	.quad	0				# ExceptionTable
	.quad	0				# CertificationTable
	.quad	0				# BaseRelocationTable

	# Section table
section_table:
	#
	# The offset & size fields are filled in by build.c.
	#
	.ascii	".setup"
	.byte	0
	.byte	0
	.long	0
	.long	0x0				# startup_{32,64}
	.long	0				# Size of initialized data
						# on disk
	.long	0x0				# startup_{32,64}
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x60500020			# Characteristics (section flags)

	#
	# The EFI application loader requires a relocation section
	# because EFI applications must be relocatable. The .reloc
	# offset & size fields are filled in by build.c.
	#
	.ascii	".reloc"
	.byte	0
	.byte	0
	.long	0
	.long	0
	.long	0				# SizeOfRawData
	.long	0				# PointerToRawData
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x42100040			# Characteristics (section flags)

	#
	# The offset & size fields are filled in by build.c.
	#
	.ascii	".text"
	.byte	0
	.byte	0
	.byte	0
	.long	0
	.long	0x0				# startup_{32,64}
	.long	0				# Size of initialized data
						# on disk
	.long	0x0				# startup_{32,64}
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0x60500020			# Characteristics (section flags)

	#
	# The offset & size fields are filled in by build.c.
	#
	.ascii	".bss"
	.byte	0
	.byte	0
	.byte	0
	.byte	0
	.long	0
	.long	0x0
	.long	0				# Size of initialized data
						# on disk
	.long	0x0
	.long	0				# PointerToRelocations
	.long	0				# PointerToLineNumbers
	.word	0				# NumberOfRelocations
	.word	0				# NumberOfLineNumbers
	.long	0xc8000080			# Characteristics (section flags)

#endif /* CONFIG_EFI_STUB */

	# Kernel attributes; used by setup.  This is part 1 of the
	# header, from the old boot sector.

	.section ".header", "a"
	.globl	sentinel
sentinel:	.byte 0xff, 0xff        /* Used to detect broken loaders */

	.globl	hdr
hdr:
setup_sects:	.byte 0			/* Filled in by build.c */
root_flags:	.word ROOT_RDONLY
syssize:	.long 0			/* Filled in by build.c */
ram_size:	.word 0			/* Obsolete */
vid_mode:	.word SVGA_MODE
root_dev:	.word 0			/* Filled in by build.c */
boot_flag:	.word 0xAA55

	# offset 512, entry point

	.globl	_start
_start:
		# Explicitly enter this as bytes, or the assembler
		# tries to generate a 3-byte jump here, which causes
		# everything else to push off to the wrong offset.
		.byte	0xeb		# short (2-byte) jump
		.byte	start_of_setup-1f
1:

	# Part 2 of the header, from the old setup.S

		.ascii	"HdrS"		# header signature
		.word	0x020d		# header version number (>= 0x0105)
					# or else old loadlin-1.5 will fail)
		.globl realmode_swtch
realmode_swtch:	.word	0, 0		# default_switch, SETUPSEG
start_sys_seg:	.word	SYSSEG		# obsolete and meaningless, but just
					# in case something decided to "use" it
		.word	kernel_version-512 # pointing to kernel version string
					# above section of header is compatible
					# with loadlin-1.5 (header v1.5). Don't
					# change it.

type_of_loader:	.byte	0		# 0 means ancient bootloader, newer
					# bootloaders know to change this.
					# See Documentation/x86/boot.txt for
					# assigned ids

# flags, unused bits must be zero (RFU) bit within loadflags
loadflags:
		.byte	LOADED_HIGH	# The kernel is to be loaded high

setup_move_size: .word  0x8000		# size to move, when setup is not
					# loaded at 0x90000. We will move setup
					# to 0x90000 then just before jumping
					# into the kernel. However, only the
					# loader knows how much data behind
					# us also needs to be loaded.

code32_start:				# here loaders can put a different
					# start address for 32-bit code.
		.long	0x100000	# 0x100000 = default for big kernel

ramdisk_image:	.long	0		# address of loaded ramdisk image
					# Here the loader puts the 32-bit
					# address where it loaded the image.
					# This only will be read by the kernel.

ramdisk_size:	.long	0		# its size in bytes

bootsect_kludge:
		.long	0		# obsolete

heap_end_ptr:	.word	_end+STACK_SIZE-512
					# (Header version 0x0201 or later)
					# space from here (exclusive) down to
					# end of setup code can be used by setup
					# for local heap purposes.

ext_loader_ver:
		.byte	0		# Extended boot loader version
ext_loader_type:
		.byte	0		# Extended boot loader type

cmd_line_ptr:	.long	0		# (Header version 0x0202 or later)
					# If nonzero, a 32-bit pointer
					# to the kernel command line.
					# The command line should be
					# located between the start of
					# setup and the end of low
					# memory (0xa0000), or it may
					# get overwritten before it
					# gets read.  If this field is
					# used, there is no longer
					# anything magical about the
					# 0x90000 segment; the setup
					# can be located anywhere in
					# low memory 0x10000 or higher.

initrd_addr_max: .long 0x7fffffff
					# (Header version 0x0203 or later)
					# The highest safe address for
					# the contents of an initrd
					# The current kernel allows up to 4 GB,
					# but leave it at 2 GB to avoid
					# possible bootloader bugs.

kernel_alignment:  .long CONFIG_PHYSICAL_ALIGN	#physical addr alignment
						#required for protected mode
						#kernel
#ifdef CONFIG_RELOCATABLE
relocatable_kernel:    .byte 1
#else
relocatable_kernel:    .byte 0
#endif
min_alignment:		.byte MIN_KERNEL_ALIGN_LG2	# minimum alignment

xloadflags:
#ifdef CONFIG_X86_64
# define XLF0 XLF_KERNEL_64			/* 64-bit kernel */
#else
# define XLF0 0
#endif

#if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64)
   /* kernel/boot_param/ramdisk could be loaded above 4g */
# define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
#else
# define XLF1 0
#endif

#ifdef CONFIG_EFI_STUB
# ifdef CONFIG_EFI_MIXED
#  define XLF23 (XLF_EFI_HANDOVER_32|XLF_EFI_HANDOVER_64)
# else
#  ifdef CONFIG_X86_64
#   define XLF23 XLF_EFI_HANDOVER_64		/* 64-bit EFI handover ok */
#  else
#   define XLF23 XLF_EFI_HANDOVER_32		/* 32-bit EFI handover ok */
#  endif
# endif
#else
# define XLF23 0
#endif

#if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC_CORE)
# define XLF4 XLF_EFI_KEXEC
#else
# define XLF4 0
#endif

			.word XLF0 | XLF1 | XLF23 | XLF4

cmdline_size:   .long   COMMAND_LINE_SIZE-1     #length of the command line,
                                                #added with boot protocol
                                                #version 2.06

hardware_subarch:	.long 0			# subarchitecture, added with 2.07
						# default to 0 for normal x86 PC

hardware_subarch_data:	.quad 0

payload_offset:		.long ZO_input_data
payload_length:		.long ZO_z_input_len

setup_data:		.quad 0			# 64-bit physical pointer to
						# single linked list of
						# struct setup_data

pref_address:		.quad LOAD_PHYSICAL_ADDR	# preferred load addr

#define ZO_INIT_SIZE	(ZO__end - ZO_startup_32 + ZO_z_extract_offset)
#define VO_INIT_SIZE	(VO__end - VO__text)
#if ZO_INIT_SIZE > VO_INIT_SIZE
#define INIT_SIZE ZO_INIT_SIZE
#else
#define INIT_SIZE VO_INIT_SIZE
#endif
init_size:		.long INIT_SIZE		# kernel initialization size
handover_offset:	.long 0			# Filled in by build.c

# End of setup header #####################################################

	.section ".entrytext", "ax"
start_of_setup:
# Force %es = %ds
	movw	%ds, %ax
	movw	%ax, %es
	cld

# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
# which happened to work by accident for the old code.  Recalculate the stack
# pointer if %ss is invalid.  Otherwise leave it alone, LOADLIN sets up the
# stack behind its own code, so we can't blindly put it directly past the heap.

	movw	%ss, %dx
	cmpw	%ax, %dx	# %ds == %ss?
	movw	%sp, %dx
	je	2f		# -> assume %sp is reasonably set

	# Invalid %ss, make up a new stack
	movw	$_end, %dx
	testb	$CAN_USE_HEAP, loadflags
	jz	1f
	movw	heap_end_ptr, %dx
1:	addw	$STACK_SIZE, %dx
	jnc	2f
	xorw	%dx, %dx	# Prevent wraparound

2:	# Now %dx should point to the end of our stack space
	andw	$~3, %dx	# dword align (might as well...)
	jnz	3f
	movw	$0xfffc, %dx	# Make sure we're not zero
3:	movw	%ax, %ss
	movzwl	%dx, %esp	# Clear upper half of %esp
	sti			# Now we should have a working stack

# We will have entered with %cs = %ds+0x20, normalize %cs so
# it is on par with the other segments.
	pushw	%ds
	pushw	$6f
	lretw
6:

# Check signature at end of setup
	cmpl	$0x5a5aaa55, setup_sig
	jne	setup_bad

# Zero the bss
	movw	$__bss_start, %di
	movw	$_end+3, %cx
	xorl	%eax, %eax
	subw	%di, %cx
	shrw	$2, %cx
	rep; stosl

# Jump to C code (should not return)
	calll	main

# Setup corrupt somehow...
setup_bad:
	movl	$setup_corrupt, %eax
	calll	puts
	# Fall through...

	.globl	die
	.type	die, @function
die:
	hlt
	jmp	die

	.size	die, .-die

	.section ".initdata", "a"
setup_corrupt:
	.byte	7
	.string	"No setup signature found...\n"
Commit	Line	Data
62607313 PA	1	/*
	2	* header.S
	3	*
	4	* Copyright (C) 1991, 1992 Linus Torvalds
	5	*
	6	* Based on bootsect.S and setup.S
	7	* modified by more people than can be counted
	8	*
	9	* Rewritten as a common file by H. Peter Anvin (Apr 2007)
	10	*
	11	* BIG FAT NOTE: We're in real mode using 64k segments. Therefore segment
	12	* addresses must be multiplied by 16 to obtain their respective linear
	13	* addresses. To avoid confusion, linear addresses are written using leading
	14	* hex while segment addresses are written as segment:offset.
	15	*
	16	*/
	17
	18	#include <asm/segment.h>
273b281f	19	#include <generated/utsrelease.h>
62607313 PA	20	#include <asm/boot.h>
62607313 PA	21	#include <asm/e820.h>
0341c14d	22	#include <asm/page_types.h>
62607313	23	#include <asm/setup.h>
09c205af	24	#include <asm/bootparam.h>
62607313	25	#include "boot.h"
77d1a499 PA	26	#include "voffset.h"
77d1a499 PA	27	#include "zoffset.h"
62607313	28
62607313	29	BOOTSEG = 0x07C0 /* original address of boot-sector */
5e47c478	30	SYSSEG = 0x1000 /* historical load address >> 4 */
62607313 PA	31
	32	#ifndef SVGA_MODE
	33	#define SVGA_MODE ASK_VGA
	34	#endif
	35
62607313 PA	36	#ifndef ROOT_RDONLY
	37	#define ROOT_RDONLY 1
	38	#endif
	39
	40	.code16
	41	.section ".bstext", "ax"
	42
	43	.global bootsect_start
	44	bootsect_start:
291f3632 MF	45	#ifdef CONFIG_EFI_STUB
	46	# "MZ", MS-DOS header
	47	.byte 0x4d
	48	.byte 0x5a
	49	#endif
62607313 PA	50
	51	# Normalize the start address
	52	ljmp $BOOTSEG, $start2
	53
	54	start2:
	55	movw %cs, %ax
	56	movw %ax, %ds
	57	movw %ax, %es
	58	movw %ax, %ss
	59	xorw %sp, %sp
	60	sti
	61	cld
	62
	63	movw $bugger_off_msg, %si
	64
	65	msg_loop:
	66	lodsb
	67	andb %al, %al
	68	jz bs_die
	69	movb $0xe, %ah
	70	movw $7, %bx
	71	int $0x10
	72	jmp msg_loop
	73
	74	bs_die:
	75	# Allow the user to press a key, then reboot
	76	xorw %ax, %ax
	77	int $0x16
	78	int $0x19
	79
	80	# int 0x19 should never return. In case it does anyway,
	81	# invoke the BIOS reset code...
	82	ljmp $0xf000,$0xfff0
	83
291f3632 MF	84	#ifdef CONFIG_EFI_STUB
	85	.org 0x3c
	86	#
	87	# Offset to the PE header.
	88	#
	89	.long pe_header
	90	#endif /* CONFIG_EFI_STUB */
	91
62607313 PA	92	.section ".bsdata", "a"
62607313 PA	93	bugger_off_msg:
c7fb93ec	94	.ascii "Use a boot loader.\r\n"
62607313	95	.ascii "\n"
c7fb93ec	96	.ascii "Remove disk and press any key to reboot...\r\n"
62607313 PA	97	.byte 0
62607313 PA	98
291f3632 MF	99	#ifdef CONFIG_EFI_STUB
	100	pe_header:
	101	.ascii "PE"
	102	.word 0
	103
	104	coff_header:
	105	#ifdef CONFIG_X86_32
	106	.word 0x14c # i386
	107	#else
	108	.word 0x8664 # x86-64
	109	#endif
c7fb93ec	110	.word 4 # nr_sections
291f3632 MF	111	.long 0 # TimeDateStamp
	112	.long 0 # PointerToSymbolTable
	113	.long 1 # NumberOfSymbols
	114	.word section_table - optional_header # SizeOfOptionalHeader
	115	#ifdef CONFIG_X86_32
	116	.word 0x306 # Characteristics.
	117	# IMAGE_FILE_32BIT_MACHINE \|
	118	# IMAGE_FILE_DEBUG_STRIPPED \|
	119	# IMAGE_FILE_EXECUTABLE_IMAGE \|
	120	# IMAGE_FILE_LINE_NUMS_STRIPPED
	121	#else
	122	.word 0x206 # Characteristics
	123	# IMAGE_FILE_DEBUG_STRIPPED \|
	124	# IMAGE_FILE_EXECUTABLE_IMAGE \|
	125	# IMAGE_FILE_LINE_NUMS_STRIPPED
	126	#endif
	127
	128	optional_header:
	129	#ifdef CONFIG_X86_32
	130	.word 0x10b # PE32 format
	131	#else
	132	.word 0x20b # PE32+ format
	133	#endif
	134	.byte 0x02 # MajorLinkerVersion
	135	.byte 0x14 # MinorLinkerVersion
	136
	137	# Filled in by build.c
	138	.long 0 # SizeOfCode
	139
	140	.long 0 # SizeOfInitializedData
	141	.long 0 # SizeOfUninitializedData
	142
	143	# Filled in by build.c
	144	.long 0x0000 # AddressOfEntryPoint
	145
e31be363	146	.long 0x0200 # BaseOfCode
291f3632 MF	147	#ifdef CONFIG_X86_32
	148	.long 0 # data
	149	#endif
	150
	151	extra_header_fields:
	152	#ifdef CONFIG_X86_32
	153	.long 0 # ImageBase
	154	#else
	155	.quad 0 # ImageBase
	156	#endif
fa5c3501	157	.long 0x20 # SectionAlignment
743628e8	158	.long 0x20 # FileAlignment
291f3632 MF	159	.word 0 # MajorOperatingSystemVersion
	160	.word 0 # MinorOperatingSystemVersion
	161	.word 0 # MajorImageVersion
	162	.word 0 # MinorImageVersion
	163	.word 0 # MajorSubsystemVersion
	164	.word 0 # MinorSubsystemVersion
	165	.long 0 # Win32VersionValue
	166
	167	#
	168	# The size of the bzImage is written in tools/build.c
	169	#
	170	.long 0 # SizeOfImage
	171
	172	.long 0x200 # SizeOfHeaders
	173	.long 0 # CheckSum
	174	.word 0xa # Subsystem (EFI application)
	175	.word 0 # DllCharacteristics
	176	#ifdef CONFIG_X86_32
	177	.long 0 # SizeOfStackReserve
	178	.long 0 # SizeOfStackCommit
	179	.long 0 # SizeOfHeapReserve
	180	.long 0 # SizeOfHeapCommit
	181	#else
	182	.quad 0 # SizeOfStackReserve
	183	.quad 0 # SizeOfStackCommit
	184	.quad 0 # SizeOfHeapReserve
	185	.quad 0 # SizeOfHeapCommit
	186	#endif
	187	.long 0 # LoaderFlags
e47bb0bd	188	.long 0x6 # NumberOfRvaAndSizes
291f3632 MF	189
	190	.quad 0 # ExportTable
	191	.quad 0 # ImportTable
	192	.quad 0 # ResourceTable
	193	.quad 0 # ExceptionTable
	194	.quad 0 # CertificationTable
	195	.quad 0 # BaseRelocationTable
	196
	197	# Section table
	198	section_table:
743628e8 JJ	199	#
	200	# The offset & size fields are filled in by build.c.
	201	#
	202	.ascii ".setup"
291f3632 MF	203	.byte 0
	204	.byte 0
	205	.long 0
	206	.long 0x0 # startup_{32,64}
	207	.long 0 # Size of initialized data
	208	# on disk
	209	.long 0x0 # startup_{32,64}
	210	.long 0 # PointerToRelocations
	211	.long 0 # PointerToLineNumbers
	212	.word 0 # NumberOfRelocations
	213	.word 0 # NumberOfLineNumbers
	214	.long 0x60500020 # Characteristics (section flags)
	215
	216	#
	217	# The EFI application loader requires a relocation section
743628e8 JJ	218	# because EFI applications must be relocatable. The .reloc
743628e8 JJ	219	# offset & size fields are filled in by build.c.
291f3632 MF	220	#
	221	.ascii ".reloc"
	222	.byte 0
	223	.byte 0
2e064b1e JJ	224	.long 0
	225	.long 0
	226	.long 0 # SizeOfRawData
	227	.long 0 # PointerToRawData
291f3632 MF	228	.long 0 # PointerToRelocations
	229	.long 0 # PointerToLineNumbers
	230	.word 0 # NumberOfRelocations
	231	.word 0 # NumberOfLineNumbers
	232	.long 0x42100040 # Characteristics (section flags)
743628e8 JJ	233
	234	#
	235	# The offset & size fields are filled in by build.c.
	236	#
	237	.ascii ".text"
	238	.byte 0
	239	.byte 0
	240	.byte 0
	241	.long 0
	242	.long 0x0 # startup_{32,64}
	243	.long 0 # Size of initialized data
	244	# on disk
	245	.long 0x0 # startup_{32,64}
	246	.long 0 # PointerToRelocations
	247	.long 0 # PointerToLineNumbers
	248	.word 0 # NumberOfRelocations
	249	.word 0 # NumberOfLineNumbers
	250	.long 0x60500020 # Characteristics (section flags)
	251
c7fb93ec MB	252	#
	253	# The offset & size fields are filled in by build.c.
	254	#
	255	.ascii ".bss"
	256	.byte 0
	257	.byte 0
	258	.byte 0
	259	.byte 0
	260	.long 0
	261	.long 0x0
	262	.long 0 # Size of initialized data
	263	# on disk
	264	.long 0x0
	265	.long 0 # PointerToRelocations
	266	.long 0 # PointerToLineNumbers
	267	.word 0 # NumberOfRelocations
	268	.word 0 # NumberOfLineNumbers
	269	.long 0xc8000080 # Characteristics (section flags)
	270
291f3632	271	#endif /* CONFIG_EFI_STUB */
62607313 PA	272
	273	# Kernel attributes; used by setup. This is part 1 of the
	274	# header, from the old boot sector.
	275
	276	.section ".header", "a"
09c205af PA	277	.globl sentinel
	278	sentinel: .byte 0xff, 0xff /* Used to detect broken loaders */
	279
62607313 PA	280	.globl hdr
62607313 PA	281	hdr:
5e47c478	282	setup_sects: .byte 0 /* Filled in by build.c */
62607313	283	root_flags: .word ROOT_RDONLY
5e47c478 PA	284	syssize: .long 0 /* Filled in by build.c */
5e47c478 PA	285	ram_size: .word 0 /* Obsolete */
62607313	286	vid_mode: .word SVGA_MODE
5e47c478	287	root_dev: .word 0 /* Filled in by build.c */
62607313 PA	288	boot_flag: .word 0xAA55
	289
	290	# offset 512, entry point
	291
	292	.globl _start
	293	_start:
	294	# Explicitly enter this as bytes, or the assembler
	295	# tries to generate a 3-byte jump here, which causes
	296	# everything else to push off to the wrong offset.
	297	.byte 0xeb # short (2-byte) jump
	298	.byte start_of_setup-1f
	299	1:
	300
	301	# Part 2 of the header, from the old setup.S
	302
	303	.ascii "HdrS" # header signature
7d453eee	304	.word 0x020d # header version number (>= 0x0105)
62607313 PA	305	# or else old loadlin-1.5 will fail)
	306	.globl realmode_swtch
	307	realmode_swtch: .word 0, 0 # default_switch, SETUPSEG
5e47c478 PA	308	start_sys_seg: .word SYSSEG # obsolete and meaningless, but just
5e47c478 PA	309	# in case something decided to "use" it
62607313 PA	310	.word kernel_version-512 # pointing to kernel version string
	311	# above section of header is compatible
	312	# with loadlin-1.5 (header v1.5). Don't
	313	# change it.
	314
5e47c478 PA	315	type_of_loader: .byte 0 # 0 means ancient bootloader, newer
5e47c478 PA	316	# bootloaders know to change this.
395cf969	317	# See Documentation/x86/boot.txt for
62607313 PA	318	# assigned ids
	319
	320	# flags, unused bits must be zero (RFU) bit within loadflags
	321	loadflags:
09c205af	322	.byte LOADED_HIGH # The kernel is to be loaded high
62607313 PA	323
	324	setup_move_size: .word 0x8000 # size to move, when setup is not
	325	# loaded at 0x90000. We will move setup
	326	# to 0x90000 then just before jumping
	327	# into the kernel. However, only the
	328	# loader knows how much data behind
	329	# us also needs to be loaded.
	330
	331	code32_start: # here loaders can put a different
	332	# start address for 32-bit code.
62607313	333	.long 0x100000 # 0x100000 = default for big kernel
62607313 PA	334
	335	ramdisk_image: .long 0 # address of loaded ramdisk image
	336	# Here the loader puts the 32-bit
	337	# address where it loaded the image.
	338	# This only will be read by the kernel.
	339
	340	ramdisk_size: .long 0 # its size in bytes
	341
	342	bootsect_kludge:
	343	.long 0 # obsolete
	344
6b6815c6 PA	345	heap_end_ptr: .word _end+STACK_SIZE-512
6b6815c6 PA	346	# (Header version 0x0201 or later)
62607313 PA	347	# space from here (exclusive) down to
	348	# end of setup code can be used by setup
	349	# for local heap purposes.
	350
5031296c PA	351	ext_loader_ver:
	352	.byte 0 # Extended boot loader version
	353	ext_loader_type:
	354	.byte 0 # Extended boot loader type
	355
62607313 PA	356	cmd_line_ptr: .long 0 # (Header version 0x0202 or later)
	357	# If nonzero, a 32-bit pointer
	358	# to the kernel command line.
	359	# The command line should be
	360	# located between the start of
	361	# setup and the end of low
	362	# memory (0xa0000), or it may
	363	# get overwritten before it
	364	# gets read. If this field is
	365	# used, there is no longer
	366	# anything magical about the
	367	# 0x90000 segment; the setup
	368	# can be located anywhere in
	369	# low memory 0x10000 or higher.
	370
3e920b53	371	initrd_addr_max: .long 0x7fffffff
62607313 PA	372	# (Header version 0x0203 or later)
	373	# The highest safe address for
	374	# the contents of an initrd
cf8fa920 PA	375	# The current kernel allows up to 4 GB,
	376	# but leave it at 2 GB to avoid
	377	# possible bootloader bugs.
62607313 PA	378
	379	kernel_alignment: .long CONFIG_PHYSICAL_ALIGN #physical addr alignment
	380	#required for protected mode
	381	#kernel
	382	#ifdef CONFIG_RELOCATABLE
	383	relocatable_kernel: .byte 1
	384	#else
	385	relocatable_kernel: .byte 0
	386	#endif
37ba7ab5	387	min_alignment: .byte MIN_KERNEL_ALIGN_LG2 # minimum alignment
09c205af PA	388
	389	xloadflags:
	390	#ifdef CONFIG_X86_64
	391	# define XLF0 XLF_KERNEL_64 /* 64-bit kernel */
	392	#else
	393	# define XLF0 0
	394	#endif
ee92d815	395
745c5167	396	#if defined(CONFIG_RELOCATABLE) && defined(CONFIG_X86_64)
ee92d815 YL	397	/* kernel/boot_param/ramdisk could be loaded above 4g */
	398	# define XLF1 XLF_CAN_BE_LOADED_ABOVE_4G
	399	#else
	400	# define XLF1 0
	401	#endif
	402
09c205af	403	#ifdef CONFIG_EFI_STUB
7d453eee MF	404	# ifdef CONFIG_EFI_MIXED
7d453eee MF	405	# define XLF23 (XLF_EFI_HANDOVER_32\|XLF_EFI_HANDOVER_64)
09c205af	406	# else
7d453eee MF	407	# ifdef CONFIG_X86_64
	408	# define XLF23 XLF_EFI_HANDOVER_64 /* 64-bit EFI handover ok */
	409	# else
	410	# define XLF23 XLF_EFI_HANDOVER_32 /* 32-bit EFI handover ok */
	411	# endif
09c205af PA	412	# endif
	413	#else
	414	# define XLF23 0
	415	#endif
456a29dd	416
2965faa5	417	#if defined(CONFIG_X86_64) && defined(CONFIG_EFI) && defined(CONFIG_KEXEC_CORE)
456a29dd DY	418	# define XLF4 XLF_EFI_KEXEC
	419	#else
	420	# define XLF4 0
	421	#endif
	422
	423	.word XLF0 \| XLF1 \| XLF23 \| XLF4
62607313 PA	424
	425	cmdline_size: .long COMMAND_LINE_SIZE-1 #length of the command line,
	426	#added with boot protocol
	427	#version 2.06
	428
a24e7851 RR	429	hardware_subarch: .long 0 # subarchitecture, added with 2.07
	430	# default to 0 for normal x86 PC
	431
	432	hardware_subarch_data: .quad 0
	433
77d1a499 PA	434	payload_offset: .long ZO_input_data
77d1a499 PA	435	payload_length: .long ZO_z_input_len
099e1377	436
8b664aa6 HY	437	setup_data: .quad 0 # 64-bit physical pointer to
	438	# single linked list of
	439	# struct setup_data
	440
37ba7ab5 PA	441	pref_address: .quad LOAD_PHYSICAL_ADDR # preferred load addr
37ba7ab5 PA	442
c6ac4c18	443	#define ZO_INIT_SIZE (ZO__end - ZO_startup_32 + ZO_z_extract_offset)
37ba7ab5 PA	444	#define VO_INIT_SIZE (VO__end - VO__text)
	445	#if ZO_INIT_SIZE > VO_INIT_SIZE
	446	#define INIT_SIZE ZO_INIT_SIZE
	447	#else
	448	#define INIT_SIZE VO_INIT_SIZE
	449	#endif
	450	init_size: .long INIT_SIZE # kernel initialization size
86134a1b	451	handover_offset: .long 0 # Filled in by build.c
37ba7ab5	452
62607313 PA	453	# End of setup header #####################################################
62607313 PA	454
7a734e7d	455	.section ".entrytext", "ax"
62607313	456	start_of_setup:
62607313 PA	457	# Force %es = %ds
	458	movw %ds, %ax
	459	movw %ax, %es
	460	cld
	461
16252da6 JR	462	# Apparently some ancient versions of LILO invoked the kernel with %ss != %ds,
	463	# which happened to work by accident for the old code. Recalculate the stack
	464	# pointer if %ss is invalid. Otherwise leave it alone, LOADLIN sets up the
	465	# stack behind its own code, so we can't blindly put it directly past the heap.
6b6815c6	466
6b6815c6 PA	467	movw %ss, %dx
	468	cmpw %ax, %dx # %ds == %ss?
	469	movw %sp, %dx
16252da6 JR	470	je 2f # -> assume %sp is reasonably set
	471
	472	# Invalid %ss, make up a new stack
	473	movw $_end, %dx
	474	testb $CAN_USE_HEAP, loadflags
	475	jz 1f
	476	movw heap_end_ptr, %dx
	477	1: addw $STACK_SIZE, %dx
	478	jnc 2f
	479	xorw %dx, %dx # Prevent wraparound
6b6815c6	480
16252da6	481	2: # Now %dx should point to the end of our stack space
6b6815c6 PA	482	andw $~3, %dx # dword align (might as well...)
	483	jnz 3f
	484	movw $0xfffc, %dx # Make sure we're not zero
16252da6	485	3: movw %ax, %ss
6b6815c6 PA	486	movzwl %dx, %esp # Clear upper half of %esp
	487	sti # Now we should have a working stack
	488
	489	# We will have entered with %cs = %ds+0x20, normalize %cs so
	490	# it is on par with the other segments.
	491	pushw %ds
	492	pushw $6f
	493	lretw
	494	6:
62607313 PA	495
	496	# Check signature at end of setup
	497	cmpl $0x5a5aaa55, setup_sig
	498	jne setup_bad
	499
	500	# Zero the bss
	501	movw $__bss_start, %di
	502	movw $_end+3, %cx
	503	xorl %eax, %eax
	504	subw %di, %cx
	505	shrw $2, %cx
	506	rep; stosl
	507
	508	# Jump to C code (should not return)
	509	calll main
	510
	511	# Setup corrupt somehow...
	512	setup_bad:
	513	movl $setup_corrupt, %eax
	514	calll puts
	515	# Fall through...
	516
	517	.globl die
	518	.type die, @function
	519	die:
	520	hlt
	521	jmp die
	522
bbc15f46	523	.size die, .-die
62607313 PA	524
	525	.section ".initdata", "a"
	526	setup_corrupt:
	527	.byte 7
8b608d2f	528	.string "No setup signature found...\n"