[deliverable/linux.git] / arch / x86 / kernel / head_64.S

/*
 *  linux/arch/x86/kernel/head_64.S -- start in 32bit and switch to 64bit
 *
 *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
 *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
 *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
 *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
 *  Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
 */


#include <linux/linkage.h>
#include <linux/threads.h>
#include <linux/init.h>
#include <asm/segment.h>
#include <asm/pgtable.h>
#include <asm/page.h>
#include <asm/msr.h>
#include <asm/cache.h>
#include <asm/processor-flags.h>
#include <asm/percpu.h>
#include <asm/nops.h>
#include "../entry/calling.h"

#ifdef CONFIG_PARAVIRT
#include <asm/asm-offsets.h>
#include <asm/paravirt.h>
#define GET_CR2_INTO(reg) GET_CR2_INTO_RAX ; movq %rax, reg
#else
#define GET_CR2_INTO(reg) movq %cr2, reg
#define INTERRUPT_RETURN iretq
#endif

/* we are not able to switch in one step to the final KERNEL ADDRESS SPACE
 * because we need identity-mapped pages.
 *
 */

#define pud_index(x)	(((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))

L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
L4_START_KERNEL = pgd_index(__START_KERNEL_map)
L3_START_KERNEL = pud_index(__START_KERNEL_map)

	.text
	__HEAD
	.code64
	.globl startup_64
startup_64:
	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 0,
	 * and someone has loaded an identity mapped page table
	 * for us.  These identity mapped page tables map all of the
	 * kernel pages and possibly all of memory.
	 *
	 * %rsi holds a physical pointer to real_mode_data.
	 *
	 * We come here either directly from a 64bit bootloader, or from
	 * arch/x86/boot/compressed/head_64.S.
	 *
	 * We only come here initially at boot nothing else comes here.
	 *
	 * Since we may be loaded at an address different from what we were
	 * compiled to run at we first fixup the physical addresses in our page
	 * tables and then reload them.
	 */

	/* Sanitize CPU configuration */
	call verify_cpu

	/*
	 * Compute the delta between the address I am compiled to run at and the
	 * address I am actually running at.
	 */
	leaq	_text(%rip), %rbp
	subq	$_text - __START_KERNEL_map, %rbp

	/* Is the address not 2M aligned? */
	testl	$~PMD_PAGE_MASK, %ebp
	jnz	bad_address

	/*
	 * Is the address too large?
	 */
	leaq	_text(%rip), %rax
	shrq	$MAX_PHYSMEM_BITS, %rax
	jnz	bad_address

	/*
	 * Fixup the physical addresses in the page table
	 */
	addq	%rbp, early_level4_pgt + (L4_START_KERNEL*8)(%rip)

	addq	%rbp, level3_kernel_pgt + (510*8)(%rip)
	addq	%rbp, level3_kernel_pgt + (511*8)(%rip)

	addq	%rbp, level2_fixmap_pgt + (506*8)(%rip)

	/*
	 * Set up the identity mapping for the switchover.  These
	 * entries should *NOT* have the global bit set!  This also
	 * creates a bunch of nonsense entries but that is fine --
	 * it avoids problems around wraparound.
	 */
	leaq	_text(%rip), %rdi
	leaq	early_level4_pgt(%rip), %rbx

	movq	%rdi, %rax
	shrq	$PGDIR_SHIFT, %rax

	leaq	(4096 + _KERNPG_TABLE)(%rbx), %rdx
	movq	%rdx, 0(%rbx,%rax,8)
	movq	%rdx, 8(%rbx,%rax,8)

	addq	$4096, %rdx
	movq	%rdi, %rax
	shrq	$PUD_SHIFT, %rax
	andl	$(PTRS_PER_PUD-1), %eax
	movq	%rdx, 4096(%rbx,%rax,8)
	incl	%eax
	andl	$(PTRS_PER_PUD-1), %eax
	movq	%rdx, 4096(%rbx,%rax,8)

	addq	$8192, %rbx
	movq	%rdi, %rax
	shrq	$PMD_SHIFT, %rdi
	addq	$(__PAGE_KERNEL_LARGE_EXEC & ~_PAGE_GLOBAL), %rax
	leaq	(_end - 1)(%rip), %rcx
	shrq	$PMD_SHIFT, %rcx
	subq	%rdi, %rcx
	incl	%ecx

1:
	andq	$(PTRS_PER_PMD - 1), %rdi
	movq	%rax, (%rbx,%rdi,8)
	incq	%rdi
	addq	$PMD_SIZE, %rax
	decl	%ecx
	jnz	1b

	/*
	 * Fixup the kernel text+data virtual addresses. Note that
	 * we might write invalid pmds, when the kernel is relocated
	 * cleanup_highmap() fixes this up along with the mappings
	 * beyond _end.
	 */
	leaq	level2_kernel_pgt(%rip), %rdi
	leaq	4096(%rdi), %r8
	/* See if it is a valid page table entry */
1:	testb	$1, 0(%rdi)
	jz	2f
	addq	%rbp, 0(%rdi)
	/* Go to the next page */
2:	addq	$8, %rdi
	cmp	%r8, %rdi
	jne	1b

	/* Fixup phys_base */
	addq	%rbp, phys_base(%rip)

	movq	$(early_level4_pgt - __START_KERNEL_map), %rax
	jmp 1f
