[deliverable/linux.git] / include / asm-generic / vmlinux.lds.h

#include <linux/section-names.h>

#ifndef LOAD_OFFSET
#define LOAD_OFFSET 0
#endif

#ifndef VMLINUX_SYMBOL
#define VMLINUX_SYMBOL(_sym_) _sym_
#endif

/* Align . to a 8 byte boundary equals to maximum function alignment. */
#define ALIGN_FUNCTION()  . = ALIGN(8)

/* The actual configuration determine if the init/exit sections
 * are handled as text/data or they can be discarded (which
 * often happens at runtime)
 */
#ifdef CONFIG_HOTPLUG
#define DEV_KEEP(sec)    *(.dev##sec)
#define DEV_DISCARD(sec)
#else
#define DEV_KEEP(sec)
#define DEV_DISCARD(sec) *(.dev##sec)
#endif

#ifdef CONFIG_HOTPLUG_CPU
#define CPU_KEEP(sec)    *(.cpu##sec)
#define CPU_DISCARD(sec)
#else
#define CPU_KEEP(sec)
#define CPU_DISCARD(sec) *(.cpu##sec)
#endif

#if defined(CONFIG_MEMORY_HOTPLUG)
#define MEM_KEEP(sec)    *(.mem##sec)
#define MEM_DISCARD(sec)
#else
#define MEM_KEEP(sec)
#define MEM_DISCARD(sec) *(.mem##sec)
#endif

#ifdef CONFIG_FTRACE_MCOUNT_RECORD
#define MCOUNT_REC()	VMLINUX_SYMBOL(__start_mcount_loc) = .; \
			*(__mcount_loc)				\
			VMLINUX_SYMBOL(__stop_mcount_loc) = .;
#else
#define MCOUNT_REC()
#endif

#ifdef CONFIG_TRACE_BRANCH_PROFILING
#define LIKELY_PROFILE()	VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
				*(_ftrace_annotated_branch)			      \
				VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
#else
#define LIKELY_PROFILE()
#endif

#ifdef CONFIG_PROFILE_ALL_BRANCHES
#define BRANCH_PROFILE()	VMLINUX_SYMBOL(__start_branch_profile) = .;   \
				*(_ftrace_branch)			      \
				VMLINUX_SYMBOL(__stop_branch_profile) = .;
#else
#define BRANCH_PROFILE()
#endif

#ifdef CONFIG_EVENT_TRACER
#define FTRACE_EVENTS()	VMLINUX_SYMBOL(__start_ftrace_events) = .;	\
			*(_ftrace_events)				\
			VMLINUX_SYMBOL(__stop_ftrace_events) = .;
#else
#define FTRACE_EVENTS()
#endif

#ifdef CONFIG_TRACING
#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .;      \
			 *(__trace_printk_fmt) /* Trace_printk fmt' pointer */ \
			 VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
#else
#define TRACE_PRINTKS()
#endif

#ifdef CONFIG_FTRACE_SYSCALLS
#define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .;	\
			 *(__syscalls_metadata)				\
			 VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
#else
#define TRACE_SYSCALLS()
#endif

/* .data section */
#define DATA_DATA							\
	*(.data)							\
	*(.ref.data)							\
	DEV_KEEP(init.data)						\
	DEV_KEEP(exit.data)						\
	CPU_KEEP(init.data)						\
	CPU_KEEP(exit.data)						\
	MEM_KEEP(init.data)						\
	MEM_KEEP(exit.data)						\
	. = ALIGN(8);							\
	VMLINUX_SYMBOL(__start___markers) = .;				\
	*(__markers)							\
	VMLINUX_SYMBOL(__stop___markers) = .;				\
	. = ALIGN(32);							\
	VMLINUX_SYMBOL(__start___tracepoints) = .;			\
	*(__tracepoints)						\
	VMLINUX_SYMBOL(__stop___tracepoints) = .;			\
	/* implement dynamic printk debug */				\
	. = ALIGN(8);							\
	VMLINUX_SYMBOL(__start___verbose) = .;                          \
	*(__verbose)                                                    \
	VMLINUX_SYMBOL(__stop___verbose) = .;				\
	LIKELY_PROFILE()		       				\
	BRANCH_PROFILE()						\
	TRACE_PRINTKS()							\
	FTRACE_EVENTS()							\
	TRACE_SYSCALLS()

