[deliverable/linux.git] / arch / x86_64 / kernel / head.S

/*
 *  linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
 *
 *  Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
 *  Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
 *  Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
 *  Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
 *
 *  $Id: head.S,v 1.49 2002/03/19 17:39:25 ak Exp $
 */


#include <linux/linkage.h>
#include <linux/threads.h>
#include <linux/init.h>
#include <asm/desc.h>
#include <asm/segment.h>
#include <asm/page.h>
#include <asm/msr.h>
#include <asm/cache.h>
	
/* we are not able to switch in one step to the final KERNEL ADRESS SPACE
 * because we need identity-mapped pages on setup so define __START_KERNEL to
 * 0x100000 for this stage
 * 
 */

	.text
	.section .bootstrap.text
	.code32
	.globl startup_32
/* %bx:	 1 if coming from smp trampoline on secondary cpu */ 
startup_32:
	
	/*
	 * At this point the CPU runs in 32bit protected mode (CS.D = 1) with
	 * paging disabled and the point of this file is to switch to 64bit
	 * long mode with a kernel mapping for kerneland to jump into the
	 * kernel virtual addresses.
 	 * There is no stack until we set one up.
	 */

	/* Initialize the %ds segment register */
	movl $__KERNEL_DS,%eax
	movl %eax,%ds

	/* Load new GDT with the 64bit segments using 32bit descriptor */
	lgdt	pGDT32 - __START_KERNEL_map

	/* If the CPU doesn't support CPUID this will double fault.
	 * Unfortunately it is hard to check for CPUID without a stack. 
	 */
	
	/* Check if extended functions are implemented */		
	movl	$0x80000000, %eax
	cpuid
	cmpl	$0x80000000, %eax
	jbe	no_long_mode
	/* Check if long mode is implemented */
	mov	$0x80000001, %eax
	cpuid
	btl	$29, %edx
	jnc	no_long_mode

	/*
	 * Prepare for entering 64bits mode
	 */

	/* Enable PAE mode */
	xorl	%eax, %eax
	btsl	$5, %eax
	movl	%eax, %cr4

	/* Setup early boot stage 4 level pagetables */
	movl	$(boot_level4_pgt - __START_KERNEL_map), %eax
	movl	%eax, %cr3

	/* Setup EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr

	/* Enable Long Mode */
	btsl	$_EFER_LME, %eax
				
	/* Make changes effective */
	wrmsr

	xorl	%eax, %eax
	btsl	$31, %eax			/* Enable paging and in turn activate Long Mode */
	btsl	$0, %eax			/* Enable protected mode */
	/* Make changes effective */
	movl	%eax, %cr0
	/*
	 * At this point we're in long mode but in 32bit compatibility mode
	 * with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
	 * EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
	 * the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	 */
	ljmp	$__KERNEL_CS, $(startup_64 - __START_KERNEL_map)

	.code64
	.org 0x100	
	.globl startup_64
startup_64:
	/* We come here either from startup_32
	 * or directly from a 64bit bootloader.
	 * Since we may have come directly from a bootloader we
	 * reload the page tables here.
	 */

	/* Enable PAE mode and PGE */
	xorq	%rax, %rax
	btsq	$5, %rax
	btsq	$7, %rax
	movq	%rax, %cr4

	/* Setup early boot stage 4 level pagetables. */
	movq	$(boot_level4_pgt - __START_KERNEL_map), %rax
	movq	%rax, %cr3

	/* Check if nx is implemented */
	movl	$0x80000001, %eax
	cpuid
	movl	%edx,%edi

	/* Setup EFER (Extended Feature Enable Register) */
	movl	$MSR_EFER, %ecx
	rdmsr

	/* Enable System Call */
	btsl	$_EFER_SCE, %eax

	/* No Execute supported? */
	btl	$20,%edi
	jnc     1f
	btsl	$_EFER_NX, %eax
1:
	/* Make changes effective */
	wrmsr

	/* Setup cr0 */