ENTRY(secondary_startup_64)
	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 0,
	 * and someone has loaded a mapped page table.
	 *
	 * %rsi holds a physical pointer to real_mode_data.
	 *
	 * We come here either from startup_64 (using physical addresses)
	 * or from trampoline.S (using virtual addresses).
	 *
	 * Using virtual addresses from trampoline.S removes the need
	 * to have any identity mapped pages in the kernel page table
	 * after the boot processor executes this code.
	 */

	/* Sanitize CPU configuration */
	call verify_cpu

	movq	$(init_level4_pgt - __START_KERNEL_map), %rax
1:

	/* Enable PAE mode and PGE */
	movl	$(X86_CR4_PAE | X86_CR4_PGE), %ecx
	movq	%rcx, %cr4

	/* Setup early boot stage 4 level pagetables. */
	addq	phys_base(%rip), %rax
	movq	%rax, %cr3

	/* Ensure I am executing from virtual addresses */
	movq	$1f, %rax
	jmp	*%rax
1:

	/* Check if nx is implemented */
	movl	$0x80000001, %eax
	cpuid
	movl	%edx,%edi

	/* Setup EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_SCE, %eax	/* Enable System Call */
	btl	$20,%edi		/* No Execute supported? */
	jnc     1f
	btsl	$_EFER_NX, %eax
	btsq	$_PAGE_BIT_NX,early_pmd_flags(%rip)
1:	wrmsr				/* Make changes effective */

	/* Setup cr0 */
#define CR0_STATE	(X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
			 X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
			 X86_CR0_PG)
	movl	$CR0_STATE, %eax
	/* Make changes effective */
	movq	%rax, %cr0

	/* Setup a boot time stack */
	movq stack_start(%rip), %rsp

	/* zero EFLAGS after setting rsp */
	pushq $0
	popfq

	/*
	 * We must switch to a new descriptor in kernel space for the GDT
	 * because soon the kernel won't have access anymore to the userspace
	 * addresses where we're currently running on. We have to do that here
	 * because in 32bit we couldn't load a 64bit linear address.
	 */
	lgdt	early_gdt_descr(%rip)

	/* set up data segments */
	xorl %eax,%eax
	movl %eax,%ds
	movl %eax,%ss
	movl %eax,%es

	/*
	 * We don't really need to load %fs or %gs, but load them anyway
	 * to kill any stale realmode selectors.  This allows execution
	 * under VT hardware.
	 */
	movl %eax,%fs
	movl %eax,%gs

	/* Set up %gs.
	 *
	 * The base of %gs always points to the bottom of the irqstack
	 * union.  If the stack protector canary is enabled, it is
	 * located at %gs:40.  Note that, on SMP, the boot cpu uses
	 * init data section till per cpu areas are set up.
	 */
	movl	$MSR_GS_BASE,%ecx
	movl	initial_gs(%rip),%eax
	movl	initial_gs+4(%rip),%edx
	wrmsr	

	/* rsi is pointer to real mode structure with interesting info.
	   pass it to C */
	movq	%rsi, %rdi
	
	/* Finally jump to run C code and to be on real kernel address
	 * Since we are running on identity-mapped space we have to jump
	 * to the full 64bit address, this is only possible as indirect
	 * jump.  In addition we need to ensure %cs is set so we make this
	 * a far return.
	 *
	 * Note: do not change to far jump indirect with 64bit offset.
	 *
	 * AMD does not support far jump indirect with 64bit offset.
	 * AMD64 Architecture Programmer's Manual, Volume 3: states only
	 *	JMP FAR mem16:16 FF /5 Far jump indirect,
	 *		with the target specified by a far pointer in memory.
	 *	JMP FAR mem16:32 FF /5 Far jump indirect,
	 *		with the target specified by a far pointer in memory.
	 *
	 * Intel64 does support 64bit offset.
	 * Software Developer Manual Vol 2: states:
	 *	FF /5 JMP m16:16 Jump far, absolute indirect,
	 *		address given in m16:16
	 *	FF /5 JMP m16:32 Jump far, absolute indirect,
	 *		address given in m16:32.
	 *	REX.W + FF /5 JMP m16:64 Jump far, absolute indirect,
	 *		address given in m16:64.
	 */
	movq	initial_code(%rip),%rax
	pushq	$0		# fake return address to stop unwinder
	pushq	$__KERNEL_CS	# set correct cs
	pushq	%rax		# target address in negative space
	lretq

#include "verify_cpu.S"

#ifdef CONFIG_HOTPLUG_CPU
/*
 * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
 * up already except stack. We just set up stack here. Then call
 * start_secondary().
 */
ENTRY(start_cpu0)
	movq stack_start(%rip),%rsp
	movq	initial_code(%rip),%rax
	pushq	$0		# fake return address to stop unwinder
	pushq	$__KERNEL_CS	# set correct cs
	pushq	%rax		# target address in negative space
	lretq
ENDPROC(start_cpu0)
#endif

	/* SMP bootup changes these two */
	__REFDATA
	.balign	8
	GLOBAL(initial_code)
	.quad	x86_64_start_kernel
	GLOBAL(initial_gs)
	.quad	INIT_PER_CPU_VAR(irq_stack_union)

	GLOBAL(stack_start)
	.quad  init_thread_union+THREAD_SIZE-8
	.word  0
	__FINITDATA

