| 1 | dnl |
| 2 | dnl Copyright (C) 2012-2016 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is free software; you can redistribute it and/or modify |
| 5 | dnl it under the terms of the GNU General Public License as published by |
| 6 | dnl the Free Software Foundation; either version 3 of the License, or |
| 7 | dnl (at your option) any later version. |
| 8 | dnl |
| 9 | dnl This program is distributed in the hope that it will be useful, |
| 10 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 11 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 12 | dnl GNU General Public License for more details. |
| 13 | dnl |
| 14 | dnl You should have received a copy of the GNU General Public License |
| 15 | dnl along with this program; see the file COPYING3. If not see |
| 16 | dnl <http://www.gnu.org/licenses/>. |
| 17 | dnl |
| 18 | |
| 19 | dnl See whether we need to use fopen-bin.h rather than fopen-same.h. |
| 20 | AC_DEFUN([BFD_BINARY_FOPEN], |
| 21 | [AC_REQUIRE([AC_CANONICAL_TARGET]) |
| 22 | case "${host}" in |
| 23 | changequote(,)dnl |
| 24 | *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*) |
| 25 | changequote([,])dnl |
| 26 | AC_DEFINE(USE_BINARY_FOPEN, 1, [Use b modifier when opening binary files?]) ;; |
| 27 | esac])dnl |
| 28 | |
| 29 | dnl Get a default for CC_FOR_BUILD to put into Makefile. |
| 30 | AC_DEFUN([BFD_CC_FOR_BUILD], |
| 31 | [# Put a plausible default for CC_FOR_BUILD in Makefile. |
| 32 | if test -z "$CC_FOR_BUILD"; then |
| 33 | if test "x$cross_compiling" = "xno"; then |
| 34 | CC_FOR_BUILD='$(CC)' |
| 35 | else |
| 36 | CC_FOR_BUILD=gcc |
| 37 | fi |
| 38 | fi |
| 39 | AC_SUBST(CC_FOR_BUILD) |
| 40 | # Also set EXEEXT_FOR_BUILD. |
| 41 | if test "x$cross_compiling" = "xno"; then |
| 42 | EXEEXT_FOR_BUILD='$(EXEEXT)' |
| 43 | else |
| 44 | AC_CACHE_CHECK([for build system executable suffix], bfd_cv_build_exeext, |
| 45 | [rm -f conftest* |
| 46 | echo 'int main () { return 0; }' > conftest.c |
| 47 | bfd_cv_build_exeext= |
| 48 | ${CC_FOR_BUILD} -o conftest conftest.c 1>&5 2>&5 |
| 49 | for file in conftest.*; do |
| 50 | case $file in |
| 51 | *.c | *.o | *.obj | *.ilk | *.pdb) ;; |
| 52 | *) bfd_cv_build_exeext=`echo $file | sed -e s/conftest//` ;; |
| 53 | esac |
| 54 | done |
| 55 | rm -f conftest* |
| 56 | test x"${bfd_cv_build_exeext}" = x && bfd_cv_build_exeext=no]) |
| 57 | EXEEXT_FOR_BUILD="" |
| 58 | test x"${bfd_cv_build_exeext}" != xno && EXEEXT_FOR_BUILD=${bfd_cv_build_exeext} |
| 59 | fi |
| 60 | AC_SUBST(EXEEXT_FOR_BUILD)])dnl |
| 61 | |
| 62 | AC_DEFUN([AM_INSTALL_LIBBFD], |
| 63 | [AC_MSG_CHECKING([whether to install libbfd]) |
| 64 | AC_ARG_ENABLE(install-libbfd, |
| 65 | [ --enable-install-libbfd controls installation of libbfd and related headers], |
| 66 | install_libbfd_p=$enableval, |
| 67 | if test "${host}" = "${target}" || test "$enable_shared" = "yes"; then |
| 68 | install_libbfd_p=yes |
| 69 | else |
| 70 | install_libbfd_p=no |
| 71 | fi) |
| 72 | AC_MSG_RESULT($install_libbfd_p) |
| 73 | AM_CONDITIONAL(INSTALL_LIBBFD, test $install_libbfd_p = yes) |
| 74 | # Need _noncanonical variables for this. |
| 75 | ACX_NONCANONICAL_HOST |
| 76 | ACX_NONCANONICAL_TARGET |
| 77 | # libbfd.a is a host library containing target dependent code |
| 78 | bfdlibdir='$(libdir)' |
| 79 | bfdincludedir='$(includedir)' |
| 80 | if test "${host}" != "${target}"; then |
| 81 | bfdlibdir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/lib' |
| 82 | bfdincludedir='$(exec_prefix)/$(host_noncanonical)/$(target_noncanonical)/include' |
| 83 | fi |
| 84 | AC_SUBST(bfdlibdir) |
| 85 | AM_SUBST_NOTMAKE(bfdlibdir) |
| 86 | AC_SUBST(bfdincludedir) |
| 87 | AM_SUBST_NOTMAKE(bfdincludedir) |
| 88 | ] |
| 89 | ) |