#define RO_DATA(align)							\
	. = ALIGN((align));						\
	.rodata           : AT(ADDR(.rodata) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start_rodata) = .;			\
		*(.rodata) *(.rodata.*)					\
		*(__vermagic)		/* Kernel version magic */	\
		*(__markers_strings)	/* Markers: strings */		\
		*(__tracepoints_strings)/* Tracepoints: strings */	\
	}								\
									\
	.rodata1          : AT(ADDR(.rodata1) - LOAD_OFFSET) {		\
		*(.rodata1)						\
	}								\
									\
	BUG_TABLE							\
									\
	/* PCI quirks */						\
	.pci_fixup        : AT(ADDR(.pci_fixup) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_pci_fixups_early) = .;		\
		*(.pci_fixup_early)					\
		VMLINUX_SYMBOL(__end_pci_fixups_early) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_header) = .;		\
		*(.pci_fixup_header)					\
		VMLINUX_SYMBOL(__end_pci_fixups_header) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_final) = .;		\
		*(.pci_fixup_final)					\
		VMLINUX_SYMBOL(__end_pci_fixups_final) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_enable) = .;		\
		*(.pci_fixup_enable)					\
		VMLINUX_SYMBOL(__end_pci_fixups_enable) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_resume) = .;		\
		*(.pci_fixup_resume)					\
		VMLINUX_SYMBOL(__end_pci_fixups_resume) = .;		\
		VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .;	\
		*(.pci_fixup_resume_early)				\
		VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .;	\
		VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .;		\
		*(.pci_fixup_suspend)					\
		VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .;		\
	}								\
									\
	/* Built-in firmware blobs */					\
	.builtin_fw        : AT(ADDR(.builtin_fw) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_builtin_fw) = .;			\
		*(.builtin_fw)						\
		VMLINUX_SYMBOL(__end_builtin_fw) = .;			\
	}								\
									\
	/* RapidIO route ops */						\
	.rio_route        : AT(ADDR(.rio_route) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start_rio_route_ops) = .;		\
		*(.rio_route_ops)					\
		VMLINUX_SYMBOL(__end_rio_route_ops) = .;		\
	}								\
									\
	TRACEDATA							\
									\
	/* Kernel symbol table: Normal symbols */			\
	__ksymtab         : AT(ADDR(__ksymtab) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___ksymtab) = .;			\
		*(__ksymtab)						\
		VMLINUX_SYMBOL(__stop___ksymtab) = .;			\
	}								\
									\
	/* Kernel symbol table: GPL-only symbols */			\
	__ksymtab_gpl     : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___ksymtab_gpl) = .;		\
		*(__ksymtab_gpl)					\
		VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .;		\
	}								\
									\
	/* Kernel symbol table: Normal unused symbols */		\
	__ksymtab_unused  : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___ksymtab_unused) = .;		\
		*(__ksymtab_unused)					\
		VMLINUX_SYMBOL(__stop___ksymtab_unused) = .;		\
	}								\
									\
	/* Kernel symbol table: GPL-only unused symbols */		\
	__ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .;	\
		*(__ksymtab_unused_gpl)					\
		VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .;	\
	}								\
									\
	/* Kernel symbol table: GPL-future-only symbols */		\
	__ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .;	\
		*(__ksymtab_gpl_future)					\
		VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .;	\
	}								\
									\
	/* Kernel symbol table: Normal symbols */			\
	__kcrctab         : AT(ADDR(__kcrctab) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___kcrctab) = .;			\
		*(__kcrctab)						\
		VMLINUX_SYMBOL(__stop___kcrctab) = .;			\
	}								\
									\
	/* Kernel symbol table: GPL-only symbols */			\
	__kcrctab_gpl     : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___kcrctab_gpl) = .;		\
		*(__kcrctab_gpl)					\
		VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .;		\
	}								\
									\
	/* Kernel symbol table: Normal unused symbols */		\
	__kcrctab_unused  : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__start___kcrctab_unused) = .;		\
		*(__kcrctab_unused)					\
		VMLINUX_SYMBOL(__stop___kcrctab_unused) = .;		\
	}								\
									\
	/* Kernel symbol table: GPL-only unused symbols */		\
	__kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .;	\
		*(__kcrctab_unused_gpl)					\
		VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .;	\
	}								\
									\
	/* Kernel symbol table: GPL-future-only symbols */		\
	__kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .;	\
		*(__kcrctab_gpl_future)					\
		VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .;	\
	}								\
									\
	/* Kernel symbol table: strings */				\
        __ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) {	\
		*(__ksymtab_strings)					\
	}								\
									\
	/* __*init sections */						\
	__init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) {		\
		*(.ref.rodata)						\
		MCOUNT_REC()						\
		DEV_KEEP(init.rodata)					\
		DEV_KEEP(exit.rodata)					\
		CPU_KEEP(init.rodata)					\
		CPU_KEEP(exit.rodata)					\
		MEM_KEEP(init.rodata)					\
		MEM_KEEP(exit.rodata)					\
	}								\
									\
	/* Built-in module parameters. */				\
	__param : AT(ADDR(__param) - LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__start___param) = .;			\
		*(__param)						\
		VMLINUX_SYMBOL(__stop___param) = .;			\
		. = ALIGN((align));					\
		VMLINUX_SYMBOL(__end_rodata) = .;			\
	}								\
	. = ALIGN((align));

/* RODATA provided for backward compatibility.
 * All archs are supposed to use RO_DATA() */
#define RODATA RO_DATA(4096)

#define SECURITY_INIT							\
	.security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
		VMLINUX_SYMBOL(__security_initcall_start) = .;		\
		*(.security_initcall.init) 				\
		VMLINUX_SYMBOL(__security_initcall_end) = .;		\
	}

/* .text section. Map to function alignment to avoid address changes
 * during second ld run in second ld pass when generating System.map */
#define TEXT_TEXT							\
		ALIGN_FUNCTION();					\
		*(.text.hot)						\
		*(.text)						\
		*(.ref.text)						\
	DEV_KEEP(init.text)						\
	DEV_KEEP(exit.text)						\
	CPU_KEEP(init.text)						\
	CPU_KEEP(exit.text)						\
	MEM_KEEP(init.text)						\
	MEM_KEEP(exit.text)						\
		*(.text.unlikely)


/* sched.text is aling to function alignment to secure we have same
 * address even at second ld pass when generating System.map */
#define SCHED_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__sched_text_start) = .;			\
		*(.sched.text)						\
		VMLINUX_SYMBOL(__sched_text_end) = .;

/* spinlock.text is aling to function alignment to secure we have same
 * address even at second ld pass when generating System.map */
#define LOCK_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__lock_text_start) = .;			\
		*(.spinlock.text)					\
		VMLINUX_SYMBOL(__lock_text_end) = .;

#define KPROBES_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__kprobes_text_start) = .;		\
		*(.kprobes.text)					\
		VMLINUX_SYMBOL(__kprobes_text_end) = .;

#ifdef CONFIG_FUNCTION_GRAPH_TRACER
#define IRQENTRY_TEXT							\
		ALIGN_FUNCTION();					\
		VMLINUX_SYMBOL(__irqentry_text_start) = .;		\
		*(.irqentry.text)					\
		VMLINUX_SYMBOL(__irqentry_text_end) = .;
#else
#define IRQENTRY_TEXT
#endif

/* Section used for early init (in .S files) */
#define HEAD_TEXT  *(HEAD_TEXT_SECTION)