#define CR0_PM				1		/* protected mode */
#define CR0_MP				(1<<1)
#define CR0_ET				(1<<4)
#define CR0_NE				(1<<5)
#define CR0_WP				(1<<16)
#define CR0_AM				(1<<18)
#define CR0_PAGING 			(1<<31)
	movl $CR0_PM|CR0_MP|CR0_ET|CR0_NE|CR0_WP|CR0_AM|CR0_PAGING,%eax
	/* Make changes effective */
	movq	%rax, %cr0

	/* Setup a boot time stack */
	movq init_rsp(%rip),%rsp

	/* zero EFLAGS after setting rsp */
	pushq $0
	popfq

	/*
	 * We must switch to a new descriptor in kernel space for the GDT
	 * because soon the kernel won't have access anymore to the userspace
	 * addresses where we're currently running on. We have to do that here
	 * because in 32bit we couldn't load a 64bit linear address.
	 */
	lgdt	cpu_gdt_descr

	/* 
	 * Setup up a dummy PDA. this is just for some early bootup code
	 * that does in_interrupt() 
	 */ 
	movl	$MSR_GS_BASE,%ecx
	movq	$empty_zero_page,%rax
	movq    %rax,%rdx
	shrq	$32,%rdx
	wrmsr	

	/* set up data segments. actually 0 would do too */
	movl $__KERNEL_DS,%eax
	movl %eax,%ds	
	movl %eax,%ss
	movl %eax,%es
			
	/* esi is pointer to real mode structure with interesting info.
	   pass it to C */
	movl	%esi, %edi
	
	/* Finally jump to run C code and to be on real kernel address
	 * Since we are running on identity-mapped space we have to jump
	 * to the full 64bit address , this is only possible as indirect
	 * jump
	 */
	movq	initial_code(%rip),%rax
	pushq	$0		# fake return address
	jmp	*%rax

	/* SMP bootup changes these two */
	.align	8
	.globl	initial_code
initial_code:
	.quad	x86_64_start_kernel
	.globl init_rsp
init_rsp:
	.quad  init_thread_union+THREAD_SIZE-8

ENTRY(early_idt_handler)
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	incl early_recursion_flag(%rip)
	xorl %eax,%eax
	movq 8(%rsp),%rsi	# get rip
	movq (%rsp),%rdx
	movq %cr2,%rcx
	leaq early_idt_msg(%rip),%rdi
	call early_printk
	cmpl $2,early_recursion_flag(%rip)
	jz  1f
	call dump_stack
#ifdef CONFIG_KALLSYMS	
	leaq early_idt_ripmsg(%rip),%rdi
	movq 8(%rsp),%rsi	# get rip again
	call __print_symbol
#endif
1:	hlt
	jmp 1b
early_recursion_flag:
	.long 0

early_idt_msg:
	.asciz "PANIC: early exception rip %lx error %lx cr2 %lx\n"
early_idt_ripmsg:
	.asciz "RIP %s\n"

.code32
ENTRY(no_long_mode)
	/* This isn't an x86-64 CPU so hang */
1:
	jmp	1b

.org 0xf00
	.globl pGDT32
pGDT32:
	.word	gdt_end-cpu_gdt_table-1
	.long	cpu_gdt_table-__START_KERNEL_map

.org 0xf10	
ljumpvector:
	.long	startup_64-__START_KERNEL_map
	.word	__KERNEL_CS

ENTRY(stext)
ENTRY(_stext)

	$page = 0
#define NEXT_PAGE(name) \
	$page = $page + 1; \
	.org $page * 0x1000; \
	phys_/**/name = $page * 0x1000 + __PHYSICAL_START; \
ENTRY(name)

NEXT_PAGE(init_level4_pgt)
	/* This gets initialized in x86_64_start_kernel */
	.fill	512,8,0

NEXT_PAGE(level3_ident_pgt)
	.quad	phys_level2_ident_pgt | 0x007
	.fill	511,8,0

NEXT_PAGE(level3_kernel_pgt)
	.fill	510,8,0
	/* (2^48-(2*1024*1024*1024)-((2^39)*511))/(2^30) = 510 */
	.quad	phys_level2_kernel_pgt | 0x007
	.fill	1,8,0

NEXT_PAGE(level2_ident_pgt)
	/* 40MB for bootup. 	*/
	i = 0
	.rept 20
	.quad	i << 21 | 0x083
	i = i + 1
	.endr
	/* Temporary mappings for the super early allocator in arch/x86_64/mm/init.c */
	.globl temp_boot_pmds
