Commit | Line | Data |
---|---|---|
07ad157f RR |
1 | #include <linux/linkage.h> |
2 | #include <linux/lguest.h> | |
47436aa4 | 3 | #include <asm/lguest_hcall.h> |
07ad157f RR |
4 | #include <asm/asm-offsets.h> |
5 | #include <asm/thread_info.h> | |
876be9d8 | 6 | #include <asm/processor-flags.h> |
07ad157f | 7 | |
2e04ef76 RR |
8 | /*G:020 |
9 | * Our story starts with the kernel booting into startup_32 in | |
a6bd8e13 RR |
10 | * arch/x86/kernel/head_32.S. It expects a boot header, which is created by |
11 | * the bootloader (the Launcher in our case). | |
12 | * | |
13 | * The startup_32 function does very little: it clears the uninitialized global | |
14 | * C variables which we expect to be zero (ie. BSS) and then copies the boot | |
15 | * header and kernel command line somewhere safe. Finally it checks the | |
16 | * 'hardware_subarch' field. This was introduced in 2.6.24 for lguest and Xen: | |
17 | * if it's set to '1' (lguest's assigned number), then it calls us here. | |
47436aa4 RR |
18 | * |
19 | * WARNING: be very careful here! We're running at addresses equal to physical | |
20 | * addesses (around 0), not above PAGE_OFFSET as most code expectes | |
21 | * (eg. 0xC0000000). Jumps are relative, so they're OK, but we can't touch any | |
a6bd8e13 | 22 | * data without remembering to subtract __PAGE_OFFSET! |
07ad157f | 23 | * |
b2b47c21 | 24 | * The .section line puts this code in .init.text so it will be discarded after |
2e04ef76 RR |
25 | * boot. |
26 | */ | |
07ad157f | 27 | .section .init.text, "ax", @progbits |
814a0e5c | 28 | ENTRY(lguest_entry) |
2e04ef76 | 29 | /* |
5dea1c88 RR |
30 | * We make the "initialization" hypercall now to tell the Host where |
31 | * our lguest_data struct is. | |
2e04ef76 | 32 | */ |
47436aa4 | 33 | movl $LHCALL_LGUEST_INIT, %eax |
4cd8b5e2 | 34 | movl $lguest_data - __PAGE_OFFSET, %ebx |
091ebf07 | 35 | int $LGUEST_TRAP_ENTRY |
47436aa4 | 36 | |
5dea1c88 RR |
37 | /* Now turn our pagetables on; setup by arch/x86/kernel/head_32.S. */ |
38 | movl $LHCALL_NEW_PGTABLE, %eax | |
39 | movl $(initial_page_table - __PAGE_OFFSET), %ebx | |
40 | int $LGUEST_TRAP_ENTRY | |
41 | ||
47436aa4 RR |
42 | /* Set up the initial stack so we can run C code. */ |
43 | movl $(init_thread_union+THREAD_SIZE),%esp | |
44 | ||
2e04ef76 | 45 | /* Jumps are relative: we're running __PAGE_OFFSET too low. */ |
47436aa4 | 46 | jmp lguest_init+__PAGE_OFFSET |
07ad157f | 47 | |
2e04ef76 RR |
48 | /*G:055 |
49 | * We create a macro which puts the assembler code between lgstart_ and lgend_ | |
50 | * markers. These templates are put in the .text section: they can't be | |
51 | * discarded after boot as we may need to patch modules, too. | |
52 | */ | |
bbbd2bf0 | 53 | .text |
07ad157f RR |
54 | #define LGUEST_PATCH(name, insns...) \ |
55 | lgstart_##name: insns; lgend_##name:; \ | |
56 | .globl lgstart_##name; .globl lgend_##name | |
57 | ||
58 | LGUEST_PATCH(cli, movl $0, lguest_data+LGUEST_DATA_irq_enabled) | |
07ad157f | 59 | LGUEST_PATCH(pushf, movl lguest_data+LGUEST_DATA_irq_enabled, %eax) |
61f4bc83 | 60 | |
2e04ef76 RR |
61 | /*G:033 |
62 | * But using those wrappers is inefficient (we'll see why that doesn't matter | |
63 | * for save_fl and irq_disable later). If we write our routines carefully in | |
64 | * assembler, we can avoid clobbering any registers and avoid jumping through | |
65 | * the wrapper functions. | |
61f4bc83 RR |
66 | * |
67 | * I skipped over our first piece of assembler, but this one is worth studying | |
2e04ef76 RR |
68 | * in a bit more detail so I'll describe in easy stages. First, the routine to |
69 | * enable interrupts: | |
70 | */ | |
61f4bc83 | 71 | ENTRY(lg_irq_enable) |
2e04ef76 RR |
72 | /* |
73 | * The reverse of irq_disable, this sets lguest_data.irq_enabled to | |
74 | * X86_EFLAGS_IF (ie. "Interrupts enabled"). | |
75 | */ | |
61f4bc83 | 76 | movl $X86_EFLAGS_IF, lguest_data+LGUEST_DATA_irq_enabled |
2e04ef76 RR |
77 | /* |
78 | * But now we need to check if the Host wants to know: there might have | |
61f4bc83 RR |
79 | * been interrupts waiting to be delivered, in which case it will have |
80 | * set lguest_data.irq_pending to X86_EFLAGS_IF. If it's not zero, we | |
2e04ef76 RR |
81 | * jump to send_interrupts, otherwise we're done. |
82 | */ | |
61f4bc83 RR |
83 | testl $0, lguest_data+LGUEST_DATA_irq_pending |
84 | jnz send_interrupts | |
2e04ef76 RR |
85 | /* |
86 | * One cool thing about x86 is that you can do many things without using | |
61f4bc83 | 87 | * a register. In this case, the normal path hasn't needed to save or |
2e04ef76 RR |
88 | * restore any registers at all! |
89 | */ | |
61f4bc83 RR |
90 | ret |
91 | send_interrupts: | |
2e04ef76 RR |
92 | /* |
93 | * OK, now we need a register: eax is used for the hypercall number, | |
61f4bc83 RR |
94 | * which is LHCALL_SEND_INTERRUPTS. |
95 | * | |
96 | * We used not to bother with this pending detection at all, which was | |
97 | * much simpler. Sooner or later the Host would realize it had to | |
98 | * send us an interrupt. But that turns out to make performance 7 | |
99 | * times worse on a simple tcp benchmark. So now we do this the hard | |
2e04ef76 RR |
100 | * way. |
101 | */ | |
61f4bc83 RR |
102 | pushl %eax |
103 | movl $LHCALL_SEND_INTERRUPTS, %eax | |
7e194144 RR |
104 | /* This is the actual hypercall trap. */ |
105 | int $LGUEST_TRAP_ENTRY | |
a91d74a3 | 106 | /* Put eax back the way we found it. */ |
61f4bc83 RR |
107 | popl %eax |
108 | ret | |
109 | ||
2e04ef76 RR |
110 | /* |
111 | * Finally, the "popf" or "restore flags" routine. The %eax register holds the | |
61f4bc83 | 112 | * flags (in practice, either X86_EFLAGS_IF or 0): if it's X86_EFLAGS_IF we're |
2e04ef76 RR |
113 | * enabling interrupts again, if it's 0 we're leaving them off. |
114 | */ | |
61f4bc83 RR |
115 | ENTRY(lg_restore_fl) |
116 | /* This is just "lguest_data.irq_enabled = flags;" */ | |
117 | movl %eax, lguest_data+LGUEST_DATA_irq_enabled | |
2e04ef76 RR |
118 | /* |
119 | * Now, if the %eax value has enabled interrupts and | |
61f4bc83 RR |
120 | * lguest_data.irq_pending is set, we want to tell the Host so it can |
121 | * deliver any outstanding interrupts. Fortunately, both values will | |
122 | * be X86_EFLAGS_IF (ie. 512) in that case, and the "testl" | |
123 | * instruction will AND them together for us. If both are set, we | |
2e04ef76 RR |
124 | * jump to send_interrupts. |
125 | */ | |
61f4bc83 RR |
126 | testl lguest_data+LGUEST_DATA_irq_pending, %eax |
127 | jnz send_interrupts | |
128 | /* Again, the normal path has used no extra registers. Clever, huh? */ | |
129 | ret | |
a91d74a3 | 130 | /*:*/ |
07ad157f | 131 | |
07ad157f RR |
132 | /* These demark the EIP range where host should never deliver interrupts. */ |
133 | .global lguest_noirq_start | |
134 | .global lguest_noirq_end | |
135 | ||
2e04ef76 RR |
136 | /*M:004 |
137 | * When the Host reflects a trap or injects an interrupt into the Guest, it | |
138 | * sets the eflags interrupt bit on the stack based on lguest_data.irq_enabled, | |
139 | * so the Guest iret logic does the right thing when restoring it. However, | |
140 | * when the Host sets the Guest up for direct traps, such as system calls, the | |
141 | * processor is the one to push eflags onto the stack, and the interrupt bit | |
142 | * will be 1 (in reality, interrupts are always enabled in the Guest). | |
f56a384e RR |
143 | * |
144 | * This turns out to be harmless: the only trap which should happen under Linux | |
145 | * with interrupts disabled is Page Fault (due to our lazy mapping of vmalloc | |
146 | * regions), which has to be reflected through the Host anyway. If another | |
147 | * trap *does* go off when interrupts are disabled, the Guest will panic, and | |
2e04ef76 RR |
148 | * we'll never get to this iret! |
149 | :*/ | |
f56a384e | 150 | |
2e04ef76 RR |
151 | /*G:045 |
152 | * There is one final paravirt_op that the Guest implements, and glancing at it | |
153 | * you can see why I left it to last. It's *cool*! It's in *assembler*! | |
b2b47c21 RR |
154 | * |
155 | * The "iret" instruction is used to return from an interrupt or trap. The | |
156 | * stack looks like this: | |
157 | * old address | |
158 | * old code segment & privilege level | |
159 | * old processor flags ("eflags") | |
160 | * | |
161 | * The "iret" instruction pops those values off the stack and restores them all | |
162 | * at once. The only problem is that eflags includes the Interrupt Flag which | |
163 | * the Guest can't change: the CPU will simply ignore it when we do an "iret". | |
164 | * So we have to copy eflags from the stack to lguest_data.irq_enabled before | |
165 | * we do the "iret". | |
166 | * | |
167 | * There are two problems with this: firstly, we need to use a register to do | |
168 | * the copy and secondly, the whole thing needs to be atomic. The first | |
169 | * problem is easy to solve: push %eax on the stack so we can use it, and then | |
170 | * restore it at the end just before the real "iret". | |
171 | * | |
172 | * The second is harder: copying eflags to lguest_data.irq_enabled will turn | |
173 | * interrupts on before we're finished, so we could be interrupted before we | |
174 | * return to userspace or wherever. Our solution to this is to surround the | |
175 | * code with lguest_noirq_start: and lguest_noirq_end: labels. We tell the | |
176 | * Host that it is *never* to interrupt us there, even if interrupts seem to be | |
2e04ef76 RR |
177 | * enabled. |
178 | */ | |
07ad157f RR |
179 | ENTRY(lguest_iret) |
180 | pushl %eax | |
181 | movl 12(%esp), %eax | |
182 | lguest_noirq_start: | |
2e04ef76 RR |
183 | /* |
184 | * Note the %ss: segment prefix here. Normal data accesses use the | |
b2b47c21 RR |
185 | * "ds" segment, but that will have already been restored for whatever |
186 | * we're returning to (such as userspace): we can't trust it. The %ss: | |
2e04ef76 RR |
187 | * prefix makes sure we use the stack segment, which is still valid. |
188 | */ | |
07ad157f RR |
189 | movl %eax,%ss:lguest_data+LGUEST_DATA_irq_enabled |
190 | popl %eax | |
191 | iret | |
192 | lguest_noirq_end: |