[deliverable/linux.git] / arch / x86 / kernel / head_64.S

/*
 *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
 *
 *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
 *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
 *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
 *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
 *  Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
 */


#include <linux/linkage.h>
#include <linux/threads.h>
#include <linux/init.h>
#include <asm/desc.h>
#include <asm/segment.h>
#include <asm/pgtable.h>
#include <asm/page.h>
#include <asm/msr.h>
#include <asm/cache.h>
#include <asm/processor-flags.h>
#include <asm/percpu.h>

#ifdef CONFIG_PARAVIRT
#include <asm/asm-offsets.h>
#include <asm/paravirt.h>
#else
#define GET_CR2_INTO_RCX movq %cr2, %rcx
#endif

/* we are not able to switch in one step to the final KERNEL ADRESS SPACE
 * because we need identity-mapped pages.
 *
 */

#define pud_index(x)	(((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))

L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
L4_START_KERNEL = pgd_index(__START_KERNEL_map)
L3_START_KERNEL = pud_index(__START_KERNEL_map)

	.text
	.section .text.head
	.code64
	.globl startup_64
startup_64:

	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	 * and someone has loaded an identity mapped page table
	 * for us.  These identity mapped page tables map all of the
	 * kernel pages and possibly all of memory.
	 *
	 * %esi holds a physical pointer to real_mode_data.
	 *
	 * We come here either directly from a 64bit bootloader, or from
	 * arch/x86_64/boot/compressed/head.S.
	 *
	 * We only come here initially at boot nothing else comes here.
	 *
	 * Since we may be loaded at an address different from what we were
	 * compiled to run at we first fixup the physical addresses in our page
	 * tables and then reload them.
	 */

	/* Compute the delta between the address I am compiled to run at and the
	 * address I am actually running at.
	 */
	leaq	_text(%rip), %rbp
	subq	$_text - __START_KERNEL_map, %rbp

	/* Is the address not 2M aligned? */
	movq	%rbp, %rax
	andl	$~PMD_PAGE_MASK, %eax
	testl	%eax, %eax
	jnz	bad_address

	/* Is the address too large? */
	leaq	_text(%rip), %rdx
	movq	$PGDIR_SIZE, %rax
	cmpq	%rax, %rdx
	jae	bad_address

	/* Fixup the physical addresses in the page table
	 */
	addq	%rbp, init_level4_pgt + 0(%rip)
	addq	%rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
	addq	%rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)

	addq	%rbp, level3_ident_pgt + 0(%rip)

	addq	%rbp, level3_kernel_pgt + (510*8)(%rip)
	addq	%rbp, level3_kernel_pgt + (511*8)(%rip)

	addq	%rbp, level2_fixmap_pgt + (506*8)(%rip)

	/* Add an Identity mapping if I am above 1G */
	leaq	_text(%rip), %rdi
	andq	$PMD_PAGE_MASK, %rdi

	movq	%rdi, %rax
	shrq	$PUD_SHIFT, %rax
	andq	$(PTRS_PER_PUD - 1), %rax
	jz	ident_complete

	leaq	(level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
	leaq	level3_ident_pgt(%rip), %rbx
	movq	%rdx, 0(%rbx, %rax, 8)

	movq	%rdi, %rax
	shrq	$PMD_SHIFT, %rax
	andq	$(PTRS_PER_PMD - 1), %rax
	leaq	__PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
	leaq	level2_spare_pgt(%rip), %rbx
	movq	%rdx, 0(%rbx, %rax, 8)
ident_complete:

	/*
	 * Fixup the kernel text+data virtual addresses. Note that
	 * we might write invalid pmds, when the kernel is relocated
	 * cleanup_highmap() fixes this up along with the mappings
	 * beyond _end.
	 */

	leaq	level2_kernel_pgt(%rip), %rdi
	leaq	4096(%rdi), %r8
	/* See if it is a valid page table entry */
1:	testq	$1, 0(%rdi)
	jz	2f
	addq	%rbp, 0(%rdi)
	/* Go to the next page */
2:	addq	$8, %rdi
	cmp	%r8, %rdi
	jne	1b

	/* Fixup phys_base */
	addq	%rbp, phys_base(%rip)

#ifdef CONFIG_X86_TRAMPOLINE
	addq	%rbp, trampoline_level4_pgt + 0(%rip)
	addq	%rbp, trampoline_level4_pgt + (511*8)(%rip)
#endif

	/* Due to ENTRY(), sometimes the empty space gets filled with
	 * zeros. Better take a jmp than relying on empty space being
	 * filled with 0x90 (nop)
	 */
	jmp secondary_startup_64
ENTRY(secondary_startup_64)
	/*
	 * At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	 * and someone has loaded a mapped page table.
	 *
	 * %esi holds a physical pointer to real_mode_data.
	 *
	 * We come here either from startup_64 (using physical addresses)
	 * or from trampoline.S (using virtual addresses).
	 *
	 * Using virtual addresses from trampoline.S removes the need
	 * to have any identity mapped pages in the kernel page table
	 * after the boot processor executes this code.
	 */

	/* Enable PAE mode and PGE */
	movl	$(X86_CR4_PAE | X86_CR4_PGE), %eax
	movq	%rax, %cr4

	/* Setup early boot stage 4 level pagetables. */
	movq	$(init_level4_pgt - __START_KERNEL_map), %rax
	addq	phys_base(%rip), %rax
	movq	%rax, %cr3

	/* Ensure I am executing from virtual addresses */
	movq	$1f, %rax
	jmp	*%rax
1:

	/* Check if nx is implemented */
	movl	$0x80000001, %eax
	cpuid
	movl	%edx,%edi

	/* Setup EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr
	btsl	$_EFER_SCE, %eax	/* Enable System Call */
	btl	$20,%edi		/* No Execute supported? */
	jnc     1f
	btsl	$_EFER_NX, %eax
1:	wrmsr				/* Make changes effective */

	/* Setup cr0 */
#define CR0_STATE	(X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
			 X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
			 X86_CR0_PG)
	movl	$CR0_STATE, %eax
	/* Make changes effective */
	movq	%rax, %cr0

	/* Setup a boot time stack */
	movq stack_start(%rip),%rsp

	/* zero EFLAGS after setting rsp */
	pushq $0
	popfq

	/*
	 * We must switch to a new descriptor in kernel space for the GDT
	 * because soon the kernel won't have access anymore to the userspace
	 * addresses where we're currently running on. We have to do that here
	 * because in 32bit we couldn't load a 64bit linear address.
	 */
	lgdt	early_gdt_descr(%rip)

	/* set up data segments. actually 0 would do too */
	movl $__KERNEL_DS,%eax
	movl %eax,%ds
	movl %eax,%ss
	movl %eax,%es

	/*
	 * We don't really need to load %fs or %gs, but load them anyway
	 * to kill any stale realmode selectors.  This allows execution
	 * under VT hardware.
	 */
	movl %eax,%fs
	movl %eax,%gs

	/* Set up %gs.
	 *
	 * The base of %gs always points to the bottom of the irqstack
	 * union.  If the stack protector canary is enabled, it is
	 * located at %gs:40.  Note that, on SMP, the boot cpu uses
	 * init data section till per cpu areas are set up.
	 */
	movl	$MSR_GS_BASE,%ecx
	movq	initial_gs(%rip),%rax
	movq    %rax,%rdx
	shrq	$32,%rdx
	wrmsr	

	/* esi is pointer to real mode structure with interesting info.
	   pass it to C */
	movl	%esi, %edi
	
	/* Finally jump to run C code and to be on real kernel address
	 * Since we are running on identity-mapped space we have to jump
	 * to the full 64bit address, this is only possible as indirect
	 * jump.  In addition we need to ensure %cs is set so we make this
	 * a far return.
	 */
	movq	initial_code(%rip),%rax
	pushq	$0		# fake return address to stop unwinder
	pushq	$__KERNEL_CS	# set correct cs
	pushq	%rax		# target address in negative space
	lretq

	/* SMP bootup changes these two */
	__REFDATA
	.align	8
	ENTRY(initial_code)
	.quad	x86_64_start_kernel
	ENTRY(initial_gs)
	.quad	INIT_PER_CPU_VAR(irq_stack_union)
	__FINITDATA

	ENTRY(stack_start)
	.quad  init_thread_union+THREAD_SIZE-8
	.word  0

