[deliverable/linux.git] / tools / perf / util / parse-events.l


%option reentrant
%option bison-bridge
%option prefix="parse_events_"
%option stack
%option bison-locations
%option yylineno

%{
#include <errno.h>
#include "../perf.h"
#include "parse-events-bison.h"
#include "parse-events.h"

char *parse_events_get_text(yyscan_t yyscanner);
YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);

static int __value(YYSTYPE *yylval, char *str, int base, int token)
{
	u64 num;

	errno = 0;
	num = strtoull(str, NULL, base);
	if (errno)
		return PE_ERROR;

	yylval->num = num;
	return token;
}

static int value(yyscan_t scanner, int base)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	return __value(yylval, text, base, PE_VALUE);
}

static int raw(yyscan_t scanner)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	return __value(yylval, text + 1, 16, PE_RAW);
}

static int str(yyscan_t scanner, int token)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	yylval->str = strdup(text);
	return token;
}

#define REWIND(__alloc)				\
do {								\
	YYSTYPE *__yylval = parse_events_get_lval(yyscanner);	\
	char *text = parse_events_get_text(yyscanner);		\
								\
	if (__alloc)						\
		__yylval->str = strdup(text);			\
								\
	yycolumn -= strlen(text);				\
	yyless(0);						\
} while (0)

static int pmu_str_check(yyscan_t scanner)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);
	char *text = parse_events_get_text(scanner);

	yylval->str = strdup(text);
	switch (perf_pmu__parse_check(text)) {
		case PMU_EVENT_SYMBOL_PREFIX:
			return PE_PMU_EVENT_PRE;
		case PMU_EVENT_SYMBOL_SUFFIX:
			return PE_PMU_EVENT_SUF;
		case PMU_EVENT_SYMBOL:
			return PE_KERNEL_PMU_EVENT;
		default:
			return PE_NAME;
	}
}

static int sym(yyscan_t scanner, int type, int config)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);

	yylval->num = (type << 16) + config;
	return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
}

static int term(yyscan_t scanner, int type)
{
	YYSTYPE *yylval = parse_events_get_lval(scanner);

	yylval->num = type;
	return PE_TERM;
}

#define YY_USER_ACTION					\
do {							\
	yylloc->last_column  = yylloc->first_column;	\
	yylloc->first_column = yycolumn;		\
	yycolumn += yyleng;				\
} while (0);

%}

%x mem
%s config
%x event

group		[^,{}/]*[{][^}]*[}][^,{}/]*
event_pmu	[^,{}/]+[/][^/]*[/][^,{}/]*
event		[^,{}/]+

num_dec		[0-9]+
num_hex		0x[a-fA-F0-9]+
num_raw_hex	[a-fA-F0-9]+
name		[a-zA-Z_*?][a-zA-Z0-9_*?.]*
name_minus	[a-zA-Z_*?][a-zA-Z0-9\-_*?.]*
/* If you add a modifier you need to update check_modifier() */
modifier_event	[ukhpPGHSDI]+
modifier_bp	[rwx]{1,3}

%%

%{
	{
		int start_token;

		start_token = parse_events_get_extra(yyscanner);

		if (start_token == PE_START_TERMS)
			BEGIN(config);
		else if (start_token == PE_START_EVENTS)
			BEGIN(event);

		if (start_token) {
			parse_events_set_extra(NULL, yyscanner);
			/*
			 * The flex parser does not init locations variable
			 * via the scan_string interface, so we need do the
			 * init in here.
			 */
			yycolumn = 0;
			return start_token;
		}
         }
%}

<event>{

{group}		{
			BEGIN(INITIAL);
			REWIND(0);
		}

{event_pmu}	|
{event}		{
			BEGIN(INITIAL);
			REWIND(1);
			return PE_EVENT_NAME;
		}

<<EOF>>		{
			BEGIN(INITIAL);
			REWIND(0);
		}

}