bad_address:
	jmp bad_address

	__INIT
ENTRY(early_idt_handler_array)
	# 104(%rsp) %rflags
	#  96(%rsp) %cs
	#  88(%rsp) %rip
	#  80(%rsp) error code
	i = 0
	.rept NUM_EXCEPTION_VECTORS
	.ifeq (EXCEPTION_ERRCODE_MASK >> i) & 1
	pushq $0		# Dummy error code, to make stack frame uniform
	.endif
	pushq $i		# 72(%rsp) Vector number
	jmp early_idt_handler_common
	i = i + 1
	.fill early_idt_handler_array + i*EARLY_IDT_HANDLER_SIZE - ., 1, 0xcc
	.endr
ENDPROC(early_idt_handler_array)

early_idt_handler_common:
	/*
	 * The stack is the hardware frame, an error code or zero, and the
	 * vector number.
	 */
	cld

	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	incl early_recursion_flag(%rip)

	/* The vector number is currently in the pt_regs->di slot. */
	pushq %rsi				/* pt_regs->si */
	movq 8(%rsp), %rsi			/* RSI = vector number */
	movq %rdi, 8(%rsp)			/* pt_regs->di = RDI */
	pushq %rdx				/* pt_regs->dx */
	pushq %rcx				/* pt_regs->cx */
	pushq %rax				/* pt_regs->ax */
	pushq %r8				/* pt_regs->r8 */
	pushq %r9				/* pt_regs->r9 */
	pushq %r10				/* pt_regs->r10 */
	pushq %r11				/* pt_regs->r11 */
	pushq %rbx				/* pt_regs->bx */
	pushq %rbp				/* pt_regs->bp */
	pushq %r12				/* pt_regs->r12 */
	pushq %r13				/* pt_regs->r13 */
	pushq %r14				/* pt_regs->r14 */
	pushq %r15				/* pt_regs->r15 */

	cmpl $__KERNEL_CS,CS(%rsp)
	jne 11f

	cmpq $14,%rsi		/* Page fault? */
	jnz 10f
	GET_CR2_INTO(%rdi)	/* Can clobber any volatile register if pv */
	call early_make_pgtable
	andl %eax,%eax
	jz 20f			/* All good */

10:
	movq %rsp,%rdi		/* RDI = pt_regs; RSI is already trapnr */
	call early_fixup_exception
	andl %eax,%eax
	jnz 20f			# Found an exception entry

11:
#ifdef CONFIG_EARLY_PRINTK
	/*
	 * On paravirt kernels, GET_CR2_INTO clobbers callee-clobbered regs.
	 * We only care about RSI, so we need to save it.
	 */
	movq %rsi,%rbx		/* Save vector number */
	GET_CR2_INTO(%r9)
	movq ORIG_RAX(%rsp),%r8	/* error code */
	movq %rbx,%rsi		/* vector number */
	movq CS(%rsp),%rdx
	movq RIP(%rsp),%rcx
	xorl %eax,%eax
	leaq early_idt_msg(%rip),%rdi
	call early_printk
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	call dump_stack
#ifdef CONFIG_KALLSYMS	
	leaq early_idt_ripmsg(%rip),%rdi
	movq RIP(%rsp),%rsi	# %rip again
	call __print_symbol
#endif
#endif /* EARLY_PRINTK */
1:	hlt
	jmp 1b

20:	/* Exception table entry found or page table generated */
	decl early_recursion_flag(%rip)
	jmp restore_regs_and_iret
ENDPROC(early_idt_handler_common)

	__INITDATA

	.balign 4
early_recursion_flag:
	.long 0

#ifdef CONFIG_EARLY_PRINTK
early_idt_msg:
	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
early_idt_ripmsg:
	.asciz "RIP %s\n"
#endif /* CONFIG_EARLY_PRINTK */

#define NEXT_PAGE(name) \
	.balign	PAGE_SIZE; \
GLOBAL(name)

/* Automate the creation of 1 to 1 mapping pmd entries */
#define PMDS(START, PERM, COUNT)			\
	i = 0 ;						\
	.rept (COUNT) ;					\
	.quad	(START) + (i << PMD_SHIFT) + (PERM) ;	\
	i = i + 1 ;					\
	.endr

	__INITDATA
NEXT_PAGE(early_level4_pgt)
	.fill	511,8,0
	.quad	level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(early_dynamic_pgts)
	.fill	512*EARLY_DYNAMIC_PAGE_TABLES,8,0

	.data

#ifndef CONFIG_XEN
NEXT_PAGE(init_level4_pgt)
	.fill	512,8,0
#else
NEXT_PAGE(init_level4_pgt)
	.quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org    init_level4_pgt + L4_PAGE_OFFSET*8, 0
	.quad   level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org    init_level4_pgt + L4_START_KERNEL*8, 0
	/* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
	.quad   level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level3_ident_pgt)
	.quad	level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.fill	511, 8, 0
NEXT_PAGE(level2_ident_pgt)
	/* Since I easily can, map the first 1G.
	 * Don't set NX because code runs from these pages.
	 */
	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
#endif

