* archive.c (bfd_generic_archive_p): Preserve tdata in case of

[deliverable/binutils-gdb.git] / sim / configure.in

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.3)dnl
AC_INIT(Makefile.in)

AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
AC_CANONICAL_SYSTEM
AC_ARG_PROGRAM
AC_PROG_CC
AC_SUBST(CFLAGS)
AC_SUBST(HDEFINES)
AR=${AR-ar}
AC_SUBST(AR)
AC_PROG_RANLIB

# Put a plausible default for CC_FOR_BUILD in Makefile.
AC_C_CROSS
if test "x$cross_compiling" = "xno"; then
  CC_FOR_BUILD='$(CC)'
else
  CC_FOR_BUILD=gcc
fi
AC_SUBST(CC_FOR_BUILD)

AC_ARG_ENABLE(sim-powerpc,
[  --enable-sim-powerpc ],
[case "${enableval}" in
yes)	powerpc_sim=yes ;;
no)	powerpc_sim=no ;;
*)	AC_MSG_ERROR(bad value ${enableval} given for sim-powerpc option) ;;
esac],[if test x"$GCC" != x""; then powerpc_sim=yes; else powerpc_sim=no; fi])

# WHEN ADDING ENTRIES TO THIS MATRIX:
#  Make sure that the left side always has two dashes.  Otherwise you
#  can get spurious matches.  Even for unambiguous cases, do this as a
#  convention, else the table becomes a real mess to understand and maintain.

case "${target}" in
  arm*-*-*)		sim_target=arm ;;
  h8300*-*-*)		sim_target=h8300 ;;
  h8500-*-*)		sim_target=h8500 ;;
  mips*-*-*)		sim_target=mips ;;
  sh*-*-*)		sim_target=sh ;; 
  powerpc*-*-eabi*)	if test x"powerpc_sim" = x"yes"; then sim_target=ppc; fi ;;
  w65-*-*)		sim_target=w65 ;;
  z8k*-*-*)		sim_target=z8k ;;
  *)			sim_target=none ;;
esac

configdirs=${sim_target}
AC_CONFIG_SUBDIRS($configdirs)

AC_OUTPUT(Makefile)

exit 0