[deliverable/linux.git] / arch / x86 / lib / copy_user_64.S

/*
 * Copyright 2008 Vitaly Mayatskikh <vmayatsk@redhat.com>
 * Copyright 2002 Andi Kleen, SuSE Labs.
 * Subject to the GNU Public License v2.
 *
 * Functions to copy from and to user space.
 */

#include <linux/linkage.h>
#include <asm/dwarf2.h>

#define FIX_ALIGNMENT 1

#include <asm/current.h>
#include <asm/asm-offsets.h>
#include <asm/thread_info.h>
#include <asm/cpufeature.h>
#include <asm/alternative-asm.h>
#include <asm/asm.h>

/*
 * By placing feature2 after feature1 in altinstructions section, we logically
 * implement:
 * If CPU has feature2, jmp to alt2 is used
 * else if CPU has feature1, jmp to alt1 is used
 * else jmp to orig is used.
 */
	.macro ALTERNATIVE_JUMP feature1,feature2,orig,alt1,alt2
0:
	.byte 0xe9	/* 32bit jump */
	.long \orig-1f	/* by default jump to orig */
1:
	.section .altinstr_replacement,"ax"
2:	.byte 0xe9			/* near jump with 32bit immediate */
	.long \alt1-1b /* offset */   /* or alternatively to alt1 */
3:	.byte 0xe9			/* near jump with 32bit immediate */
	.long \alt2-1b /* offset */   /* or alternatively to alt2 */
	.previous

	.section .altinstructions,"a"
	altinstruction_entry 0b,2b,\feature1,5,5
	altinstruction_entry 0b,3b,\feature2,5,5
	.previous
	.endm

	.macro ALIGN_DESTINATION
#ifdef FIX_ALIGNMENT
	/* check for bad alignment of destination */
	movl %edi,%ecx
	andl $7,%ecx
	jz 102f				/* already aligned */
	subl $8,%ecx
	negl %ecx
	subl %ecx,%edx
100:	movb (%rsi),%al
101:	movb %al,(%rdi)
	incq %rsi
	incq %rdi
	decl %ecx
	jnz 100b
102:
	.section .fixup,"ax"
103:	addl %ecx,%edx			/* ecx is zerorest also */
	jmp copy_user_handle_tail
	.previous

	_ASM_EXTABLE(100b,103b)
	_ASM_EXTABLE(101b,103b)
#endif
	.endm

/* Standard copy_to_user with segment limit checking */
ENTRY(_copy_to_user)
	CFI_STARTPROC
	GET_THREAD_INFO(%rax)
	movq %rdi,%rcx
	addq %rdx,%rcx
	jc bad_to_user
	cmpq TI_addr_limit(%rax),%rcx
	ja bad_to_user
	ALTERNATIVE_JUMP X86_FEATURE_REP_GOOD,X86_FEATURE_ERMS,	\
		copy_user_generic_unrolled,copy_user_generic_string,	\
		copy_user_enhanced_fast_string
	CFI_ENDPROC
ENDPROC(_copy_to_user)

/* Standard copy_from_user with segment limit checking */
ENTRY(_copy_from_user)
	CFI_STARTPROC
	GET_THREAD_INFO(%rax)
	movq %rsi,%rcx
	addq %rdx,%rcx
	jc bad_from_user
	cmpq TI_addr_limit(%rax),%rcx
	ja bad_from_user
	ALTERNATIVE_JUMP X86_FEATURE_REP_GOOD,X86_FEATURE_ERMS,	\
		copy_user_generic_unrolled,copy_user_generic_string,	\
		copy_user_enhanced_fast_string
	CFI_ENDPROC
ENDPROC(_copy_from_user)

	.section .fixup,"ax"
	/* must zero dest */
ENTRY(bad_from_user)
bad_from_user:
	CFI_STARTPROC
	movl %edx,%ecx
	xorl %eax,%eax
	rep
	stosb