temp_boot_pmds:
	.fill	492,8,0
	
NEXT_PAGE(level2_kernel_pgt)
	/* 40MB kernel mapping. The kernel code cannot be bigger than that.
	   When you change this change KERNEL_TEXT_SIZE in page.h too. */
	/* (2^48-(2*1024*1024*1024)-((2^39)*511)-((2^30)*510)) = 0 */
	i = 0
	.rept 20
	.quad	i << 21 | 0x183
	i = i + 1
	.endr
	/* Module mapping starts here */
	.fill	492,8,0

NEXT_PAGE(level3_physmem_pgt)
	.quad	phys_level2_kernel_pgt | 0x007	/* so that __va works even before pagetable_init */
	.fill	511,8,0

#undef NEXT_PAGE

	.data

#ifdef CONFIG_ACPI_SLEEP
	.align PAGE_SIZE
ENTRY(wakeup_level4_pgt)
	.quad	phys_level3_ident_pgt | 0x007
	.fill	255,8,0
	.quad	phys_level3_physmem_pgt | 0x007
	.fill	254,8,0
	/* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
	.quad	phys_level3_kernel_pgt | 0x007
#endif

#ifndef CONFIG_HOTPLUG_CPU
	__INITDATA
#endif
	/*
	 * This default setting generates an ident mapping at address 0x100000
	 * and a mapping for the kernel that precisely maps virtual address
	 * 0xffffffff80000000 to physical address 0x000000. (always using
	 * 2Mbyte large pages provided by PAE mode)
	 */
	.align PAGE_SIZE
ENTRY(boot_level4_pgt)
	.quad	phys_level3_ident_pgt | 0x007
	.fill	255,8,0
	.quad	phys_level3_physmem_pgt | 0x007
	.fill	254,8,0
	/* (2^48-(2*1024*1024*1024))/(2^39) = 511 */
	.quad	phys_level3_kernel_pgt | 0x007

	.data

	.align 16
	.globl cpu_gdt_descr
cpu_gdt_descr:
	.word	gdt_end-cpu_gdt_table-1
gdt:
	.quad	cpu_gdt_table
#ifdef CONFIG_SMP
	.rept	NR_CPUS-1
	.word	0
	.quad	0
	.endr
#endif

/* We need valid kernel segments for data and code in long mode too
 * IRET will check the segment types  kkeil 2000/10/28
 * Also sysret mandates a special GDT layout 
 */
		 		
	.section .data.page_aligned, "aw"
	.align PAGE_SIZE

/* The TLS descriptors are currently at a different place compared to i386.
   Hopefully nobody expects them at a fixed place (Wine?) */
	
ENTRY(cpu_gdt_table)
	.quad	0x0000000000000000	/* NULL descriptor */
	.quad	0x0			/* unused */
	.quad	0x00af9a000000ffff	/* __KERNEL_CS */
	.quad	0x00cf92000000ffff	/* __KERNEL_DS */
	.quad	0x00cffa000000ffff	/* __USER32_CS */
	.quad	0x00cff2000000ffff	/* __USER_DS, __USER32_DS  */		
	.quad	0x00affa000000ffff	/* __USER_CS */
	.quad	0x00cf9a000000ffff	/* __KERNEL32_CS */
	.quad	0,0			/* TSS */
	.quad	0,0			/* LDT */
	.quad   0,0,0			/* three TLS descriptors */ 
	.quad	0			/* unused */
gdt_end:	
	/* asm/segment.h:GDT_ENTRIES must match this */	
	/* This should be a multiple of the cache line size */
	/* GDTs of other CPUs are now dynamically allocated */

	/* zero the remaining page */
	.fill PAGE_SIZE / 8 - GDT_ENTRIES,8,0

	.section .bss, "aw", @nobits
	.align L1_CACHE_BYTES
ENTRY(idt_table)
	.skip 256 * 16

	.section .bss.page_aligned, "aw", @nobits
	.align PAGE_SIZE
ENTRY(empty_zero_page)
	.skip PAGE_SIZE