bad_address:
	jmp bad_address

	.section ".init.text","ax"
#ifdef CONFIG_EARLY_PRINTK
	.globl early_idt_handlers
early_idt_handlers:
	i = 0
	.rept NUM_EXCEPTION_VECTORS
	movl $i, %esi
	jmp early_idt_handler
	i = i + 1
	.endr
#endif

ENTRY(early_idt_handler)
#ifdef CONFIG_EARLY_PRINTK
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	incl early_recursion_flag(%rip)
	GET_CR2_INTO_RCX
	movq %rcx,%r9
	xorl %r8d,%r8d		# zero for error code
	movl %esi,%ecx		# get vector number
	# Test %ecx against mask of vectors that push error code.
	cmpl $31,%ecx
	ja 0f
	movl $1,%eax
	salq %cl,%rax
	testl $0x27d00,%eax
	je 0f
	popq %r8		# get error code
0:	movq 0(%rsp),%rcx	# get ip
	movq 8(%rsp),%rdx	# get cs
	xorl %eax,%eax
	leaq early_idt_msg(%rip),%rdi
	call early_printk
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	call dump_stack
#ifdef CONFIG_KALLSYMS	
	leaq early_idt_ripmsg(%rip),%rdi
	movq 0(%rsp),%rsi	# get rip again
	call __print_symbol