bad_to_user:
	movl %edx,%eax
	ret
	CFI_ENDPROC
ENDPROC(bad_from_user)
	.previous

/*
 * copy_user_generic_unrolled - memory copy with exception handling.
 * This version is for CPUs like P4 that don't have efficient micro
 * code for rep movsq
 *
 * Input:
 * rdi destination
 * rsi source
 * rdx count
 *
 * Output:
 * eax uncopied bytes or 0 if successful.
 */
ENTRY(copy_user_generic_unrolled)
	CFI_STARTPROC
	cmpl $8,%edx
	jb 20f		/* less then 8 bytes, go to byte copy loop */
	ALIGN_DESTINATION
	movl %edx,%ecx
	andl $63,%edx
	shrl $6,%ecx
	jz 17f
1:	movq (%rsi),%r8
2:	movq 1*8(%rsi),%r9
3:	movq 2*8(%rsi),%r10
4:	movq 3*8(%rsi),%r11
5:	movq %r8,(%rdi)
6:	movq %r9,1*8(%rdi)
7:	movq %r10,2*8(%rdi)
8:	movq %r11,3*8(%rdi)
9:	movq 4*8(%rsi),%r8
10:	movq 5*8(%rsi),%r9
11:	movq 6*8(%rsi),%r10
12:	movq 7*8(%rsi),%r11
13:	movq %r8,4*8(%rdi)
14:	movq %r9,5*8(%rdi)
15:	movq %r10,6*8(%rdi)
16:	movq %r11,7*8(%rdi)
	leaq 64(%rsi),%rsi
	leaq 64(%rdi),%rdi
	decl %ecx
	jnz 1b
17:	movl %edx,%ecx
	andl $7,%edx
	shrl $3,%ecx
	jz 20f
18:	movq (%rsi),%r8
19:	movq %r8,(%rdi)
	leaq 8(%rsi),%rsi
	leaq 8(%rdi),%rdi
	decl %ecx
	jnz 18b
20:	andl %edx,%edx
	jz 23f
	movl %edx,%ecx
21:	movb (%rsi),%al
22:	movb %al,(%rdi)
	incq %rsi
	incq %rdi
	decl %ecx
	jnz 21b
23:	xor %eax,%eax
	ret

	.section .fixup,"ax"
30:	shll $6,%ecx
	addl %ecx,%edx
	jmp 60f
40:	lea (%rdx,%rcx,8),%rdx
	jmp 60f
50:	movl %ecx,%edx
60:	jmp copy_user_handle_tail /* ecx is zerorest also */
	.previous

	_ASM_EXTABLE(1b,30b)
	_ASM_EXTABLE(2b,30b)
	_ASM_EXTABLE(3b,30b)
	_ASM_EXTABLE(4b,30b)
	_ASM_EXTABLE(5b,30b)
	_ASM_EXTABLE(6b,30b)
	_ASM_EXTABLE(7b,30b)
	_ASM_EXTABLE(8b,30b)
	_ASM_EXTABLE(9b,30b)
	_ASM_EXTABLE(10b,30b)
	_ASM_EXTABLE(11b,30b)
	_ASM_EXTABLE(12b,30b)
	_ASM_EXTABLE(13b,30b)
	_ASM_EXTABLE(14b,30b)
	_ASM_EXTABLE(15b,30b)
	_ASM_EXTABLE(16b,30b)
	_ASM_EXTABLE(18b,40b)
	_ASM_EXTABLE(19b,40b)
	_ASM_EXTABLE(21b,50b)
	_ASM_EXTABLE(22b,50b)
	CFI_ENDPROC
ENDPROC(copy_user_generic_unrolled)