/* init and exit section handling */
#define INIT_DATA							\
	*(.init.data)							\
	DEV_DISCARD(init.data)						\
	DEV_DISCARD(init.rodata)					\
	CPU_DISCARD(init.data)						\
	CPU_DISCARD(init.rodata)					\
	MEM_DISCARD(init.data)						\
	MEM_DISCARD(init.rodata)

#define INIT_TEXT							\
	*(.init.text)							\
	DEV_DISCARD(init.text)						\
	CPU_DISCARD(init.text)						\
	MEM_DISCARD(init.text)

#define EXIT_DATA							\
	*(.exit.data)							\
	DEV_DISCARD(exit.data)						\
	DEV_DISCARD(exit.rodata)					\
	CPU_DISCARD(exit.data)						\
	CPU_DISCARD(exit.rodata)					\
	MEM_DISCARD(exit.data)						\
	MEM_DISCARD(exit.rodata)

#define EXIT_TEXT							\
	*(.exit.text)							\
	DEV_DISCARD(exit.text)						\
	CPU_DISCARD(exit.text)						\
	MEM_DISCARD(exit.text)

		/* DWARF debug sections.
		Symbols in the DWARF debugging sections are relative to
		the beginning of the section so we begin them at 0.  */
#define DWARF_DEBUG							\
		/* DWARF 1 */						\
		.debug          0 : { *(.debug) }			\
		.line           0 : { *(.line) }			\
		/* GNU DWARF 1 extensions */				\
		.debug_srcinfo  0 : { *(.debug_srcinfo) }		\
		.debug_sfnames  0 : { *(.debug_sfnames) }		\
		/* DWARF 1.1 and DWARF 2 */				\
		.debug_aranges  0 : { *(.debug_aranges) }		\
		.debug_pubnames 0 : { *(.debug_pubnames) }		\
		/* DWARF 2 */						\
		.debug_info     0 : { *(.debug_info			\
				.gnu.linkonce.wi.*) }			\
		.debug_abbrev   0 : { *(.debug_abbrev) }		\
		.debug_line     0 : { *(.debug_line) }			\
		.debug_frame    0 : { *(.debug_frame) }			\
		.debug_str      0 : { *(.debug_str) }			\
		.debug_loc      0 : { *(.debug_loc) }			\
		.debug_macinfo  0 : { *(.debug_macinfo) }		\
		/* SGI/MIPS DWARF 2 extensions */			\
		.debug_weaknames 0 : { *(.debug_weaknames) }		\
		.debug_funcnames 0 : { *(.debug_funcnames) }		\
		.debug_typenames 0 : { *(.debug_typenames) }		\
		.debug_varnames  0 : { *(.debug_varnames) }		\

		/* Stabs debugging sections.  */
#define STABS_DEBUG							\
		.stab 0 : { *(.stab) }					\
		.stabstr 0 : { *(.stabstr) }				\
		.stab.excl 0 : { *(.stab.excl) }			\
		.stab.exclstr 0 : { *(.stab.exclstr) }			\
		.stab.index 0 : { *(.stab.index) }			\
		.stab.indexstr 0 : { *(.stab.indexstr) }		\
		.comment 0 : { *(.comment) }

#ifdef CONFIG_GENERIC_BUG
#define BUG_TABLE							\
	. = ALIGN(8);							\
	__bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__start___bug_table) = .;		\
		*(__bug_table)						\
		VMLINUX_SYMBOL(__stop___bug_table) = .;			\
	}
#else
#define BUG_TABLE
#endif

#ifdef CONFIG_PM_TRACE
#define TRACEDATA							\
	. = ALIGN(4);							\
	.tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) {		\
		VMLINUX_SYMBOL(__tracedata_start) = .;			\
		*(.tracedata)						\
		VMLINUX_SYMBOL(__tracedata_end) = .;			\
	}
#else
#define TRACEDATA
#endif

#define NOTES								\
	.notes : AT(ADDR(.notes) - LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__start_notes) = .;			\
		*(.note.*)						\
		VMLINUX_SYMBOL(__stop_notes) = .;			\
	}

#define INITCALLS							\
	*(.initcallearly.init)						\
	VMLINUX_SYMBOL(__early_initcall_end) = .;			\
  	*(.initcall0.init)						\
  	*(.initcall0s.init)						\
  	*(.initcall1.init)						\
  	*(.initcall1s.init)						\
  	*(.initcall2.init)						\
  	*(.initcall2s.init)						\
  	*(.initcall3.init)						\
  	*(.initcall3s.init)						\
  	*(.initcall4.init)						\
  	*(.initcall4s.init)						\
  	*(.initcall5.init)						\
  	*(.initcall5s.init)						\
	*(.initcallrootfs.init)						\
  	*(.initcall6.init)						\
  	*(.initcall6s.init)						\
  	*(.initcall7.init)						\
  	*(.initcall7s.init)

/**
 * PERCPU_VADDR - define output section for percpu area
 * @vaddr: explicit base address (optional)
 * @phdr: destination PHDR (optional)
 *
 * Macro which expands to output section for percpu area.  If @vaddr
 * is not blank, it specifies explicit base address and all percpu
 * symbols will be offset from the given address.  If blank, @vaddr
 * always equals @laddr + LOAD_OFFSET.
 *
 * @phdr defines the output PHDR to use if not blank.  Be warned that
 * output PHDR is sticky.  If @phdr is specified, the next output
 * section in the linker script will go there too.  @phdr should have
 * a leading colon.
 *
 * Note that this macros defines __per_cpu_load as an absolute symbol.
 * If there is no need to put the percpu section at a predetermined
 * address, use PERCPU().
 */
#define PERCPU_VADDR(vaddr, phdr)					\
	VMLINUX_SYMBOL(__per_cpu_load) = .;				\
	.data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load)		\
				- LOAD_OFFSET) {			\
		VMLINUX_SYMBOL(__per_cpu_start) = .;			\
		*(.data.percpu.first)					\
		*(.data.percpu.page_aligned)				\
		*(.data.percpu)						\
		*(.data.percpu.shared_aligned)				\
		VMLINUX_SYMBOL(__per_cpu_end) = .;			\
	} phdr								\
	. = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);