#endif
#endif /* EARLY_PRINTK */
1:	hlt
	jmp 1b

#ifdef CONFIG_EARLY_PRINTK
early_recursion_flag:
	.long 0

early_idt_msg:
	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
early_idt_ripmsg:
	.asciz "RIP %s\n"
#endif /* CONFIG_EARLY_PRINTK */
	.previous

#define NEXT_PAGE(name) \
	.balign	PAGE_SIZE; \
ENTRY(name)

/* Automate the creation of 1 to 1 mapping pmd entries */
#define PMDS(START, PERM, COUNT)			\
	i = 0 ;						\
	.rept (COUNT) ;					\
	.quad	(START) + (i << PMD_SHIFT) + (PERM) ;	\
	i = i + 1 ;					\
	.endr

	/*
	 * This default setting generates an ident mapping at address 0x100000
	 * and a mapping for the kernel that precisely maps virtual address
	 * 0xffffffff80000000 to physical address 0x000000. (always using
	 * 2Mbyte large pages provided by PAE mode)
	 */
NEXT_PAGE(init_level4_pgt)
	.quad	level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org	init_level4_pgt + L4_PAGE_OFFSET*8, 0
	.quad	level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.org	init_level4_pgt + L4_START_KERNEL*8, 0
	/* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
	.quad	level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level3_ident_pgt)
	.quad	level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.fill	511,8,0

NEXT_PAGE(level3_kernel_pgt)
	.fill	L3_START_KERNEL,8,0
	/* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
	.quad	level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
	.quad	level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE

NEXT_PAGE(level2_fixmap_pgt)
	.fill	506,8,0
	.quad	level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	.fill	5,8,0

NEXT_PAGE(level1_fixmap_pgt)
	.fill	512,8,0

NEXT_PAGE(level2_ident_pgt)
	/* Since I easily can, map the first 1G.
	 * Don't set NX because code runs from these pages.
	 */
	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)

NEXT_PAGE(level2_kernel_pgt)
	/*
	 * 512 MB kernel mapping. We spend a full page on this pagetable
	 * anyway.
	 *
	 * The kernel code+data+bss must not be bigger than that.
	 *
	 * (NOTE: at +512MB starts the module area, see MODULES_VADDR.
	 *  If you want to increase this then increase MODULES_VADDR
	 *  too.)
	 */
	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
		KERNEL_IMAGE_SIZE/PMD_SIZE)

NEXT_PAGE(level2_spare_pgt)
	.fill   512, 8, 0

#undef PMDS
#undef NEXT_PAGE

	.data
	.align 16
	.globl early_gdt_descr
early_gdt_descr:
	.word	GDT_ENTRIES*8-1
early_gdt_descr_base:
	.quad	INIT_PER_CPU_VAR(gdt_page)