/* Some CPUs run faster using the string copy instructions.
 * This is also a lot simpler. Use them when possible.
 *
 * Only 4GB of copy is supported. This shouldn't be a problem
 * because the kernel normally only writes from/to page sized chunks
 * even if user space passed a longer buffer.
 * And more would be dangerous because both Intel and AMD have
 * errata with rep movsq > 4GB. If someone feels the need to fix
 * this please consider this.
 *
 * Input:
 * rdi destination
 * rsi source
 * rdx count
 *
 * Output:
 * eax uncopied bytes or 0 if successful.
 */
ENTRY(copy_user_generic_string)
	CFI_STARTPROC
	andl %edx,%edx
	jz 4f
	cmpl $8,%edx
	jb 2f		/* less than 8 bytes, go to byte copy loop */
	ALIGN_DESTINATION
	movl %edx,%ecx
	shrl $3,%ecx
	andl $7,%edx
1:	rep
	movsq
2:	movl %edx,%ecx
3:	rep
	movsb
4:	xorl %eax,%eax
	ret

	.section .fixup,"ax"
11:	lea (%rdx,%rcx,8),%rcx
12:	movl %ecx,%edx		/* ecx is zerorest also */
	jmp copy_user_handle_tail
	.previous

	_ASM_EXTABLE(1b,11b)
	_ASM_EXTABLE(3b,12b)
	CFI_ENDPROC
ENDPROC(copy_user_generic_string)

/*
 * Some CPUs are adding enhanced REP MOVSB/STOSB instructions.
 * It's recommended to use enhanced REP MOVSB/STOSB if it's enabled.
 *
 * Input:
 * rdi destination
 * rsi source
 * rdx count
 *
 * Output:
 * eax uncopied bytes or 0 if successful.
 */
ENTRY(copy_user_enhanced_fast_string)
	CFI_STARTPROC
	andl %edx,%edx
	jz 2f
	movl %edx,%ecx
1:	rep
	movsb
2:	xorl %eax,%eax
	ret

	.section .fixup,"ax"
12:	movl %ecx,%edx		/* ecx is zerorest also */
	jmp copy_user_handle_tail
	.previous

	_ASM_EXTABLE(1b,12b)
	CFI_ENDPROC
ENDPROC(copy_user_enhanced_fast_string)
Commit	Line	Data
ad2fc2cd VM	1	/*
	2	* Copyright 2008 Vitaly Mayatskikh <vmayatsk@redhat.com>
	3	* Copyright 2002 Andi Kleen, SuSE Labs.
1da177e4	4	* Subject to the GNU Public License v2.
ad2fc2cd VM	5	*
	6	* Functions to copy from and to user space.
	7	*/
1da177e4	8
8d379dad JB	9	#include <linux/linkage.h>
	10	#include <asm/dwarf2.h>
	11
7bcd3f34 AK	12	#define FIX_ALIGNMENT 1
7bcd3f34 AK	13
3022d734 AK	14	#include <asm/current.h>
	15	#include <asm/asm-offsets.h>
	16	#include <asm/thread_info.h>
	17	#include <asm/cpufeature.h>
4307bec9	18	#include <asm/alternative-asm.h>
9732da8c	19	#include <asm/asm.h>
3022d734	20
4307bec9 FY	21	/*
	22	* By placing feature2 after feature1 in altinstructions section, we logically
	23	* implement:
	24	* If CPU has feature2, jmp to alt2 is used
	25	* else if CPU has feature1, jmp to alt1 is used
	26	* else jmp to orig is used.
	27	*/
	28	.macro ALTERNATIVE_JUMP feature1,feature2,orig,alt1,alt2
3022d734 AK	29	0:
	30	.byte 0xe9 /* 32bit jump */
	31	.long \orig-1f /* by default jump to orig */
	32	1:
	33	.section .altinstr_replacement,"ax"
ad2fc2cd	34	2: .byte 0xe9 /* near jump with 32bit immediate */
4307bec9 FY	35	.long \alt1-1b /* offset / / or alternatively to alt1 */
	36	3: .byte 0xe9 /* near jump with 32bit immediate */
	37	.long \alt2-1b /* offset / / or alternatively to alt2 */
