[deliverable/linux.git] / arch / x86 / lib / msr-reg.S

#include <linux/linkage.h>
#include <linux/errno.h>
#include <asm/dwarf2.h>
#include <asm/asm.h>
#include <asm/msr.h>

#ifdef CONFIG_X86_64
/*
 * int {rdmsr,wrmsr}_safe_regs(u32 gprs[8]);
 *
 * reg layout: u32 gprs[eax, ecx, edx, ebx, esp, ebp, esi, edi]
 *
 */
.macro op_safe_regs op
ENTRY(\op\()_safe_regs)
	CFI_STARTPROC
	pushq_cfi_reg rbx
	pushq_cfi_reg rbp
	movq	%rdi, %r10	/* Save pointer */
	xorl	%r11d, %r11d	/* Return value */
	movl    (%rdi), %eax
	movl    4(%rdi), %ecx
	movl    8(%rdi), %edx
	movl    12(%rdi), %ebx
	movl    20(%rdi), %ebp
	movl    24(%rdi), %esi
	movl    28(%rdi), %edi
	CFI_REMEMBER_STATE
1:	\op
2:	movl    %eax, (%r10)
	movl	%r11d, %eax	/* Return value */
	movl    %ecx, 4(%r10)
	movl    %edx, 8(%r10)
	movl    %ebx, 12(%r10)
	movl    %ebp, 20(%r10)
	movl    %esi, 24(%r10)
	movl    %edi, 28(%r10)
	popq_cfi_reg rbp
	popq_cfi_reg rbx
	ret
3:
	CFI_RESTORE_STATE
	movl    $-EIO, %r11d
	jmp     2b

	_ASM_EXTABLE(1b, 3b)
	CFI_ENDPROC
ENDPROC(\op\()_safe_regs)
.endm

#else /* X86_32 */

.macro op_safe_regs op
ENTRY(\op\()_safe_regs)
	CFI_STARTPROC
	pushl_cfi_reg ebx
	pushl_cfi_reg ebp
	pushl_cfi_reg esi
	pushl_cfi_reg edi
	pushl_cfi $0              /* Return value */
	pushl_cfi %eax
	movl    4(%eax), %ecx
	movl    8(%eax), %edx
	movl    12(%eax), %ebx
	movl    20(%eax), %ebp
	movl    24(%eax), %esi
	movl    28(%eax), %edi
	movl    (%eax), %eax
	CFI_REMEMBER_STATE
1:	\op
2:	pushl_cfi %eax
	movl    4(%esp), %eax
	popl_cfi (%eax)
	addl    $4, %esp
	CFI_ADJUST_CFA_OFFSET -4
	movl    %ecx, 4(%eax)
	movl    %edx, 8(%eax)
	movl    %ebx, 12(%eax)
	movl    %ebp, 20(%eax)
	movl    %esi, 24(%eax)
	movl    %edi, 28(%eax)
	popl_cfi %eax
	popl_cfi_reg edi
	popl_cfi_reg esi
	popl_cfi_reg ebp
	popl_cfi_reg ebx
	ret
3:
	CFI_RESTORE_STATE
	movl    $-EIO, 4(%esp)
	jmp     2b

	_ASM_EXTABLE(1b, 3b)
	CFI_ENDPROC
ENDPROC(\op\()_safe_regs)
.endm

#endif

op_safe_regs rdmsr
op_safe_regs wrmsr
Commit	Line	Data
132ec92f BP	1	#include <linux/linkage.h>
132ec92f BP	2	#include <linux/errno.h>
79c5dca3	3	#include <asm/dwarf2.h>
132ec92f BP	4	#include <asm/asm.h>
	5	#include <asm/msr.h>
	6
	7	#ifdef CONFIG_X86_64
	8	/*
1f975f78	9	* int {rdmsr,wrmsr}_safe_regs(u32 gprs[8]);
132ec92f BP	10	*
	11	* reg layout: u32 gprs[eax, ecx, edx, ebx, esp, ebp, esi, edi]
	12	*
	13	*/