Commit	Line	Data
1da177e4 LT	1	/*
	2	* linux/arch/x86_64/kernel/head.S -- start in 32bit and switch to 64bit
	3	*
	4	* Copyright (C) 2000 Andrea Arcangeli <andrea@suse.de> SuSE
	5	* Copyright (C) 2000 Pavel Machek <pavel@suse.cz>
	6	* Copyright (C) 2000 Karsten Keil <kkeil@suse.de>
	7	* Copyright (C) 2001,2002 Andi Kleen <ak@suse.de>
	8	*
	9	* $Id: head.S,v 1.49 2002/03/19 17:39:25 ak Exp $
	10	*/
	11
	12
	13	#include <linux/linkage.h>
	14	#include <linux/threads.h>
f6c2e333	15	#include <linux/init.h>
1da177e4 LT	16	#include <asm/desc.h>
	17	#include <asm/segment.h>
	18	#include <asm/page.h>
	19	#include <asm/msr.h>
	20	#include <asm/cache.h>
	21
	22	/* we are not able to switch in one step to the final KERNEL ADRESS SPACE
	23	* because we need identity-mapped pages on setup so define __START_KERNEL to
	24	* 0x100000 for this stage
	25	*
	26	*/
	27
	28	.text
eaeae0cc	29	.section .bootstrap.text
1da177e4 LT	30	.code32
	31	.globl startup_32
	32	/* %bx: 1 if coming from smp trampoline on secondary cpu */
	33	startup_32:
	34
	35	/*
	36	* At this point the CPU runs in 32bit protected mode (CS.D = 1) with
	37	* paging disabled and the point of this file is to switch to 64bit
	38	* long mode with a kernel mapping for kerneland to jump into the
	39	* kernel virtual addresses.
	40	* There is no stack until we set one up.
	41	*/
	42
	43	/* Initialize the %ds segment register */
	44	movl $__KERNEL_DS,%eax
	45	movl %eax,%ds
	46
	47	/* Load new GDT with the 64bit segments using 32bit descriptor */
	48	lgdt pGDT32 - __START_KERNEL_map
	49
	50	/* If the CPU doesn't support CPUID this will double fault.
	51	* Unfortunately it is hard to check for CPUID without a stack.
	52	*/
	53
	54	/* Check if extended functions are implemented */
	55	movl $0x80000000, %eax
	56	cpuid
	57	cmpl $0x80000000, %eax
	58	jbe no_long_mode
	59	/* Check if long mode is implemented */
	60	mov $0x80000001, %eax
	61	cpuid
	62	btl $29, %edx
	63	jnc no_long_mode
	64
	65	/*
	66	* Prepare for entering 64bits mode
	67	*/
	68
	69	/* Enable PAE mode */
	70	xorl %eax, %eax
	71	btsl $5, %eax
	72	movl %eax, %cr4
	73
	74	/* Setup early boot stage 4 level pagetables */
f6c2e333	75	movl $(boot_level4_pgt - __START_KERNEL_map), %eax
1da177e4 LT	76	movl %eax, %cr3
	77
	78	/* Setup EFER (Extended Feature Enable Register) */
	79	movl $MSR_EFER, %ecx
	80	rdmsr
	81
	82	/* Enable Long Mode */
	83	btsl $_EFER_LME, %eax
	84
	85	/* Make changes effective */
	86	wrmsr
	87
	88	xorl %eax, %eax
	89	btsl $31, %eax /* Enable paging and in turn activate Long Mode */
	90	btsl $0, %eax /* Enable protected mode */
	91	/* Make changes effective */
	92	movl %eax, %cr0
	93	/*
	94	* At this point we're in long mode but in 32bit compatibility mode
	95	* with EFER.LME = 1, CS.L = 0, CS.D = 1 (and in turn
	96	* EFER.LMA = 1). Now we want to jump in 64bit mode, to do that we use
	97	* the new gdt/idt that has __KERNEL_CS with CS.L = 1.
	98	*/
	99	ljmp $__KERNEL_CS, $(startup_64 - __START_KERNEL_map)
	100
	101	.code64
	102	.org 0x100
	103	.globl startup_64
	104	startup_64:
	105	/* We come here either from startup_32
	106	* or directly from a 64bit bootloader.
	107	* Since we may have come directly from a bootloader we
	108	* reload the page tables here.
	109	*/
	110
	111	/* Enable PAE mode and PGE */
	112	xorq %rax, %rax
	113	btsq $5, %rax
	114	btsq $7, %rax
	115	movq %rax, %cr4
	116
	117	/* Setup early boot stage 4 level pagetables. */