3022d734	38	.previous
4307bec9	39
3022d734	40	.section .altinstructions,"a"
4307bec9 FY	41	altinstruction_entry 0b,2b,\feature1,5,5
4307bec9 FY	42	altinstruction_entry 0b,3b,\feature2,5,5
3022d734 AK	43	.previous
3022d734 AK	44	.endm
1da177e4	45
ad2fc2cd VM	46	.macro ALIGN_DESTINATION
	47	#ifdef FIX_ALIGNMENT
	48	/* check for bad alignment of destination */
	49	movl %edi,%ecx
	50	andl $7,%ecx
	51	jz 102f /* already aligned */
	52	subl $8,%ecx
	53	negl %ecx
	54	subl %ecx,%edx
	55	100: movb (%rsi),%al
	56	101: movb %al,(%rdi)
	57	incq %rsi
	58	incq %rdi
	59	decl %ecx
	60	jnz 100b
	61	102:
	62	.section .fixup,"ax"
afd962a9	63	103: addl %ecx,%edx /* ecx is zerorest also */
ad2fc2cd VM	64	jmp copy_user_handle_tail
	65	.previous
	66
9732da8c PA	67	_ASM_EXTABLE(100b,103b)
9732da8c PA	68	_ASM_EXTABLE(101b,103b)
ad2fc2cd VM	69	#endif
	70	.endm
	71
	72	/* Standard copy_to_user with segment limit checking */
3c93ca00	73	ENTRY(_copy_to_user)
8d379dad	74	CFI_STARTPROC
1da177e4 LT	75	GET_THREAD_INFO(%rax)
	76	movq %rdi,%rcx
	77	addq %rdx,%rcx
ad2fc2cd	78	jc bad_to_user
26ccb8a7	79	cmpq TI_addr_limit(%rax),%rcx
26afb7c6	80	ja bad_to_user
4307bec9 FY	81	ALTERNATIVE_JUMP X86_FEATURE_REP_GOOD,X86_FEATURE_ERMS, \
	82	copy_user_generic_unrolled,copy_user_generic_string, \
	83	copy_user_enhanced_fast_string
8d379dad	84	CFI_ENDPROC
3c93ca00	85	ENDPROC(_copy_to_user)
7bcd3f34	86
ad2fc2cd	87	/* Standard copy_from_user with segment limit checking */
9f0cf4ad	88	ENTRY(_copy_from_user)
3022d734	89	CFI_STARTPROC
ad2fc2cd VM	90	GET_THREAD_INFO(%rax)
	91	movq %rsi,%rcx
	92	addq %rdx,%rcx
	93	jc bad_from_user
	94	cmpq TI_addr_limit(%rax),%rcx
26afb7c6	95	ja bad_from_user
4307bec9 FY	96	ALTERNATIVE_JUMP X86_FEATURE_REP_GOOD,X86_FEATURE_ERMS, \
	97	copy_user_generic_unrolled,copy_user_generic_string, \
	98	copy_user_enhanced_fast_string
3022d734	99	CFI_ENDPROC
9f0cf4ad	100	ENDPROC(_copy_from_user)
3022d734	101
1da177e4 LT	102	.section .fixup,"ax"
1da177e4 LT	103	/* must zero dest */
ad2fc2cd	104	ENTRY(bad_from_user)
1da177e4	105	bad_from_user:
8d379dad	106	CFI_STARTPROC
1da177e4 LT	107	movl %edx,%ecx
	108	xorl %eax,%eax
	109	rep
	110	stosb
	111	bad_to_user:
ad2fc2cd	112	movl %edx,%eax
1da177e4	113	ret
8d379dad	114	CFI_ENDPROC
ad2fc2cd	115	ENDPROC(bad_from_user)
1da177e4	116	.previous
ad2fc2cd	117
1da177e4	118	/*
3022d734	119	* copy_user_generic_unrolled - memory copy with exception handling.
ad2fc2cd VM	120	* This version is for CPUs like P4 that don't have efficient micro
	121	* code for rep movsq
	122	*
	123	* Input:
1da177e4 LT	124	* rdi destination
	125	* rsi source
	126	* rdx count
	127	*
ad2fc2cd	128	* Output:
0d2eb44f	129	* eax uncopied bytes or 0 if successful.
1da177e4	130	*/
3022d734	131	ENTRY(copy_user_generic_unrolled)
8d379dad	132	CFI_STARTPROC
ad2fc2cd VM	133	cmpl $8,%edx
	134	jb 20f /* less then 8 bytes, go to byte copy loop */
	135	ALIGN_DESTINATION
	136	movl %edx,%ecx
	137	andl $63,%edx
	138	shrl $6,%ecx
	139	jz 17f
	140	1: movq (%rsi),%r8
	141	2: movq 1*8(%rsi),%r9
	142	3: movq 2*8(%rsi),%r10
	143	4: movq 3*8(%rsi),%r11
	144	5: movq %r8,(%rdi)
	145	6: movq %r9,1*8(%rdi)
	146	7: movq %r10,2*8(%rdi)
	147	8: movq %r11,3*8(%rdi)
	148	9: movq 4*8(%rsi),%r8
	149	10: movq 5*8(%rsi),%r9
	150	11: movq 6*8(%rsi),%r10
	151	12: movq 7*8(%rsi),%r11
	152	13: movq %r8,4*8(%rdi)
	153	14: movq %r9,5*8(%rdi)
	154	15: movq %r10,6*8(%rdi)
	155	16: movq %r11,7*8(%rdi)
7bcd3f34 AK	156	leaq 64(%rsi),%rsi
7bcd3f34 AK	157	leaq 64(%rdi),%rdi
7bcd3f34	158	decl %ecx
ad2fc2cd VM	159	jnz 1b
	160	17: movl %edx,%ecx
	161	andl $7,%edx
	162	shrl $3,%ecx
	163	jz 20f
	164	18: movq (%rsi),%r8
	165	19: movq %r8,(%rdi)
7bcd3f34	166	leaq 8(%rsi),%rsi
ad2fc2cd VM	167	leaq 8(%rdi),%rdi
	168	decl %ecx
	169	jnz 18b
	170	20: andl %edx,%edx
	171	jz 23f
7bcd3f34	172	movl %edx,%ecx
ad2fc2cd VM	173	21: movb (%rsi),%al
ad2fc2cd VM	174	22: movb %al,(%rdi)
7bcd3f34	175	incq %rsi
ad2fc2cd	176	incq %rdi
7bcd3f34	177	decl %ecx
ad2fc2cd VM	178	jnz 21b
ad2fc2cd VM	179	23: xor %eax,%eax
7bcd3f34 AK	180	ret
7bcd3f34 AK	181
ad2fc2cd VM	182	.section .fixup,"ax"
	183	30: shll $6,%ecx
	184	addl %ecx,%edx
	185	jmp 60f
27cb0a75	186	40: lea (%rdx,%rcx,8),%rdx
ad2fc2cd VM	187	jmp 60f
	188	50: movl %ecx,%edx
	189	60: jmp copy_user_handle_tail /* ecx is zerorest also */
	190	.previous
