Commit | Line | Data |
---|---|---|
252b5132 RH |
1 | dnl Process this file with autoconf to produce a configure script |
2 | dnl | |
da594c4a AM |
3 | AC_PREREQ(2.59) |
4 | AC_INIT | |
5 | AC_CONFIG_SRCDIR(ldmain.c) | |
252b5132 | 6 | |
da594c4a | 7 | AC_CANONICAL_TARGET |
5d64ca4e | 8 | AC_ISC_POSIX |
252b5132 | 9 | |
27b7e12d AM |
10 | changequote(,)dnl |
11 | BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[ ]*\([^ ]*\)[ ]*).*/\1/p' < ${srcdir}/../bfd/configure.in` | |
12 | changequote([,])dnl | |
13 | AM_INIT_AUTOMAKE(ld, ${BFD_VERSION}) | |
252b5132 | 14 | |
8e523c23 | 15 | AC_ARG_WITH(lib-path, [ --with-lib-path=dir1:dir2... set default LIB_PATH],LIB_PATH=$withval) |
252b5132 RH |
16 | AC_ARG_ENABLE(targets, |
17 | [ --enable-targets alternative target configurations], | |
18 | [case "${enableval}" in | |
da594c4a | 19 | yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all') |
252b5132 RH |
20 | ;; |
21 | no) enable_targets= ;; | |
22 | *) enable_targets=$enableval ;; | |
23 | esac])dnl | |
24 | AC_ARG_ENABLE(64-bit-bfd, | |
25 | [ --enable-64-bit-bfd 64-bit support (on hosts with narrower word sizes)], | |
26 | [case "${enableval}" in | |
27 | yes) want64=true ;; | |
28 | no) want64=false ;; | |
29 | *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;; | |
30 | esac],[want64=false])dnl | |
31 | ||
9c8ebd6a DJ |
32 | AC_ARG_WITH(sysroot, |
33 | [ --with-sysroot[=DIR] Search for usr/lib et al within DIR.], | |
34 | [ | |
35 | case ${with_sysroot} in | |
715d1656 | 36 | yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;; |
9c8ebd6a DJ |
37 | *) TARGET_SYSTEM_ROOT=$with_sysroot ;; |
38 | esac | |
39 | ||
40 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"' | |
41 | use_sysroot=yes | |
42 | ||
fa1e8d8e RS |
43 | if test "x$prefix" = xNONE; then |
44 | test_prefix=/usr/local | |
45 | else | |
46 | test_prefix=$prefix | |
47 | fi | |
9c8ebd6a | 48 | if test "x$exec_prefix" = xNONE; then |
fa1e8d8e | 49 | test_exec_prefix=$test_prefix |
9c8ebd6a | 50 | else |
fa1e8d8e | 51 | test_exec_prefix=$exec_prefix |
9c8ebd6a DJ |
52 | fi |
53 | case ${TARGET_SYSTEM_ROOT} in | |
715d1656 | 54 | "${test_prefix}"|"${test_prefix}/"*|\ |
fa1e8d8e RS |
55 | "${test_exec_prefix}"|"${test_exec_prefix}/"*|\ |
56 | '${prefix}'|'${prefix}/'*|\ | |
715d1656 | 57 | '${exec_prefix}'|'${exec_prefix}/'*) |
9c8ebd6a DJ |
58 | t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE" |
59 | TARGET_SYSTEM_ROOT_DEFINE="$t" | |
60 | ;; | |
61 | esac | |
62 | ], [ | |
63 | use_sysroot=no | |
64 | TARGET_SYSTEM_ROOT= | |
65 | TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"' | |
66 | ]) | |
67 | AC_SUBST(use_sysroot) | |
68 | AC_SUBST(TARGET_SYSTEM_ROOT) | |
69 | AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE) | |
70 | ||
7fb9f789 NC |
71 | AC_ARG_ENABLE([got], |
72 | AS_HELP_STRING([--enable-got=<type>], | |
73 | [GOT handling scheme (target, single, negative, multigot)]), | |
74 | [case "${enableval}" in | |
75 | target | single | negative | multigot) got_handling=$enableval ;; | |
da594c4a | 76 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;; |
7fb9f789 NC |
77 | esac], |
78 | [got_handling=target]) | |
79 | ||
80 | case "${got_handling}" in | |
81 | target) | |
82 | AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT], | |
83 | [Define to choose default GOT handling scheme]) ;; | |
84 | single) | |
85 | AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE], | |
86 | [Define to choose default GOT handling scheme]) ;; | |
87 | negative) | |
88 | AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE], | |
89 | [Define to choose default GOT handling scheme]) ;; | |
90 | multigot) | |
91 | AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT], | |
92 | [Define to choose default GOT handling scheme]) ;; | |
da594c4a | 93 | *) AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;; |
7fb9f789 NC |
94 | esac |
95 | ||
502bdb00 | 96 | AM_BINUTILS_WARNINGS |
a2d91340 | 97 | |
da594c4a | 98 | AC_CONFIG_HEADERS([config.h:config.in]) |
252b5132 RH |
99 | |
100 | if test -z "$target" ; then | |
101 | AC_MSG_ERROR(Unrecognized target system type; please check config.sub.) | |
102 | fi | |
103 | if test -z "$host" ; then | |
104 | AC_MSG_ERROR(Unrecognized host system type; please check config.sub.) | |
105 | fi | |
106 | ||
107 | # host-specific stuff: | |
108 | ||
109 | AC_PROG_CC | |
67310ccd | 110 | AC_GNU_SOURCE |
7357c5b6 | 111 | AC_USE_SYSTEM_EXTENSIONS |
d053aef8 | 112 | AC_SYS_LARGEFILE |
252b5132 RH |
113 | AC_PROG_INSTALL |
114 | ||
da594c4a | 115 | LT_INIT |
ce2cded5 | 116 | |
19aec961 | 117 | ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi" |
20e95c23 DJ |
118 | ZW_GNU_GETTEXT_SISTER_DIR |
119 | AM_PO_SUBDIRS | |
252b5132 RH |
120 | |
121 | AC_EXEEXT | |
122 | ||
123 | AC_PROG_YACC | |
124 | AM_PROG_LEX | |
125 | ||
126 | AM_MAINTAINER_MODE | |
d5fbea21 | 127 | AM_CONDITIONAL(GENINSRC_NEVER, false) |
252b5132 RH |
128 | |
129 | . ${srcdir}/configure.host | |
130 | ||
131 | AC_SUBST(HDEFINES) | |
132 | AC_SUBST(HOSTING_CRT0) | |
133 | AC_SUBST(HOSTING_LIBS) | |
134 | AC_SUBST(NATIVE_LIB_DIRS) | |
135 | ||
a3ffa599 | 136 | AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h) |
dc27aea4 | 137 | AC_CHECK_FUNCS(glob mkstemp realpath sbrk waitpid) |
252b5132 RH |
138 | AC_HEADER_DIRENT |
139 | ||
34875e64 NC |
140 | AC_MSG_CHECKING(for a known getopt prototype in unistd.h) |
141 | AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h, | |
da594c4a | 142 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])], |
34875e64 NC |
143 | ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)]) |
144 | AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h) | |
145 | if test $ld_cv_decl_getopt_unistd_h = yes; then | |
146 | AC_DEFINE([HAVE_DECL_GETOPT], 1, | |
147 | [Is the prototype for getopt in <unistd.h> in the expected format?]) | |
148 | fi | |
149 | ||
252b5132 RH |
150 | BFD_BINARY_FOPEN |
151 | ||
502bdb00 | 152 | AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ]) |
252b5132 | 153 | |
4474d12b CS |
154 | # Link in zlib if we can. This is needed only for the bootstrap tests |
155 | # right now, since those tests use libbfd, which depends on zlib. | |
156 | AC_SEARCH_LIBS(zlibVersion, z, [AC_CHECK_HEADERS(zlib.h)]) | |
157 | ||
597e2591 ILT |
158 | # When converting linker scripts into strings for use in emulation |
159 | # files, use astring.sed if the compiler supports ANSI string | |
160 | # concatenation, or ostring.sed otherwise. This is to support the | |
161 | # broken Microsoft MSVC compiler, which limits the length of string | |
162 | # constants, while still supporting pre-ANSI compilers which do not | |
163 | # support string concatenation. | |
e4dabd0e | 164 | AC_MSG_CHECKING([whether ANSI C string concatenation works]) |
597e2591 | 165 | AC_CACHE_VAL(ld_cv_string_concatenation, |
da594c4a AM |
166 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])], |
167 | ld_cv_string_concatenation=yes, | |
168 | ld_cv_string_concatenation=no)]) | |
e4dabd0e AS |
169 | AC_MSG_RESULT($ld_cv_string_concatenation) |
170 | if test "$ld_cv_string_concatenation" = "yes"; then | |
597e2591 ILT |
171 | STRINGIFY=astring.sed |
172 | else | |
173 | STRINGIFY=ostring.sed | |
174 | fi | |
175 | AC_SUBST(STRINGIFY) | |
176 | ||
252b5132 RH |
177 | # target-specific stuff: |
178 | ||
179 | all_targets= | |
180 | EMUL= | |
181 | all_emuls= | |
182 | all_emul_extras= | |
ba2be581 | 183 | all_libpath= |
252b5132 RH |
184 | |
185 | dnl We need to get an arbitrary number of tdir definitions into | |
186 | dnl Makefile. We can't do it using AC_SUBST, because autoconf does | |
187 | dnl not permit literal newlines in an AC_SUBST variables. So we use a | |
188 | dnl file. | |
189 | rm -f tdirs | |
190 | ||
191 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` | |
192 | do | |
193 | if test "$targ_alias" = "all"; then | |
194 | all_targets=true | |
195 | else | |
196 | # Canonicalize the secondary target names. | |
42ecbf5e | 197 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
252b5132 RH |
198 | if test -n "$result"; then |
199 | targ=$result | |
200 | else | |
201 | targ=$targ_alias | |
202 | fi | |
203 | ||
204 | . ${srcdir}/configure.tgt | |
205 | ||
206 | if test "$targ" = "$target"; then | |
207 | EMUL=$targ_emul | |
208 | fi | |
209 | ||
314e9a4e L |
210 | if test x${want64} = xfalse; then |
211 | . ${srcdir}/../bfd/config.bfd | |
212 | fi | |
213 | ||
534d3119 L |
214 | if test x${want64} = xtrue; then |
215 | targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls" | |
216 | targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath" | |
217 | fi | |
218 | ||
3336653a | 219 | for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do |
252b5132 RH |
220 | case " $all_emuls " in |
221 | *" e${i}.o "*) ;; | |
222 | *) | |
223 | all_emuls="$all_emuls e${i}.o" | |
224 | eval result=\$tdir_$i | |
225 | test -z "$result" && result=$targ_alias | |
226 | echo tdir_$i=$result >> tdirs | |
227 | ;; | |
228 | esac | |
229 | done | |
230 | ||
ba2be581 | 231 | for i in $targ_emul $targ_extra_libpath; do |
3336653a RH |
232 | case " $all_libpath " in |
233 | *" ${i} "*) ;; | |
234 | *) | |
ba2be581 RH |
235 | if test -z "$all_libpath"; then |
236 | all_libpath=${i} | |
237 | else | |
238 | all_libpath="$all_libpath ${i}" | |
239 | fi | |
3336653a RH |
240 | ;; |
241 | esac | |
242 | done | |
243 | ||
252b5132 RH |
244 | for i in $targ_extra_ofiles; do |
245 | case " $all_emul_extras " in | |
246 | *" ${i} "*) ;; | |
247 | *) | |
248 | all_emul_extras="$all_emul_extras ${i}" | |
249 | ;; | |
250 | esac | |
251 | done | |
252 | fi | |
253 | done | |
254 | ||
255 | AC_SUBST(EMUL) | |
256 | ||
257 | TDIRS=tdirs | |
258 | AC_SUBST_FILE(TDIRS) | |
259 | ||
252b5132 | 260 | if test x${all_targets} = xtrue; then |
314e9a4e L |
261 | if test x${want64} = xfalse; then |
262 | AC_CHECK_SIZEOF(long) | |
263 | if test "x${ac_cv_sizeof_long}" = "x8"; then | |
264 | want64=true | |
265 | fi | |
266 | fi | |
252b5132 RH |
267 | if test x${want64} = xtrue; then |
268 | EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)' | |
269 | else | |
270 | EMULATION_OFILES='$(ALL_EMULATIONS)' | |
271 | fi | |
272 | EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)' | |
273 | else | |
274 | EMULATION_OFILES=$all_emuls | |
275 | EMUL_EXTRA_OFILES=$all_emul_extras | |
276 | fi | |
277 | AC_SUBST(EMULATION_OFILES) | |
278 | AC_SUBST(EMUL_EXTRA_OFILES) | |
8e523c23 | 279 | AC_SUBST(LIB_PATH) |
252b5132 | 280 | |
3336653a RH |
281 | EMULATION_LIBPATH=$all_libpath |
282 | AC_SUBST(EMULATION_LIBPATH) | |
283 | ||
252b5132 RH |
284 | if test x${enable_static} = xno; then |
285 | TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so" | |
286 | else | |
287 | TESTBFDLIB="../bfd/.libs/libbfd.a" | |
288 | fi | |
289 | AC_SUBST(TESTBFDLIB) | |
290 | ||
93a6d436 JL |
291 | target_vendor=${target_vendor=$host_vendor} |
292 | case "$target_vendor" in | |
293 | hp) EXTRA_SHLIB_EXTENSION=".sl" ;; | |
294 | *) EXTRA_SHLIB_EXTENSION= ;; | |
295 | esac | |
f234d5fe NC |
296 | |
297 | case "$target_os" in | |
298 | lynxos) EXTRA_SHLIB_EXTENSION=".a" ;; | |
299 | esac | |
300 | ||
93a6d436 JL |
301 | if test x${EXTRA_SHLIB_EXTENSION} != x ; then |
302 | AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION", | |
303 | [Additional extension a shared object might have.]) | |
304 | fi | |
305 | ||
108a6f8e CD |
306 | dnl Required by html and install-html |
307 | AC_SUBST(datarootdir) | |
308 | AC_SUBST(docdir) | |
309 | AC_SUBST(htmldir) | |
310 | ||
da594c4a AM |
311 | AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in) |
312 | AC_OUTPUT |