f6c2e333	118	movq $(boot_level4_pgt - __START_KERNEL_map), %rax
1da177e4 LT	119	movq %rax, %cr3
	120
	121	/* Check if nx is implemented */
	122	movl $0x80000001, %eax
	123	cpuid
	124	movl %edx,%edi
	125
	126	/* Setup EFER (Extended Feature Enable Register) */
	127	movl $MSR_EFER, %ecx
	128	rdmsr
	129
	130	/* Enable System Call */
	131	btsl $_EFER_SCE, %eax
	132
	133	/* No Execute supported? */
	134	btl $20,%edi
	135	jnc 1f
	136	btsl $_EFER_NX, %eax
	137	1:
	138	/* Make changes effective */
	139	wrmsr
	140
	141	/* Setup cr0 */
3829ee6b AK	142	#define CR0_PM 1 /* protected mode */
	143	#define CR0_MP (1<<1)
	144	#define CR0_ET (1<<4)
	145	#define CR0_NE (1<<5)
	146	#define CR0_WP (1<<16)
	147	#define CR0_AM (1<<18)
	148	#define CR0_PAGING (1<<31)
	149	movl $CR0_PM\|CR0_MP\|CR0_ET\|CR0_NE\|CR0_WP\|CR0_AM\|CR0_PAGING,%eax
1da177e4 LT	150	/* Make changes effective */
	151	movq %rax, %cr0
	152
	153	/* Setup a boot time stack */
	154	movq init_rsp(%rip),%rsp
	155
	156	/* zero EFLAGS after setting rsp */
	157	pushq $0
	158	popfq
	159
	160	/*
	161	* We must switch to a new descriptor in kernel space for the GDT
	162	* because soon the kernel won't have access anymore to the userspace
	163	* addresses where we're currently running on. We have to do that here
	164	* because in 32bit we couldn't load a 64bit linear address.
	165	*/
	166	lgdt cpu_gdt_descr
	167
	168	/*
	169	* Setup up a dummy PDA. this is just for some early bootup code
	170	* that does in_interrupt()
	171	*/
	172	movl $MSR_GS_BASE,%ecx
	173	movq $empty_zero_page,%rax
	174	movq %rax,%rdx
	175	shrq $32,%rdx
	176	wrmsr
	177
	178	/* set up data segments. actually 0 would do too */
	179	movl $__KERNEL_DS,%eax
	180	movl %eax,%ds
	181	movl %eax,%ss
	182	movl %eax,%es
	183
	184	/* esi is pointer to real mode structure with interesting info.
	185	pass it to C */
	186	movl %esi, %edi
	187
	188	/* Finally jump to run C code and to be on real kernel address
	189	* Since we are running on identity-mapped space we have to jump
	190	* to the full 64bit address , this is only possible as indirect
	191	* jump
	192	*/
	193	movq initial_code(%rip),%rax
c05991ed	194	pushq $0 # fake return address
1da177e4 LT	195	jmp *%rax
1da177e4 LT	196
e57113bc JB	197	/* SMP bootup changes these two */
e57113bc JB	198	.align 8
1da177e4 LT	199	.globl initial_code
	200	initial_code:
	201	.quad x86_64_start_kernel
	202	.globl init_rsp
	203	init_rsp:
	204	.quad init_thread_union+THREAD_SIZE-8
	205
	206	ENTRY(early_idt_handler)
b957591f AK	207	cmpl $2,early_recursion_flag(%rip)
	208	jz 1f
	209	incl early_recursion_flag(%rip)
1da177e4 LT	210	xorl %eax,%eax
	211	movq 8(%rsp),%rsi # get rip
	212	movq (%rsp),%rdx
	213	movq %cr2,%rcx
	214	leaq early_idt_msg(%rip),%rdi
	215	call early_printk
b957591f AK	216	cmpl $2,early_recursion_flag(%rip)
	217	jz 1f
	218	call dump_stack