7bcd3f34	191
9732da8c PA	192	_ASM_EXTABLE(1b,30b)
	193	_ASM_EXTABLE(2b,30b)
	194	_ASM_EXTABLE(3b,30b)
	195	_ASM_EXTABLE(4b,30b)
	196	_ASM_EXTABLE(5b,30b)
	197	_ASM_EXTABLE(6b,30b)
	198	_ASM_EXTABLE(7b,30b)
	199	_ASM_EXTABLE(8b,30b)
	200	_ASM_EXTABLE(9b,30b)
	201	_ASM_EXTABLE(10b,30b)
	202	_ASM_EXTABLE(11b,30b)
	203	_ASM_EXTABLE(12b,30b)
	204	_ASM_EXTABLE(13b,30b)
	205	_ASM_EXTABLE(14b,30b)
	206	_ASM_EXTABLE(15b,30b)
	207	_ASM_EXTABLE(16b,30b)
	208	_ASM_EXTABLE(18b,40b)
	209	_ASM_EXTABLE(19b,40b)
	210	_ASM_EXTABLE(21b,50b)
	211	_ASM_EXTABLE(22b,50b)
8d379dad	212	CFI_ENDPROC
ad2fc2cd	213	ENDPROC(copy_user_generic_unrolled)
8d379dad	214
ad2fc2cd VM	215	/* Some CPUs run faster using the string copy instructions.
	216	* This is also a lot simpler. Use them when possible.
	217	*
	218	* Only 4GB of copy is supported. This shouldn't be a problem
	219	* because the kernel normally only writes from/to page sized chunks
	220	* even if user space passed a longer buffer.
	221	* And more would be dangerous because both Intel and AMD have
	222	* errata with rep movsq > 4GB. If someone feels the need to fix
	223	* this please consider this.
	224	*
	225	* Input:
	226	* rdi destination
	227	* rsi source
	228	* rdx count
	229	*
	230	* Output:
	231	* eax uncopied bytes or 0 if successful.
	232	*/
3022d734	233	ENTRY(copy_user_generic_string)
8d379dad	234	CFI_STARTPROC
ad2fc2cd VM	235	andl %edx,%edx
	236	jz 4f
	237	cmpl $8,%edx
	238	jb 2f /* less than 8 bytes, go to byte copy loop */
	239	ALIGN_DESTINATION
1da177e4 LT	240	movl %edx,%ecx
1da177e4 LT	241	shrl $3,%ecx
ad2fc2cd VM	242	andl $7,%edx
ad2fc2cd VM	243	1: rep
3022d734	244	movsq
ad2fc2cd VM	245	2: movl %edx,%ecx
	246	3: rep
	247	movsb
	248	4: xorl %eax,%eax
1da177e4	249	ret
3022d734	250
ad2fc2cd	251	.section .fixup,"ax"
27cb0a75	252	11: lea (%rdx,%rcx,8),%rcx
ad2fc2cd VM	253	12: movl %ecx,%edx /* ecx is zerorest also */
	254	jmp copy_user_handle_tail
	255	.previous
2cbc9ee3	256
9732da8c PA	257	_ASM_EXTABLE(1b,11b)
9732da8c PA	258	_ASM_EXTABLE(3b,12b)
ad2fc2cd VM	259	CFI_ENDPROC
ad2fc2cd VM	260	ENDPROC(copy_user_generic_string)
4307bec9 FY	261
	262	/*
	263	* Some CPUs are adding enhanced REP MOVSB/STOSB instructions.
	264	* It's recommended to use enhanced REP MOVSB/STOSB if it's enabled.
	265	*
	266	* Input:
	267	* rdi destination
	268	* rsi source
	269	* rdx count
	270	*
	271	* Output:
	272	* eax uncopied bytes or 0 if successful.
	273	*/
	274	ENTRY(copy_user_enhanced_fast_string)
	275	CFI_STARTPROC
	276	andl %edx,%edx
	277	jz 2f
	278	movl %edx,%ecx
	279	1: rep
	280	movsb
	281	2: xorl %eax,%eax
	282	ret
	283
	284	.section .fixup,"ax"
	285	12: movl %ecx,%edx /* ecx is zerorest also */
	286	jmp copy_user_handle_tail
	287	.previous
	288
9732da8c	289	_ASM_EXTABLE(1b,12b)
4307bec9 FY	290	CFI_ENDPROC
4307bec9 FY	291	ENDPROC(copy_user_enhanced_fast_string)