[deliverable/linux.git] / arch / x86 / tools / gen-insn-attr-x86.awk

#!/bin/awk -f
# gen-insn-attr-x86.awk: Instruction attribute table generator
# Written by Masami Hiramatsu <mhiramat@redhat.com>
#
# Usage: awk -f gen-insn-attr-x86.awk x86-opcode-map.txt > inat-tables.c

# Awk implementation sanity check
function check_awk_implement() {
	if (sprintf("%x", 0) != "0")
		return "Your awk has a printf-format problem."
	return ""
}

# Clear working vars
function clear_vars() {
	delete table
	delete lptable2
	delete lptable1
	delete lptable3
	eid = -1 # escape id
	gid = -1 # group id
	aid = -1 # AVX id
	tname = ""
}

BEGIN {
	# Implementation error checking
	awkchecked = check_awk_implement()
	if (awkchecked != "") {
		print "Error: " awkchecked > "/dev/stderr"
		print "Please try to use gawk." > "/dev/stderr"
		exit 1
	}

	# Setup generating tables
	print "/* x86 opcode map generated from x86-opcode-map.txt */"
	print "/* Do not change this code. */\n"
	ggid = 1
	geid = 1
	gaid = 0
	delete etable
	delete gtable
	delete atable

	opnd_expr = "^[A-Za-z/]"
	ext_expr = "^\\("
	sep_expr = "^\\|$"
	group_expr = "^Grp[0-9A-Za-z]+"

	imm_expr = "^[IJAOL][a-z]"
	imm_flag["Ib"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	imm_flag["Jb"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	imm_flag["Iw"] = "INAT_MAKE_IMM(INAT_IMM_WORD)"
	imm_flag["Id"] = "INAT_MAKE_IMM(INAT_IMM_DWORD)"
	imm_flag["Iq"] = "INAT_MAKE_IMM(INAT_IMM_QWORD)"
	imm_flag["Ap"] = "INAT_MAKE_IMM(INAT_IMM_PTR)"
	imm_flag["Iz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	imm_flag["Jz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	imm_flag["Iv"] = "INAT_MAKE_IMM(INAT_IMM_VWORD)"
	imm_flag["Ob"] = "INAT_MOFFSET"
	imm_flag["Ov"] = "INAT_MOFFSET"
	imm_flag["Lx"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"

	modrm_expr = "^([CDEGMNPQRSUVW/][a-z]+|NTA|T[012])"
	force64_expr = "\\([df]64\\)"
	rex_expr = "^REX(\\.[XRWB]+)*"
	fpu_expr = "^ESC" # TODO

	lprefix1_expr = "\\((66|!F3)\\)"
	lprefix2_expr = "\\(F3\\)"
	lprefix3_expr = "\\((F2|!F3)\\)"
	lprefix_expr = "\\((66|F2|F3)\\)"
	max_lprefix = 4

	# All opcodes starting with lower-case 'v' or with (v1) superscript
	# accepts VEX prefix
	vexok_opcode_expr = "^v.*"
	vexok_expr = "\\(v1\\)"
	# All opcodes with (v) superscript supports *only* VEX prefix
	vexonly_expr = "\\(v\\)"

	prefix_expr = "\\(Prefix\\)"
	prefix_num["Operand-Size"] = "INAT_PFX_OPNDSZ"
	prefix_num["REPNE"] = "INAT_PFX_REPNE"
	prefix_num["REP/REPE"] = "INAT_PFX_REPE"
	prefix_num["LOCK"] = "INAT_PFX_LOCK"
	prefix_num["SEG=CS"] = "INAT_PFX_CS"
	prefix_num["SEG=DS"] = "INAT_PFX_DS"
	prefix_num["SEG=ES"] = "INAT_PFX_ES"
	prefix_num["SEG=FS"] = "INAT_PFX_FS"
	prefix_num["SEG=GS"] = "INAT_PFX_GS"
	prefix_num["SEG=SS"] = "INAT_PFX_SS"
	prefix_num["Address-Size"] = "INAT_PFX_ADDRSZ"
	prefix_num["VEX+1byte"] = "INAT_PFX_VEX2"
	prefix_num["VEX+2byte"] = "INAT_PFX_VEX3"

	clear_vars()
}

function semantic_error(msg) {
	print "Semantic error at " NR ": " msg > "/dev/stderr"
	exit 1
}

function debug(msg) {
	print "DEBUG: " msg
}

function array_size(arr,   i,c) {
	c = 0
	for (i in arr)
		c++
	return c
}

/^Table:/ {
	print "/* " $0 " */"
	if (tname != "")
		semantic_error("Hit Table: before EndTable:.");
}

/^Referrer:/ {
	if (NF != 1) {
		# escape opcode table
		ref = ""
		for (i = 2; i <= NF; i++)
			ref = ref $i
		eid = escape[ref]
		tname = sprintf("inat_escape_table_%d", eid)
	}
}

/^AVXcode:/ {
	if (NF != 1) {
		# AVX/escape opcode table
		aid = $2
		if (gaid <= aid)
			gaid = aid + 1
		if (tname == "")	# AVX only opcode table
			tname = sprintf("inat_avx_table_%d", $2)
	}
	if (aid == -1 && eid == -1)	# primary opcode table
		tname = "inat_primary_table"
}

/^GrpTable:/ {
	print "/* " $0 " */"
	if (!($2 in group))
		semantic_error("No group: " $2 )
	gid = group[$2]
	tname = "inat_group_table_" gid
}

function print_table(tbl,name,fmt,n)
{
	print "const insn_attr_t " name " = {"
	for (i = 0; i < n; i++) {
		id = sprintf(fmt, i)
		if (tbl[id])
			print "	[" id "] = " tbl[id] ","
	}
	print "};"
}

/^EndTable/ {
	if (gid != -1) {
		# print group tables
		if (array_size(table) != 0) {
			print_table(table, tname "[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,0] = tname
		}
		if (array_size(lptable1) != 0) {
			print_table(lptable1, tname "_1[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,1] = tname "_1"
		}
		if (array_size(lptable2) != 0) {
			print_table(lptable2, tname "_2[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,2] = tname "_2"
		}
		if (array_size(lptable3) != 0) {
			print_table(lptable3, tname "_3[INAT_GROUP_TABLE_SIZE]",
				    "0x%x", 8)
			gtable[gid,3] = tname "_3"
		}
	} else {
		# print primary/escaped tables
		if (array_size(table) != 0) {
			print_table(table, tname "[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,0] = tname
			if (aid >= 0)
				atable[aid,0] = tname
		}
		if (array_size(lptable1) != 0) {
			print_table(lptable1,tname "_1[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,1] = tname "_1"
			if (aid >= 0)
				atable[aid,1] = tname "_1"
		}
		if (array_size(lptable2) != 0) {
			print_table(lptable2,tname "_2[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,2] = tname "_2"
			if (aid >= 0)
				atable[aid,2] = tname "_2"
		}
		if (array_size(lptable3) != 0) {
			print_table(lptable3,tname "_3[INAT_OPCODE_TABLE_SIZE]",
				    "0x%02x", 256)
			etable[eid,3] = tname "_3"
			if (aid >= 0)
				atable[aid,3] = tname "_3"
		}
	}
	print ""
	clear_vars()
}

function add_flags(old,new) {
	if (old && new)
		return old " | " new
	else if (old)
		return old
	else
		return new
}

# convert operands to flags.
function convert_operands(count,opnd,       i,j,imm,mod)
{
	imm = null
	mod = null
	for (j = 1; j <= count; j++) {
		i = opnd[j]
		if (match(i, imm_expr) == 1) {
			if (!imm_flag[i])
				semantic_error("Unknown imm opnd: " i)
			if (imm) {
				if (i != "Ib")
					semantic_error("Second IMM error")
				imm = add_flags(imm, "INAT_SCNDIMM")
			} else
				imm = imm_flag[i]
		} else if (match(i, modrm_expr))
			mod = "INAT_MODRM"
	}
	return add_flags(imm, mod)
}

/^[0-9a-f]+\:/ {
	if (NR == 1)
		next
	# get index
	idx = "0x" substr($1, 1, index($1,":") - 1)
	if (idx in table)
		semantic_error("Redefine " idx " in " tname)

	# check if escaped opcode
	if ("escape" == $2) {
		if ($3 != "#")
			semantic_error("No escaped name")
		ref = ""
		for (i = 4; i <= NF; i++)
			ref = ref $i
		if (ref in escape)
			semantic_error("Redefine escape (" ref ")")
		escape[ref] = geid
		geid++
		table[idx] = "INAT_MAKE_ESCAPE(" escape[ref] ")"
		next
	}

	variant = null
	# converts
	i = 2
	while (i <= NF) {
		opcode = $(i++)
		delete opnds
		ext = null
		flags = null
		opnd = null
		# parse one opcode
		if (match($i, opnd_expr)) {
			opnd = $i
			count = split($(i++), opnds, ",")
			flags = convert_operands(count, opnds)
		}
		if (match($i, ext_expr))
			ext = $(i++)
		if (match($i, sep_expr))
			i++
		else if (i < NF)
			semantic_error($i " is not a separator")

		# check if group opcode
		if (match(opcode, group_expr)) {
			if (!(opcode in group)) {
				group[opcode] = ggid
				ggid++
			}
			flags = add_flags(flags, "INAT_MAKE_GROUP(" group[opcode] ")")
		}
		# check force(or default) 64bit
		if (match(ext, force64_expr))
			flags = add_flags(flags, "INAT_FORCE64")

		# check REX prefix
		if (match(opcode, rex_expr))
			flags = add_flags(flags, "INAT_MAKE_PREFIX(INAT_PFX_REX)")

		# check coprocessor escape : TODO
		if (match(opcode, fpu_expr))
			flags = add_flags(flags, "INAT_MODRM")

		# check VEX codes
		if (match(ext, vexonly_expr))
			flags = add_flags(flags, "INAT_VEXOK | INAT_VEXONLY")
		else if (match(ext, vexok_expr) || match(opcode, vexok_opcode_expr))
			flags = add_flags(flags, "INAT_VEXOK")

		# check prefixes
		if (match(ext, prefix_expr)) {
			if (!prefix_num[opcode])
				semantic_error("Unknown prefix: " opcode)
			flags = add_flags(flags, "INAT_MAKE_PREFIX(" prefix_num[opcode] ")")
		}
		if (length(flags) == 0)
			continue
		# check if last prefix
		if (match(ext, lprefix1_expr)) {
			lptable1[idx] = add_flags(lptable1[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (match(ext, lprefix2_expr)) {
			lptable2[idx] = add_flags(lptable2[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (match(ext, lprefix3_expr)) {
			lptable3[idx] = add_flags(lptable3[idx],flags)
			variant = "INAT_VARIANT"
		}
		if (!match(ext, lprefix_expr)){
			table[idx] = add_flags(table[idx],flags)
		}
	}
	if (variant)
		table[idx] = add_flags(table[idx],variant)
}

END {
	if (awkchecked != "")
		exit 1
	# print escape opcode map's array
	print "/* Escape opcode map array */"
	print "const insn_attr_t const *inat_escape_tables[INAT_ESC_MAX + 1]" \
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < geid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (etable[i,j])
				print "	["i"]["j"] = "etable[i,j]","
	print "};\n"
	# print group opcode map's array
	print "/* Group opcode map array */"
	print "const insn_attr_t const *inat_group_tables[INAT_GRP_MAX + 1]"\
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < ggid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (gtable[i,j])
				print "	["i"]["j"] = "gtable[i,j]","
	print "};\n"
	# print AVX opcode map's array
	print "/* AVX opcode map array */"
	print "const insn_attr_t const *inat_avx_tables[X86_VEX_M_MAX + 1]"\
	      "[INAT_LSTPFX_MAX + 1] = {"
	for (i = 0; i < gaid; i++)
		for (j = 0; j < max_lprefix; j++)
			if (atable[i,j])
				print "	["i"]["j"] = "atable[i,j]","
	print "};"
}
Commit	Line	Data
eb13296c MH	1	#!/bin/awk -f
	2	# gen-insn-attr-x86.awk: Instruction attribute table generator
	3	# Written by Masami Hiramatsu <mhiramat@redhat.com>
	4	#
	5	# Usage: awk -f gen-insn-attr-x86.awk x86-opcode-map.txt > inat-tables.c
	6
69d991f3 MH	7	# Awk implementation sanity check
69d991f3 MH	8	function check_awk_implement() {
69d991f3 MH	9	if (sprintf("%x", 0) != "0")
	10	return "Your awk has a printf-format problem."
	11	return ""
	12	}
	13
e0e492e9 MH	14	# Clear working vars
	15	function clear_vars() {
	16	delete table
	17	delete lptable2
	18	delete lptable1
	19	delete lptable3
	20	eid = -1 # escape id
	21	gid = -1 # group id
	22	aid = -1 # AVX id
	23	tname = ""
	24	}
	25
eb13296c	26	BEGIN {
69d991f3 MH	27	# Implementation error checking
	28	awkchecked = check_awk_implement()
	29	if (awkchecked != "") {
	30	print "Error: " awkchecked > "/dev/stderr"
	31	print "Please try to use gawk." > "/dev/stderr"
	32	exit 1
	33	}
	34
	35	# Setup generating tables
eb13296c	36	print "/* x86 opcode map generated from x86-opcode-map.txt */"
e0e492e9	37	print "/* Do not change this code. */\n"
eb13296c MH	38	ggid = 1
eb13296c MH	39	geid = 1
e0e492e9 MH	40	gaid = 0
	41	delete etable
	42	delete gtable
	43	delete atable
eb13296c	44
4beb3d6d	45	opnd_expr = "^[A-Za-z/]"
eb13296c MH	46	ext_expr = "^\\("
eb13296c MH	47	sep_expr = "^\\\|$"
4beb3d6d	48	group_expr = "^Grp[0-9A-Za-z]+"
eb13296c	49
a9c373d0	50	imm_expr = "^[IJAOL][a-z]"
eb13296c MH	51	imm_flag["Ib"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	52	imm_flag["Jb"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
	53	imm_flag["Iw"] = "INAT_MAKE_IMM(INAT_IMM_WORD)"
	54	imm_flag["Id"] = "INAT_MAKE_IMM(INAT_IMM_DWORD)"
	55	imm_flag["Iq"] = "INAT_MAKE_IMM(INAT_IMM_QWORD)"
	56	imm_flag["Ap"] = "INAT_MAKE_IMM(INAT_IMM_PTR)"
	57	imm_flag["Iz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	58	imm_flag["Jz"] = "INAT_MAKE_IMM(INAT_IMM_VWORD32)"
	59	imm_flag["Iv"] = "INAT_MAKE_IMM(INAT_IMM_VWORD)"
	60	imm_flag["Ob"] = "INAT_MOFFSET"
	61	imm_flag["Ov"] = "INAT_MOFFSET"
a9c373d0	62	imm_flag["Lx"] = "INAT_MAKE_IMM(INAT_IMM_BYTE)"
eb13296c	63
4beb3d6d	64	modrm_expr = "^([CDEGMNPQRSUVW/][a-z]+\|NTA\|T[012])"
eb13296c MH	65	force64_expr = "\\([df]64\\)"
	66	rex_expr = "^REX(\\.[XRWB]+)*"
	67	fpu_expr = "^ESC" # TODO
	68
436d03fa	69	lprefix1_expr = "\\((66\|!F3)\\)"
e0e492e9	70	lprefix2_expr = "\\(F3\\)"
436d03fa MH	71	lprefix3_expr = "\\((F2\|!F3)\\)"
436d03fa MH	72	lprefix_expr = "\\((66\|F2\|F3)\\)"
eb13296c MH	73	max_lprefix = 4
eb13296c MH	74
a9c373d0 MH	75	# All opcodes starting with lower-case 'v' or with (v1) superscript
	76	# accepts VEX prefix
	77	vexok_opcode_expr = "^v.*"
	78	vexok_expr = "\\(v1\\)"
	79	# All opcodes with (v) superscript supports only VEX prefix
	80	vexonly_expr = "\\(v\\)"
e0e492e9	81
eb13296c MH	82	prefix_expr = "\\(Prefix\\)"
	83	prefix_num["Operand-Size"] = "INAT_PFX_OPNDSZ"
	84	prefix_num["REPNE"] = "INAT_PFX_REPNE"
	85	prefix_num["REP/REPE"] = "INAT_PFX_REPE"
	86	prefix_num["LOCK"] = "INAT_PFX_LOCK"
	87	prefix_num["SEG=CS"] = "INAT_PFX_CS"
	88	prefix_num["SEG=DS"] = "INAT_PFX_DS"
	89	prefix_num["SEG=ES"] = "INAT_PFX_ES"
	90	prefix_num["SEG=FS"] = "INAT_PFX_FS"
	91	prefix_num["SEG=GS"] = "INAT_PFX_GS"
	92	prefix_num["SEG=SS"] = "INAT_PFX_SS"
	93	prefix_num["Address-Size"] = "INAT_PFX_ADDRSZ"
a9c373d0 MH	94	prefix_num["VEX+1byte"] = "INAT_PFX_VEX2"
a9c373d0 MH	95	prefix_num["VEX+2byte"] = "INAT_PFX_VEX3"
eb13296c	96
e0e492e9	97	clear_vars()
eb13296c MH	98	}
	99
	100	function semantic_error(msg) {
	101	print "Semantic error at " NR ": " msg > "/dev/stderr"
	102	exit 1
	103	}
	104
	105	function debug(msg) {
	106	print "DEBUG: " msg
	107	}
	108
	109	function array_size(arr, i,c) {
	110	c = 0
	111	for (i in arr)
	112	c++
	113	return c
	114	}
	115
	116	/^Table:/ {
	117	print "/* " $0 " */"
e0e492e9 MH	118	if (tname != "")
e0e492e9 MH	119	semantic_error("Hit Table: before EndTable:.");
eb13296c MH	120	}
	121
	122	/^Referrer:/ {
e0e492e9	123	if (NF != 1) {
eb13296c MH	124	# escape opcode table
	125	ref = ""
	126	for (i = 2; i <= NF; i++)
	127	ref = ref $i
	128	eid = escape[ref]
	129	tname = sprintf("inat_escape_table_%d", eid)
	130	}
	131	}
	132
e0e492e9 MH	133	/^AVXcode:/ {
	134	if (NF != 1) {
	135	# AVX/escape opcode table
	136	aid = $2
	137	if (gaid <= aid)
	138	gaid = aid + 1
	139	if (tname == "") # AVX only opcode table
	140	tname = sprintf("inat_avx_table_%d", $2)
	141	}
	142	if (aid == -1 && eid == -1) # primary opcode table
	143	tname = "inat_primary_table"
	144	}
	145
eb13296c MH	146	/^GrpTable:/ {
	147	print "/* " $0 " */"
	148	if (!($2 in group))
	149	semantic_error("No group: " $2 )
	150	gid = group[$2]
	151	tname = "inat_group_table_" gid
	152	}
	153
	154	function print_table(tbl,name,fmt,n)
	155	{
	156	print "const insn_attr_t " name " = {"
	157	for (i = 0; i < n; i++) {
	158	id = sprintf(fmt, i)
	159	if (tbl[id])
	160	print " [" id "] = " tbl[id] ","
	161	}
	162	print "};"
	163	}
	164
	165	/^EndTable/ {
	166	if (gid != -1) {
	167	# print group tables
	168	if (array_size(table) != 0) {
	169	print_table(table, tname "[INAT_GROUP_TABLE_SIZE]",
	170	"0x%x", 8)
	171	gtable[gid,0] = tname
	172	}
	173	if (array_size(lptable1) != 0) {
	174	print_table(lptable1, tname "_1[INAT_GROUP_TABLE_SIZE]",
	175	"0x%x", 8)
	176	gtable[gid,1] = tname "_1"
	177	}
	178	if (array_size(lptable2) != 0) {
	179	print_table(lptable2, tname "_2[INAT_GROUP_TABLE_SIZE]",
	180	"0x%x", 8)
	181	gtable[gid,2] = tname "_2"
	182	}
	183	if (array_size(lptable3) != 0) {
	184	print_table(lptable3, tname "_3[INAT_GROUP_TABLE_SIZE]",
	185	"0x%x", 8)
	186	gtable[gid,3] = tname "_3"
	187	}
	188	} else {
	189	# print primary/escaped tables
	190	if (array_size(table) != 0) {
	191	print_table(table, tname "[INAT_OPCODE_TABLE_SIZE]",
	192	"0x%02x", 256)
	193	etable[eid,0] = tname
e0e492e9 MH	194	if (aid >= 0)
e0e492e9 MH	195	atable[aid,0] = tname
eb13296c MH	196	}
	197	if (array_size(lptable1) != 0) {
	198	print_table(lptable1,tname "_1[INAT_OPCODE_TABLE_SIZE]",
	199	"0x%02x", 256)
	200	etable[eid,1] = tname "_1"
e0e492e9 MH	201	if (aid >= 0)
e0e492e9 MH	202	atable[aid,1] = tname "_1"
eb13296c MH	203	}
	204	if (array_size(lptable2) != 0) {
	205	print_table(lptable2,tname "_2[INAT_OPCODE_TABLE_SIZE]",
	206	"0x%02x", 256)
	207	etable[eid,2] = tname "_2"
e0e492e9 MH	208	if (aid >= 0)
e0e492e9 MH	209	atable[aid,2] = tname "_2"
eb13296c MH	210	}
	211	if (array_size(lptable3) != 0) {
	212	print_table(lptable3,tname "_3[INAT_OPCODE_TABLE_SIZE]",
	213	"0x%02x", 256)
	214	etable[eid,3] = tname "_3"
e0e492e9 MH	215	if (aid >= 0)
e0e492e9 MH	216	atable[aid,3] = tname "_3"
eb13296c MH	217	}
	218	}
	219	print ""
e0e492e9	220	clear_vars()
eb13296c MH	221	}
	222
	223	function add_flags(old,new) {
	224	if (old && new)
	225	return old " \| " new
	226	else if (old)
	227	return old
	228	else
	229	return new
	230	}
	231
	232	# convert operands to flags.
23637568	233	function convert_operands(count,opnd, i,j,imm,mod)
eb13296c MH	234	{
	235	imm = null
	236	mod = null
23637568 JN	237	for (j = 1; j <= count; j++) {
23637568 JN	238	i = opnd[j]
eb13296c MH	239	if (match(i, imm_expr) == 1) {
	240	if (!imm_flag[i])
	241	semantic_error("Unknown imm opnd: " i)
	242	if (imm) {
	243	if (i != "Ib")
	244	semantic_error("Second IMM error")
	245	imm = add_flags(imm, "INAT_SCNDIMM")
	246	} else
	247	imm = imm_flag[i]
	248	} else if (match(i, modrm_expr))
	249	mod = "INAT_MODRM"
	250	}
	251	return add_flags(imm, mod)
	252	}
	253
	254	/^[0-9a-f]+\:/ {
	255	if (NR == 1)
	256	next
	257	# get index
	258	idx = "0x" substr($1, 1, index($1,":") - 1)
	259	if (idx in table)
	260	semantic_error("Redefine " idx " in " tname)
	261
	262	# check if escaped opcode
	263	if ("escape" == $2) {
	264	if ($3 != "#")
	265	semantic_error("No escaped name")
	266	ref = ""
	267	for (i = 4; i <= NF; i++)
	268	ref = ref $i
	269	if (ref in escape)
	270	semantic_error("Redefine escape (" ref ")")
	271	escape[ref] = geid
	272	geid++
	273	table[idx] = "INAT_MAKE_ESCAPE(" escape[ref] ")"
	274	next
	275	}
	276
	277	variant = null
	278	# converts
	279	i = 2
	280	while (i <= NF) {
	281	opcode = $(i++)
	282	delete opnds
	283	ext = null
	284	flags = null
	285	opnd = null
	286	# parse one opcode
	287	if (match($i, opnd_expr)) {
	288	opnd = $i
23637568 JN	289	count = split($(i++), opnds, ",")
23637568 JN	290	flags = convert_operands(count, opnds)
eb13296c MH	291	}
	292	if (match($i, ext_expr))
	293	ext = $(i++)
	294	if (match($i, sep_expr))
	295	i++
	296	else if (i < NF)
	297	semantic_error($i " is not a separator")
	298
	299	# check if group opcode
	300	if (match(opcode, group_expr)) {
	301	if (!(opcode in group)) {
	302	group[opcode] = ggid
	303	ggid++
	304	}
	305	flags = add_flags(flags, "INAT_MAKE_GROUP(" group[opcode] ")")
	306	}
	307	# check force(or default) 64bit
	308	if (match(ext, force64_expr))
	309	flags = add_flags(flags, "INAT_FORCE64")
	310
	311	# check REX prefix
	312	if (match(opcode, rex_expr))
04d46c1b	313	flags = add_flags(flags, "INAT_MAKE_PREFIX(INAT_PFX_REX)")
eb13296c MH	314
	315	# check coprocessor escape : TODO
	316	if (match(opcode, fpu_expr))
	317	flags = add_flags(flags, "INAT_MODRM")
	318
a9c373d0	319	# check VEX codes
e0e492e9 MH	320	if (match(ext, vexonly_expr))
e0e492e9 MH	321	flags = add_flags(flags, "INAT_VEXOK \| INAT_VEXONLY")
a9c373d0	322	else if (match(ext, vexok_expr) \|\| match(opcode, vexok_opcode_expr))
e0e492e9 MH	323	flags = add_flags(flags, "INAT_VEXOK")
e0e492e9 MH	324
eb13296c MH	325	# check prefixes
	326	if (match(ext, prefix_expr)) {
	327	if (!prefix_num[opcode])
	328	semantic_error("Unknown prefix: " opcode)
	329	flags = add_flags(flags, "INAT_MAKE_PREFIX(" prefix_num[opcode] ")")
	330	}
	331	if (length(flags) == 0)
	332	continue
	333	# check if last prefix
	334	if (match(ext, lprefix1_expr)) {
	335	lptable1[idx] = add_flags(lptable1[idx],flags)
	336	variant = "INAT_VARIANT"
436d03fa MH	337	}
436d03fa MH	338	if (match(ext, lprefix2_expr)) {
eb13296c MH	339	lptable2[idx] = add_flags(lptable2[idx],flags)
eb13296c MH	340	variant = "INAT_VARIANT"
436d03fa MH	341	}
436d03fa MH	342	if (match(ext, lprefix3_expr)) {
eb13296c MH	343	lptable3[idx] = add_flags(lptable3[idx],flags)
eb13296c MH	344	variant = "INAT_VARIANT"
436d03fa MH	345	}
436d03fa MH	346	if (!match(ext, lprefix_expr)){
eb13296c MH	347	table[idx] = add_flags(table[idx],flags)
	348	}
	349	}
	350	if (variant)
	351	table[idx] = add_flags(table[idx],variant)
	352	}
	353
	354	END {
69d991f3 MH	355	if (awkchecked != "")
69d991f3 MH	356	exit 1
eb13296c MH	357	# print escape opcode map's array
	358	print "/* Escape opcode map array */"
	359	print "const insn_attr_t const *inat_escape_tables[INAT_ESC_MAX + 1]" \
04d46c1b	360	"[INAT_LSTPFX_MAX + 1] = {"
eb13296c MH	361	for (i = 0; i < geid; i++)
	362	for (j = 0; j < max_lprefix; j++)
	363	if (etable[i,j])
	364	print " ["i"]["j"] = "etable[i,j]","
	365	print "};\n"
	366	# print group opcode map's array
	367	print "/* Group opcode map array */"
	368	print "const insn_attr_t const *inat_group_tables[INAT_GRP_MAX + 1]"\
04d46c1b	369	"[INAT_LSTPFX_MAX + 1] = {"
eb13296c MH	370	for (i = 0; i < ggid; i++)
	371	for (j = 0; j < max_lprefix; j++)
	372	if (gtable[i,j])
	373	print " ["i"]["j"] = "gtable[i,j]","
e0e492e9 MH	374	print "};\n"
	375	# print AVX opcode map's array
	376	print "/* AVX opcode map array */"
	377	print "const insn_attr_t const *inat_avx_tables[X86_VEX_M_MAX + 1]"\
	378	"[INAT_LSTPFX_MAX + 1] = {"
	379	for (i = 0; i < gaid; i++)
	380	for (j = 0; j < max_lprefix; j++)
	381	if (atable[i,j])
	382	print " ["i"]["j"] = "atable[i,j]","
eb13296c MH	383	print "};"
eb13296c MH	384	}
e0e492e9	385