6574ffd7 AK	219	#ifdef CONFIG_KALLSYMS
	220	leaq early_idt_ripmsg(%rip),%rdi
	221	movq 8(%rsp),%rsi # get rip again
	222	call __print_symbol
	223	#endif
1da177e4 LT	224	1: hlt
1da177e4 LT	225	jmp 1b
b957591f AK	226	early_recursion_flag:
b957591f AK	227	.long 0
1da177e4 LT	228
	229	early_idt_msg:
	230	.asciz "PANIC: early exception rip %lx error %lx cr2 %lx\n"
6574ffd7 AK	231	early_idt_ripmsg:
6574ffd7 AK	232	.asciz "RIP %s\n"
1da177e4 LT	233
	234	.code32
	235	ENTRY(no_long_mode)
	236	/* This isn't an x86-64 CPU so hang */
	237	1:
	238	jmp 1b
	239
	240	.org 0xf00
	241	.globl pGDT32
	242	pGDT32:
e57113bc	243	.word gdt_end-cpu_gdt_table-1
1da177e4 LT	244	.long cpu_gdt_table-__START_KERNEL_map
	245
	246	.org 0xf10
	247	ljumpvector:
	248	.long startup_64-__START_KERNEL_map
	249	.word __KERNEL_CS
	250
	251	ENTRY(stext)
	252	ENTRY(_stext)
	253
f0cf5d1a JB	254	$page = 0
	255	#define NEXT_PAGE(name) \
	256	$page = $page + 1; \
	257	.org $page * 0x1000; \
	258	phys_/*/name = $page 0x1000 + __PHYSICAL_START; \
	259	ENTRY(name)
	260
	261	NEXT_PAGE(init_level4_pgt)
f6c2e333 SS	262	/* This gets initialized in x86_64_start_kernel */
f6c2e333 SS	263	.fill 512,8,0
1da177e4	264
f0cf5d1a JB	265	NEXT_PAGE(level3_ident_pgt)
f0cf5d1a JB	266	.quad phys_level2_ident_pgt \| 0x007
1da177e4 LT	267	.fill 511,8,0
1da177e4 LT	268
f0cf5d1a	269	NEXT_PAGE(level3_kernel_pgt)
1da177e4 LT	270	.fill 510,8,0
1da177e4 LT	271	/* (2^48-(2102410241024)-((2^39)511))/(2^30) = 510 */
f0cf5d1a	272	.quad phys_level2_kernel_pgt \| 0x007
1da177e4 LT	273	.fill 1,8,0
1da177e4 LT	274
f0cf5d1a	275	NEXT_PAGE(level2_ident_pgt)
1da177e4	276	/* 40MB for bootup. */
f0cf5d1a JB	277	i = 0
	278	.rept 20
	279	.quad i << 21 \| 0x083
	280	i = i + 1
	281	.endr
1da177e4 LT	282	/* Temporary mappings for the super early allocator in arch/x86_64/mm/init.c */
	283	.globl temp_boot_pmds
	284	temp_boot_pmds:
	285	.fill 492,8,0
	286
f0cf5d1a	287	NEXT_PAGE(level2_kernel_pgt)
1da177e4 LT	288	/* 40MB kernel mapping. The kernel code cannot be bigger than that.
	289	When you change this change KERNEL_TEXT_SIZE in page.h too. */
	290	/* (2^48-(2102410241024)-((2^39)511)-((2^30)510)) = 0 /
f0cf5d1a JB	291	i = 0
	292	.rept 20
	293	.quad i << 21 \| 0x183
	294	i = i + 1
	295	.endr
1da177e4 LT	296	/* Module mapping starts here */
	297	.fill 492,8,0
	298
f0cf5d1a JB	299	NEXT_PAGE(level3_physmem_pgt)
	300	.quad phys_level2_kernel_pgt \| 0x007 /* so that __va works even before pagetable_init */
	301	.fill 511,8,0