<config>{
	/*
	 * Please update parse_events_formats_error_string any time
	 * new static term is added.
	 */
config			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
config1			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
config2			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
name			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
period			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
freq			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
branch_type		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
time			{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
call-graph		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
stack-size		{ return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
,			{ return ','; }
"/"			{ BEGIN(INITIAL); return '/'; }
{name_minus}		{ return str(yyscanner, PE_NAME); }
}

<mem>{
{modifier_bp}		{ return str(yyscanner, PE_MODIFIER_BP); }
:			{ return ':'; }
"/"			{ return '/'; }
{num_dec}		{ return value(yyscanner, 10); }
{num_hex}		{ return value(yyscanner, 16); }
	/*
	 * We need to separate 'mem:' scanner part, in order to get specific
	 * modifier bits parsed out. Otherwise we would need to handle PE_NAME
	 * and we'd need to parse it manually. During the escape from <mem>
	 * state we need to put the escaping char back, so we dont miss it.
	 */
.			{ unput(*yytext); BEGIN(INITIAL); }
	/*
	 * We destroy the scanner after reaching EOF,
	 * but anyway just to be sure get back to INIT state.
	 */
<<EOF>>			{ BEGIN(INITIAL); }
}

cpu-cycles|cycles				{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
stalled-cycles-frontend|idle-cycles-frontend	{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
stalled-cycles-backend|idle-cycles-backend	{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
instructions					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
cache-references				{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
cache-misses					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
branch-instructions|branches			{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
branch-misses					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
bus-cycles					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
ref-cycles					{ return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
cpu-clock					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
task-clock					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
page-faults|faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
minor-faults					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
major-faults					{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
context-switches|cs				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
cpu-migrations|migrations			{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
alignment-faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
emulation-faults				{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
dummy						{ return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }

	/*
	 * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
	 * Because the prefix cycles is mixed up with cpu-cycles.
	 * loads and stores are mixed up with cache event
	 */
cycles-ct					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
cycles-t					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
mem-loads					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }
mem-stores					{ return str(yyscanner, PE_KERNEL_PMU_EVENT); }

L1-dcache|l1-d|l1d|L1-data		|
L1-icache|l1-i|l1i|L1-instruction	|
LLC|L2					|
dTLB|d-tlb|Data-TLB			|
iTLB|i-tlb|Instruction-TLB		|
branch|branches|bpu|btb|bpc		|
node					{ return str(yyscanner, PE_NAME_CACHE_TYPE); }

load|loads|read				|
store|stores|write			|
prefetch|prefetches			|
speculative-read|speculative-load	|
refs|Reference|ops|access		|
misses|miss				{ return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }

mem:			{ BEGIN(mem); return PE_PREFIX_MEM; }
r{num_raw_hex}		{ return raw(yyscanner); }
{num_dec}		{ return value(yyscanner, 10); }
{num_hex}		{ return value(yyscanner, 16); }

{modifier_event}	{ return str(yyscanner, PE_MODIFIER_EVENT); }
{name}			{ return pmu_str_check(yyscanner); }
"/"			{ BEGIN(config); return '/'; }
-			{ return '-'; }
,			{ BEGIN(event); return ','; }
:			{ return ':'; }
"{"			{ BEGIN(event); return '{'; }
"}"			{ return '}'; }
=			{ return '='; }
\n			{ }
.			{ }

%%

int parse_events_wrap(void *scanner __maybe_unused)
{
	return 1;
}
Commit	Line	Data
89812fc8	1
ac20de6f ZY	2	%option reentrant
ac20de6f ZY	3	%option bison-bridge
89812fc8	4	%option prefix="parse_events_"
08d2f762	5	%option stack
6297d423 JO	6	%option bison-locations
6297d423 JO	7	%option yylineno
89812fc8 JO	8
	9	%{
	10	#include <errno.h>
	11	#include "../perf.h"
	12	#include "parse-events-bison.h"
8f707d84	13	#include "parse-events.h"
89812fc8	14
ac20de6f ZY	15	char *parse_events_get_text(yyscan_t yyscanner);
	16	YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
	17
	18	static int __value(YYSTYPE yylval, char str, int base, int token)
89812fc8	19	{
b527bab5	20	u64 num;
89812fc8 JO	21
89812fc8 JO	22	errno = 0;
b527bab5	23	num = strtoull(str, NULL, base);
89812fc8 JO	24	if (errno)
	25	return PE_ERROR;
	26
ac20de6f	27	yylval->num = num;
89812fc8 JO	28	return token;
	29	}
	30
ac20de6f	31	static int value(yyscan_t scanner, int base)
89812fc8	32	{
ac20de6f ZY	33	YYSTYPE *yylval = parse_events_get_lval(scanner);
	34	char *text = parse_events_get_text(scanner);
	35
	36	return __value(yylval, text, base, PE_VALUE);
89812fc8 JO	37	}
89812fc8 JO	38
ac20de6f	39	static int raw(yyscan_t scanner)
89812fc8	40	{
ac20de6f ZY	41	YYSTYPE *yylval = parse_events_get_lval(scanner);
	42	char *text = parse_events_get_text(scanner);
	43
	44	return __value(yylval, text + 1, 16, PE_RAW);
89812fc8 JO	45	}
89812fc8 JO	46
ac20de6f	47	static int str(yyscan_t scanner, int token)
89812fc8	48	{
ac20de6f ZY	49	YYSTYPE *yylval = parse_events_get_lval(scanner);
	50	char *text = parse_events_get_text(scanner);
	51
	52	yylval->str = strdup(text);
89812fc8 JO	53	return token;
	54	}
	55
6297d423 JO	56	#define REWIND(__alloc) \
	57	do { \
	58	YYSTYPE *__yylval = parse_events_get_lval(yyscanner); \
	59	char *text = parse_events_get_text(yyscanner); \
	60	\
	61	if (__alloc) \
	62	__yylval->str = strdup(text); \
	63	\
	64	yycolumn -= strlen(text); \
	65	yyless(0); \
	66	} while (0)
	67
ba32a451 KL	68	static int pmu_str_check(yyscan_t scanner)
	69	{
	70	YYSTYPE *yylval = parse_events_get_lval(scanner);
	71	char *text = parse_events_get_text(scanner);
	72
	73	yylval->str = strdup(text);
	74	switch (perf_pmu__parse_check(text)) {
	75	case PMU_EVENT_SYMBOL_PREFIX:
	76	return PE_PMU_EVENT_PRE;
	77	case PMU_EVENT_SYMBOL_SUFFIX:
	78	return PE_PMU_EVENT_SUF;
	79	case PMU_EVENT_SYMBOL:
	80	return PE_KERNEL_PMU_EVENT;
	81	default:
	82	return PE_NAME;
	83	}
	84	}
	85
ac20de6f	86	static int sym(yyscan_t scanner, int type, int config)
89812fc8	87	{
ac20de6f ZY	88	YYSTYPE *yylval = parse_events_get_lval(scanner);
	89
	90	yylval->num = (type << 16) + config;
cf3506dc	91	return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
89812fc8 JO	92	}
89812fc8 JO	93
ac20de6f	94	static int term(yyscan_t scanner, int type)
8f707d84	95	{
ac20de6f ZY	96	YYSTYPE *yylval = parse_events_get_lval(scanner);
	97
	98	yylval->num = type;
8f707d84 JO	99	return PE_TERM;
	100	}
	101
6297d423 JO	102	#define YY_USER_ACTION \
	103	do { \
	104	yylloc->last_column = yylloc->first_column; \
	105	yylloc->first_column = yycolumn; \
	106	yycolumn += yyleng; \
	107	} while (0);
	108
89812fc8 JO	109	%}
89812fc8 JO	110
08d2f762	111	%x mem
ac2ba9f3 RR	112	%s config
	113	%x event
	114
	115	group [^,{}/][{][^}][}][^,{}/]*
	116	event_pmu [^,{}/]+[/][^/][/][^,{}/]
	117	event [^,{}/]+
08d2f762	118
89812fc8 JO	119	num_dec [0-9]+
	120	num_hex 0x[a-fA-F0-9]+
	121	num_raw_hex [a-fA-F0-9]+
5b021ddf AK	122	name [a-zA-Z_?][a-zA-Z0-9_?.]*
5b021ddf AK	123	name_minus [a-zA-Z_?][a-zA-Z0-9\-_?.]*
e9a7c414	124	/* If you add a modifier you need to update check_modifier() */
7f94af7a	125	modifier_event [ukhpPGHSDI]+
7582732f	126	modifier_bp [rwx]{1,3}
89812fc8 JO	127
89812fc8 JO	128	%%
90e2b22d JO	129
	130	%{
	131	{
	132	int start_token;
	133
ac2ba9f3 RR	134	start_token = parse_events_get_extra(yyscanner);
	135
	136	if (start_token == PE_START_TERMS)
	137	BEGIN(config);
	138	else if (start_token == PE_START_EVENTS)
	139	BEGIN(event);
	140
90e2b22d JO	141	if (start_token) {
90e2b22d JO	142	parse_events_set_extra(NULL, yyscanner);
6297d423 JO	143	/*
	144	* The flex parser does not init locations variable
	145	* via the scan_string interface, so we need do the
	146	* init in here.
	147	*/
	148	yycolumn = 0;
90e2b22d JO	149	return start_token;
	150	}
	151	}
	152	%}
	153
ac2ba9f3 RR	154	<event>{
	155
	156	{group} {
6297d423 JO	157	BEGIN(INITIAL);
6297d423 JO	158	REWIND(0);
ac2ba9f3 RR	159	}
	160
	161	{event_pmu} \|
	162	{event} {
6297d423 JO	163	BEGIN(INITIAL);
6297d423 JO	164	REWIND(1);
ac2ba9f3 RR	165	return PE_EVENT_NAME;
	166	}
	167
ac2ba9f3	168	<<EOF>> {
6297d423 JO	169	BEGIN(INITIAL);
6297d423 JO	170	REWIND(0);
ac2ba9f3 RR	171	}
	172
	173	}
	174
82004223	175	<config>{
e64b020b	176	/*
ffeb883e	177	* Please update parse_events_formats_error_string any time
e64b020b JO	178	* new static term is added.
e64b020b JO	179	*/
82004223 JO	180	config { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
	181	config1 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
	182	config2 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
	183	name { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
	184	period { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
09af2a55	185	freq { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
82004223	186	branch_type { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
32067712	187	time { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
d457c963 KL	188	call-graph { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
d457c963 KL	189	stack-size { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
82004223 JO	190	, { return ','; }
	191	"/" { BEGIN(INITIAL); return '/'; }
	192	{name_minus} { return str(yyscanner, PE_NAME); }
	193	}
	194
	195	<mem>{
	196	{modifier_bp} { return str(yyscanner, PE_MODIFIER_BP); }
	197	: { return ':'; }
3741eb9f	198	"/" { return '/'; }
82004223 JO	199	{num_dec} { return value(yyscanner, 10); }
	200	{num_hex} { return value(yyscanner, 16); }
	201	/*
	202	* We need to separate 'mem:' scanner part, in order to get specific
	203	* modifier bits parsed out. Otherwise we would need to handle PE_NAME
	204	* and we'd need to parse it manually. During the escape from <mem>
	205	* state we need to put the escaping char back, so we dont miss it.
	206	*/
	207	. { unput(*yytext); BEGIN(INITIAL); }
	208	/*
	209	* We destroy the scanner after reaching EOF,
	210	* but anyway just to be sure get back to INIT state.
	211	*/
	212	<<EOF>> { BEGIN(INITIAL); }
	213	}
	214
ac20de6f ZY	215	cpu-cycles\|cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
	216	stalled-cycles-frontend\|idle-cycles-frontend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
	217	stalled-cycles-backend\|idle-cycles-backend { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
	218	instructions { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
	219	cache-references { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
	220	cache-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
	221	branch-instructions\|branches { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
	222	branch-misses { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
	223	bus-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
	224	ref-cycles { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
	225	cpu-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
	226	task-clock { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
	227	page-faults\|faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
	228	minor-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
	229	major-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
	230	context-switches\|cs { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
	231	cpu-migrations\|migrations { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
	232	alignment-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
	233	emulation-faults { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
d22d1a2a	234	dummy { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
89812fc8	235
ba32a451 KL	236	/*
	237	* We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
	238	* Because the prefix cycles is mixed up with cpu-cycles.
	239	* loads and stores are mixed up with cache event
	240	*/
	241	cycles-ct { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	242	cycles-t { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	243	mem-loads { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	244	mem-stores { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
	245
89812fc8 JO	246	L1-dcache\|l1-d\|l1d\|L1-data \|
	247	L1-icache\|l1-i\|l1i\|L1-instruction \|
	248	LLC\|L2 \|
	249	dTLB\|d-tlb\|Data-TLB \|
	250	iTLB\|i-tlb\|Instruction-TLB \|
	251	branch\|branches\|bpu\|btb\|bpc \|
ac20de6f	252	node { return str(yyscanner, PE_NAME_CACHE_TYPE); }
89812fc8 JO	253
	254	load\|loads\|read \|
	255	store\|stores\|write \|
	256	prefetch\|prefetches \|
	257	speculative-read\|speculative-load \|
	258	refs\|Reference\|ops\|access \|
ac20de6f	259	misses\|miss { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
89812fc8	260
08d2f762	261	mem: { BEGIN(mem); return PE_PREFIX_MEM; }
ac20de6f ZY	262	r{num_raw_hex} { return raw(yyscanner); }
	263	{num_dec} { return value(yyscanner, 10); }
	264	{num_hex} { return value(yyscanner, 16); }
89812fc8	265
ac20de6f	266	{modifier_event} { return str(yyscanner, PE_MODIFIER_EVENT); }
ba32a451	267	{name} { return pmu_str_check(yyscanner); }
ac2ba9f3	268	"/" { BEGIN(config); return '/'; }
89812fc8	269	- { return '-'; }
ac2ba9f3	270	, { BEGIN(event); return ','; }
89812fc8	271	: { return ':'; }
ac2ba9f3	272	"{" { BEGIN(event); return '{'; }
89efb029	273	"}" { return '}'; }
89812fc8	274	= { return '='; }
8c5f0a84	275	\n { }
82004223	276	. { }
08d2f762	277
89812fc8 JO	278	%%
89812fc8 JO	279
1d037ca1	280	int parse_events_wrap(void *scanner __maybe_unused)
89812fc8 JO	281	{
	282	return 1;
	283	}