ENTRY(phys_base)
	/* This must match the first entry in level2_kernel_pgt */
	.quad   0x0000000000000000

#include "../../x86/xen/xen-head.S"
	
	.section .bss, "aw", @nobits
	.align L1_CACHE_BYTES
ENTRY(idt_table)
	.skip 256 * 16

	.section .bss.page_aligned, "aw", @nobits
	.align PAGE_SIZE
ENTRY(empty_zero_page)
	.skip PAGE_SIZE
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
	3	*
	4	* Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
	5	* Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
	6	* Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
	7	* Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
1ab60e0f	8	* Copyright (C) 2005 Eric Biederman <ebiederm@xmission.com>
1da177e4 LT	9	*/
	10
	11
	12	#include <linux/linkage.h>
	13	#include <linux/threads.h>
f6c2e333	14	#include <linux/init.h>
1da177e4 LT	15	#include <asm/desc.h>
1da177e4 LT	16	#include <asm/segment.h>
67dcbb6b	17	#include <asm/pgtable.h>
1da177e4 LT	18	#include <asm/page.h>
	19	#include <asm/msr.h>
	20	#include <asm/cache.h>
369101da	21	#include <asm/processor-flags.h>
b12d8db8	22	#include <asm/percpu.h>
1ab60e0f	23
49a69787 GOC	24	#ifdef CONFIG_PARAVIRT
	25	#include <asm/asm-offsets.h>
	26	#include <asm/paravirt.h>
	27	#else
	28	#define GET_CR2_INTO_RCX movq %cr2, %rcx
	29	#endif
	30
1da177e4	31	/* we are not able to switch in one step to the final KERNEL ADRESS SPACE
1ab60e0f VG	32	* because we need identity-mapped pages.
1ab60e0f VG	33	*
1da177e4 LT	34	*/
1da177e4 LT	35
a6523748 EH	36	#define pud_index(x) (((x) >> PUD_SHIFT) & (PTRS_PER_PUD-1))
	37
	38	L4_PAGE_OFFSET = pgd_index(__PAGE_OFFSET)
	39	L3_PAGE_OFFSET = pud_index(__PAGE_OFFSET)
	40	L4_START_KERNEL = pgd_index(__START_KERNEL_map)
	41	L3_START_KERNEL = pud_index(__START_KERNEL_map)
	42
1da177e4	43	.text
92417df0	44	.section .text.head
1ab60e0f VG	45	.code64
	46	.globl startup_64
	47	startup_64:
	48
1da177e4	49	/*
1ab60e0f VG	50	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	51	* and someone has loaded an identity mapped page table
	52	* for us. These identity mapped page tables map all of the
	53	* kernel pages and possibly all of memory.
	54	*
	55	* %esi holds a physical pointer to real_mode_data.
	56	*
	57	* We come here either directly from a 64bit bootloader, or from
	58	* arch/x86_64/boot/compressed/head.S.
	59	*
	60	* We only come here initially at boot nothing else comes here.
	61	*
	62	* Since we may be loaded at an address different from what we were
	63	* compiled to run at we first fixup the physical addresses in our page
	64	* tables and then reload them.
1da177e4 LT	65	*/
1da177e4 LT	66
1ab60e0f VG	67	/* Compute the delta between the address I am compiled to run at and the
1ab60e0f VG	68	* address I am actually running at.
1da177e4	69	*/
1ab60e0f VG	70	leaq _text(%rip), %rbp
	71	subq $_text - __START_KERNEL_map, %rbp
	72
	73	/* Is the address not 2M aligned? */
	74	movq %rbp, %rax
31422c51	75	andl $~PMD_PAGE_MASK, %eax
1ab60e0f VG	76	testl %eax, %eax
	77	jnz bad_address
	78
	79	/* Is the address too large? */
	80	leaq _text(%rip), %rdx
	81	movq $PGDIR_SIZE, %rax
	82	cmpq %rax, %rdx
	83	jae bad_address
	84
	85	/* Fixup the physical addresses in the page table
1da177e4	86	*/
1ab60e0f	87	addq %rbp, init_level4_pgt + 0(%rip)
a6523748 EH	88	addq %rbp, init_level4_pgt + (L4_PAGE_OFFSET*8)(%rip)
a6523748 EH	89	addq %rbp, init_level4_pgt + (L4_START_KERNEL*8)(%rip)
1ab60e0f VG	90
1ab60e0f VG	91	addq %rbp, level3_ident_pgt + 0(%rip)
b1c931e3	92
1ab60e0f	93	addq %rbp, level3_kernel_pgt + (510*8)(%rip)
b1c931e3 EB	94	addq %rbp, level3_kernel_pgt + (511*8)(%rip)
	95
	96	addq %rbp, level2_fixmap_pgt + (506*8)(%rip)