f6909f39	14	.macro op_safe_regs op
1f975f78	15	ENTRY(\op\()_safe_regs)
79c5dca3	16	CFI_STARTPROC
49db46a6 DV	17	pushq_cfi_reg rbx
49db46a6 DV	18	pushq_cfi_reg rbp
79c5dca3 PA	19	movq %rdi, %r10 /* Save pointer */
79c5dca3 PA	20	xorl %r11d, %r11d /* Return value */
132ec92f BP	21	movl (%rdi), %eax
	22	movl 4(%rdi), %ecx
	23	movl 8(%rdi), %edx
	24	movl 12(%rdi), %ebx
	25	movl 20(%rdi), %ebp
	26	movl 24(%rdi), %esi
	27	movl 28(%rdi), %edi
79c5dca3	28	CFI_REMEMBER_STATE
132ec92f	29	1: \op
79c5dca3 PA	30	2: movl %eax, (%r10)
	31	movl %r11d, %eax /* Return value */
	32	movl %ecx, 4(%r10)
	33	movl %edx, 8(%r10)
	34	movl %ebx, 12(%r10)
	35	movl %ebp, 20(%r10)
	36	movl %esi, 24(%r10)
	37	movl %edi, 28(%r10)
49db46a6 DV	38	popq_cfi_reg rbp
49db46a6 DV	39	popq_cfi_reg rbx
132ec92f BP	40	ret
132ec92f BP	41	3:
79c5dca3 PA	42	CFI_RESTORE_STATE
79c5dca3 PA	43	movl $-EIO, %r11d
132ec92f	44	jmp 2b
79c5dca3 PA	45
	46	_ASM_EXTABLE(1b, 3b)
	47	CFI_ENDPROC
1f975f78	48	ENDPROC(\op\()_safe_regs)
132ec92f BP	49	.endm
	50
	51	#else /* X86_32 */
	52
8adf65cf	53	.macro op_safe_regs op
1f975f78	54	ENTRY(\op\()_safe_regs)
79c5dca3	55	CFI_STARTPROC
49db46a6 DV	56	pushl_cfi_reg ebx
	57	pushl_cfi_reg ebp
	58	pushl_cfi_reg esi
	59	pushl_cfi_reg edi
79c5dca3 PA	60	pushl_cfi $0 /* Return value */
79c5dca3 PA	61	pushl_cfi %eax
132ec92f BP	62	movl 4(%eax), %ecx
	63	movl 8(%eax), %edx
	64	movl 12(%eax), %ebx
	65	movl 20(%eax), %ebp
	66	movl 24(%eax), %esi
	67	movl 28(%eax), %edi
	68	movl (%eax), %eax
79c5dca3	69	CFI_REMEMBER_STATE
132ec92f	70	1: \op
79c5dca3	71	2: pushl_cfi %eax
132ec92f	72	movl 4(%esp), %eax
79c5dca3	73	popl_cfi (%eax)
132ec92f	74	addl $4, %esp
79c5dca3	75	CFI_ADJUST_CFA_OFFSET -4
132ec92f BP	76	movl %ecx, 4(%eax)
	77	movl %edx, 8(%eax)
	78	movl %ebx, 12(%eax)
	79	movl %ebp, 20(%eax)
	80	movl %esi, 24(%eax)
	81	movl %edi, 28(%eax)
79c5dca3	82	popl_cfi %eax
49db46a6 DV	83	popl_cfi_reg edi
	84	popl_cfi_reg esi
	85	popl_cfi_reg ebp
	86	popl_cfi_reg ebx
132ec92f BP	87	ret
132ec92f BP	88	3:
79c5dca3	89	CFI_RESTORE_STATE
132ec92f BP	90	movl $-EIO, 4(%esp)
132ec92f BP	91	jmp 2b
79c5dca3 PA	92
	93	_ASM_EXTABLE(1b, 3b)
	94	CFI_ENDPROC
1f975f78	95	ENDPROC(\op\()_safe_regs)
132ec92f BP	96	.endm
	97
	98	#endif
	99
	100	op_safe_regs rdmsr
	101	op_safe_regs wrmsr
	102