NEXT_PAGE(level3_kernel_pgt)
	.fill	L3_START_KERNEL,8,0
	/* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
	.quad	level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.quad	level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level2_kernel_pgt)
	/*
	 * 512 MB kernel mapping. We spend a full page on this pagetable
	 * anyway.
	 *
	 * The kernel code+data+bss must not be bigger than that.
	 *
	 * (NOTE: at +512MB starts the module area, see MODULES_VADDR.
	 *  If you want to increase this then increase MODULES_VADDR
	 *  too.)
	 */
	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
		KERNEL_IMAGE_SIZE/PMD_SIZE)

NEXT_PAGE(level2_fixmap_pgt)
	.fill	506,8,0
	.quad	level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	.fill	5,8,0

NEXT_PAGE(level1_fixmap_pgt)
	.fill	512,8,0

#undef PMDS

	.data
	.align 16
	.globl early_gdt_descr
early_gdt_descr:
	.word	GDT_ENTRIES*8-1
early_gdt_descr_base:
	.quad	INIT_PER_CPU_VAR(gdt_page)

ENTRY(phys_base)
	/* This must match the first entry in level2_kernel_pgt */
	.quad   0x0000000000000000

#include "../../x86/xen/xen-head.S"
	
	__PAGE_ALIGNED_BSS
NEXT_PAGE(empty_zero_page)
	.skip PAGE_SIZE
Commit	Line	Data
1da177e4	1	/*
5b171e82	2	* linux/arch/x86/kernel/head_64.S -- start in 32bit and switch to 64bit
1da177e4 LT	3	*
	4	* Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
	5	* Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
	6	* Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
	7	* Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
1ab60e0f	8	* Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
1da177e4 LT	9	*/
	10
	11
	12	#include <linux/linkage.h>
	13	#include <linux/threads.h>
f6c2e333	14	#include <linux/init.h>
1da177e4	15	#include <asm/segment.h>
67dcbb6b	16	#include <asm/pgtable.h>
1da177e4 LT	17	#include <asm/page.h>
	18	#include <asm/msr.h>
	19	#include <asm/cache.h>
369101da	20	#include <asm/processor-flags.h>
b12d8db8	21	#include <asm/percpu.h>
9900aa2f	22	#include <asm/nops.h>
7bbcdb1c	23	#include "../entry/calling.h"
1ab60e0f	24
49a69787 GOC	25	#ifdef CONFIG_PARAVIRT
	26	#include <asm/asm-offsets.h>
	27	#include <asm/paravirt.h>
ffc4bc9c	28	#define GET_CR2_INTO(reg) GET_CR2_INTO_RAX ; movq %rax, reg
49a69787	29	#else
ffc4bc9c	30	#define GET_CR2_INTO(reg) movq %cr2, reg
9900aa2f	31	#define INTERRUPT_RETURN iretq
49a69787 GOC	32	#endif
49a69787 GOC	33
3ad2f3fb	34	/* we are not able to switch in one step to the final KERNEL ADDRESS SPACE
1ab60e0f VG	35	* because we need identity-mapped pages.
1ab60e0f VG	36	*
1da177e4 LT	37	*/
1da177e4 LT	38
a6523748 EH	39	#define pud_index(x) (((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))
	40
	41	L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
a6523748 EH	42	L4_START_KERNEL = pgd_index(__START_KERNEL_map)
	43	L3_START_KERNEL = pud_index(__START_KERNEL_map)
	44
1da177e4	45	.text
4ae59b91	46	__HEAD
1ab60e0f VG	47	.code64
	48	.globl startup_64
	49	startup_64:
1da177e4	50	/*
1256276c	51	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 0,
1ab60e0f VG	52	* and someone has loaded an identity mapped page table
	53	* for us. These identity mapped page tables map all of the
	54	* kernel pages and possibly all of memory.
	55	*
8170e6be	56	* %rsi holds a physical pointer to real_mode_data.
1ab60e0f VG	57	*
1ab60e0f VG	58	* We come here either directly from a 64bit bootloader, or from
5b171e82	59	* arch/x86/boot/compressed/head_64.S.
1ab60e0f VG	60	*
	61	* We only come here initially at boot nothing else comes here.
	62	*
	63	* Since we may be loaded at an address different from what we were
	64	* compiled to run at we first fixup the physical addresses in our page
	65	* tables and then reload them.
1da177e4 LT	66	*/
1da177e4 LT	67
04633df0 BP	68	/* Sanitize CPU configuration */
	69	call verify_cpu
	70
8170e6be PA	71	/*
8170e6be PA	72	* Compute the delta between the address I am compiled to run at and the
1ab60e0f	73	* address I am actually running at.
1da177e4	74	*/
1ab60e0f VG	75	leaq _text(%rip), %rbp
	76	subq $_text - __START_KERNEL_map, %rbp
	77
	78	/* Is the address not 2M aligned? */
a4733143	79	testl $~PMD_PAGE_MASK, %ebp
1ab60e0f VG	80	jnz bad_address
1ab60e0f VG	81
8170e6be PA	82	/*
8170e6be PA	83	* Is the address too large?
1da177e4	84	*/
8170e6be PA	85	leaq _text(%rip), %rax
	86	shrq $MAX_PHYSMEM_BITS, %rax
	87	jnz bad_address