1ab60e0f VG	97
	98	/* Add an Identity mapping if I am above 1G */
	99	leaq _text(%rip), %rdi
31422c51	100	andq $PMD_PAGE_MASK, %rdi
1ab60e0f VG	101
	102	movq %rdi, %rax
	103	shrq $PUD_SHIFT, %rax
	104	andq $(PTRS_PER_PUD - 1), %rax
	105	jz ident_complete
	106
	107	leaq (level2_spare_pgt - __START_KERNEL_map + _KERNPG_TABLE)(%rbp), %rdx
	108	leaq level3_ident_pgt(%rip), %rbx
	109	movq %rdx, 0(%rbx, %rax, 8)
	110
	111	movq %rdi, %rax
	112	shrq $PMD_SHIFT, %rax
	113	andq $(PTRS_PER_PMD - 1), %rax
b2bc2731	114	leaq __PAGE_KERNEL_IDENT_LARGE_EXEC(%rdi), %rdx
1ab60e0f VG	115	leaq level2_spare_pgt(%rip), %rbx
	116	movq %rdx, 0(%rbx, %rax, 8)
	117	ident_complete:
	118
31eedd82 TG	119	/*
	120	* Fixup the kernel text+data virtual addresses. Note that
	121	* we might write invalid pmds, when the kernel is relocated
	122	* cleanup_highmap() fixes this up along with the mappings
	123	* beyond _end.
1ab60e0f	124	*/
31eedd82	125
1ab60e0f VG	126	leaq level2_kernel_pgt(%rip), %rdi
	127	leaq 4096(%rdi), %r8
	128	/* See if it is a valid page table entry */
	129	1: testq $1, 0(%rdi)
	130	jz 2f
	131	addq %rbp, 0(%rdi)
	132	/* Go to the next page */
	133	2: addq $8, %rdi
	134	cmp %r8, %rdi
	135	jne 1b
	136
	137	/* Fixup phys_base */
	138	addq %rbp, phys_base(%rip)
1da177e4	139
64e83b5a	140	#ifdef CONFIG_X86_TRAMPOLINE
1ab60e0f VG	141	addq %rbp, trampoline_level4_pgt + 0(%rip)
	142	addq %rbp, trampoline_level4_pgt + (511*8)(%rip)
	143	#endif
1da177e4	144
1ab60e0f VG	145	/* Due to ENTRY(), sometimes the empty space gets filled with
	146	* zeros. Better take a jmp than relying on empty space being
	147	* filled with 0x90 (nop)
1da177e4	148	*/
1ab60e0f	149	jmp secondary_startup_64
90b1c208	150	ENTRY(secondary_startup_64)
1ab60e0f VG	151	/*
	152	* At this point the CPU runs in 64bit mode CS.L = 1 CS.D = 1,
	153	* and someone has loaded a mapped page table.
	154	*
	155	* %esi holds a physical pointer to real_mode_data.
	156	*
	157	* We come here either from startup_64 (using physical addresses)
	158	* or from trampoline.S (using virtual addresses).
	159	*
	160	* Using virtual addresses from trampoline.S removes the need
	161	* to have any identity mapped pages in the kernel page table
	162	* after the boot processor executes this code.
1da177e4 LT	163	*/
	164
	165	/* Enable PAE mode and PGE */
05139d8f	166	movl $(X86_CR4_PAE \| X86_CR4_PGE), %eax
1da177e4 LT	167	movq %rax, %cr4
	168
	169	/* Setup early boot stage 4 level pagetables. */
