Commit | Line | Data |
---|---|---|
17ce265d SR |
1 | /* |
2 | * ld script for the x86 kernel | |
3 | * | |
4 | * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz> | |
5 | * | |
91fd7fe8 IM |
6 | * Modernisation, unification and other changes and fixes: |
7 | * Copyright (C) 2007-2009 Sam Ravnborg <sam@ravnborg.org> | |
17ce265d SR |
8 | * |
9 | * | |
10 | * Don't define absolute symbols until and unless you know that symbol | |
11 | * value is should remain constant even if kernel image is relocated | |
12 | * at run time. Absolute symbols are not relocated. If symbol value should | |
13 | * change if kernel is relocated, make the symbol section relative and | |
14 | * put it inside the section definition. | |
15 | */ | |
16 | ||
17 | #ifdef CONFIG_X86_32 | |
18 | #define LOAD_OFFSET __PAGE_OFFSET | |
19 | #else | |
20 | #define LOAD_OFFSET __START_KERNEL_map | |
21 | #endif | |
22 | ||
23 | #include <asm-generic/vmlinux.lds.h> | |
24 | #include <asm/asm-offsets.h> | |
25 | #include <asm/thread_info.h> | |
26 | #include <asm/page_types.h> | |
27 | #include <asm/cache.h> | |
28 | #include <asm/boot.h> | |
29 | ||
30 | #undef i386 /* in case the preprocessor is a 32bit one */ | |
31 | ||
32 | OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT) | |
33 | ||
34 | #ifdef CONFIG_X86_32 | |
35 | OUTPUT_ARCH(i386) | |
36 | ENTRY(phys_startup_32) | |
6b35eb9d | 37 | jiffies = jiffies_64; |
17ce265d SR |
38 | #else |
39 | OUTPUT_ARCH(i386:x86-64) | |
40 | ENTRY(phys_startup_64) | |
6b35eb9d | 41 | jiffies_64 = jiffies; |
17ce265d SR |
42 | #endif |
43 | ||
74e08179 | 44 | #if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA) |
d6cc1c3a SS |
45 | /* |
46 | * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA | |
47 | * we retain large page mappings for boundaries spanning kernel text, rodata | |
48 | * and data sections. | |
49 | * | |
50 | * However, kernel identity mappings will have different RWX permissions | |
51 | * to the pages mapping to text and to the pages padding (which are freed) the | |
52 | * text section. Hence kernel identity mappings will be broken to smaller | |
53 | * pages. For 64-bit, kernel text and kernel identity mappings are different, | |
54 | * so we can enable protection checks that come with CONFIG_DEBUG_RODATA, | |
55 | * as well as retain 2MB large page mappings for kernel text. | |
56 | */ | |
74e08179 SS |
57 | #define X64_ALIGN_DEBUG_RODATA_BEGIN . = ALIGN(HPAGE_SIZE); |
58 | ||
59 | #define X64_ALIGN_DEBUG_RODATA_END \ | |
60 | . = ALIGN(HPAGE_SIZE); \ | |
61 | __end_rodata_hpage_align = .; | |
62 | ||
63 | #else | |
64 | ||
65 | #define X64_ALIGN_DEBUG_RODATA_BEGIN | |
66 | #define X64_ALIGN_DEBUG_RODATA_END | |
67 | ||
68 | #endif | |
69 | ||
afb8095a SR |
70 | PHDRS { |
71 | text PT_LOAD FLAGS(5); /* R_E */ | |
5bd5a452 | 72 | data PT_LOAD FLAGS(6); /* RW_ */ |
afb8095a | 73 | #ifdef CONFIG_X86_64 |
afb8095a | 74 | #ifdef CONFIG_SMP |
8d0cc631 | 75 | percpu PT_LOAD FLAGS(6); /* RW_ */ |
afb8095a | 76 | #endif |
c62e4320 | 77 | init PT_LOAD FLAGS(7); /* RWE */ |
afb8095a SR |
78 | #endif |
79 | note PT_NOTE FLAGS(0); /* ___ */ | |
80 | } | |
17ce265d | 81 | |
444e0ae4 SR |
82 | SECTIONS |
83 | { | |
84 | #ifdef CONFIG_X86_32 | |
85 | . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR; | |
86 | phys_startup_32 = startup_32 - LOAD_OFFSET; | |
87 | #else | |
88 | . = __START_KERNEL; | |
89 | phys_startup_64 = startup_64 - LOAD_OFFSET; | |
90 | #endif | |
91 | ||
dfc20895 | 92 | /* Text and read-only data */ |
dfc20895 | 93 | .text : AT(ADDR(.text) - LOAD_OFFSET) { |
4ae59b91 TA |
94 | _text = .; |
95 | /* bootstrapping code */ | |
96 | HEAD_TEXT | |
dfc20895 | 97 | #ifdef CONFIG_X86_32 |
dfc20895 | 98 | . = ALIGN(PAGE_SIZE); |
819d6762 | 99 | *(.text..page_aligned) |
dfc20895 SR |
100 | #endif |
101 | . = ALIGN(8); | |
102 | _stext = .; | |
103 | TEXT_TEXT | |
104 | SCHED_TEXT | |
105 | LOCK_TEXT | |
106 | KPROBES_TEXT | |
ea714547 | 107 | ENTRY_TEXT |
dfc20895 SR |
108 | IRQENTRY_TEXT |
109 | *(.fixup) | |
110 | *(.gnu.warning) | |
111 | /* End of text section */ | |
112 | _etext = .; | |
113 | } :text = 0x9090 | |
114 | ||
115 | NOTES :text :note | |
116 | ||
123f3e1d | 117 | EXCEPTION_TABLE(16) :text = 0x9090 |
448bc3ab | 118 | |
5bd5a452 MC |
119 | #if defined(CONFIG_DEBUG_RODATA) |
120 | /* .text should occupy whole number of pages */ | |
121 | . = ALIGN(PAGE_SIZE); | |
122 | #endif | |
74e08179 | 123 | X64_ALIGN_DEBUG_RODATA_BEGIN |
c62e4320 | 124 | RO_DATA(PAGE_SIZE) |
74e08179 | 125 | X64_ALIGN_DEBUG_RODATA_END |
448bc3ab | 126 | |
1f6397ba | 127 | /* Data */ |
1f6397ba | 128 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
1260866a CM |
129 | /* Start of data section */ |
130 | _sdata = .; | |
c62e4320 JB |
131 | |
132 | /* init_task */ | |
133 | INIT_TASK_DATA(THREAD_SIZE) | |
1f6397ba SR |
134 | |
135 | #ifdef CONFIG_X86_32 | |
c62e4320 JB |
136 | /* 32 bit has nosave before _edata */ |
137 | NOSAVE_DATA | |
1f6397ba SR |
138 | #endif |
139 | ||
c62e4320 | 140 | PAGE_ALIGNED_DATA(PAGE_SIZE) |
1f6397ba | 141 | |
350f8f56 | 142 | CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES) |
1f6397ba | 143 | |
c62e4320 JB |
144 | DATA_DATA |
145 | CONSTRUCTORS | |
146 | ||
147 | /* rarely changed data like cpu maps */ | |
350f8f56 | 148 | READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES) |
1f6397ba | 149 | |
1f6397ba SR |
150 | /* End of data section */ |
151 | _edata = .; | |
c62e4320 | 152 | } :data |
1f6397ba | 153 | |
ff6f87e1 SR |
154 | #ifdef CONFIG_X86_64 |
155 | ||
9c40818d AL |
156 | . = ALIGN(PAGE_SIZE); |
157 | __vvar_page = .; | |
158 | ||
159 | .vvar : AT(ADDR(.vvar) - LOAD_OFFSET) { | |
f670bb76 AL |
160 | /* work around gold bug 13023 */ |
161 | __vvar_beginning_hack = .; | |
9c40818d | 162 | |
f670bb76 AL |
163 | /* Place all vvars at the offsets in asm/vvar.h. */ |
164 | #define EMIT_VVAR(name, offset) \ | |
165 | . = __vvar_beginning_hack + offset; \ | |
9c40818d AL |
166 | *(.vvar_ ## name) |
167 | #define __VVAR_KERNEL_LDS | |
168 | #include <asm/vvar.h> | |
169 | #undef __VVAR_KERNEL_LDS | |
170 | #undef EMIT_VVAR | |
171 | ||
172 | } :data | |
173 | ||
174 | . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE); | |
175 | ||
ff6f87e1 | 176 | #endif /* CONFIG_X86_64 */ |
dfc20895 | 177 | |
c62e4320 JB |
178 | /* Init code and data - will be freed after init */ |
179 | . = ALIGN(PAGE_SIZE); | |
180 | .init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) { | |
181 | __init_begin = .; /* paired with __init_end */ | |
e58bdaa8 | 182 | } |
e58bdaa8 | 183 | |
c62e4320 | 184 | #if defined(CONFIG_X86_64) && defined(CONFIG_SMP) |
e58bdaa8 | 185 | /* |
c62e4320 JB |
186 | * percpu offsets are zero-based on SMP. PERCPU_VADDR() changes the |
187 | * output PHDR, so the next output section - .init.text - should | |
188 | * start another segment - init. | |
e58bdaa8 | 189 | */ |
19df0c2f | 190 | PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu) |
c62e4320 | 191 | #endif |
e58bdaa8 | 192 | |
123f3e1d | 193 | INIT_TEXT_SECTION(PAGE_SIZE) |
c62e4320 JB |
194 | #ifdef CONFIG_X86_64 |
195 | :init | |
196 | #endif | |
e58bdaa8 | 197 | |
123f3e1d | 198 | INIT_DATA_SECTION(16) |
e58bdaa8 SR |
199 | |
200 | .x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) { | |
201 | __x86_cpu_dev_start = .; | |
202 | *(.x86_cpu_dev.init) | |
203 | __x86_cpu_dev_end = .; | |
204 | } | |
205 | ||
6f44d033 KRW |
206 | /* |
207 | * start address and size of operations which during runtime | |
208 | * can be patched with virtualization friendly instructions or | |
209 | * baremetal native ones. Think page table operations. | |
210 | * Details in paravirt_types.h | |
211 | */ | |
ae618362 SR |
212 | . = ALIGN(8); |
213 | .parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) { | |
214 | __parainstructions = .; | |
215 | *(.parainstructions) | |
216 | __parainstructions_end = .; | |
217 | } | |
218 | ||
6f44d033 KRW |
219 | /* |
220 | * struct alt_inst entries. From the header (alternative.h): | |
221 | * "Alternative instructions for different CPU types or capabilities" | |
222 | * Think locking instructions on spinlocks. | |
223 | */ | |
ae618362 SR |
224 | . = ALIGN(8); |
225 | .altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) { | |
226 | __alt_instructions = .; | |
227 | *(.altinstructions) | |
228 | __alt_instructions_end = .; | |
229 | } | |
230 | ||
6f44d033 KRW |
231 | /* |
232 | * And here are the replacement instructions. The linker sticks | |
233 | * them as binary blobs. The .altinstructions has enough data to | |
234 | * get the address and the length of them to patch the kernel safely. | |
235 | */ | |
ae618362 SR |
236 | .altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) { |
237 | *(.altinstr_replacement) | |
238 | } | |
239 | ||
6f44d033 KRW |
240 | /* |
241 | * struct iommu_table_entry entries are injected in this section. | |
242 | * It is an array of IOMMUs which during run time gets sorted depending | |
243 | * on its dependency order. After rootfs_initcall is complete | |
244 | * this section can be safely removed. | |
245 | */ | |
0444ad93 KRW |
246 | .iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) { |
247 | __iommu_table = .; | |
248 | *(.iommu_table) | |
0444ad93 KRW |
249 | __iommu_table_end = .; |
250 | } | |
4822b7fc | 251 | |
107e0e0c SS |
252 | . = ALIGN(8); |
253 | .apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) { | |
254 | __apicdrivers = .; | |
255 | *(.apicdrivers); | |
256 | __apicdrivers_end = .; | |
257 | } | |
258 | ||
7ac41ccf | 259 | . = ALIGN(8); |
bf6a5741 SR |
260 | /* |
261 | * .exit.text is discard at runtime, not link time, to deal with | |
262 | * references from .altinstructions and .eh_frame | |
263 | */ | |
264 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { | |
265 | EXIT_TEXT | |
266 | } | |
267 | ||
268 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { | |
269 | EXIT_DATA | |
270 | } | |
271 | ||
c62e4320 | 272 | #if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP) |
0415b00d | 273 | PERCPU_SECTION(INTERNODE_CACHE_BYTES) |
9d16e783 SR |
274 | #endif |
275 | ||
276 | . = ALIGN(PAGE_SIZE); | |
fd073194 | 277 | |
9d16e783 | 278 | /* freed after init ends here */ |
fd073194 IM |
279 | .init.end : AT(ADDR(.init.end) - LOAD_OFFSET) { |
280 | __init_end = .; | |
281 | } | |
9d16e783 | 282 | |
c62e4320 JB |
283 | /* |
284 | * smp_locks might be freed after init | |
285 | * start/end must be page aligned | |
286 | */ | |
287 | . = ALIGN(PAGE_SIZE); | |
288 | .smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) { | |
289 | __smp_locks = .; | |
290 | *(.smp_locks) | |
c62e4320 | 291 | . = ALIGN(PAGE_SIZE); |
596b711e | 292 | __smp_locks_end = .; |
c62e4320 JB |
293 | } |
294 | ||
9d16e783 SR |
295 | #ifdef CONFIG_X86_64 |
296 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { | |
c62e4320 JB |
297 | NOSAVE_DATA |
298 | } | |
9d16e783 SR |
299 | #endif |
300 | ||
091e52c3 SR |
301 | /* BSS */ |
302 | . = ALIGN(PAGE_SIZE); | |
303 | .bss : AT(ADDR(.bss) - LOAD_OFFSET) { | |
304 | __bss_start = .; | |
7c74df07 | 305 | *(.bss..page_aligned) |
091e52c3 | 306 | *(.bss) |
5bd5a452 | 307 | . = ALIGN(PAGE_SIZE); |
091e52c3 SR |
308 | __bss_stop = .; |
309 | } | |
9d16e783 | 310 | |
091e52c3 SR |
311 | . = ALIGN(PAGE_SIZE); |
312 | .brk : AT(ADDR(.brk) - LOAD_OFFSET) { | |
313 | __brk_base = .; | |
314 | . += 64 * 1024; /* 64k alignment slop space */ | |
315 | *(.brk_reservation) /* areas brk users have reserved */ | |
316 | __brk_limit = .; | |
317 | } | |
318 | ||
873b5271 | 319 | _end = .; |
091e52c3 | 320 | |
444e0ae4 SR |
321 | STABS_DEBUG |
322 | DWARF_DEBUG | |
023bf6f1 TH |
323 | |
324 | /* Sections to be discarded */ | |
325 | DISCARDS | |
326 | /DISCARD/ : { *(.eh_frame) } | |
444e0ae4 SR |
327 | } |
328 | ||
17ce265d SR |
329 | |
330 | #ifdef CONFIG_X86_32 | |
a5912f6b IM |
331 | /* |
332 | * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility: | |
333 | */ | |
d2ba8b21 PA |
334 | . = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE), |
335 | "kernel image bigger than KERNEL_IMAGE_SIZE"); | |
17ce265d SR |
336 | #else |
337 | /* | |
338 | * Per-cpu symbols which need to be offset from __per_cpu_load | |
339 | * for the boot processor. | |
340 | */ | |
dd17c8f7 | 341 | #define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load |
17ce265d SR |
342 | INIT_PER_CPU(gdt_page); |
343 | INIT_PER_CPU(irq_stack_union); | |
344 | ||
345 | /* | |
346 | * Build-time check on the image size: | |
347 | */ | |
d2ba8b21 PA |
348 | . = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE), |
349 | "kernel image bigger than KERNEL_IMAGE_SIZE"); | |
17ce265d SR |
350 | |
351 | #ifdef CONFIG_SMP | |
dd17c8f7 | 352 | . = ASSERT((irq_stack_union == 0), |
d2ba8b21 | 353 | "irq_stack_union is not at start of per-cpu area"); |
17ce265d SR |
354 | #endif |
355 | ||
356 | #endif /* CONFIG_X86_32 */ | |
357 | ||
358 | #ifdef CONFIG_KEXEC | |
359 | #include <asm/kexec.h> | |
360 | ||
d2ba8b21 PA |
361 | . = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE, |
362 | "kexec control code size is too big"); | |
17ce265d SR |
363 | #endif |
364 |