1da177e4	302
f0cf5d1a	303	#undef NEXT_PAGE
1da177e4	304
f0cf5d1a	305	.data
1da177e4	306
1da177e4	307	#ifdef CONFIG_ACPI_SLEEP
f0cf5d1a	308	.align PAGE_SIZE
1da177e4	309	ENTRY(wakeup_level4_pgt)
f0cf5d1a	310	.quad phys_level3_ident_pgt \| 0x007
1da177e4	311	.fill 255,8,0
f0cf5d1a	312	.quad phys_level3_physmem_pgt \| 0x007
1da177e4 LT	313	.fill 254,8,0
1da177e4 LT	314	/* (2^48-(2102410241024))/(2^39) = 511 /
f0cf5d1a	315	.quad phys_level3_kernel_pgt \| 0x007
1da177e4 LT	316	#endif
1da177e4 LT	317
f6c2e333 SS	318	#ifndef CONFIG_HOTPLUG_CPU
	319	__INITDATA
	320	#endif
	321	/*
	322	* This default setting generates an ident mapping at address 0x100000
	323	* and a mapping for the kernel that precisely maps virtual address
	324	* 0xffffffff80000000 to physical address 0x000000. (always using
	325	* 2Mbyte large pages provided by PAE mode)
	326	*/
	327	.align PAGE_SIZE
	328	ENTRY(boot_level4_pgt)
f0cf5d1a	329	.quad phys_level3_ident_pgt \| 0x007
f6c2e333	330	.fill 255,8,0
f0cf5d1a	331	.quad phys_level3_physmem_pgt \| 0x007
f6c2e333 SS	332	.fill 254,8,0
f6c2e333 SS	333	/* (2^48-(2102410241024))/(2^39) = 511 /
f0cf5d1a	334	.quad phys_level3_kernel_pgt \| 0x007
f6c2e333	335
1da177e4 LT	336	.data
	337
	338	.align 16
	339	.globl cpu_gdt_descr
	340	cpu_gdt_descr:
e57113bc	341	.word gdt_end-cpu_gdt_table-1
1da177e4 LT	342	gdt:
	343	.quad cpu_gdt_table
	344	#ifdef CONFIG_SMP
	345	.rept NR_CPUS-1
	346	.word 0
	347	.quad 0
	348	.endr
	349	#endif
	350
	351	/* We need valid kernel segments for data and code in long mode too
	352	* IRET will check the segment types kkeil 2000/10/28
	353	* Also sysret mandates a special GDT layout
	354	*/
	355
e57113bc JB	356	.section .data.page_aligned, "aw"
e57113bc JB	357	.align PAGE_SIZE
1da177e4 LT	358
	359	/* The TLS descriptors are currently at a different place compared to i386.
	360	Hopefully nobody expects them at a fixed place (Wine?) */
	361
	362	ENTRY(cpu_gdt_table)
	363	.quad 0x0000000000000000 /* NULL descriptor */
cdc4b9c0	364	.quad 0x0 /* unused */
1da177e4 LT	365	.quad 0x00af9a000000ffff /* __KERNEL_CS */
	366	.quad 0x00cf92000000ffff /* __KERNEL_DS */
	367	.quad 0x00cffa000000ffff /* __USER32_CS */
	368	.quad 0x00cff2000000ffff /* __USER_DS, __USER32_DS */
	369	.quad 0x00affa000000ffff /* __USER_CS */
	370	.quad 0x00cf9a000000ffff /* __KERNEL32_CS */
	371	.quad 0,0 /* TSS */
	372	.quad 0,0 /* LDT */
	373	.quad 0,0,0 /* three TLS descriptors */
cdc4b9c0	374	.quad 0 /* unused */
1da177e4 LT	375	gdt_end:
	376	/* asm/segment.h:GDT_ENTRIES must match this */
	377	/* This should be a multiple of the cache line size */
c11efdf9 RT	378	/* GDTs of other CPUs are now dynamically allocated */
	379
	380	/* zero the remaining page */
	381	.fill PAGE_SIZE / 8 - GDT_ENTRIES,8,0
1da177e4	382
e57113bc JB	383	.section .bss, "aw", @nobits
	384	.align L1_CACHE_BYTES
	385	ENTRY(idt_table)
	386	.skip 256 * 16
1da177e4	387
e57113bc JB	388	.section .bss.page_aligned, "aw", @nobits
	389	.align PAGE_SIZE
	390	ENTRY(empty_zero_page)
	391	.skip PAGE_SIZE