1ab60e0f	88
8170e6be PA	89	/*
	90	* Fixup the physical addresses in the page table
	91	*/
	92	addq %rbp, early_level4_pgt + (L4_START_KERNEL*8)(%rip)
b1c931e3	93
1ab60e0f	94	addq %rbp, level3_kernel_pgt + (510*8)(%rip)
b1c931e3 EB	95	addq %rbp, level3_kernel_pgt + (511*8)(%rip)
	96
	97	addq %rbp, level2_fixmap_pgt + (506*8)(%rip)
1ab60e0f	98
8170e6be PA	99	/*
	100	* Set up the identity mapping for the switchover. These
	101	* entries should NOT have the global bit set! This also
	102	* creates a bunch of nonsense entries but that is fine --
	103	* it avoids problems around wraparound.
	104	*/
1ab60e0f	105	leaq _text(%rip), %rdi
8170e6be	106	leaq early_level4_pgt(%rip), %rbx
1ab60e0f VG	107
1ab60e0f VG	108	movq %rdi, %rax
8170e6be	109	shrq $PGDIR_SHIFT, %rax
1ab60e0f	110
8170e6be PA	111	leaq (4096 + _KERNPG_TABLE)(%rbx), %rdx
	112	movq %rdx, 0(%rbx,%rax,8)
	113	movq %rdx, 8(%rbx,%rax,8)
1ab60e0f	114
8170e6be	115	addq $4096, %rdx
1ab60e0f	116	movq %rdi, %rax
8170e6be PA	117	shrq $PUD_SHIFT, %rax
8170e6be PA	118	andl $(PTRS_PER_PUD-1), %eax
e9d0626e ZY	119	movq %rdx, 4096(%rbx,%rax,8)
	120	incl %eax
	121	andl $(PTRS_PER_PUD-1), %eax
	122	movq %rdx, 4096(%rbx,%rax,8)
8170e6be PA	123
	124	addq $8192, %rbx
	125	movq %rdi, %rax
	126	shrq $PMD_SHIFT, %rdi
	127	addq $(__PAGE_KERNEL_LARGE_EXEC & ~_PAGE_GLOBAL), %rax
	128	leaq (_end - 1)(%rip), %rcx
	129	shrq $PMD_SHIFT, %rcx
	130	subq %rdi, %rcx
	131	incl %ecx
	132
	133	1:
	134	andq $(PTRS_PER_PMD - 1), %rdi
	135	movq %rax, (%rbx,%rdi,8)
	136	incq %rdi
	137	addq $PMD_SIZE, %rax
	138	decl %ecx
	139	jnz 1b
1ab60e0f	140
31eedd82 TG	141	/*
	142	* Fixup the kernel text+data virtual addresses. Note that
	143	* we might write invalid pmds, when the kernel is relocated
	144	* cleanup_highmap() fixes this up along with the mappings
	145	* beyond _end.
1ab60e0f VG	146	*/
	147	leaq level2_kernel_pgt(%rip), %rdi
	148	leaq 4096(%rdi), %r8
	149	/* See if it is a valid page table entry */
3e1aa7cb	150	1: testb $1, 0(%rdi)
1ab60e0f VG	151	jz 2f
	152	addq %rbp, 0(%rdi)
	153	/* Go to the next page */
	154	2: addq $8, %rdi
	155	cmp %r8, %rdi
	156	jne 1b
	157
	158	/* Fixup phys_base */
	159	addq %rbp, phys_base(%rip)
1da177e4	160
8170e6be PA	161	movq $(early_level4_pgt - __START_KERNEL_map), %rax
8170e6be PA	162	jmp 1f
90b1c208	163	ENTRY(secondary_startup_64)
1ab60e0f	164	/*
1256276c	165	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 0,
1ab60e0f VG	166	* and someone has loaded a mapped page table.
1ab60e0f VG	167	*
8170e6be	168	* %rsi holds a physical pointer to real_mode_data.
1ab60e0f VG	169	*
	170	* We come here either from startup_64 (using physical addresses)
	171	* or from trampoline.S (using virtual addresses).
	172	*
	173	* Using virtual addresses from trampoline.S removes the need
	174	* to have any identity mapped pages in the kernel page table
	175	* after the boot processor executes this code.
1da177e4 LT	176	*/
1da177e4 LT	177
04633df0 BP	178	/* Sanitize CPU configuration */
	179	call verify_cpu
	180
8170e6be PA	181	movq $(init_level4_pgt - __START_KERNEL_map), %rax
	182	1:
	183
1da177e4	184	/* Enable PAE mode and PGE */
8170e6be PA	185	movl $(X86_CR4_PAE \| X86_CR4_PGE), %ecx
8170e6be PA	186	movq %rcx, %cr4
1da177e4 LT	187
1da177e4 LT	188	/* Setup early boot stage 4 level pagetables. */
1ab60e0f	189	addq phys_base(%rip), %rax
1da177e4 LT	190	movq %rax, %cr3
1da177e4 LT	191
1ab60e0f VG	192	/* Ensure I am executing from virtual addresses */
	193	movq $1f, %rax
	194	jmp *%rax
	195	1:
	196
1da177e4 LT	197	/* Check if nx is implemented */
	198	movl $0x80000001, %eax
	199	cpuid
	200	movl %edx,%edi
	201
	202	/* Setup EFER (Extended Feature Enable Register) */
	203	movl $MSR_EFER, %ecx
	204	rdmsr