cfd243d4	170	movq $(init_level4_pgt - __START_KERNEL_map), %rax
1ab60e0f	171	addq phys_base(%rip), %rax
1da177e4 LT	172	movq %rax, %cr3
1da177e4 LT	173
1ab60e0f VG	174	/* Ensure I am executing from virtual addresses */
	175	movq $1f, %rax
	176	jmp *%rax
	177	1:
	178
1da177e4 LT	179	/* Check if nx is implemented */
	180	movl $0x80000001, %eax
	181	cpuid
	182	movl %edx,%edi
	183
	184	/* Setup EFER (Extended Feature Enable Register) */
	185	movl $MSR_EFER, %ecx
	186	rdmsr
1ab60e0f VG	187	btsl $_EFER_SCE, %eax /* Enable System Call */
1ab60e0f VG	188	btl $20,%edi /* No Execute supported? */
1da177e4 LT	189	jnc 1f
1da177e4 LT	190	btsl $_EFER_NX, %eax
1ab60e0f	191	1: wrmsr /* Make changes effective */
1da177e4 LT	192
1da177e4 LT	193	/* Setup cr0 */
369101da CG	194	#define CR0_STATE (X86_CR0_PE \| X86_CR0_MP \| X86_CR0_ET \| \
	195	X86_CR0_NE \| X86_CR0_WP \| X86_CR0_AM \| \
	196	X86_CR0_PG)
	197	movl $CR0_STATE, %eax
1da177e4 LT	198	/* Make changes effective */
	199	movq %rax, %cr0
	200
	201	/* Setup a boot time stack */
9cf4f298	202	movq stack_start(%rip),%rsp
1da177e4 LT	203
	204	/* zero EFLAGS after setting rsp */
	205	pushq $0
	206	popfq
	207
	208	/*
	209	* We must switch to a new descriptor in kernel space for the GDT
	210	* because soon the kernel won't have access anymore to the userspace
	211	* addresses where we're currently running on. We have to do that here
	212	* because in 32bit we couldn't load a 64bit linear address.
	213	*/
a939098a	214	lgdt early_gdt_descr(%rip)
1da177e4	215
ffb60175 ZA	216	/* set up data segments. actually 0 would do too */
	217	movl $__KERNEL_DS,%eax
	218	movl %eax,%ds
	219	movl %eax,%ss
	220	movl %eax,%es
	221
	222	/*
	223	* We don't really need to load %fs or %gs, but load them anyway
	224	* to kill any stale realmode selectors. This allows execution
	225	* under VT hardware.
	226	*/
	227	movl %eax,%fs
	228	movl %eax,%gs
	229
f32ff538 TH	230	/* Set up %gs.
f32ff538 TH	231	*
947e76cd BG	232	* The base of %gs always points to the bottom of the irqstack
	233	* union. If the stack protector canary is enabled, it is
	234	* located at %gs:40. Note that, on SMP, the boot cpu uses
	235	* init data section till per cpu areas are set up.
f32ff538	236	*/
1da177e4	237	movl $MSR_GS_BASE,%ecx
f32ff538	238	movq initial_gs(%rip),%rax
1da177e4 LT	239	movq %rax,%rdx
	240	shrq $32,%rdx
	241	wrmsr
	242
1da177e4 LT	243	/* esi is pointer to real mode structure with interesting info.
	244	pass it to C */
	245	movl %esi, %edi
	246
	247	/* Finally jump to run C code and to be on real kernel address
	248	* Since we are running on identity-mapped space we have to jump
26374c7b EB	249	* to the full 64bit address, this is only possible as indirect
	250	* jump. In addition we need to ensure %cs is set so we make this
	251	* a far return.
1da177e4 LT	252	*/
1da177e4 LT	253	movq initial_code(%rip),%rax
26374c7b EB	254	pushq $0 # fake return address to stop unwinder
	255	pushq $__KERNEL_CS # set correct cs
	256	pushq %rax # target address in negative space
	257	lretq
