[deliverable/linux.git] / arch / x86_64 / lib / getuser.S

/*
 * __get_user functions.
 *
 * (C) Copyright 1998 Linus Torvalds
 * (C) Copyright 2005 Andi Kleen
 *
 * These functions have a non-standard call interface
 * to make them more efficient, especially as they
 * return an error value in addition to the "real"
 * return value.
 */

/*
 * __get_user_X
 *
 * Inputs:	%rcx contains the address.
 *		The register is modified, but all changes are undone
 *		before returning because the C code doesn't know about it.
 *
 * Outputs:	%rax is error code (0 or -EFAULT)
 *		%rdx contains zero-extended value
 * 
 * %r8 is destroyed.
 *
 * These functions should not modify any other registers,
 * as they get called from within inline assembly.
 */

#include <linux/linkage.h>
#include <asm/dwarf2.h>
#include <asm/page.h>
#include <asm/errno.h>
#include <asm/asm-offsets.h>
#include <asm/thread_info.h>

	.text
ENTRY(__get_user_1)
	CFI_STARTPROC
	GET_THREAD_INFO(%r8)
	cmpq threadinfo_addr_limit(%r8),%rcx
	jae bad_get_user
1:	movzb (%rcx),%edx
	xorl %eax,%eax
	ret
	CFI_ENDPROC
ENDPROC(__get_user_1)

ENTRY(__get_user_2)
	CFI_STARTPROC
	GET_THREAD_INFO(%r8)
	addq $1,%rcx
	jc 20f
	cmpq threadinfo_addr_limit(%r8),%rcx
	jae 20f
	decq   %rcx
2:	movzwl (%rcx),%edx
	xorl %eax,%eax
	ret
20:	decq    %rcx
	jmp	bad_get_user
	CFI_ENDPROC
ENDPROC(__get_user_2)

ENTRY(__get_user_4)
	CFI_STARTPROC
	GET_THREAD_INFO(%r8)
	addq $3,%rcx
	jc 30f
	cmpq threadinfo_addr_limit(%r8),%rcx
	jae 30f
	subq $3,%rcx
3:	movl (%rcx),%edx
	xorl %eax,%eax
	ret
30:	subq $3,%rcx
	jmp bad_get_user
	CFI_ENDPROC
ENDPROC(__get_user_4)

ENTRY(__get_user_8)
	CFI_STARTPROC
	GET_THREAD_INFO(%r8)
	addq $7,%rcx
	jc 40f
	cmpq threadinfo_addr_limit(%r8),%rcx
	jae	40f
	subq	$7,%rcx
4:	movq (%rcx),%rdx
	xorl %eax,%eax
	ret
40:	subq $7,%rcx
	jmp bad_get_user
	CFI_ENDPROC
ENDPROC(__get_user_8)

bad_get_user:
	CFI_STARTPROC
	xorl %edx,%edx
	movq $(-EFAULT),%rax
	ret
	CFI_ENDPROC
END(bad_get_user)

.section __ex_table,"a"
	.quad 1b,bad_get_user
	.quad 2b,bad_get_user
	.quad 3b,bad_get_user
	.quad 4b,bad_get_user
.previous
Commit	Line	Data
1da177e4 LT	1	/*
	2	* __get_user functions.
	3	*
	4	* (C) Copyright 1998 Linus Torvalds
	5	* (C) Copyright 2005 Andi Kleen
	6	*
	7	* These functions have a non-standard call interface
	8	* to make them more efficient, especially as they
	9	* return an error value in addition to the "real"
	10	* return value.
	11	*/
	12
	13	/*
	14	* __get_user_X
	15	*
	16	* Inputs: %rcx contains the address.
	17	* The register is modified, but all changes are undone
	18	* before returning because the C code doesn't know about it.
	19	*
	20	* Outputs: %rax is error code (0 or -EFAULT)
	21	* %rdx contains zero-extended value
	22	*
	23	* %r8 is destroyed.
	24	*
	25	* These functions should not modify any other registers,
	26	* as they get called from within inline assembly.
	27	*/
	28
	29	#include <linux/linkage.h>
8d379dad	30	#include <asm/dwarf2.h>
1da177e4 LT	31	#include <asm/page.h>
1da177e4 LT	32	#include <asm/errno.h>
e2d5df93	33	#include <asm/asm-offsets.h>
1da177e4 LT	34	#include <asm/thread_info.h>
	35
	36	.text
8d379dad JB	37	ENTRY(__get_user_1)
8d379dad JB	38	CFI_STARTPROC
1da177e4 LT	39	GET_THREAD_INFO(%r8)
	40	cmpq threadinfo_addr_limit(%r8),%rcx
	41	jae bad_get_user
	42	1: movzb (%rcx),%edx
	43	xorl %eax,%eax
	44	ret
8d379dad JB	45	CFI_ENDPROC
8d379dad JB	46	ENDPROC(__get_user_1)
1da177e4	47
8d379dad JB	48	ENTRY(__get_user_2)
8d379dad JB	49	CFI_STARTPROC
1da177e4 LT	50	GET_THREAD_INFO(%r8)
	51	addq $1,%rcx
	52	jc 20f
	53	cmpq threadinfo_addr_limit(%r8),%rcx
	54	jae 20f
	55	decq %rcx
	56	2: movzwl (%rcx),%edx
	57	xorl %eax,%eax
	58	ret
	59	20: decq %rcx
	60	jmp bad_get_user
8d379dad JB	61	CFI_ENDPROC
8d379dad JB	62	ENDPROC(__get_user_2)
1da177e4	63
8d379dad JB	64	ENTRY(__get_user_4)
8d379dad JB	65	CFI_STARTPROC
1da177e4 LT	66	GET_THREAD_INFO(%r8)
	67	addq $3,%rcx
	68	jc 30f
	69	cmpq threadinfo_addr_limit(%r8),%rcx
	70	jae 30f
	71	subq $3,%rcx
	72	3: movl (%rcx),%edx
	73	xorl %eax,%eax
	74	ret
	75	30: subq $3,%rcx
	76	jmp bad_get_user
8d379dad JB	77	CFI_ENDPROC
8d379dad JB	78	ENDPROC(__get_user_4)
1da177e4	79
8d379dad JB	80	ENTRY(__get_user_8)
8d379dad JB	81	CFI_STARTPROC
1da177e4 LT	82	GET_THREAD_INFO(%r8)
1da177e4 LT	83	addq $7,%rcx
3a6fd752	84	jc 40f
1da177e4	85	cmpq threadinfo_addr_limit(%r8),%rcx
3a6fd752	86	jae 40f
1da177e4 LT	87	subq $7,%rcx
	88	4: movq (%rcx),%rdx
	89	xorl %eax,%eax
	90	ret
	91	40: subq $7,%rcx
	92	jmp bad_get_user
8d379dad JB	93	CFI_ENDPROC
8d379dad JB	94	ENDPROC(__get_user_8)
1da177e4 LT	95
1da177e4 LT	96	bad_get_user:
8d379dad	97	CFI_STARTPROC
1da177e4 LT	98	xorl %edx,%edx
	99	movq $(-EFAULT),%rax
	100	ret
8d379dad JB	101	CFI_ENDPROC
8d379dad JB	102	END(bad_get_user)
1da177e4 LT	103
	104	.section __ex_table,"a"
	105	.quad 1b,bad_get_user
	106	.quad 2b,bad_get_user
	107	.quad 3b,bad_get_user
	108	.quad 4b,bad_get_user
	109	.previous