[deliverable/linux.git] / arch / x86 / tools / gen-insn-attr-x86.awk

#!/bin/awk -f
# gen-insn-attr-x86.awk: Instruction attribute table generator
# Written by Masami Hiramatsu <mhiramat@redhat.com>
#
# Usage: awk -f gen-insn-attr-x86.awk x86-opcode-map.txt > inat-tables.c

# Awk implementation sanity check
function check_awk_implement() {
	if (sprintf("%x", 0) != "0")
		return "Your awk has a printf-format problem."
	return ""
}

# Clear working vars
function clear_vars() {
	delete table
	delete lptable2
	delete lptable1
	delete lptable3
	eid = -1 # escape id
	gid = -1 # group id
	aid = -1 # AVX id
	tname = ""
}

BEGIN {
	# Implementation error checking
	awkchecked = check_awk_implement()
	if (awkchecked != "") {
		print "Error: " awkchecked > "/dev/stderr"
		print "Please try to use gawk." > "/dev/stderr"
		exit 1
	}

	# Setup generating tables
	print "/* x86 opcode map generated from x86-opcode-map.txt */"
	print "/* Do not change this code. */\n"
	ggid = 1
	geid = 1
	gaid = 0
	delete etable
	delete gtable
	delete atable

	opnd_expr = "^[A-Za-z/]"
	ext_expr = "^\\("
	sep_expr = "^\\|$"
	group_expr = "^Grp[0-9A-Za-z]+"

	imm_expr = "^[IJAOL][a-z]"
	imm_flag["Ib"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	imm_flag["Jb"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	imm_flag["Iw"] = "INAT_MAKE_IMM(INAT_IMM_WORD)"
	imm_flag["Id"] = "INAT_MAKE_IMM(INAT_IMM_DWORD)"
	imm_flag["Iq"] = "INAT_MAKE_IMM(INAT_IMM_QWORD)"
	imm_flag["Ap"] = "INAT_MAKE_IMM(INAT_IMM_PTR)"
	imm_flag["Iz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	imm_flag["Jz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	imm_flag["Iv"] = "INAT_MAKE_IMM(INAT_IMM_VWORD)"
	imm_flag["Ob"] = "INAT_MOFFSET"
	imm_flag["Ov"] = "INAT_MOFFSET"
	imm_flag["Lx"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"

	modrm_expr = "^([CDEGMNPQRSUVW/][a-z]+|NTA|T[012])"
	force64_expr = "\\([df]64\\)"
	rex_expr = "^REX(\\.[XRWB]+)*"
	fpu_expr = "^ESC" # TODO

	lprefix1_expr = "\\((66|!F3)\\)"
	lprefix2_expr = "\\(F3\\)"
	lprefix3_expr = "\\((F2|!F3|66\\&F2)\\)"
	lprefix_expr = "\\((66|F2|F3)\\)"
	max_lprefix = 4

	# All opcodes starting with lower-case 'v' or with (v1) superscript
	# accepts VEX prefix
	vexok_opcode_expr = "^v.*"
	vexok_expr = "\\(v1\\)"
	# All opcodes with (v) superscript supports *only* VEX prefix
	vexonly_expr = "\\(v\\)"

	prefix_expr = "\\(Prefix\\)"
	prefix_num["Operand-Size"] = "INAT_PFX_OPNDSZ"
	prefix_num["REPNE"] = "INAT_PFX_REPNE"
	prefix_num["REP/REPE"] = "INAT_PFX_REPE"
	prefix_num["XACQUIRE"] = "INAT_PFX_REPNE"
	prefix_num["XRELEASE"] = "INAT_PFX_REPE"
	prefix_num["LOCK"] = "INAT_PFX_LOCK"
	prefix_num["SEG=CS"] = "INAT_PFX_CS"
	prefix_num["SEG=DS"] = "INAT_PFX_DS"
	prefix_num["SEG=ES"] = "INAT_PFX_ES"
	prefix_num["SEG=FS"] = "INAT_PFX_FS"
	prefix_num["SEG=GS"] = "INAT_PFX_GS"
	prefix_num["SEG=SS"] = "INAT_PFX_SS"
	prefix_num["Address-Size"] = "INAT_PFX_ADDRSZ"
	prefix_num["VEX+1byte"] = "INAT_PFX_VEX2"
	prefix_num["VEX+2byte"] = "INAT_PFX_VEX3"

	clear_vars()
}

function semantic_error(msg) {
	print "Semantic error at " NR ": " msg > "/dev/stderr"
	exit 1
}

function debug(msg) {
	print "DEBUG: " msg
}

function array_size(arr,   i,c) {
	c = 0
	for (i in arr)
		c++
	return c
}

/^Table:/ {
	print "/* " $0 " */"
	if (tname != "")
		semantic_error("Hit Table: before EndTable:.");
}

/^Referrer:/ {
	if (NF != 1) {
		# escape opcode table
		ref = ""
		for (i = 2; i <= NF; i++)
			ref = ref $i
		eid = escape[ref]
		tname = sprintf("inat_escape_table_%d", eid)
	}
}

/^AVXcode:/ {
	if (NF != 1) {
		# AVX/escape opcode table
		aid = $2
		if (gaid <= aid)
			gaid = aid + 1
		if (tname == "")	# AVX only opcode table
			tname = sprintf("inat_avx_table_%d", $2)
	}
	if (aid == -1 && eid == -1)	# primary opcode table
		tname = "inat_primary_table"
}

/^GrpTable:/ {
	print "/* " $0 " */"
	if (!($2 in group))
		semantic_error("No group: " $2 )
	gid = group[$2]
	tname = "inat_group_table_" gid
}

function print_table(tbl,name,fmt,n)
{
	print "const insn_attr_t " name " = {"
	for (i = 0; i < n; i++) {
		id = sprintf(fmt, i)
		if (tbl[id])
			print "	[" id "] = " tbl[id] ","
	}
	print "};"
}

/^EndTable/ {
	if (gid != -1) {
		# print group tables
		if (array_size(table) != 0) {
			print_table(table, tname "[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,0] = tname
		}
		if (array_size(lptable1) != 0) {
			print_table(lptable1, tname "_1[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,1] = tname "_1"
		}
		if (array_size(lptable2) != 0) {
			print_table(lptable2, tname "_2[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,2] = tname "_2"
		}
		if (array_size(lptable3) != 0) {
			print_table(lptable3, tname "_3[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,3] = tname "_3"
		}
	} else {
		# print primary/escaped tables
		if (array_size(table) != 0) {
			print_table(table, tname "[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,0] = tname
			if (aid >= 0)
				atable[aid,0] = tname
		}
		if (array_size(lptable1) != 0) {
			print_table(lptable1,tname "_1[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,1] = tname "_1"
			if (aid >= 0)
				atable[aid,1] = tname "_1"
		}
		if (array_size(lptable2) != 0) {
			print_table(lptable2,tname "_2[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,2] = tname "_2"
			if (aid >= 0)
				atable[aid,2] = tname "_2"
		}
		if (array_size(lptable3) != 0) {
			print_table(lptable3,tname "_3[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,3] = tname "_3"
			if (aid >= 0)
				atable[aid,3] = tname "_3"
		}
	}
	print ""
	clear_vars()
}

function add_flags(old,new) {
	if (old && new)
		return old " | " new
	else if (old)
		return old
	else
		return new
}

# convert operands to flags.
function convert_operands(count,opnd,       i,j,imm,mod)
{
	imm = null
	mod = null
	for (j = 1; j <= count; j++) {
		i = opnd[j]
		if (match(i, imm_expr) == 1) {
			if (!imm_flag[i])
				semantic_error("Unknown imm opnd: " i)
			if (imm) {
				if (i != "Ib")
					semantic_error("Second IMM error")
				imm = add_flags(imm, "INAT_SCNDIMM")
			} else
				imm = imm_flag[i]
		} else if (match(i, modrm_expr))
			mod = "INAT_MODRM"
	}
	return add_flags(imm, mod)
}

/^[0-9a-f]+\:/ {
	if (NR == 1)
		next
	# get index
	idx = "0x" substr($1, 1, index($1,":") - 1)
	if (idx in table)
		semantic_error("Redefine " idx " in " tname)

	# check if escaped opcode
	if ("escape" == $2) {
		if ($3 != "#")
			semantic_error("No escaped name")
		ref = ""
		for (i = 4; i <= NF; i++)
			ref = ref $i
		if (ref in escape)
			semantic_error("Redefine escape (" ref ")")
		escape[ref] = geid
		geid++
		table[idx] = "INAT_MAKE_ESCAPE(" escape[ref] ")"
		next
	}

	variant = null
	# converts
	i = 2
	while (i <= NF) {
		opcode = $(i++)
		delete opnds
		ext = null
		flags = null
		opnd = null
		# parse one opcode
		if (match($i, opnd_expr)) {
			opnd = $i
			count = split($(i++), opnds, ",")
			flags = convert_operands(count, opnds)
		}
		if (match($i, ext_expr))
			ext = $(i++)
		if (match($i, sep_expr))
			i++
		else if (i < NF)
			semantic_error($i " is not a separator")

		# check if group opcode
		if (match(opcode, group_expr)) {
			if (!(opcode in group)) {
				group[opcode] = ggid
				ggid++
			}
			flags = add_flags(flags, "INAT_MAKE_GROUP(" group[opcode] ")")
		}
		# check force(or default) 64bit
		if (match(ext, force64_expr))
			flags = add_flags(flags, "INAT_FORCE64")

		# check REX prefix
		if (match(opcode, rex_expr))
			flags = add_flags(flags, "INAT_MAKE_PREFIX(INAT_PFX_REX)")

		# check coprocessor escape : TODO
		if (match(opcode, fpu_expr))
			flags = add_flags(flags, "INAT_MODRM")

		# check VEX codes
		if (match(ext, vexonly_expr))
			flags = add_flags(flags, "INAT_VEXOK | INAT_VEXONLY")
		else if (match(ext, vexok_expr) || match(opcode, vexok_opcode_expr))
			flags = add_flags(flags, "INAT_VEXOK")

		# check prefixes
		if (match(ext, prefix_expr)) {
			if (!prefix_num[opcode])
				semantic_error("Unknown prefix: " opcode)
			flags = add_flags(flags, "INAT_MAKE_PREFIX(" prefix_num[opcode] ")")
		}
		if (length(flags) == 0)
			continue
		# check if last prefix
		if (match(ext, lprefix1_expr)) {
			lptable1[idx] = add_flags(lptable1[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (match(ext, lprefix2_expr)) {
			lptable2[idx] = add_flags(lptable2[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (match(ext, lprefix3_expr)) {
			lptable3[idx] = add_flags(lptable3[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (!match(ext, lprefix_expr)){
			table[idx] = add_flags(table[idx],flags)
		}
	}
	if (variant)
		table[idx] = add_flags(table[idx],variant)
}

END {
	if (awkchecked != "")
		exit 1
	# print escape opcode map's array
	print "/* Escape opcode map array */"
	print "const insn_attr_t * const inat_escape_tables[INAT_ESC_MAX + 1]" \
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < geid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (etable[i,j])
				print "	["i"]["j"] = "etable[i,j]","
	print "};\n"
	# print group opcode map's array
	print "/* Group opcode map array */"
	print "const insn_attr_t * const inat_group_tables[INAT_GRP_MAX + 1]"\
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < ggid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (gtable[i,j])
				print "	["i"]["j"] = "gtable[i,j]","
	print "};\n"
	# print AVX opcode map's array
	print "/* AVX opcode map array */"
	print "const insn_attr_t * const inat_avx_tables[X86_VEX_M_MAX + 1]"\
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < gaid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (atable[i,j])
				print "	["i"]["j"] = "atable[i,j]","
	print "};"
}
Commit	Line	Data
eb13296c MH	1	#!/bin/awk -f
	2	# gen-insn-attr-x86.awk: Instruction attribute table generator
	3	# Written by Masami Hiramatsu <mhiramat@redhat.com>
	4	#
	5	# Usage: awk -f gen-insn-attr-x86.awk x86-opcode-map.txt > inat-tables.c
	6
69d991f3 MH	7	# Awk implementation sanity check
69d991f3 MH	8	function check_awk_implement() {
69d991f3 MH	9	if (sprintf("%x", 0) != "0")
	10	return "Your awk has a printf-format problem."
	11	return ""
	12	}
	13
e0e492e9 MH	14	# Clear working vars
	15	function clear_vars() {
	16	delete table
	17	delete lptable2
	18	delete lptable1
	19	delete lptable3
	20	eid = -1 # escape id
	21	gid = -1 # group id
	22	aid = -1 # AVX id
	23	tname = ""
	24	}
	25
eb13296c	26	BEGIN {
69d991f3 MH	27	# Implementation error checking
	28	awkchecked = check_awk_implement()
	29	if (awkchecked != "") {
	30	print "Error: " awkchecked > "/dev/stderr"
	31	print "Please try to use gawk." > "/dev/stderr"
	32	exit 1
	33	}
	34
	35	# Setup generating tables
eb13296c	36	print "/* x86 opcode map generated from x86-opcode-map.txt */"
e0e492e9	37	print "/* Do not change this code. */\n"
eb13296c MH	38	ggid = 1
eb13296c MH	39	geid = 1
e0e492e9 MH	40	gaid = 0
	41	delete etable
	42	delete gtable
	43	delete atable
eb13296c	44
4beb3d6d	45	opnd_expr = "^[A-Za-z/]"
eb13296c MH	46	ext_expr = "^\\("
eb13296c MH	47	sep_expr = "^\\\|$"
4beb3d6d	48	group_expr = "^Grp[0-9A-Za-z]+"
eb13296c	49
a9c373d0	50	imm_expr = "^[IJAOL][a-z]"
eb13296c MH	51	imm_flag["Ib"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	52	imm_flag["Jb"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	53	imm_flag["Iw"] = "INAT_MAKE_IMM(INAT_IMM_WORD)"
	54	imm_flag["Id"] = "INAT_MAKE_IMM(INAT_IMM_DWORD)"
	55	imm_flag["Iq"] = "INAT_MAKE_IMM(INAT_IMM_QWORD)"
	56	imm_flag["Ap"] = "INAT_MAKE_IMM(INAT_IMM_PTR)"
	57	imm_flag["Iz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	58	imm_flag["Jz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	59	imm_flag["Iv"] = "INAT_MAKE_IMM(INAT_IMM_VWORD)"
	60	imm_flag["Ob"] = "INAT_MOFFSET"
	61	imm_flag["Ov"] = "INAT_MOFFSET"
a9c373d0	62	imm_flag["Lx"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
eb13296c	63
4beb3d6d	64	modrm_expr = "^([CDEGMNPQRSUVW/][a-z]+\|NTA\|T[012])"
eb13296c MH	65	force64_expr = "\\([df]64\\)"
	66	rex_expr = "^REX(\\.[XRWB]+)*"
	67	fpu_expr = "^ESC" # TODO
	68
436d03fa	69	lprefix1_expr = "\\((66\|!F3)\\)"
e0e492e9	70	lprefix2_expr = "\\(F3\\)"
3e21bb09	71	lprefix3_expr = "\\((F2\|!F3\|66\\&F2)\\)"
436d03fa	72	lprefix_expr = "\\((66\|F2\|F3)\\)"
eb13296c MH	73	max_lprefix = 4
eb13296c MH	74
a9c373d0 MH	75	# All opcodes starting with lower-case 'v' or with (v1) superscript
	76	# accepts VEX prefix
	77	vexok_opcode_expr = "^v.*"
	78	vexok_expr = "\\(v1\\)"
	79	# All opcodes with (v) superscript supports only VEX prefix
	80	vexonly_expr = "\\(v\\)"
e0e492e9	81
eb13296c MH	82	prefix_expr = "\\(Prefix\\)"
	83	prefix_num["Operand-Size"] = "INAT_PFX_OPNDSZ"
	84	prefix_num["REPNE"] = "INAT_PFX_REPNE"
	85	prefix_num["REP/REPE"] = "INAT_PFX_REPE"
3e21bb09 MH	86	prefix_num["XACQUIRE"] = "INAT_PFX_REPNE"
3e21bb09 MH	87	prefix_num["XRELEASE"] = "INAT_PFX_REPE"
eb13296c MH	88	prefix_num["LOCK"] = "INAT_PFX_LOCK"
	89	prefix_num["SEG=CS"] = "INAT_PFX_CS"
	90	prefix_num["SEG=DS"] = "INAT_PFX_DS"
	91	prefix_num["SEG=ES"] = "INAT_PFX_ES"
	92	prefix_num["SEG=FS"] = "INAT_PFX_FS"
	93	prefix_num["SEG=GS"] = "INAT_PFX_GS"
	94	prefix_num["SEG=SS"] = "INAT_PFX_SS"
	95	prefix_num["Address-Size"] = "INAT_PFX_ADDRSZ"
a9c373d0 MH	96	prefix_num["VEX+1byte"] = "INAT_PFX_VEX2"
a9c373d0 MH	97	prefix_num["VEX+2byte"] = "INAT_PFX_VEX3"
eb13296c	98
e0e492e9	99	clear_vars()
eb13296c MH	100	}
	101
	102	function semantic_error(msg) {
	103	print "Semantic error at " NR ": " msg > "/dev/stderr"
	104	exit 1
	105	}
	106
	107	function debug(msg) {
	108	print "DEBUG: " msg
	109	}
	110
	111	function array_size(arr, i,c) {
	112	c = 0
	113	for (i in arr)
	114	c++
	115	return c
	116	}
	117
	118	/^Table:/ {
	119	print "/* " $0 " */"
e0e492e9 MH	120	if (tname != "")
e0e492e9 MH	121	semantic_error("Hit Table: before EndTable:.");
eb13296c MH	122	}
	123
	124	/^Referrer:/ {
e0e492e9	125	if (NF != 1) {
eb13296c MH	126	# escape opcode table
	127	ref = ""
	128	for (i = 2; i <= NF; i++)
	129	ref = ref $i
	130	eid = escape[ref]
	131	tname = sprintf("inat_escape_table_%d", eid)
	132	}
	133	}
	134
e0e492e9 MH	135	/^AVXcode:/ {
	136	if (NF != 1) {
	137	# AVX/escape opcode table
	138	aid = $2
	139	if (gaid <= aid)
	140	gaid = aid + 1
	141	if (tname == "") # AVX only opcode table
	142	tname = sprintf("inat_avx_table_%d", $2)
	143	}
	144	if (aid == -1 && eid == -1) # primary opcode table
	145	tname = "inat_primary_table"
	146	}
	147
eb13296c MH	148	/^GrpTable:/ {
	149	print "/* " $0 " */"
	150	if (!($2 in group))
	151	semantic_error("No group: " $2 )
	152	gid = group[$2]
	153	tname = "inat_group_table_" gid
	154	}
	155
	156	function print_table(tbl,name,fmt,n)
	157	{
	158	print "const insn_attr_t " name " = {"
	159	for (i = 0; i < n; i++) {
	160	id = sprintf(fmt, i)
	161	if (tbl[id])
	162	print " [" id "] = " tbl[id] ","
	163	}
	164	print "};"
	165	}
	166
	167	/^EndTable/ {
	168	if (gid != -1) {
	169	# print group tables
	170	if (array_size(table) != 0) {
	171	print_table(table, tname "[INAT_GROUP_TABLE_SIZE]",
	172	"0x%x", 8)
	173	gtable[gid,0] = tname
	174	}
	175	if (array_size(lptable1) != 0) {
	176	print_table(lptable1, tname "_1[INAT_GROUP_TABLE_SIZE]",
	177	"0x%x", 8)
	178	gtable[gid,1] = tname "_1"
	179	}
	180	if (array_size(lptable2) != 0) {
	181	print_table(lptable2, tname "_2[INAT_GROUP_TABLE_SIZE]",
	182	"0x%x", 8)
	183	gtable[gid,2] = tname "_2"
	184	}
	185	if (array_size(lptable3) != 0) {
	186	print_table(lptable3, tname "_3[INAT_GROUP_TABLE_SIZE]",
	187	"0x%x", 8)
	188	gtable[gid,3] = tname "_3"
	189	}
	190	} else {
	191	# print primary/escaped tables
	192	if (array_size(table) != 0) {
	193	print_table(table, tname "[INAT_OPCODE_TABLE_SIZE]",
	194	"0x%02x", 256)
	195	etable[eid,0] = tname
e0e492e9 MH	196	if (aid >= 0)
e0e492e9 MH	197	atable[aid,0] = tname
eb13296c MH	198	}
	199	if (array_size(lptable1) != 0) {
	200	print_table(lptable1,tname "_1[INAT_OPCODE_TABLE_SIZE]",
	201	"0x%02x", 256)
	202	etable[eid,1] = tname "_1"
e0e492e9 MH	203	if (aid >= 0)
e0e492e9 MH	204	atable[aid,1] = tname "_1"
eb13296c MH	205	}
	206	if (array_size(lptable2) != 0) {
	207	print_table(lptable2,tname "_2[INAT_OPCODE_TABLE_SIZE]",
	208	"0x%02x", 256)
	209	etable[eid,2] = tname "_2"
e0e492e9 MH	210	if (aid >= 0)
e0e492e9 MH	211	atable[aid,2] = tname "_2"
eb13296c MH	212	}
	213	if (array_size(lptable3) != 0) {
	214	print_table(lptable3,tname "_3[INAT_OPCODE_TABLE_SIZE]",
	215	"0x%02x", 256)
	216	etable[eid,3] = tname "_3"
e0e492e9 MH	217	if (aid >= 0)
e0e492e9 MH	218	atable[aid,3] = tname "_3"
eb13296c MH	219	}
	220	}
	221	print ""
e0e492e9	222	clear_vars()
eb13296c MH	223	}
	224
	225	function add_flags(old,new) {
	226	if (old && new)
	227	return old " \| " new
	228	else if (old)
	229	return old
	230	else
	231	return new
	232	}
	233
	234	# convert operands to flags.
23637568	235	function convert_operands(count,opnd, i,j,imm,mod)
eb13296c MH	236	{
	237	imm = null
	238	mod = null
23637568 JN	239	for (j = 1; j <= count; j++) {
23637568 JN	240	i = opnd[j]
eb13296c MH	241	if (match(i, imm_expr) == 1) {
	242	if (!imm_flag[i])
	243	semantic_error("Unknown imm opnd: " i)
	244	if (imm) {
	245	if (i != "Ib")
	246	semantic_error("Second IMM error")
	247	imm = add_flags(imm, "INAT_SCNDIMM")
	248	} else
	249	imm = imm_flag[i]
	250	} else if (match(i, modrm_expr))
	251	mod = "INAT_MODRM"
	252	}
	253	return add_flags(imm, mod)
	254	}
	255
	256	/^[0-9a-f]+\:/ {
	257	if (NR == 1)
	258	next
	259	# get index
	260	idx = "0x" substr($1, 1, index($1,":") - 1)
	261	if (idx in table)
	262	semantic_error("Redefine " idx " in " tname)
	263
	264	# check if escaped opcode
	265	if ("escape" == $2) {
	266	if ($3 != "#")
	267	semantic_error("No escaped name")
	268	ref = ""
	269	for (i = 4; i <= NF; i++)
	270	ref = ref $i
	271	if (ref in escape)
	272	semantic_error("Redefine escape (" ref ")")
	273	escape[ref] = geid
	274	geid++
	275	table[idx] = "INAT_MAKE_ESCAPE(" escape[ref] ")"
	276	next
	277	}
	278
	279	variant = null
	280	# converts
	281	i = 2
	282	while (i <= NF) {
	283	opcode = $(i++)
	284	delete opnds
	285	ext = null
	286	flags = null
	287	opnd = null
	288	# parse one opcode
	289	if (match($i, opnd_expr)) {
	290	opnd = $i
23637568 JN	291	count = split($(i++), opnds, ",")
23637568 JN	292	flags = convert_operands(count, opnds)
eb13296c MH	293	}
	294	if (match($i, ext_expr))
	295	ext = $(i++)
	296	if (match($i, sep_expr))
	297	i++
	298	else if (i < NF)
	299	semantic_error($i " is not a separator")
	300
	301	# check if group opcode
	302	if (match(opcode, group_expr)) {
	303	if (!(opcode in group)) {
	304	group[opcode] = ggid
	305	ggid++
	306	}
	307	flags = add_flags(flags, "INAT_MAKE_GROUP(" group[opcode] ")")
	308	}
	309	# check force(or default) 64bit
	310	if (match(ext, force64_expr))
	311	flags = add_flags(flags, "INAT_FORCE64")
	312
	313	# check REX prefix
	314	if (match(opcode, rex_expr))
04d46c1b	315	flags = add_flags(flags, "INAT_MAKE_PREFIX(INAT_PFX_REX)")
eb13296c MH	316
	317	# check coprocessor escape : TODO
	318	if (match(opcode, fpu_expr))
	319	flags = add_flags(flags, "INAT_MODRM")
	320
a9c373d0	321	# check VEX codes
e0e492e9 MH	322	if (match(ext, vexonly_expr))
e0e492e9 MH	323	flags = add_flags(flags, "INAT_VEXOK \| INAT_VEXONLY")
a9c373d0	324	else if (match(ext, vexok_expr) \|\| match(opcode, vexok_opcode_expr))
e0e492e9 MH	325	flags = add_flags(flags, "INAT_VEXOK")
e0e492e9 MH	326
eb13296c MH	327	# check prefixes
	328	if (match(ext, prefix_expr)) {
	329	if (!prefix_num[opcode])
	330	semantic_error("Unknown prefix: " opcode)
	331	flags = add_flags(flags, "INAT_MAKE_PREFIX(" prefix_num[opcode] ")")
	332	}
	333	if (length(flags) == 0)
	334	continue
	335	# check if last prefix
	336	if (match(ext, lprefix1_expr)) {
	337	lptable1[idx] = add_flags(lptable1[idx],flags)
	338	variant = "INAT_VARIANT"
436d03fa MH	339	}
436d03fa MH	340	if (match(ext, lprefix2_expr)) {
eb13296c MH	341	lptable2[idx] = add_flags(lptable2[idx],flags)
eb13296c MH	342	variant = "INAT_VARIANT"
436d03fa MH	343	}
436d03fa MH	344	if (match(ext, lprefix3_expr)) {
eb13296c MH	345	lptable3[idx] = add_flags(lptable3[idx],flags)
eb13296c MH	346	variant = "INAT_VARIANT"
436d03fa MH	347	}
436d03fa MH	348	if (!match(ext, lprefix_expr)){
eb13296c MH	349	table[idx] = add_flags(table[idx],flags)
	350	}
	351	}
	352	if (variant)
	353	table[idx] = add_flags(table[idx],variant)
	354	}
	355
	356	END {
69d991f3 MH	357	if (awkchecked != "")
69d991f3 MH	358	exit 1
eb13296c MH	359	# print escape opcode map's array
eb13296c MH	360	print "/* Escape opcode map array */"
28a79389	361	print "const insn_attr_t * const inat_escape_tables[INAT_ESC_MAX + 1]" \
04d46c1b	362	"[INAT_LSTPFX_MAX + 1] = {"
eb13296c MH	363	for (i = 0; i < geid; i++)
	364	for (j = 0; j < max_lprefix; j++)
	365	if (etable[i,j])
	366	print " ["i"]["j"] = "etable[i,j]","
	367	print "};\n"
	368	# print group opcode map's array
	369	print "/* Group opcode map array */"
28a79389	370	print "const insn_attr_t * const inat_group_tables[INAT_GRP_MAX + 1]"\
04d46c1b	371	"[INAT_LSTPFX_MAX + 1] = {"
eb13296c MH	372	for (i = 0; i < ggid; i++)
	373	for (j = 0; j < max_lprefix; j++)
	374	if (gtable[i,j])
	375	print " ["i"]["j"] = "gtable[i,j]","
e0e492e9 MH	376	print "};\n"
	377	# print AVX opcode map's array
	378	print "/* AVX opcode map array */"
28a79389	379	print "const insn_attr_t * const inat_avx_tables[X86_VEX_M_MAX + 1]"\
e0e492e9 MH	380	"[INAT_LSTPFX_MAX + 1] = {"
	381	for (i = 0; i < gaid; i++)
	382	for (j = 0; j < max_lprefix; j++)
	383	if (atable[i,j])
	384	print " ["i"]["j"] = "atable[i,j]","
eb13296c MH	385	print "};"
eb13296c MH	386	}
e0e492e9	387