1da177e4	258
e57113bc	259	/* SMP bootup changes these two */
da5968ae	260	__REFDATA
e57113bc	261	.align 8
f1fbabb3	262	ENTRY(initial_code)
1da177e4	263	.quad x86_64_start_kernel
f32ff538	264	ENTRY(initial_gs)
2add8e23	265	.quad INIT_PER_CPU_VAR(irq_stack_union)
f1fbabb3 SR	266	__FINITDATA
f1fbabb3 SR	267
9cf4f298	268	ENTRY(stack_start)
1da177e4	269	.quad init_thread_union+THREAD_SIZE-8
9cf4f298	270	.word 0
1da177e4	271
1ab60e0f VG	272	bad_address:
	273	jmp bad_address
	274
41bd4eac	275	.section ".init.text","ax"
076f9776	276	#ifdef CONFIG_EARLY_PRINTK
8866cd9d RM	277	.globl early_idt_handlers
8866cd9d RM	278	early_idt_handlers:
749c970a AK	279	i = 0
	280	.rept NUM_EXCEPTION_VECTORS
	281	movl $i, %esi
	282	jmp early_idt_handler
	283	i = i + 1
	284	.endr
076f9776	285	#endif
8866cd9d	286
1da177e4	287	ENTRY(early_idt_handler)
076f9776	288	#ifdef CONFIG_EARLY_PRINTK
b957591f AK	289	cmpl $2,early_recursion_flag(%rip)
	290	jz 1f
	291	incl early_recursion_flag(%rip)
49a69787	292	GET_CR2_INTO_RCX
8866cd9d RM	293	movq %rcx,%r9
	294	xorl %r8d,%r8d # zero for error code
	295	movl %esi,%ecx # get vector number
	296	# Test %ecx against mask of vectors that push error code.
	297	cmpl $31,%ecx
	298	ja 0f
	299	movl $1,%eax
	300	salq %cl,%rax
	301	testl $0x27d00,%eax
	302	je 0f
	303	popq %r8 # get error code
	304	0: movq 0(%rsp),%rcx # get ip
	305	movq 8(%rsp),%rdx # get cs
	306	xorl %eax,%eax
1da177e4 LT	307	leaq early_idt_msg(%rip),%rdi
1da177e4 LT	308	call early_printk
b957591f AK	309	cmpl $2,early_recursion_flag(%rip)
	310	jz 1f
	311	call dump_stack
6574ffd7 AK	312	#ifdef CONFIG_KALLSYMS
6574ffd7 AK	313	leaq early_idt_ripmsg(%rip),%rdi
7aed55d1	314	movq 0(%rsp),%rsi # get rip again
6574ffd7 AK	315	call __print_symbol
6574ffd7 AK	316	#endif
076f9776	317	#endif /* EARLY_PRINTK */
1da177e4 LT	318	1: hlt
1da177e4 LT	319	jmp 1b
076f9776 IM	320
076f9776 IM	321	#ifdef CONFIG_EARLY_PRINTK
b957591f AK	322	early_recursion_flag:
b957591f AK	323	.long 0
1da177e4 LT	324
1da177e4 LT	325	early_idt_msg:
8866cd9d	326	.asciz "PANIC: early exception %02lx rip %lx:%lx error %lx cr2 %lx\n"
6574ffd7 AK	327	early_idt_ripmsg:
6574ffd7 AK	328	.asciz "RIP %s\n"
076f9776	329	#endif /* CONFIG_EARLY_PRINTK */
41bd4eac	330	.previous
1da177e4	331
f0cf5d1a	332	#define NEXT_PAGE(name) \
67dcbb6b	333	.balign PAGE_SIZE; \
f0cf5d1a JB	334	ENTRY(name)
f0cf5d1a JB	335
67dcbb6b	336	/* Automate the creation of 1 to 1 mapping pmd entries */
0e192b99 CG	337	#define PMDS(START, PERM, COUNT) \
	338	i = 0 ; \
	339	.rept (COUNT) ; \
	340	.quad (START) + (i << PMD_SHIFT) + (PERM) ; \
	341	i = i + 1 ; \
67dcbb6b VG	342	.endr
67dcbb6b VG	343
cfd243d4 VG	344	/*
	345	* This default setting generates an ident mapping at address 0x100000
	346	* and a mapping for the kernel that precisely maps virtual address
	347	* 0xffffffff80000000 to physical address 0x000000. (always using
	348	* 2Mbyte large pages provided by PAE mode)
	349	*/