/**
 * PERCPU - define output section for percpu area, simple version
 * @align: required alignment
 *
 * Align to @align and outputs output section for percpu area.  This
 * macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
 * __per_cpu_start will be identical.
 *
 * This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
 * that __per_cpu_load is defined as a relative symbol against
 * .data.percpu which is required for relocatable x86_32
 * configuration.
 */
#define PERCPU(align)							\
	. = ALIGN(align);						\
	.data.percpu	: AT(ADDR(.data.percpu) - LOAD_OFFSET) {	\
		VMLINUX_SYMBOL(__per_cpu_load) = .;			\
		VMLINUX_SYMBOL(__per_cpu_start) = .;			\
		*(.data.percpu.first)					\
		*(.data.percpu.page_aligned)				\
		*(.data.percpu)						\
		*(.data.percpu.shared_aligned)				\
		VMLINUX_SYMBOL(__per_cpu_end) = .;			\
	}
Commit	Line	Data
c80d471a TA	1	#include <linux/section-names.h>
c80d471a TA	2
1da177e4 LT	3	#ifndef LOAD_OFFSET
	4	#define LOAD_OFFSET 0
	5	#endif
	6
	7	#ifndef VMLINUX_SYMBOL
	8	#define VMLINUX_SYMBOL(_sym_) _sym_
	9	#endif
	10
6d30e3a8 SR	11	/* Align . to a 8 byte boundary equals to maximum function alignment. */
	12	#define ALIGN_FUNCTION() . = ALIGN(8)
	13
eb8f6890 SR	14	/* The actual configuration determine if the init/exit sections
	15	* are handled as text/data or they can be discarded (which
	16	* often happens at runtime)
	17	*/
	18	#ifdef CONFIG_HOTPLUG
	19	#define DEV_KEEP(sec) *(.dev##sec)
	20	#define DEV_DISCARD(sec)
	21	#else
	22	#define DEV_KEEP(sec)
	23	#define DEV_DISCARD(sec) *(.dev##sec)
	24	#endif
	25
	26	#ifdef CONFIG_HOTPLUG_CPU
	27	#define CPU_KEEP(sec) *(.cpu##sec)
	28	#define CPU_DISCARD(sec)
	29	#else
	30	#define CPU_KEEP(sec)
	31	#define CPU_DISCARD(sec) *(.cpu##sec)
	32	#endif
	33
1a3fb6d4	34	#if defined(CONFIG_MEMORY_HOTPLUG)
eb8f6890 SR	35	#define MEM_KEEP(sec) *(.mem##sec)
	36	#define MEM_DISCARD(sec)
	37	#else
	38	#define MEM_KEEP(sec)
	39	#define MEM_DISCARD(sec) *(.mem##sec)
	40	#endif
	41
8da3821b SR	42	#ifdef CONFIG_FTRACE_MCOUNT_RECORD
	43	#define MCOUNT_REC() VMLINUX_SYMBOL(__start_mcount_loc) = .; \
	44	*(__mcount_loc) \
	45	VMLINUX_SYMBOL(__stop_mcount_loc) = .;
	46	#else
	47	#define MCOUNT_REC()
	48	#endif
eb8f6890	49
2ed84eeb	50	#ifdef CONFIG_TRACE_BRANCH_PROFILING
45b79749 SR	51	#define LIKELY_PROFILE() VMLINUX_SYMBOL(__start_annotated_branch_profile) = .; \
	52	*(_ftrace_annotated_branch) \
	53	VMLINUX_SYMBOL(__stop_annotated_branch_profile) = .;
1f0d69a9 SR	54	#else
	55	#define LIKELY_PROFILE()
	56	#endif
	57
2bcd521a SR	58	#ifdef CONFIG_PROFILE_ALL_BRANCHES
	59	#define BRANCH_PROFILE() VMLINUX_SYMBOL(__start_branch_profile) = .; \
	60	*(_ftrace_branch) \
	61	VMLINUX_SYMBOL(__stop_branch_profile) = .;
	62	#else
	63	#define BRANCH_PROFILE()
	64	#endif
	65
b77e38aa SR	66	#ifdef CONFIG_EVENT_TRACER
	67	#define FTRACE_EVENTS() VMLINUX_SYMBOL(__start_ftrace_events) = .; \
	68	*(_ftrace_events) \
	69	VMLINUX_SYMBOL(__stop_ftrace_events) = .;
	70	#else
	71	#define FTRACE_EVENTS()
	72	#endif
	73
1ba28e02 LJ	74	#ifdef CONFIG_TRACING
	75	#define TRACE_PRINTKS() VMLINUX_SYMBOL(__start___trace_bprintk_fmt) = .; \
	76	(__trace_printk_fmt) / Trace_printk fmt' pointer */ \
	77	VMLINUX_SYMBOL(__stop___trace_bprintk_fmt) = .;
	78	#else
	79	#define TRACE_PRINTKS()
	80	#endif
	81
bed1ffca FW	82	#ifdef CONFIG_FTRACE_SYSCALLS
	83	#define TRACE_SYSCALLS() VMLINUX_SYMBOL(__start_syscalls_metadata) = .; \
	84	*(__syscalls_metadata) \
	85	VMLINUX_SYMBOL(__stop_syscalls_metadata) = .;
	86	#else
	87	#define TRACE_SYSCALLS()
	88	#endif
	89
ca967258 SR	90	/* .data section */
ca967258 SR	91	#define DATA_DATA \
0e0d314e	92	*(.data) \
312b1485	93	*(.ref.data) \
eb8f6890 SR	94	DEV_KEEP(init.data) \
	95	DEV_KEEP(exit.data) \
	96	CPU_KEEP(init.data) \
	97	CPU_KEEP(exit.data) \
	98	MEM_KEEP(init.data) \
	99	MEM_KEEP(exit.data) \