1ab60e0f VG	205	btsl $_EFER_SCE, %eax /* Enable System Call */
1ab60e0f VG	206	btl $20,%edi /* No Execute supported? */
1da177e4 LT	207	jnc 1f
1da177e4 LT	208	btsl $_EFER_NX, %eax
78d77df7	209	btsq $_PAGE_BIT_NX,early_pmd_flags(%rip)
1ab60e0f	210	1: wrmsr /* Make changes effective */
1da177e4 LT	211
1da177e4 LT	212	/* Setup cr0 */
369101da CG	213	#define CR0_STATE (X86_CR0_PE \| X86_CR0_MP \| X86_CR0_ET \| \
	214	X86_CR0_NE \| X86_CR0_WP \| X86_CR0_AM \| \
	215	X86_CR0_PG)
	216	movl $CR0_STATE, %eax
1da177e4 LT	217	/* Make changes effective */
	218	movq %rax, %cr0
	219
	220	/* Setup a boot time stack */
8170e6be	221	movq stack_start(%rip), %rsp
1da177e4 LT	222
	223	/* zero EFLAGS after setting rsp */
	224	pushq $0
	225	popfq
	226
	227	/*
	228	* We must switch to a new descriptor in kernel space for the GDT
	229	* because soon the kernel won't have access anymore to the userspace
	230	* addresses where we're currently running on. We have to do that here
	231	* because in 32bit we couldn't load a 64bit linear address.
	232	*/
a939098a	233	lgdt early_gdt_descr(%rip)
1da177e4	234
8ec6993d BG	235	/* set up data segments */
8ec6993d BG	236	xorl %eax,%eax
ffb60175 ZA	237	movl %eax,%ds
	238	movl %eax,%ss
	239	movl %eax,%es
	240
	241	/*
	242	* We don't really need to load %fs or %gs, but load them anyway
	243	* to kill any stale realmode selectors. This allows execution
	244	* under VT hardware.
	245	*/
	246	movl %eax,%fs
	247	movl %eax,%gs
	248
f32ff538 TH	249	/* Set up %gs.
f32ff538 TH	250	*
947e76cd BG	251	* The base of %gs always points to the bottom of the irqstack
	252	* union. If the stack protector canary is enabled, it is
	253	* located at %gs:40. Note that, on SMP, the boot cpu uses
	254	* init data section till per cpu areas are set up.
f32ff538	255	*/
1da177e4	256	movl $MSR_GS_BASE,%ecx
650fb439 BG	257	movl initial_gs(%rip),%eax
650fb439 BG	258	movl initial_gs+4(%rip),%edx
1da177e4 LT	259	wrmsr
1da177e4 LT	260
8170e6be	261	/* rsi is pointer to real mode structure with interesting info.
1da177e4	262	pass it to C */
8170e6be	263	movq %rsi, %rdi
1da177e4 LT	264
	265	/* Finally jump to run C code and to be on real kernel address
	266	* Since we are running on identity-mapped space we have to jump
26374c7b EB	267	* to the full 64bit address, this is only possible as indirect
	268	* jump. In addition we need to ensure %cs is set so we make this
	269	* a far return.
8170e6be PA	270	*
	271	* Note: do not change to far jump indirect with 64bit offset.
	272	*
	273	* AMD does not support far jump indirect with 64bit offset.
	274	* AMD64 Architecture Programmer's Manual, Volume 3: states only
	275	* JMP FAR mem16:16 FF /5 Far jump indirect,
	276	* with the target specified by a far pointer in memory.
	277	* JMP FAR mem16:32 FF /5 Far jump indirect,
	278	* with the target specified by a far pointer in memory.
	279	*
	280	* Intel64 does support 64bit offset.
	281	* Software Developer Manual Vol 2: states:
	282	* FF /5 JMP m16:16 Jump far, absolute indirect,
	283	* address given in m16:16
	284	* FF /5 JMP m16:32 Jump far, absolute indirect,
	285	* address given in m16:32.
	286	* REX.W + FF /5 JMP m16:64 Jump far, absolute indirect,
	287	* address given in m16:64.
1da177e4 LT	288	*/
1da177e4 LT	289	movq initial_code(%rip),%rax
26374c7b EB	290	pushq $0 # fake return address to stop unwinder
	291	pushq $__KERNEL_CS # set correct cs
	292	pushq %rax # target address in negative space
	293	lretq
1da177e4	294
04633df0 BP	295	#include "verify_cpu.S"
04633df0 BP	296
42e78e97 FY	297	#ifdef CONFIG_HOTPLUG_CPU
	298	/*
	299	* Boot CPU0 entry point. It's called from play_dead(). Everything has been set
	300	* up already except stack. We just set up stack here. Then call
	301	* start_secondary().
	302	*/
	303	ENTRY(start_cpu0)
	304	movq stack_start(%rip),%rsp
	305	movq initial_code(%rip),%rax
	306	pushq $0 # fake return address to stop unwinder
	307	pushq $__KERNEL_CS # set correct cs
	308	pushq %rax # target address in negative space
	309	lretq
	310	ENDPROC(start_cpu0)
	311	#endif
	312