f0cf5d1a	350	NEXT_PAGE(init_level4_pgt)
cfd243d4	351	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
a6523748	352	.org init_level4_pgt + L4_PAGE_OFFSET*8, 0
cfd243d4	353	.quad level3_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
a6523748	354	.org init_level4_pgt + L4_START_KERNEL*8, 0
cfd243d4 VG	355	/* (2^48-(2102410241024))/(2^39) = 511 /
cfd243d4 VG	356	.quad level3_kernel_pgt - __START_KERNEL_map + _PAGE_TABLE
1da177e4	357
f0cf5d1a	358	NEXT_PAGE(level3_ident_pgt)
67dcbb6b	359	.quad level2_ident_pgt - __START_KERNEL_map + _KERNPG_TABLE
1da177e4 LT	360	.fill 511,8,0
1da177e4 LT	361
f0cf5d1a	362	NEXT_PAGE(level3_kernel_pgt)
a6523748	363	.fill L3_START_KERNEL,8,0
1da177e4	364	/* (2^48-(2102410241024)-((2^39)511))/(2^30) = 510 */
67dcbb6b	365	.quad level2_kernel_pgt - __START_KERNEL_map + _KERNPG_TABLE
b1c931e3 EB	366	.quad level2_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	367
	368	NEXT_PAGE(level2_fixmap_pgt)
6596f242 IM	369	.fill 506,8,0
	370	.quad level1_fixmap_pgt - __START_KERNEL_map + _PAGE_TABLE
	371	/* 8MB reserved for vsyscalls + a 2MB hole = 4 + 1 entries */
	372	.fill 5,8,0
	373
	374	NEXT_PAGE(level1_fixmap_pgt)
b1c931e3	375	.fill 512,8,0
1da177e4	376
f0cf5d1a	377	NEXT_PAGE(level2_ident_pgt)
67dcbb6b VG	378	/* Since I easily can, map the first 1G.
	379	* Don't set NX because code runs from these pages.
	380	*/
b2bc2731	381	PMDS(0, __PAGE_KERNEL_IDENT_LARGE_EXEC, PTRS_PER_PMD)
1ab60e0f	382
f0cf5d1a	383	NEXT_PAGE(level2_kernel_pgt)
88f3aec7	384	/*
85eb69a1	385	* 512 MB kernel mapping. We spend a full page on this pagetable
88f3aec7 IM	386	* anyway.
	387	*
	388	* The kernel code+data+bss must not be bigger than that.
	389	*
85eb69a1	390	* (NOTE: at +512MB starts the module area, see MODULES_VADDR.
88f3aec7 IM	391	* If you want to increase this then increase MODULES_VADDR
	392	* too.)
	393	*/
8490638c	394	PMDS(0, __PAGE_KERNEL_LARGE_EXEC,
d4afe414	395	KERNEL_IMAGE_SIZE/PMD_SIZE)
1da177e4	396
1ab60e0f	397	NEXT_PAGE(level2_spare_pgt)
88f3aec7	398	.fill 512, 8, 0
1ab60e0f	399
67dcbb6b	400	#undef PMDS
f0cf5d1a	401	#undef NEXT_PAGE
1da177e4	402
f0cf5d1a	403	.data
1da177e4	404	.align 16
a939098a GC	405	.globl early_gdt_descr
	406	early_gdt_descr:
	407	.word GDT_ENTRIES*8-1
3e5d8f97	408	early_gdt_descr_base:
2add8e23	409	.quad INIT_PER_CPU_VAR(gdt_page)
1da177e4	410
1ab60e0f VG	411	ENTRY(phys_base)
	412	/* This must match the first entry in level2_kernel_pgt */
	413	.quad 0x0000000000000000
	414
8c5e5ac3	415	#include "../../x86/xen/xen-head.S"
1da177e4	416
e57113bc JB	417	.section .bss, "aw", @nobits
	418	.align L1_CACHE_BYTES
	419	ENTRY(idt_table)
	420	.skip 256 * 16
1da177e4	421
e57113bc JB	422	.section .bss.page_aligned, "aw", @nobits
	423	.align PAGE_SIZE
	424	ENTRY(empty_zero_page)
	425	.skip PAGE_SIZE