8256e47c MD	100	. = ALIGN(8); \
	101	VMLINUX_SYMBOL(__start___markers) = .; \
	102	*(__markers) \
97e1c18e	103	VMLINUX_SYMBOL(__stop___markers) = .; \
7e066fb8	104	. = ALIGN(32); \
97e1c18e MD	105	VMLINUX_SYMBOL(__start___tracepoints) = .; \
97e1c18e MD	106	*(__tracepoints) \
1f0d69a9	107	VMLINUX_SYMBOL(__stop___tracepoints) = .; \
e9d376f0 JB	108	/* implement dynamic printk debug */ \
	109	. = ALIGN(8); \
	110	VMLINUX_SYMBOL(__start___verbose) = .; \
	111	*(__verbose) \
	112	VMLINUX_SYMBOL(__stop___verbose) = .; \
2bcd521a	113	LIKELY_PROFILE() \
b77e38aa	114	BRANCH_PROFILE() \
8a20d84d	115	TRACE_PRINTKS() \
bed1ffca FW	116	FTRACE_EVENTS() \
bed1ffca FW	117	TRACE_SYSCALLS()
ca967258	118
4096b46f SR	119	#define RO_DATA(align) \
4096b46f SR	120	. = ALIGN((align)); \
1da177e4	121	.rodata : AT(ADDR(.rodata) - LOAD_OFFSET) { \
6569580d	122	VMLINUX_SYMBOL(__start_rodata) = .; \
1da177e4 LT	123	(.rodata) (.rodata.*) \
1da177e4 LT	124	(__vermagic) / Kernel version magic */ \
8256e47c	125	(__markers_strings) / Markers: strings */ \
97e1c18e	126	(__tracepoints_strings)/ Tracepoints: strings */ \
1da177e4 LT	127	} \
	128	\
	129	.rodata1 : AT(ADDR(.rodata1) - LOAD_OFFSET) { \
	130	*(.rodata1) \
	131	} \
	132	\
6360b1fb JB	133	BUG_TABLE \
6360b1fb JB	134	\
1da177e4 LT	135	/* PCI quirks */ \
	136	.pci_fixup : AT(ADDR(.pci_fixup) - LOAD_OFFSET) { \
	137	VMLINUX_SYMBOL(__start_pci_fixups_early) = .; \
	138	*(.pci_fixup_early) \
	139	VMLINUX_SYMBOL(__end_pci_fixups_early) = .; \
	140	VMLINUX_SYMBOL(__start_pci_fixups_header) = .; \
	141	*(.pci_fixup_header) \
	142	VMLINUX_SYMBOL(__end_pci_fixups_header) = .; \
	143	VMLINUX_SYMBOL(__start_pci_fixups_final) = .; \
	144	*(.pci_fixup_final) \
	145	VMLINUX_SYMBOL(__end_pci_fixups_final) = .; \
	146	VMLINUX_SYMBOL(__start_pci_fixups_enable) = .; \
	147	*(.pci_fixup_enable) \
	148	VMLINUX_SYMBOL(__end_pci_fixups_enable) = .; \
1597cacb AC	149	VMLINUX_SYMBOL(__start_pci_fixups_resume) = .; \
	150	*(.pci_fixup_resume) \
	151	VMLINUX_SYMBOL(__end_pci_fixups_resume) = .; \
e1a2a51e RW	152	VMLINUX_SYMBOL(__start_pci_fixups_resume_early) = .; \
	153	*(.pci_fixup_resume_early) \
	154	VMLINUX_SYMBOL(__end_pci_fixups_resume_early) = .; \
	155	VMLINUX_SYMBOL(__start_pci_fixups_suspend) = .; \
	156	*(.pci_fixup_suspend) \
	157	VMLINUX_SYMBOL(__end_pci_fixups_suspend) = .; \
1da177e4 LT	158	} \
1da177e4 LT	159	\
5658c769 DW	160	/* Built-in firmware blobs */ \
	161	.builtin_fw : AT(ADDR(.builtin_fw) - LOAD_OFFSET) { \
	162	VMLINUX_SYMBOL(__start_builtin_fw) = .; \
	163	*(.builtin_fw) \
	164	VMLINUX_SYMBOL(__end_builtin_fw) = .; \
	165	} \
	166	\
394b701c MP	167	/* RapidIO route ops */ \
	168	.rio_route : AT(ADDR(.rio_route) - LOAD_OFFSET) { \
	169	VMLINUX_SYMBOL(__start_rio_route_ops) = .; \
	170	*(.rio_route_ops) \
	171	VMLINUX_SYMBOL(__end_rio_route_ops) = .; \
	172	} \
	173	\
63687a52 JB	174	TRACEDATA \
63687a52 JB	175	\
1da177e4 LT	176	/* Kernel symbol table: Normal symbols */ \
	177	__ksymtab : AT(ADDR(__ksymtab) - LOAD_OFFSET) { \
	178	VMLINUX_SYMBOL(__start___ksymtab) = .; \
	179	*(__ksymtab) \
	180	VMLINUX_SYMBOL(__stop___ksymtab) = .; \
	181	} \
	182	\
	183	/* Kernel symbol table: GPL-only symbols */ \
	184	__ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - LOAD_OFFSET) { \
	185	VMLINUX_SYMBOL(__start___ksymtab_gpl) = .; \
	186	*(__ksymtab_gpl) \
	187	VMLINUX_SYMBOL(__stop___ksymtab_gpl) = .; \
	188	} \
	189	\