e57113bc	313	/* SMP bootup changes these two */
da5968ae	314	__REFDATA
8170e6be PA	315	.balign 8
8170e6be PA	316	GLOBAL(initial_code)
1da177e4	317	.quad x86_64_start_kernel
8170e6be	318	GLOBAL(initial_gs)
2add8e23	319	.quad INIT_PER_CPU_VAR(irq_stack_union)
f1fbabb3	320
8170e6be	321	GLOBAL(stack_start)
1da177e4	322	.quad init_thread_union+THREAD_SIZE-8
9cf4f298	323	.word 0
b9af7c0d	324	__FINITDATA
1da177e4	325
1ab60e0f VG	326	bad_address:
	327	jmp bad_address
	328
8170e6be	329	__INIT
cdeb6048	330	ENTRY(early_idt_handler_array)
9900aa2f PA	331	# 104(%rsp) %rflags
	332	# 96(%rsp) %cs
	333	# 88(%rsp) %rip
	334	# 80(%rsp) error code
749c970a AK	335	i = 0
749c970a AK	336	.rept NUM_EXCEPTION_VECTORS
cdeb6048	337	.ifeq (EXCEPTION_ERRCODE_MASK >> i) & 1
9900aa2f PA	338	pushq $0 # Dummy error code, to make stack frame uniform
	339	.endif
	340	pushq $i # 72(%rsp) Vector number
cdeb6048	341	jmp early_idt_handler_common
749c970a	342	i = i + 1
cdeb6048	343	.fill early_idt_handler_array + i*EARLY_IDT_HANDLER_SIZE - ., 1, 0xcc
749c970a	344	.endr
cdeb6048	345	ENDPROC(early_idt_handler_array)
8866cd9d	346
cdeb6048 AL	347	early_idt_handler_common:
	348	/*
	349	* The stack is the hardware frame, an error code or zero, and the
	350	* vector number.
	351	*/
9900aa2f PA	352	cld
9900aa2f PA	353
b957591f AK	354	cmpl $2,early_recursion_flag(%rip)
	355	jz 1f
	356	incl early_recursion_flag(%rip)
9900aa2f	357
7bbcdb1c AL	358	/* The vector number is currently in the pt_regs->di slot. */
	359	pushq %rsi /* pt_regs->si */
	360	movq 8(%rsp), %rsi /* RSI = vector number */
	361	movq %rdi, 8(%rsp) /* pt_regs->di = RDI */
	362	pushq %rdx /* pt_regs->dx */
	363	pushq %rcx /* pt_regs->cx */
	364	pushq %rax /* pt_regs->ax */
	365	pushq %r8 /* pt_regs->r8 */
	366	pushq %r9 /* pt_regs->r9 */
	367	pushq %r10 /* pt_regs->r10 */
	368	pushq %r11 /* pt_regs->r11 */
	369	pushq %rbx /* pt_regs->bx */
	370	pushq %rbp /* pt_regs->bp */
	371	pushq %r12 /* pt_regs->r12 */
	372	pushq %r13 /* pt_regs->r13 */
	373	pushq %r14 /* pt_regs->r14 */
	374	pushq %r15 /* pt_regs->r15 */
	375
	376	cmpl $__KERNEL_CS,CS(%rsp)
8170e6be PA	377	jne 11f
8170e6be PA	378
7bbcdb1c	379	cmpq $14,%rsi /* Page fault? */
8170e6be	380	jnz 10f
7bbcdb1c	381	GET_CR2_INTO(%rdi) /* Can clobber any volatile register if pv */
8170e6be PA	382	call early_make_pgtable
8170e6be PA	383	andl %eax,%eax
7bbcdb1c	384	jz 20f /* All good */
9900aa2f	385
8170e6be	386	10:
7bbcdb1c	387	movq %rsp,%rdi /* RDI = pt_regs; RSI is already trapnr */
9900aa2f PA	388	call early_fixup_exception
	389	andl %eax,%eax
	390	jnz 20f # Found an exception entry
	391
8170e6be	392	11:
9900aa2f	393	#ifdef CONFIG_EARLY_PRINTK
7bbcdb1c AL	394	/*
	395	* On paravirt kernels, GET_CR2_INTO clobbers callee-clobbered regs.
	396	* We only care about RSI, so we need to save it.
	397	*/
	398	movq %rsi,%rbx /* Save vector number */
	399	GET_CR2_INTO(%r9)
	400	movq ORIG_RAX(%rsp),%r8 /* error code */
	401	movq %rbx,%rsi /* vector number */
	402	movq CS(%rsp),%rdx
	403	movq RIP(%rsp),%rcx
8866cd9d	404	xorl %eax,%eax
1da177e4 LT	405	leaq early_idt_msg(%rip),%rdi
1da177e4 LT	406	call early_printk
b957591f AK	407	cmpl $2,early_recursion_flag(%rip)
	408	jz 1f
	409	call dump_stack