f71d20e9 AV	190	/* Kernel symbol table: Normal unused symbols */ \
	191	__ksymtab_unused : AT(ADDR(__ksymtab_unused) - LOAD_OFFSET) { \
	192	VMLINUX_SYMBOL(__start___ksymtab_unused) = .; \
	193	*(__ksymtab_unused) \
	194	VMLINUX_SYMBOL(__stop___ksymtab_unused) = .; \
	195	} \
	196	\
	197	/* Kernel symbol table: GPL-only unused symbols */ \
	198	__ksymtab_unused_gpl : AT(ADDR(__ksymtab_unused_gpl) - LOAD_OFFSET) { \
	199	VMLINUX_SYMBOL(__start___ksymtab_unused_gpl) = .; \
	200	*(__ksymtab_unused_gpl) \
	201	VMLINUX_SYMBOL(__stop___ksymtab_unused_gpl) = .; \
	202	} \
	203	\
9f28bb7e GKH	204	/* Kernel symbol table: GPL-future-only symbols */ \
	205	__ksymtab_gpl_future : AT(ADDR(__ksymtab_gpl_future) - LOAD_OFFSET) { \
	206	VMLINUX_SYMBOL(__start___ksymtab_gpl_future) = .; \
	207	*(__ksymtab_gpl_future) \
	208	VMLINUX_SYMBOL(__stop___ksymtab_gpl_future) = .; \
	209	} \
	210	\
1da177e4 LT	211	/* Kernel symbol table: Normal symbols */ \
	212	__kcrctab : AT(ADDR(__kcrctab) - LOAD_OFFSET) { \
	213	VMLINUX_SYMBOL(__start___kcrctab) = .; \
	214	*(__kcrctab) \
	215	VMLINUX_SYMBOL(__stop___kcrctab) = .; \
	216	} \
	217	\
	218	/* Kernel symbol table: GPL-only symbols */ \
	219	__kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - LOAD_OFFSET) { \
	220	VMLINUX_SYMBOL(__start___kcrctab_gpl) = .; \
	221	*(__kcrctab_gpl) \
	222	VMLINUX_SYMBOL(__stop___kcrctab_gpl) = .; \
	223	} \
	224	\
f71d20e9 AV	225	/* Kernel symbol table: Normal unused symbols */ \
	226	__kcrctab_unused : AT(ADDR(__kcrctab_unused) - LOAD_OFFSET) { \
	227	VMLINUX_SYMBOL(__start___kcrctab_unused) = .; \
	228	*(__kcrctab_unused) \
	229	VMLINUX_SYMBOL(__stop___kcrctab_unused) = .; \
	230	} \
	231	\
	232	/* Kernel symbol table: GPL-only unused symbols */ \
	233	__kcrctab_unused_gpl : AT(ADDR(__kcrctab_unused_gpl) - LOAD_OFFSET) { \
	234	VMLINUX_SYMBOL(__start___kcrctab_unused_gpl) = .; \
	235	*(__kcrctab_unused_gpl) \
	236	VMLINUX_SYMBOL(__stop___kcrctab_unused_gpl) = .; \
	237	} \
	238	\
9f28bb7e GKH	239	/* Kernel symbol table: GPL-future-only symbols */ \
	240	__kcrctab_gpl_future : AT(ADDR(__kcrctab_gpl_future) - LOAD_OFFSET) { \
	241	VMLINUX_SYMBOL(__start___kcrctab_gpl_future) = .; \
	242	*(__kcrctab_gpl_future) \
	243	VMLINUX_SYMBOL(__stop___kcrctab_gpl_future) = .; \
	244	} \
	245	\
1da177e4 LT	246	/* Kernel symbol table: strings */ \
	247	__ksymtab_strings : AT(ADDR(__ksymtab_strings) - LOAD_OFFSET) { \
	248	*(__ksymtab_strings) \
	249	} \
	250	\
eb8f6890 SR	251	/* __init sections / \
eb8f6890 SR	252	__init_rodata : AT(ADDR(__init_rodata) - LOAD_OFFSET) { \
312b1485	253	*(.ref.rodata) \
8da3821b	254	MCOUNT_REC() \
eb8f6890 SR	255	DEV_KEEP(init.rodata) \
	256	DEV_KEEP(exit.rodata) \
	257	CPU_KEEP(init.rodata) \
	258	CPU_KEEP(exit.rodata) \
	259	MEM_KEEP(init.rodata) \
	260	MEM_KEEP(exit.rodata) \
	261	} \
	262	\
1da177e4 LT	263	/* Built-in module parameters. */ \
	264	__param : AT(ADDR(__param) - LOAD_OFFSET) { \
	265	VMLINUX_SYMBOL(__start___param) = .; \
	266	*(__param) \
	267	VMLINUX_SYMBOL(__stop___param) = .; \
edeed305	268	. = ALIGN((align)); \
6569580d	269	VMLINUX_SYMBOL(__end_rodata) = .; \
7583ddfd	270	} \
4096b46f SR	271	. = ALIGN((align));
	272
	273	/* RODATA provided for backward compatibility.
	274	* All archs are supposed to use RO_DATA() */
	275	#define RODATA RO_DATA(4096)
1da177e4 LT	276
1da177e4 LT	277	#define SECURITY_INIT \
60bad7fa	278	.security_initcall.init : AT(ADDR(.security_initcall.init) - LOAD_OFFSET) { \
1da177e4 LT	279	VMLINUX_SYMBOL(__security_initcall_start) = .; \
	280	*(.security_initcall.init) \
	281	VMLINUX_SYMBOL(__security_initcall_end) = .; \
	282	}
	283
7664709b SR	284	/* .text section. Map to function alignment to avoid address changes
	285	* during second ld run in second ld pass when generating System.map */
	286	#define TEXT_TEXT \
	287	ALIGN_FUNCTION(); \
fb5e2b37	288	*(.text.hot) \
0e0d314e	289	*(.text) \
312b1485	290	*(.ref.text) \
eb8f6890 SR	291	DEV_KEEP(init.text) \
	292	DEV_KEEP(exit.text) \
	293	CPU_KEEP(init.text) \
	294	CPU_KEEP(exit.text) \
	295	MEM_KEEP(init.text) \
fb5e2b37 JB	296	MEM_KEEP(exit.text) \
fb5e2b37 JB	297	*(.text.unlikely)
eb8f6890	298
7664709b	299
6d30e3a8 SR	300	/* sched.text is aling to function alignment to secure we have same
6d30e3a8 SR	301	* address even at second ld pass when generating System.map */
1da177e4	302	#define SCHED_TEXT \
6d30e3a8	303	ALIGN_FUNCTION(); \
1da177e4 LT	304	VMLINUX_SYMBOL(__sched_text_start) = .; \
	305	*(.sched.text) \
	306	VMLINUX_SYMBOL(__sched_text_end) = .;
	307
6d30e3a8 SR	308	/* spinlock.text is aling to function alignment to secure we have same
6d30e3a8 SR	309	* address even at second ld pass when generating System.map */
1da177e4	310	#define LOCK_TEXT \
6d30e3a8	311	ALIGN_FUNCTION(); \
1da177e4 LT	312	VMLINUX_SYMBOL(__lock_text_start) = .; \
	313	*(.spinlock.text) \
	314	VMLINUX_SYMBOL(__lock_text_end) = .;
d0aaff97 PP	315
	316	#define KPROBES_TEXT \
	317	ALIGN_FUNCTION(); \
	318	VMLINUX_SYMBOL(__kprobes_text_start) = .; \
	319	*(.kprobes.text) \
	320	VMLINUX_SYMBOL(__kprobes_text_end) = .;
a7d0c210	321
a0343e82 FW	322	#ifdef CONFIG_FUNCTION_GRAPH_TRACER
	323	#define IRQENTRY_TEXT \
	324	ALIGN_FUNCTION(); \
	325	VMLINUX_SYMBOL(__irqentry_text_start) = .; \
	326	*(.irqentry.text) \
	327	VMLINUX_SYMBOL(__irqentry_text_end) = .;
	328	#else
	329	#define IRQENTRY_TEXT
	330	#endif
	331
37c514e3	332	/* Section used for early init (in .S files) */
c80d471a	333	#define HEAD_TEXT *(HEAD_TEXT_SECTION)
37c514e3	334
01ba2bdc	335	/* init and exit section handling */
eb8f6890 SR	336	#define INIT_DATA \
	337	*(.init.data) \
	338	DEV_DISCARD(init.data) \
	339	DEV_DISCARD(init.rodata) \
	340	CPU_DISCARD(init.data) \
	341	CPU_DISCARD(init.rodata) \
	342	MEM_DISCARD(init.data) \
e9d376f0	343	MEM_DISCARD(init.rodata)
eb8f6890 SR	344
	345	#define INIT_TEXT \
	346	*(.init.text) \
	347	DEV_DISCARD(init.text) \
	348	CPU_DISCARD(init.text) \
	349	MEM_DISCARD(init.text)
	350
	351	#define EXIT_DATA \
	352	*(.exit.data) \
	353	DEV_DISCARD(exit.data) \
	354	DEV_DISCARD(exit.rodata) \
	355	CPU_DISCARD(exit.data) \
	356	CPU_DISCARD(exit.rodata) \
	357	MEM_DISCARD(exit.data) \
	358	MEM_DISCARD(exit.rodata)
01ba2bdc	359
eb8f6890 SR	360	#define EXIT_TEXT \
	361	*(.exit.text) \
	362	DEV_DISCARD(exit.text) \
	363	CPU_DISCARD(exit.text) \
	364	MEM_DISCARD(exit.text)
01ba2bdc	365
a7d0c210 PBG	366	/* DWARF debug sections.
	367	Symbols in the DWARF debugging sections are relative to
	368	the beginning of the section so we begin them at 0. */
	369	#define DWARF_DEBUG \
	370	/* DWARF 1 */ \
	371	.debug 0 : { *(.debug) } \
	372	.line 0 : { *(.line) } \
	373	/* GNU DWARF 1 extensions */ \
	374	.debug_srcinfo 0 : { *(.debug_srcinfo) } \
	375	.debug_sfnames 0 : { *(.debug_sfnames) } \
	376	/* DWARF 1.1 and DWARF 2 */ \
	377	.debug_aranges 0 : { *(.debug_aranges) } \
	378	.debug_pubnames 0 : { *(.debug_pubnames) } \
	379	/* DWARF 2 */ \
	380	.debug_info 0 : { *(.debug_info \
	381	.gnu.linkonce.wi.*) } \
	382	.debug_abbrev 0 : { *(.debug_abbrev) } \
	383	.debug_line 0 : { *(.debug_line) } \
	384	.debug_frame 0 : { *(.debug_frame) } \
	385	.debug_str 0 : { *(.debug_str) } \
	386	.debug_loc 0 : { *(.debug_loc) } \
	387	.debug_macinfo 0 : { *(.debug_macinfo) } \
	388	/* SGI/MIPS DWARF 2 extensions */ \
	389	.debug_weaknames 0 : { *(.debug_weaknames) } \
	390	.debug_funcnames 0 : { *(.debug_funcnames) } \
	391	.debug_typenames 0 : { *(.debug_typenames) } \
	392	.debug_varnames 0 : { *(.debug_varnames) } \
	393
	394	/* Stabs debugging sections. */
	395	#define STABS_DEBUG \
	396	.stab 0 : { *(.stab) } \
	397	.stabstr 0 : { *(.stabstr) } \
	398	.stab.excl 0 : { *(.stab.excl) } \
	399	.stab.exclstr 0 : { *(.stab.exclstr) } \
	400	.stab.index 0 : { *(.stab.index) } \
	401	.stab.indexstr 0 : { *(.stab.indexstr) } \
	402	.comment 0 : { *(.comment) }