6574ffd7 AK	410	#ifdef CONFIG_KALLSYMS
6574ffd7 AK	411	leaq early_idt_ripmsg(%rip),%rdi
7bbcdb1c	412	movq RIP(%rsp),%rsi # %rip again
6574ffd7 AK	413	call __print_symbol
6574ffd7 AK	414	#endif
076f9776	415	#endif /* EARLY_PRINTK */
1da177e4 LT	416	1: hlt
1da177e4 LT	417	jmp 1b
076f9776	418
7bbcdb1c	419	20: /* Exception table entry found or page table generated */
9900aa2f	420	decl early_recursion_flag(%rip)
7bbcdb1c	421	jmp restore_regs_and_iret
cdeb6048	422	ENDPROC(early_idt_handler_common)
9900aa2f	423
8170e6be PA	424	__INITDATA
8170e6be PA	425
9900aa2f	426	.balign 4
b957591f AK	427	early_recursion_flag:
b957591f AK	428	.long 0
1da177e4	429
9900aa2f	430	#ifdef CONFIG_EARLY_PRINTK
1da177e4	431	early_idt_msg:
8866cd9d	432	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
6574ffd7 AK	433	early_idt_ripmsg:
6574ffd7 AK	434	.asciz "RIP %s\n"
076f9776	435	#endif /* CONFIG_EARLY_PRINTK */
1da177e4	436
f0cf5d1a	437	#define NEXT_PAGE(name) \
67dcbb6b	438	.balign PAGE_SIZE; \
8170e6be	439	GLOBAL(name)
f0cf5d1a	440
67dcbb6b	441	/* Automate the creation of 1 to 1 mapping pmd entries */
0e192b99 CG	442	#define PMDS(START, PERM, COUNT) \
	443	i = 0 ; \
	444	.rept (COUNT) ; \
	445	.quad (START) + (i << PMD_SHIFT) + (PERM) ; \
	446	i = i + 1 ; \
67dcbb6b VG	447	.endr
67dcbb6b VG	448
8170e6be PA	449	__INITDATA
	450	NEXT_PAGE(early_level4_pgt)
	451	.fill 511,8,0
	452	.quad level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
	453
	454	NEXT_PAGE(early_dynamic_pgts)
	455	.fill 512*EARLY_DYNAMIC_PAGE_TABLES,8,0
	456
b9af7c0d	457	.data
8170e6be PA	458
8170e6be PA	459	#ifndef CONFIG_XEN
f0cf5d1a	460	NEXT_PAGE(init_level4_pgt)
8170e6be PA	461	.fill 512,8,0
	462	#else
	463	NEXT_PAGE(init_level4_pgt)
	464	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	465	.org init_level4_pgt + L4_PAGE_OFFSET*8, 0
	466	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	467	.org init_level4_pgt + L4_START_KERNEL*8, 0
cfd243d4	468	/* (2^48-(2102410241024))/(2^39) = 511 /
8170e6be	469	.quad level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
1da177e4	470
f0cf5d1a	471	NEXT_PAGE(level3_ident_pgt)
67dcbb6b	472	.quad level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
8170e6be PA	473	.fill 511, 8, 0
	474	NEXT_PAGE(level2_ident_pgt)
	475	/* Since I easily can, map the first 1G.
	476	* Don't set NX because code runs from these pages.
	477	*/
	478	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
	479	#endif
1da177e4	480
f0cf5d1a	481	NEXT_PAGE(level3_kernel_pgt)
a6523748	482	.fill L3_START_KERNEL,8,0
1da177e4	483	/* (2^48-(2102410241024)-((2^39)511))/(2^30) = 510 */
67dcbb6b	484	.quad level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
b1c931e3 EB	485	.quad level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
b1c931e3 EB	486
f0cf5d1a	487	NEXT_PAGE(level2_kernel_pgt)
88f3aec7	488	/*
85eb69a1	489	* 512 MB kernel mapping. We spend a full page on this pagetable
88f3aec7 IM	490	* anyway.
	491	*
	492	* The kernel code+data+bss must not be bigger than that.
	493	*
85eb69a1	494	* (NOTE: at +512MB starts the module area, see MODULES_VADDR.
88f3aec7 IM	495	* If you want to increase this then increase MODULES_VADDR
	496	* too.)
	497	*/
8490638c	498	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
d4afe414	499	KERNEL_IMAGE_SIZE/PMD_SIZE)
1da177e4	500
8170e6be PA	501	NEXT_PAGE(level2_fixmap_pgt)
	502	.fill 506,8,0
	503	.quad level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	504	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	505	.fill 5,8,0
	506
	507	NEXT_PAGE(level1_fixmap_pgt)
	508	.fill 512,8,0
1ab60e0f	509
67dcbb6b	510	#undef PMDS
1da177e4	511
f0cf5d1a	512	.data
1da177e4	513	.align 16
a939098a GC	514	.globl early_gdt_descr
	515	early_gdt_descr:
	516	.word GDT_ENTRIES*8-1
3e5d8f97	517	early_gdt_descr_base:
2add8e23	518	.quad INIT_PER_CPU_VAR(gdt_page)
1da177e4	519
1ab60e0f VG	520	ENTRY(phys_base)
	521	/* This must match the first entry in level2_kernel_pgt */
	522	.quad 0x0000000000000000
	523
8c5e5ac3	524	#include "../../x86/xen/xen-head.S"
1da177e4	525
02b7da37	526	__PAGE_ALIGNED_BSS
8170e6be	527	NEXT_PAGE(empty_zero_page)
e57113bc	528	.skip PAGE_SIZE
ef7f0d6a	529