9c9b8b38	403
6360b1fb	404	#ifdef CONFIG_GENERIC_BUG
7664c5a1 JF	405	#define BUG_TABLE \
	406	. = ALIGN(8); \
	407	__bug_table : AT(ADDR(__bug_table) - LOAD_OFFSET) { \
c6de0026	408	VMLINUX_SYMBOL(__start___bug_table) = .; \
7664c5a1	409	*(__bug_table) \
c6de0026	410	VMLINUX_SYMBOL(__stop___bug_table) = .; \
7664c5a1	411	}
6360b1fb JB	412	#else
	413	#define BUG_TABLE
	414	#endif
7664c5a1	415
63687a52 JB	416	#ifdef CONFIG_PM_TRACE
	417	#define TRACEDATA \
	418	. = ALIGN(4); \
	419	.tracedata : AT(ADDR(.tracedata) - LOAD_OFFSET) { \
c6de0026	420	VMLINUX_SYMBOL(__tracedata_start) = .; \
63687a52	421	*(.tracedata) \
c6de0026	422	VMLINUX_SYMBOL(__tracedata_end) = .; \
63687a52 JB	423	}
	424	#else
	425	#define TRACEDATA
	426	#endif
	427
9c9b8b38	428	#define NOTES \
cbe87121 RM	429	.notes : AT(ADDR(.notes) - LOAD_OFFSET) { \
	430	VMLINUX_SYMBOL(__start_notes) = .; \
	431	(.note.) \
	432	VMLINUX_SYMBOL(__stop_notes) = .; \
	433	}
61ce1efe AM	434
61ce1efe AM	435	#define INITCALLS \
c2147a50	436	*(.initcallearly.init) \
c6de0026	437	VMLINUX_SYMBOL(__early_initcall_end) = .; \
b3438f82 LT	438	*(.initcall0.init) \
b3438f82 LT	439	*(.initcall0s.init) \
61ce1efe	440	*(.initcall1.init) \
735a7ffb	441	*(.initcall1s.init) \
61ce1efe	442	*(.initcall2.init) \
735a7ffb	443	*(.initcall2s.init) \
61ce1efe	444	*(.initcall3.init) \
735a7ffb	445	*(.initcall3s.init) \
61ce1efe	446	*(.initcall4.init) \
735a7ffb	447	*(.initcall4s.init) \
61ce1efe	448	*(.initcall5.init) \
735a7ffb	449	*(.initcall5s.init) \
8d610dd5	450	*(.initcallrootfs.init) \
61ce1efe	451	*(.initcall6.init) \
735a7ffb AM	452	*(.initcall6s.init) \
	453	*(.initcall7.init) \
	454	*(.initcall7s.init)
61ce1efe	455
3e5d8f97	456	/**
6b7c38d5	457	* PERCPU_VADDR - define output section for percpu area
3e5d8f97 TH	458	* @vaddr: explicit base address (optional)
	459	* @phdr: destination PHDR (optional)
	460	*
	461	* Macro which expands to output section for percpu area. If @vaddr
	462	* is not blank, it specifies explicit base address and all percpu
	463	* symbols will be offset from the given address. If blank, @vaddr
	464	* always equals @laddr + LOAD_OFFSET.
	465	*
	466	* @phdr defines the output PHDR to use if not blank. Be warned that
	467	* output PHDR is sticky. If @phdr is specified, the next output
	468	* section in the linker script will go there too. @phdr should have
	469	* a leading colon.
	470	*
3ac6cffe TH	471	* Note that this macros defines __per_cpu_load as an absolute symbol.
	472	* If there is no need to put the percpu section at a predetermined
	473	* address, use PERCPU().
3e5d8f97 TH	474	*/
3e5d8f97 TH	475	#define PERCPU_VADDR(vaddr, phdr) \
dba3d36b IM	476	VMLINUX_SYMBOL(__per_cpu_load) = .; \
dba3d36b IM	477	.data.percpu vaddr : AT(VMLINUX_SYMBOL(__per_cpu_load) \
6b7c38d5 TH	478	- LOAD_OFFSET) { \
6b7c38d5 TH	479	VMLINUX_SYMBOL(__per_cpu_start) = .; \
0bd74fa8	480	*(.data.percpu.first) \
63cc8c75	481	*(.data.percpu.page_aligned) \
5fb7dc37 FY	482	*(.data.percpu) \
5fb7dc37 FY	483	*(.data.percpu.shared_aligned) \
6b7c38d5 TH	484	VMLINUX_SYMBOL(__per_cpu_end) = .; \
6b7c38d5 TH	485	} phdr \
dba3d36b	486	. = VMLINUX_SYMBOL(__per_cpu_load) + SIZEOF(.data.percpu);
3e5d8f97 TH	487
	488	/**
	489	* PERCPU - define output section for percpu area, simple version
	490	* @align: required alignment
	491	*
	492	* Align to @align and outputs output section for percpu area. This
	493	* macro doesn't maniuplate @vaddr or @phdr and __per_cpu_load and
	494	* __per_cpu_start will be identical.
3ac6cffe TH	495	*
	496	* This macro is equivalent to ALIGN(align); PERCPU_VADDR( , ) except
	497	* that __per_cpu_load is defined as a relative symbol against
	498	* .data.percpu which is required for relocatable x86_32
	499	* configuration.
3e5d8f97	500	*/
5fb7dc37 FY	501	#define PERCPU(align) \
5fb7dc37 FY	502	. = ALIGN(align); \
3ac6cffe TH	503	.data.percpu : AT(ADDR(.data.percpu) - LOAD_OFFSET) { \
	504	VMLINUX_SYMBOL(__per_cpu_load) = .; \
	505	VMLINUX_SYMBOL(__per_cpu_start) = .; \
	506	*(.data.percpu.first) \
63cc8c75	507	*(.data.percpu.page_aligned) \
5fb7dc37 FY	508	*(.data.percpu) \
5fb7dc37 FY	509	*(.data.percpu.shared_aligned) \
3ac6cffe TH	510	VMLINUX_SYMBOL(__per_cpu_end) = .; \
3ac6cffe TH	511	}