| 1 | # Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, |
| 2 | # 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012 |
| 3 | # Free Software Foundation, Inc. |
| 4 | # |
| 5 | # This file is free software; you can redistribute it and/or modify it |
| 6 | # under the terms of the GNU General Public License as published by |
| 7 | # the Free Software Foundation; either version 3 of the License, or |
| 8 | # (at your option) any later version. |
| 9 | # |
| 10 | # This program is distributed in the hope that it will be useful, but |
| 11 | # WITHOUT ANY WARRANTY; without even the implied warranty of |
| 12 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| 13 | # General Public License for more details. |
| 14 | # |
| 15 | # You should have received a copy of the GNU General Public License |
| 16 | # along with this program; see the file COPYING3. If not see |
| 17 | # <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | ############################################################################## |
| 20 | ### WARNING: this file contains embedded tabs. Do not run untabify on this file. |
| 21 | |
| 22 | m4_include(config/acx.m4) |
| 23 | m4_include(config/override.m4) |
| 24 | m4_include(config/proginstall.m4) |
| 25 | m4_include(config/elf.m4) |
| 26 | m4_include([libtool.m4]) |
| 27 | m4_include([ltoptions.m4]) |
| 28 | m4_include([ltsugar.m4]) |
| 29 | m4_include([ltversion.m4]) |
| 30 | m4_include([lt~obsolete.m4]) |
| 31 | m4_include([config/isl.m4]) |
| 32 | m4_include([config/cloog.m4]) |
| 33 | |
| 34 | AC_INIT(move-if-change) |
| 35 | AC_PREREQ(2.64) |
| 36 | AC_DISABLE_OPTION_CHECKING |
| 37 | |
| 38 | progname=$0 |
| 39 | # if PWD already has a value, it is probably wrong. |
| 40 | if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi |
| 41 | |
| 42 | # Export original configure arguments for use by sub-configures. |
| 43 | # Quote arguments with shell meta charatcers. |
| 44 | TOPLEVEL_CONFIGURE_ARGUMENTS= |
| 45 | set -- "$progname" "$@" |
| 46 | for ac_arg |
| 47 | do |
| 48 | case "$ac_arg" in |
| 49 | *" "*|*" "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*) |
| 50 | ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` |
| 51 | # if the argument is of the form -foo=baz, quote the baz part only |
| 52 | ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;; |
| 53 | *) ;; |
| 54 | esac |
| 55 | # Add the quoted argument to the list. |
| 56 | TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg" |
| 57 | done |
| 58 | if test "$silent" = yes; then |
| 59 | TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent" |
| 60 | fi |
| 61 | # Remove the initial space we just introduced and, as these will be |
| 62 | # expanded by make, quote '$'. |
| 63 | TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'` |
| 64 | AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS) |
| 65 | |
| 66 | # Find the build, host, and target systems. |
| 67 | ACX_NONCANONICAL_BUILD |
| 68 | ACX_NONCANONICAL_HOST |
| 69 | ACX_NONCANONICAL_TARGET |
| 70 | |
| 71 | dnl Autoconf 2.5x and later will set a default program prefix if |
| 72 | dnl --target was used, even if it was the same as --host. Disable |
| 73 | dnl that behavior. This must be done before AC_CANONICAL_SYSTEM |
| 74 | dnl to take effect. |
| 75 | test "$host_noncanonical" = "$target_noncanonical" && |
| 76 | test "$program_prefix$program_suffix$program_transform_name" = \ |
| 77 | NONENONEs,x,x, && |
| 78 | program_transform_name=s,y,y, |
| 79 | |
| 80 | AC_CANONICAL_SYSTEM |
| 81 | AC_ARG_PROGRAM |
| 82 | |
| 83 | m4_pattern_allow([^AS_FOR_TARGET$])dnl |
| 84 | m4_pattern_allow([^AS_FOR_BUILD$])dnl |
| 85 | |
| 86 | # Get 'install' or 'install-sh' and its variants. |
| 87 | AC_PROG_INSTALL |
| 88 | ACX_PROG_LN |
| 89 | AC_PROG_LN_S |
| 90 | AC_PROG_SED |
| 91 | AC_PROG_AWK |
| 92 | |
| 93 | srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}` |
| 94 | |
| 95 | # We pass INSTALL explicitly to sub-makes. Make sure that it is not |
| 96 | # a relative path. |
| 97 | if test "$INSTALL" = "${srcdir}/install-sh -c"; then |
| 98 | INSTALL="${srcpwd}/install-sh -c" |
| 99 | fi |
| 100 | |
| 101 | # Set srcdir to "." if that's what it is. |
| 102 | # This is important for multilib support. |
| 103 | pwd=`${PWDCMD-pwd}` |
| 104 | if test "${pwd}" = "${srcpwd}" ; then |
| 105 | srcdir=. |
| 106 | fi |
| 107 | |
| 108 | topsrcdir=$srcpwd |
| 109 | |
| 110 | extra_host_args= |
| 111 | |
| 112 | ### To add a new directory to the tree, first choose whether it is a target |
| 113 | ### or a host dependent tool. Then put it into the appropriate list |
| 114 | ### (library or tools, host or target), doing a dependency sort. |
| 115 | |
| 116 | # Subdirs will be configured in the order listed in build_configdirs, |
| 117 | # configdirs, or target_configdirs; see the serialization section below. |
| 118 | |
| 119 | # Dependency sorting is only needed when *configuration* must be done in |
| 120 | # a particular order. In all cases a dependency should be specified in |
| 121 | # the Makefile, whether or not it's implicitly specified here. |
| 122 | |
| 123 | # Double entries in build_configdirs, configdirs, or target_configdirs may |
| 124 | # cause circular dependencies and break everything horribly. |
| 125 | |
| 126 | # these library is used by various programs built for the build |
| 127 | # environment |
| 128 | # |
| 129 | build_libs="build-libiberty" |
| 130 | |
| 131 | # these tools are built for the build environment |
| 132 | build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes" |
| 133 | |
| 134 | # these libraries are used by various programs built for the host environment |
| 135 | # |
| 136 | host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl cloog libelf libiconv" |
| 137 | |
| 138 | # these tools are built for the host environment |
| 139 | # Note, the powerpc-eabi build depends on sim occurring before gdb in order to |
| 140 | # know that we are building the simulator. |
| 141 | # binutils, gas and ld appear in that order because it makes sense to run |
| 142 | # "make check" in that particular order. |
| 143 | # If --enable-gold is used, "gold" may replace "ld". |
| 144 | host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools" |
| 145 | |
| 146 | # libgcj represents the runtime libraries only used by gcj. |
| 147 | libgcj="target-libffi \ |
| 148 | target-zlib \ |
| 149 | target-libjava" |
| 150 | |
| 151 | # these libraries are built for the target environment, and are built after |
| 152 | # the host libraries and the host tools (which may be a cross compiler) |
| 153 | # Note that libiberty is not a target library. |
| 154 | target_libraries="target-libgcc \ |
| 155 | target-libbacktrace \ |
| 156 | target-libgloss \ |
| 157 | target-newlib \ |
| 158 | target-libgomp \ |
| 159 | target-libcilkrts \ |
| 160 | target-libatomic \ |
| 161 | target-libitm \ |
| 162 | target-libstdc++-v3 \ |
| 163 | target-libsanitizer \ |
| 164 | target-libvtv \ |
| 165 | target-libssp \ |
| 166 | target-libquadmath \ |
| 167 | target-libgfortran \ |
| 168 | target-boehm-gc \ |
| 169 | ${libgcj} \ |
| 170 | target-libobjc \ |
| 171 | target-libada \ |
| 172 | target-libgo" |
| 173 | |
| 174 | # these tools are built using the target libraries, and are intended to |
| 175 | # run only in the target environment |
| 176 | # |
| 177 | # note: any program that *uses* libraries that are in the "target_libraries" |
| 178 | # list belongs in this list. |
| 179 | # |
| 180 | target_tools="target-rda" |
| 181 | |
| 182 | ################################################################################ |
| 183 | |
| 184 | ## All tools belong in one of the four categories, and are assigned above |
| 185 | ## We assign ${configdirs} this way to remove all embedded newlines. This |
| 186 | ## is important because configure will choke if they ever get through. |
| 187 | ## ${configdirs} is directories we build using the host tools. |
| 188 | ## ${target_configdirs} is directories we build using the target tools. |
| 189 | configdirs=`echo ${host_libs} ${host_tools}` |
| 190 | target_configdirs=`echo ${target_libraries} ${target_tools}` |
| 191 | build_configdirs=`echo ${build_libs} ${build_tools}` |
| 192 | |
| 193 | m4_divert_text([PARSE_ARGS], |
| 194 | [case $srcdir in |
| 195 | *" "*) |
| 196 | m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl |
| 197 | AC_MSG_ERROR([path to source, $srcdir, contains spaces]) |
| 198 | m4_popdef([AS_MESSAGE_LOG_FD])dnl |
| 199 | ;; |
| 200 | esac |
| 201 | ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'` |
| 202 | ]) |
| 203 | |
| 204 | ################################################################################ |
| 205 | |
| 206 | srcname="gnu development package" |
| 207 | |
| 208 | # This gets set non-empty for some net releases of packages. |
| 209 | appdirs="" |
| 210 | |
| 211 | # Define is_cross_compiler to save on calls to 'test'. |
| 212 | is_cross_compiler= |
| 213 | if test x"${host}" = x"${target}" ; then |
| 214 | is_cross_compiler=no |
| 215 | else |
| 216 | is_cross_compiler=yes |
| 217 | fi |
| 218 | |
| 219 | # Find the build and target subdir names. |
| 220 | GCC_TOPLEV_SUBDIRS |
| 221 | # Be sure to cover against remnants of an in-tree build. |
| 222 | if test $srcdir != . && test -d $srcdir/host-${host_noncanonical}; then |
| 223 | AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}. |
| 224 | Use a pristine source tree when building in a separate tree]) |
| 225 | fi |
| 226 | |
| 227 | # Skipdirs are removed silently. |
| 228 | skipdirs= |
| 229 | # Noconfigdirs are removed loudly. |
| 230 | noconfigdirs="" |
| 231 | |
| 232 | use_gnu_ld= |
| 233 | # Make sure we don't let GNU ld be added if we didn't want it. |
| 234 | if test x$with_gnu_ld = xno ; then |
| 235 | use_gnu_ld=no |
| 236 | noconfigdirs="$noconfigdirs ld gold" |
| 237 | fi |
| 238 | |
| 239 | use_gnu_as= |
| 240 | # Make sure we don't let GNU as be added if we didn't want it. |
| 241 | if test x$with_gnu_as = xno ; then |
| 242 | use_gnu_as=no |
| 243 | noconfigdirs="$noconfigdirs gas" |
| 244 | fi |
| 245 | |
| 246 | use_included_zlib= |
| 247 | # Make sure we don't let ZLIB be added if we didn't want it. |
| 248 | if test x$with_system_zlib = xyes ; then |
| 249 | use_included_zlib=no |
| 250 | noconfigdirs="$noconfigdirs zlib" |
| 251 | fi |
| 252 | |
| 253 | # some tools are so dependent upon X11 that if we're not building with X, |
| 254 | # it's not even worth trying to configure, much less build, that tool. |
| 255 | |
| 256 | case ${with_x} in |
| 257 | yes | "") ;; # the default value for this tree is that X11 is available |
| 258 | no) |
| 259 | skipdirs="${skipdirs} tk itcl libgui" |
| 260 | # We won't be able to build gdbtk without X. |
| 261 | enable_gdbtk=no |
| 262 | ;; |
| 263 | *) echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;; |
| 264 | esac |
| 265 | |
| 266 | # Some are only suitable for cross toolchains. |
| 267 | # Remove these if host=target. |
| 268 | cross_only="target-libgloss target-newlib target-opcodes" |
| 269 | |
| 270 | case $is_cross_compiler in |
| 271 | no) skipdirs="${skipdirs} ${cross_only}" ;; |
| 272 | esac |
| 273 | |
| 274 | # If both --with-headers and --with-libs are specified, default to |
| 275 | # --without-newlib. |
| 276 | if test x"${with_headers}" != x && test x"${with_headers}" != xno \ |
| 277 | && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then |
| 278 | if test x"${with_newlib}" = x ; then |
| 279 | with_newlib=no |
| 280 | fi |
| 281 | fi |
| 282 | |
| 283 | # Recognize --with-newlib/--without-newlib. |
| 284 | case ${with_newlib} in |
| 285 | no) skipdirs="${skipdirs} target-newlib" ;; |
| 286 | yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;; |
| 287 | esac |
| 288 | |
| 289 | # Handle --enable-gold, --enable-ld. |
| 290 | # --disable-gold [--enable-ld] |
| 291 | # Build only ld. Default option. |
| 292 | # --enable-gold [--enable-ld] |
| 293 | # Build both gold and ld. Install gold as "ld.gold", install ld |
| 294 | # as "ld.bfd" and "ld". |
| 295 | # --enable-gold=default [--enable-ld] |
| 296 | # Build both gold and ld. Install gold as "ld.gold" and "ld", |
| 297 | # install ld as "ld.bfd". |
| 298 | # --enable-gold[=default] --disable-ld |
| 299 | # Build only gold, which is then installed as both "ld.gold" and "ld". |
| 300 | # --enable-gold --enable-ld=default |
| 301 | # Build both gold (installed as "ld.gold") and ld (installed as "ld" |
| 302 | # and ld.bfd). |
| 303 | # In other words, ld is default |
| 304 | # --enable-gold=default --enable-ld=default |
| 305 | # Error. |
| 306 | |
| 307 | default_ld= |
| 308 | AC_ARG_ENABLE(gold, |
| 309 | [AS_HELP_STRING([[--enable-gold[=ARG]]], |
| 310 | [build gold @<:@ARG={default,yes,no}@:>@])], |
| 311 | ENABLE_GOLD=$enableval, |
| 312 | ENABLE_GOLD=no) |
| 313 | case "${ENABLE_GOLD}" in |
| 314 | yes|default) |
| 315 | # Check for ELF target. |
| 316 | is_elf=no |
| 317 | case "${target}" in |
| 318 | *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \ |
| 319 | | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \ |
| 320 | | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \ |
| 321 | | *-*-solaris2* | *-*-nto* | *-*-nacl*) |
| 322 | case "${target}" in |
| 323 | *-*-linux*aout* | *-*-linux*oldld*) |
| 324 | ;; |
| 325 | *) |
| 326 | is_elf=yes |
| 327 | ;; |
| 328 | esac |
| 329 | esac |
| 330 | |
| 331 | if test "$is_elf" = "yes"; then |
| 332 | # Check for target supported by gold. |
| 333 | case "${target}" in |
| 334 | i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* | tilegx*-*-*) |
| 335 | configdirs="$configdirs gold" |
| 336 | if test x${ENABLE_GOLD} = xdefault; then |
| 337 | default_ld=gold |
| 338 | fi |
| 339 | ENABLE_GOLD=yes |
| 340 | ;; |
| 341 | esac |
| 342 | fi |
| 343 | ;; |
| 344 | no) |
| 345 | ;; |
| 346 | *) |
| 347 | AC_MSG_ERROR([invalid --enable-gold argument]) |
| 348 | ;; |
| 349 | esac |
| 350 | |
| 351 | AC_ARG_ENABLE(ld, |
| 352 | [AS_HELP_STRING([[--enable-ld[=ARG]]], |
| 353 | [build ld @<:@ARG={default,yes,no}@:>@])], |
| 354 | ENABLE_LD=$enableval, |
| 355 | ENABLE_LD=yes) |
| 356 | |
| 357 | case "${ENABLE_LD}" in |
| 358 | default) |
| 359 | if test x${default_ld} != x; then |
| 360 | AC_MSG_ERROR([either gold or ld can be the default ld]) |
| 361 | fi |
| 362 | ;; |
| 363 | yes) |
| 364 | ;; |
| 365 | no) |
| 366 | if test x${ENABLE_GOLD} != xyes; then |
| 367 | AC_MSG_WARN([neither ld nor gold are enabled]) |
| 368 | fi |
| 369 | configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'` |
| 370 | ;; |
| 371 | *) |
| 372 | AC_MSG_ERROR([invalid --enable-ld argument]) |
| 373 | ;; |
| 374 | esac |
| 375 | |
| 376 | # Configure extra directories which are host specific |
| 377 | |
| 378 | case "${host}" in |
| 379 | *-cygwin*) |
| 380 | configdirs="$configdirs libtermcap" ;; |
| 381 | esac |
| 382 | |
| 383 | # A target can indicate whether a language isn't supported for some reason. |
| 384 | # Only spaces may be used in this macro; not newlines or tabs. |
| 385 | unsupported_languages= |
| 386 | |
| 387 | # Remove more programs from consideration, based on the host or |
| 388 | # target this usually means that a port of the program doesn't |
| 389 | # exist yet. |
| 390 | |
| 391 | case "${host}" in |
| 392 | i[[3456789]]86-*-msdosdjgpp*) |
| 393 | noconfigdirs="$noconfigdirs tcl tk itcl" |
| 394 | ;; |
| 395 | esac |
| 396 | |
| 397 | |
| 398 | AC_ARG_ENABLE(libquadmath, |
| 399 | AS_HELP_STRING([--disable-libquadmath], |
| 400 | [do not build libquadmath directory]), |
| 401 | ENABLE_LIBQUADMATH=$enableval, |
| 402 | ENABLE_LIBQUADMATH=yes) |
| 403 | if test "${ENABLE_LIBQUADMATH}" = "no" ; then |
| 404 | noconfigdirs="$noconfigdirs target-libquadmath" |
| 405 | fi |
| 406 | |
| 407 | |
| 408 | AC_ARG_ENABLE(libquadmath-support, |
| 409 | AS_HELP_STRING([--disable-libquadmath-support], |
| 410 | [disable libquadmath support for Fortran]), |
| 411 | ENABLE_LIBQUADMATH_SUPPORT=$enableval, |
| 412 | ENABLE_LIBQUADMATH_SUPPORT=yes) |
| 413 | enable_libquadmath_support= |
| 414 | if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then |
| 415 | enable_libquadmath_support=no |
| 416 | fi |
| 417 | |
| 418 | |
| 419 | AC_ARG_ENABLE(libada, |
| 420 | [AS_HELP_STRING([--enable-libada], [build libada directory])], |
| 421 | ENABLE_LIBADA=$enableval, |
| 422 | ENABLE_LIBADA=yes) |
| 423 | if test "${ENABLE_LIBADA}" != "yes" ; then |
| 424 | noconfigdirs="$noconfigdirs gnattools" |
| 425 | fi |
| 426 | |
| 427 | AC_ARG_ENABLE(libssp, |
| 428 | [AS_HELP_STRING([--enable-libssp], [build libssp directory])], |
| 429 | ENABLE_LIBSSP=$enableval, |
| 430 | ENABLE_LIBSSP=yes) |
| 431 | |
| 432 | AC_ARG_ENABLE(libstdcxx, |
| 433 | AS_HELP_STRING([--disable-libstdcxx], |
| 434 | [do not build libstdc++-v3 directory]), |
| 435 | ENABLE_LIBSTDCXX=$enableval, |
| 436 | ENABLE_LIBSTDCXX=default) |
| 437 | [if test "${ENABLE_LIBSTDCXX}" = "no" ; then |
| 438 | noconfigdirs="$noconfigdirs libstdc++-v3" |
| 439 | fi] |
| 440 | |
| 441 | # Save it here so that, even in case of --enable-libgcj, if the Java |
| 442 | # front-end isn't enabled, we still get libgcj disabled. |
| 443 | libgcj_saved=$libgcj |
| 444 | case $enable_libgcj in |
| 445 | yes) |
| 446 | # If we reset it here, it won't get added to noconfigdirs in the |
| 447 | # target-specific build rules, so it will be forcibly enabled |
| 448 | # (unless the Java language itself isn't enabled). |
| 449 | libgcj= |
| 450 | ;; |
| 451 | no) |
| 452 | # Make sure we get it printed in the list of not supported target libs. |
| 453 | # Don't disable libffi, though, other languages use it. |
| 454 | noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`" |
| 455 | # Clear libgcj_saved so that even if java is enabled libffi won't be |
| 456 | # built. |
| 457 | libgcj_saved= |
| 458 | ;; |
| 459 | esac |
| 460 | |
| 461 | AC_ARG_ENABLE(static-libjava, |
| 462 | [AS_HELP_STRING([[--enable-static-libjava[=ARG]]], |
| 463 | [build static libjava @<:@default=no@:>@])], |
| 464 | ENABLE_STATIC_LIBJAVA=$enableval, |
| 465 | ENABLE_STATIC_LIBJAVA=no) |
| 466 | enable_static_libjava= |
| 467 | if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then |
| 468 | enable_static_libjava=yes |
| 469 | fi |
| 470 | |
| 471 | if test x$enable_static_libjava != xyes ; then |
| 472 | EXTRA_CONFIGARGS_LIBJAVA=--disable-static |
| 473 | fi |
| 474 | AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA) |
| 475 | |
| 476 | # Disable libgomp on non POSIX hosted systems. |
| 477 | if test x$enable_libgomp = x ; then |
| 478 | # Enable libgomp by default on hosted POSIX systems. |
| 479 | case "${target}" in |
| 480 | *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu) |
| 481 | ;; |
| 482 | *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*) |
| 483 | ;; |
| 484 | *-*-solaris2* | *-*-hpux11*) |
| 485 | ;; |
| 486 | *-*-darwin* | *-*-aix*) |
| 487 | ;; |
| 488 | *) |
| 489 | noconfigdirs="$noconfigdirs target-libgomp" |
| 490 | ;; |
| 491 | esac |
| 492 | fi |
| 493 | |
| 494 | # Disable libatomic on unsupported systems. |
| 495 | if test -d ${srcdir}/libatomic; then |
| 496 | if test x$enable_libatomic = x; then |
| 497 | AC_MSG_CHECKING([for libatomic support]) |
| 498 | if (srcdir=${srcdir}/libatomic; \ |
| 499 | . ${srcdir}/configure.tgt; \ |
| 500 | test -n "$UNSUPPORTED") |
| 501 | then |
| 502 | AC_MSG_RESULT([no]) |
| 503 | noconfigdirs="$noconfigdirs target-libatomic" |
| 504 | else |
| 505 | AC_MSG_RESULT([yes]) |
| 506 | fi |
| 507 | fi |
| 508 | fi |
| 509 | |
| 510 | # Disable libcilkrts on unsupported systems. |
| 511 | if test -d ${srcdir}/libcilkrts; then |
| 512 | if test x$enable_libcilkrts = x; then |
| 513 | AC_MSG_CHECKING([for libcilkrts support]) |
| 514 | if (srcdir=${srcdir}/libcilkrts; \ |
| 515 | . ${srcdir}/configure.tgt; \ |
| 516 | test -n "$UNSUPPORTED") |
| 517 | then |
| 518 | AC_MSG_RESULT([no]) |
| 519 | noconfigdirs="$noconfigdirs target-libcilkrts" |
| 520 | else |
| 521 | AC_MSG_RESULT([yes]) |
| 522 | fi |
| 523 | fi |
| 524 | fi |
| 525 | |
| 526 | # Disable libitm on unsupported systems. |
| 527 | if test -d ${srcdir}/libitm; then |
| 528 | if test x$enable_libitm = x; then |
| 529 | AC_MSG_CHECKING([for libitm support]) |
| 530 | if (srcdir=${srcdir}/libitm; \ |
| 531 | . ${srcdir}/configure.tgt; \ |
| 532 | test -n "$UNSUPPORTED") |
| 533 | then |
| 534 | AC_MSG_RESULT([no]) |
| 535 | noconfigdirs="$noconfigdirs target-libitm" |
| 536 | else |
| 537 | AC_MSG_RESULT([yes]) |
| 538 | fi |
| 539 | fi |
| 540 | fi |
| 541 | |
| 542 | # Disable libsanitizer on unsupported systems. |
| 543 | if test -d ${srcdir}/libsanitizer; then |
| 544 | if test x$enable_libsanitizer = x; then |
| 545 | AC_MSG_CHECKING([for libsanitizer support]) |
| 546 | if (srcdir=${srcdir}/libsanitizer; \ |
| 547 | . ${srcdir}/configure.tgt; \ |
| 548 | test -n "$UNSUPPORTED") |
| 549 | then |
| 550 | AC_MSG_RESULT([no]) |
| 551 | noconfigdirs="$noconfigdirs target-libsanitizer" |
| 552 | else |
| 553 | AC_MSG_RESULT([yes]) |
| 554 | fi |
| 555 | fi |
| 556 | fi |
| 557 | |
| 558 | # Disable libvtv on unsupported systems. |
| 559 | if test -d ${srcdir}/libvtv; then |
| 560 | if test x$enable_libvtv = x; then |
| 561 | AC_MSG_CHECKING([for libvtv support]) |
| 562 | if (srcdir=${srcdir}/libvtv; \ |
| 563 | . ${srcdir}/configure.tgt; \ |
| 564 | test "$VTV_SUPPORTED" != "yes") |
| 565 | then |
| 566 | AC_MSG_RESULT([no]) |
| 567 | noconfigdirs="$noconfigdirs target-libvtv" |
| 568 | else |
| 569 | AC_MSG_RESULT([yes]) |
| 570 | fi |
| 571 | fi |
| 572 | fi |
| 573 | |
| 574 | # Disable libquadmath for some systems. |
| 575 | case "${target}" in |
| 576 | avr-*-*) |
| 577 | noconfigdirs="$noconfigdirs target-libquadmath" |
| 578 | ;; |
| 579 | # libquadmath is unused on AIX and libquadmath build process use of |
| 580 | # LD_LIBRARY_PATH can break AIX bootstrap. |
| 581 | powerpc-*-aix* | rs6000-*-aix*) |
| 582 | noconfigdirs="$noconfigdirs target-libquadmath" |
| 583 | ;; |
| 584 | esac |
| 585 | |
| 586 | # Disable libssp for some systems. |
| 587 | case "${target}" in |
| 588 | avr-*-*) |
| 589 | # No hosted I/O support. |
| 590 | noconfigdirs="$noconfigdirs target-libssp" |
| 591 | ;; |
| 592 | powerpc-*-aix* | rs6000-*-aix*) |
| 593 | noconfigdirs="$noconfigdirs target-libssp" |
| 594 | ;; |
| 595 | rl78-*-*) |
| 596 | # libssp uses a misaligned load to trigger a fault, but the RL78 |
| 597 | # doesn't fault for those - instead, it gives a build-time error |
| 598 | # for explicit misaligned loads. |
| 599 | noconfigdirs="$noconfigdirs target-libssp" |
| 600 | ;; |
| 601 | esac |
| 602 | |
| 603 | # Disable libstdc++-v3 for some systems. |
| 604 | # Allow user to override this if they pass --enable-libstdc++-v3 |
| 605 | if test "${ENABLE_LIBSTDCXX}" = "default" ; then |
| 606 | case "${target}" in |
| 607 | *-*-vxworks*) |
| 608 | # VxWorks uses the Dinkumware C++ library. |
| 609 | noconfigdirs="$noconfigdirs target-libstdc++-v3" |
| 610 | ;; |
| 611 | arm*-wince-pe*) |
| 612 | # the C++ libraries don't build on top of CE's C libraries |
| 613 | noconfigdirs="$noconfigdirs target-libstdc++-v3" |
| 614 | ;; |
| 615 | avr-*-*) |
| 616 | noconfigdirs="$noconfigdirs target-libstdc++-v3" |
| 617 | ;; |
| 618 | esac |
| 619 | fi |
| 620 | |
| 621 | # Disable Fortran for some systems. |
| 622 | case "${target}" in |
| 623 | mmix-*-*) |
| 624 | # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>. |
| 625 | unsupported_languages="$unsupported_languages fortran" |
| 626 | ;; |
| 627 | esac |
| 628 | |
| 629 | # Disable Java if libffi is not supported. |
| 630 | case "${target}" in |
| 631 | aarch64-*-*) |
| 632 | ;; |
| 633 | alpha*-*-*) |
| 634 | ;; |
| 635 | arm*-*-*) |
| 636 | ;; |
| 637 | cris-*-*) |
| 638 | ;; |
| 639 | frv-*-*) |
| 640 | ;; |
| 641 | hppa*-*-linux*) |
| 642 | ;; |
| 643 | hppa*-*-hpux*) |
| 644 | ;; |
| 645 | i?86-*-*) |
| 646 | ;; |
| 647 | ia64*-*-*) |
| 648 | ;; |
| 649 | m32r*-*-*) |
| 650 | ;; |
| 651 | m68k-*-*) |
| 652 | ;; |
| 653 | mips*-*-rtems*) |
| 654 | ;; |
| 655 | mips*-*-linux*) |
| 656 | ;; |
| 657 | powerpc*-*-linux*) |
| 658 | ;; |
| 659 | powerpc-*-darwin*) |
| 660 | ;; |
| 661 | powerpc-*-aix* | rs6000-*-aix*) |
| 662 | ;; |
| 663 | powerpc-*-freebsd*) |
| 664 | ;; |
| 665 | powerpc64-*-freebsd*) |
| 666 | ;; |
| 667 | powerpc*-*-rtems*) |
| 668 | ;; |
| 669 | s390-*-* | s390x-*-*) |
| 670 | ;; |
| 671 | sh-*-* | sh[[34]]*-*-*) |
| 672 | ;; |
| 673 | sh64-*-* | sh5*-*-*) |
| 674 | ;; |
| 675 | sparc*-*-*) |
| 676 | ;; |
| 677 | x86_64-*-*) |
| 678 | ;; |
| 679 | *-*-*) |
| 680 | unsupported_languages="$unsupported_languages java" |
| 681 | ;; |
| 682 | esac |
| 683 | |
| 684 | # Disable Java, libgcj or related libraries for some systems. |
| 685 | case "${target}" in |
| 686 | powerpc-*-darwin*) |
| 687 | ;; |
| 688 | i[[3456789]]86-*-darwin*) |
| 689 | ;; |
| 690 | x86_64-*-darwin[[912]]*) |
| 691 | ;; |
| 692 | *-*-darwin*) |
| 693 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 694 | ;; |
| 695 | *-*-netware*) |
| 696 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 697 | ;; |
| 698 | *-*-rtems*) |
| 699 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 700 | ;; |
| 701 | *-*-tpf*) |
| 702 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 703 | ;; |
| 704 | *-*-uclinux*) |
| 705 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 706 | ;; |
| 707 | *-*-vxworks*) |
| 708 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 709 | ;; |
| 710 | alpha*-*-*vms*) |
| 711 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 712 | ;; |
| 713 | arm-wince-pe) |
| 714 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 715 | ;; |
| 716 | arm*-*-symbianelf*) |
| 717 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 718 | ;; |
| 719 | bfin-*-*) |
| 720 | noconfigdirs="$noconfigdirs target-boehm-gc" |
| 721 | ;; |
| 722 | cris-*-* | crisv32-*-*) |
| 723 | unsupported_languages="$unsupported_languages java" |
| 724 | case "${target}" in |
| 725 | *-*-linux*) |
| 726 | ;; |
| 727 | *) # See PR46792 regarding target-libffi. |
| 728 | noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";; |
| 729 | esac |
| 730 | ;; |
| 731 | hppa*64*-*-linux*) |
| 732 | # In this case, it's because the hppa64-linux target is for |
| 733 | # the kernel only at this point and has no libc, and thus no |
| 734 | # headers, crt*.o, etc., all of which are needed by these. |
| 735 | unsupported_languages="$unsupported_languages java" |
| 736 | ;; |
| 737 | hppa*64*-*-hpux*) |
| 738 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 739 | ;; |
| 740 | hppa*-hp-hpux11*) |
| 741 | ;; |
| 742 | hppa*-*-hpux*) |
| 743 | # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't |
| 744 | # build on HP-UX 10.20. |
| 745 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 746 | ;; |
| 747 | ia64*-*-*vms*) |
| 748 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 749 | ;; |
| 750 | i[[3456789]]86-w64-mingw*) |
| 751 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 752 | ;; |
| 753 | i[[3456789]]86-*-mingw*) |
| 754 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 755 | ;; |
| 756 | x86_64-*-mingw*) |
| 757 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 758 | ;; |
| 759 | mmix-*-*) |
| 760 | noconfigdirs="$noconfigdirs target-libffi target-boehm-gc" |
| 761 | ;; |
| 762 | powerpc-*-aix*) |
| 763 | # copied from rs6000-*-* entry |
| 764 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 765 | ;; |
| 766 | rs6000-*-aix*) |
| 767 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 768 | ;; |
| 769 | *-*-lynxos*) |
| 770 | noconfigdirs="$noconfigdirs ${libgcj}" |
| 771 | ;; |
| 772 | esac |
| 773 | |
| 774 | # Disable libgo for some systems where it is known to not work. |
| 775 | # For testing, you can easily override this with --enable-libgo. |
| 776 | if test x$enable_libgo = x; then |
| 777 | case "${target}" in |
| 778 | *-*-darwin*) |
| 779 | # PR 46986 |
| 780 | noconfigdirs="$noconfigdirs target-libgo" |
| 781 | ;; |
| 782 | *-*-cygwin* | *-*-mingw*) |
| 783 | noconfigdirs="$noconfigdirs target-libgo" |
| 784 | ;; |
| 785 | *-*-aix*) |
| 786 | noconfigdirs="$noconfigdirs target-libgo" |
| 787 | ;; |
| 788 | esac |
| 789 | fi |
| 790 | |
| 791 | # Default libgloss CPU subdirectory. |
| 792 | libgloss_dir="$target_cpu" |
| 793 | |
| 794 | case "${target}" in |
| 795 | sh*-*-pe|mips*-*-pe|*arm-wince-pe) |
| 796 | libgloss_dir=wince |
| 797 | ;; |
| 798 | aarch64*-*-* ) |
| 799 | libgloss_dir=aarch64 |
| 800 | ;; |
| 801 | arm*-*-*) |
| 802 | libgloss_dir=arm |
| 803 | ;; |
| 804 | cris-*-* | crisv32-*-*) |
| 805 | libgloss_dir=cris |
| 806 | ;; |
| 807 | hppa*-*-*) |
| 808 | libgloss_dir=pa |
| 809 | ;; |
| 810 | i[[3456789]]86-*-*) |
| 811 | libgloss_dir=i386 |
| 812 | ;; |
| 813 | m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*) |
| 814 | libgloss_dir=m68hc11 |
| 815 | ;; |
| 816 | m68*-*-* | fido-*-*) |
| 817 | libgloss_dir=m68k |
| 818 | ;; |
| 819 | mips*-*-*) |
| 820 | libgloss_dir=mips |
| 821 | ;; |
| 822 | powerpc*-*-*) |
| 823 | libgloss_dir=rs6000 |
| 824 | ;; |
| 825 | sparc*-*-*) |
| 826 | libgloss_dir=sparc |
| 827 | ;; |
| 828 | esac |
| 829 | |
| 830 | # Disable newlib and libgloss for various target OSes. |
| 831 | case "${target}" in |
| 832 | alpha*-dec-osf*) |
| 833 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 834 | ;; |
| 835 | i[[3456789]]86-*-linux*) |
| 836 | # This section makes it possible to build newlib natively on linux. |
| 837 | # If we are using a cross compiler then don't configure newlib. |
| 838 | if test x${is_cross_compiler} != xno ; then |
| 839 | noconfigdirs="$noconfigdirs target-newlib" |
| 840 | fi |
| 841 | noconfigdirs="$noconfigdirs target-libgloss" |
| 842 | # If we are not using a cross compiler, do configure newlib. |
| 843 | # Note however, that newlib will only be configured in this situation |
| 844 | # if the --with-newlib option has been given, because otherwise |
| 845 | # 'target-newlib' will appear in skipdirs. |
| 846 | ;; |
| 847 | i[[3456789]]86-*-rdos*) |
| 848 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 849 | ;; |
| 850 | sh*-*-pe|mips*-*-pe|arm-wince-pe) |
| 851 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 852 | ;; |
| 853 | sparc-*-sunos4*) |
| 854 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 855 | ;; |
| 856 | *-*-aix*) |
| 857 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 858 | ;; |
| 859 | *-*-beos*) |
| 860 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 861 | ;; |
| 862 | *-*-chorusos) |
| 863 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 864 | ;; |
| 865 | *-*-dragonfly*) |
| 866 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 867 | ;; |
| 868 | *-*-freebsd*) |
| 869 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 870 | ;; |
| 871 | *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu) |
| 872 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 873 | ;; |
| 874 | *-*-lynxos*) |
| 875 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 876 | ;; |
| 877 | *-*-mingw*) |
| 878 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 879 | ;; |
| 880 | *-*-netbsd*) |
| 881 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 882 | ;; |
| 883 | *-*-netware*) |
| 884 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 885 | ;; |
| 886 | *-*-tpf*) |
| 887 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 888 | ;; |
| 889 | *-*-uclinux*) |
| 890 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 891 | ;; |
| 892 | *-*-vxworks*) |
| 893 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 894 | ;; |
| 895 | esac |
| 896 | |
| 897 | case "${target}" in |
| 898 | *-*-chorusos) |
| 899 | ;; |
| 900 | powerpc-*-darwin*) |
| 901 | noconfigdirs="$noconfigdirs ld gas gdb gprof" |
| 902 | noconfigdirs="$noconfigdirs sim target-rda" |
| 903 | ;; |
| 904 | i[[3456789]]86-*-darwin*) |
| 905 | noconfigdirs="$noconfigdirs ld gprof" |
| 906 | noconfigdirs="$noconfigdirs sim target-rda" |
| 907 | ;; |
| 908 | x86_64-*-darwin[[912]]*) |
| 909 | noconfigdirs="$noconfigdirs ld gas gprof" |
| 910 | noconfigdirs="$noconfigdirs sim target-rda" |
| 911 | ;; |
| 912 | *-*-darwin*) |
| 913 | noconfigdirs="$noconfigdirs ld gas gdb gprof" |
| 914 | noconfigdirs="$noconfigdirs sim target-rda" |
| 915 | ;; |
| 916 | *-*-dragonfly*) |
| 917 | ;; |
| 918 | *-*-freebsd*) |
| 919 | if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \ |
| 920 | && test -f /usr/local/include/gmp.h; then |
| 921 | with_gmp=/usr/local |
| 922 | fi |
| 923 | ;; |
| 924 | *-*-kaos*) |
| 925 | # Remove unsupported stuff on all kaOS configurations. |
| 926 | noconfigdirs="$noconfigdirs target-libgloss" |
| 927 | ;; |
| 928 | *-*-netbsd*) |
| 929 | ;; |
| 930 | *-*-netware*) |
| 931 | ;; |
| 932 | *-*-rtems*) |
| 933 | noconfigdirs="$noconfigdirs target-libgloss" |
| 934 | ;; |
| 935 | # The tpf target doesn't support gdb yet. |
| 936 | *-*-tpf*) |
| 937 | noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl" |
| 938 | ;; |
| 939 | *-*-uclinux*) |
| 940 | noconfigdirs="$noconfigdirs target-rda" |
| 941 | ;; |
| 942 | *-*-vxworks*) |
| 943 | ;; |
| 944 | alpha*-dec-osf*) |
| 945 | # ld works, but does not support shared libraries. |
| 946 | # gas doesn't generate exception information. |
| 947 | noconfigdirs="$noconfigdirs gas ld" |
| 948 | ;; |
| 949 | alpha*-*-*vms*) |
| 950 | noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss" |
| 951 | ;; |
| 952 | alpha*-*-*) |
| 953 | # newlib is not 64 bit ready |
| 954 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 955 | ;; |
| 956 | sh*-*-pe|mips*-*-pe|*arm-wince-pe) |
| 957 | noconfigdirs="$noconfigdirs tcl tk itcl libgui sim" |
| 958 | ;; |
| 959 | arc-*-*|arceb-*-*) |
| 960 | noconfigdirs="$noconfigdirs target-libgloss" |
| 961 | ;; |
| 962 | arm-*-pe*) |
| 963 | noconfigdirs="$noconfigdirs target-libgloss" |
| 964 | ;; |
| 965 | arm-*-riscix*) |
| 966 | noconfigdirs="$noconfigdirs ld target-libgloss" |
| 967 | ;; |
| 968 | avr-*-rtems*) |
| 969 | ;; |
| 970 | avr-*-*) |
| 971 | if test x${with_avrlibc} != xno; then |
| 972 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 973 | fi |
| 974 | ;; |
| 975 | c4x-*-* | tic4x-*-*) |
| 976 | noconfigdirs="$noconfigdirs target-libgloss" |
| 977 | ;; |
| 978 | tic54x-*-*) |
| 979 | noconfigdirs="$noconfigdirs target-libgloss gdb" |
| 980 | ;; |
| 981 | d10v-*-*) |
| 982 | noconfigdirs="$noconfigdirs target-libgloss" |
| 983 | ;; |
| 984 | d30v-*-*) |
| 985 | noconfigdirs="$noconfigdirs gdb" |
| 986 | ;; |
| 987 | fr30-*-elf*) |
| 988 | noconfigdirs="$noconfigdirs gdb" |
| 989 | ;; |
| 990 | moxie-*-*) |
| 991 | noconfigdirs="$noconfigdirs gprof" |
| 992 | ;; |
| 993 | h8300*-*-*) |
| 994 | noconfigdirs="$noconfigdirs target-libgloss" |
| 995 | ;; |
| 996 | h8500-*-*) |
| 997 | noconfigdirs="$noconfigdirs target-libgloss" |
| 998 | ;; |
| 999 | hppa1.1-*-osf* | hppa1.1-*-bsd* ) |
| 1000 | ;; |
| 1001 | hppa*64*-*-linux*) |
| 1002 | ;; |
| 1003 | hppa*-*-linux*) |
| 1004 | ;; |
| 1005 | hppa*-*-*elf* | \ |
| 1006 | hppa*-*-lites* | \ |
| 1007 | hppa*-*-openbsd* | \ |
| 1008 | hppa*64*-*-*) |
| 1009 | ;; |
| 1010 | hppa*-hp-hpux11*) |
| 1011 | noconfigdirs="$noconfigdirs ld" |
| 1012 | ;; |
| 1013 | hppa*-*-pro*) |
| 1014 | ;; |
| 1015 | hppa*-*-*) |
| 1016 | noconfigdirs="$noconfigdirs ld" |
| 1017 | ;; |
| 1018 | i960-*-*) |
| 1019 | noconfigdirs="$noconfigdirs gdb" |
| 1020 | ;; |
| 1021 | ia64*-*-elf*) |
| 1022 | # No gdb support yet. |
| 1023 | noconfigdirs="$noconfigdirs readline libgui itcl gdb" |
| 1024 | ;; |
| 1025 | ia64*-**-hpux*) |
| 1026 | # No ld support yet. |
| 1027 | noconfigdirs="$noconfigdirs libgui itcl ld" |
| 1028 | ;; |
| 1029 | ia64*-*-*vms*) |
| 1030 | # No ld support yet. |
| 1031 | noconfigdirs="$noconfigdirs libgui itcl ld" |
| 1032 | ;; |
| 1033 | i[[3456789]]86-w64-mingw*) |
| 1034 | ;; |
| 1035 | i[[3456789]]86-*-mingw*) |
| 1036 | target_configdirs="$target_configdirs target-winsup" |
| 1037 | ;; |
| 1038 | *-*-cygwin*) |
| 1039 | target_configdirs="$target_configdirs target-libtermcap target-winsup" |
| 1040 | noconfigdirs="$noconfigdirs target-libgloss" |
| 1041 | # always build newlib if winsup directory is present. |
| 1042 | if test -d "$srcdir/winsup/cygwin"; then |
| 1043 | skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` |
| 1044 | elif test -d "$srcdir/newlib"; then |
| 1045 | echo "Warning: winsup/cygwin is missing so newlib can't be built." |
| 1046 | fi |
| 1047 | ;; |
| 1048 | i[[3456789]]86-*-pe) |
| 1049 | noconfigdirs="$noconfigdirs target-libgloss" |
| 1050 | ;; |
| 1051 | i[[3456789]]86-*-sco3.2v5*) |
| 1052 | # The linker does not yet know about weak symbols in COFF, |
| 1053 | # and is not configured to handle mixed ELF and COFF. |
| 1054 | noconfigdirs="$noconfigdirs ld target-libgloss" |
| 1055 | ;; |
| 1056 | i[[3456789]]86-*-sco*) |
| 1057 | noconfigdirs="$noconfigdirs gprof target-libgloss" |
| 1058 | ;; |
| 1059 | i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*) |
| 1060 | noconfigdirs="$noconfigdirs target-libgloss" |
| 1061 | ;; |
| 1062 | i[[3456789]]86-*-sysv4*) |
| 1063 | noconfigdirs="$noconfigdirs target-libgloss" |
| 1064 | ;; |
| 1065 | i[[3456789]]86-*-beos*) |
| 1066 | noconfigdirs="$noconfigdirs gdb" |
| 1067 | ;; |
| 1068 | i[[3456789]]86-*-rdos*) |
| 1069 | noconfigdirs="$noconfigdirs gdb" |
| 1070 | ;; |
| 1071 | mmix-*-*) |
| 1072 | noconfigdirs="$noconfigdirs gdb" |
| 1073 | ;; |
| 1074 | mt-*-*) |
| 1075 | noconfigdirs="$noconfigdirs sim" |
| 1076 | ;; |
| 1077 | powerpc-*-aix*) |
| 1078 | # copied from rs6000-*-* entry |
| 1079 | noconfigdirs="$noconfigdirs gprof" |
| 1080 | ;; |
| 1081 | powerpc*-*-winnt* | powerpc*-*-pe*) |
| 1082 | target_configdirs="$target_configdirs target-winsup" |
| 1083 | noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl" |
| 1084 | # always build newlib. |
| 1085 | skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` |
| 1086 | ;; |
| 1087 | # This is temporary until we can link against shared libraries |
| 1088 | powerpcle-*-solaris*) |
| 1089 | noconfigdirs="$noconfigdirs gdb sim tcl tk itcl" |
| 1090 | ;; |
| 1091 | powerpc-*-beos*) |
| 1092 | noconfigdirs="$noconfigdirs gdb" |
| 1093 | ;; |
| 1094 | rs6000-*-lynxos*) |
| 1095 | noconfigdirs="$noconfigdirs gprof" |
| 1096 | ;; |
| 1097 | rs6000-*-aix*) |
| 1098 | noconfigdirs="$noconfigdirs gprof" |
| 1099 | ;; |
| 1100 | rs6000-*-*) |
| 1101 | noconfigdirs="$noconfigdirs gprof" |
| 1102 | ;; |
| 1103 | m68k-apollo-*) |
| 1104 | noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss" |
| 1105 | ;; |
| 1106 | microblaze*) |
| 1107 | noconfigdirs="$noconfigdirs gprof" |
| 1108 | ;; |
| 1109 | mips*-sde-elf* | mips*-mti-elf*) |
| 1110 | if test x$with_newlib = xyes; then |
| 1111 | noconfigdirs="$noconfigdirs gprof" |
| 1112 | fi |
| 1113 | ;; |
| 1114 | mips*-*-irix5*) |
| 1115 | noconfigdirs="$noconfigdirs gprof target-libgloss" |
| 1116 | ;; |
| 1117 | mips*-*-irix6*) |
| 1118 | noconfigdirs="$noconfigdirs gprof target-libgloss" |
| 1119 | ;; |
| 1120 | mips*-*-bsd*) |
| 1121 | noconfigdirs="$noconfigdirs ld gas gprof target-libgloss" |
| 1122 | ;; |
| 1123 | mips*-*-linux*) |
| 1124 | ;; |
| 1125 | mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \ |
| 1126 | | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*) |
| 1127 | noconfigdirs="$noconfigdirs ld gas gprof" |
| 1128 | ;; |
| 1129 | mips*-*-*) |
| 1130 | noconfigdirs="$noconfigdirs gprof" |
| 1131 | ;; |
| 1132 | sh-*-* | sh64-*-*) |
| 1133 | case "${target}" in |
| 1134 | sh*-*-elf) |
| 1135 | ;; |
| 1136 | *) |
| 1137 | noconfigdirs="$noconfigdirs target-libgloss" ;; |
| 1138 | esac |
| 1139 | ;; |
| 1140 | sparc-*-sunos4*) |
| 1141 | if test x${is_cross_compiler} = xno ; then |
| 1142 | use_gnu_ld=no |
| 1143 | fi |
| 1144 | ;; |
| 1145 | tic6x-*-*) |
| 1146 | noconfigdirs="$noconfigdirs sim" |
| 1147 | ;; |
| 1148 | tilepro-*-* | tilegx-*-*) |
| 1149 | noconfigdirs="$noconfigdirs sim" |
| 1150 | ;; |
| 1151 | v810-*-*) |
| 1152 | noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss" |
| 1153 | ;; |
| 1154 | vax-*-*) |
| 1155 | noconfigdirs="$noconfigdirs target-newlib target-libgloss" |
| 1156 | ;; |
| 1157 | esac |
| 1158 | |
| 1159 | # If we aren't building newlib, then don't build libgloss, since libgloss |
| 1160 | # depends upon some newlib header files. |
| 1161 | case "${noconfigdirs}" in |
| 1162 | *target-libgloss*) ;; |
| 1163 | *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;; |
| 1164 | esac |
| 1165 | |
| 1166 | # Work in distributions that contain no compiler tools, like Autoconf. |
| 1167 | host_makefile_frag=/dev/null |
| 1168 | if test -d ${srcdir}/config ; then |
| 1169 | case "${host}" in |
| 1170 | i[[3456789]]86-*-msdosdjgpp*) |
| 1171 | host_makefile_frag="config/mh-djgpp" |
| 1172 | ;; |
| 1173 | *-cygwin*) |
| 1174 | ACX_CHECK_CYGWIN_CAT_WORKS |
| 1175 | host_makefile_frag="config/mh-cygwin" |
| 1176 | ;; |
| 1177 | *-mingw*) |
| 1178 | host_makefile_frag="config/mh-mingw" |
| 1179 | ;; |
| 1180 | hppa*-hp-hpux10*) |
| 1181 | host_makefile_frag="config/mh-pa-hpux10" |
| 1182 | ;; |
| 1183 | hppa*-hp-hpux*) |
| 1184 | host_makefile_frag="config/mh-pa" |
| 1185 | ;; |
| 1186 | hppa*-*) |
| 1187 | host_makefile_frag="config/mh-pa" |
| 1188 | ;; |
| 1189 | *-*-darwin*) |
| 1190 | host_makefile_frag="config/mh-darwin" |
| 1191 | ;; |
| 1192 | powerpc-*-aix*) |
| 1193 | host_makefile_frag="config/mh-ppc-aix" |
| 1194 | ;; |
| 1195 | rs6000-*-aix*) |
| 1196 | host_makefile_frag="config/mh-ppc-aix" |
| 1197 | ;; |
| 1198 | esac |
| 1199 | fi |
| 1200 | |
| 1201 | if test "${build}" != "${host}" ; then |
| 1202 | AR_FOR_BUILD=${AR_FOR_BUILD-ar} |
| 1203 | AS_FOR_BUILD=${AS_FOR_BUILD-as} |
| 1204 | CC_FOR_BUILD=${CC_FOR_BUILD-gcc} |
| 1205 | CXX_FOR_BUILD=${CXX_FOR_BUILD-g++} |
| 1206 | GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj} |
| 1207 | GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran} |
| 1208 | GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo} |
| 1209 | DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool} |
| 1210 | LD_FOR_BUILD=${LD_FOR_BUILD-ld} |
| 1211 | NM_FOR_BUILD=${NM_FOR_BUILD-nm} |
| 1212 | RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib} |
| 1213 | WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres} |
| 1214 | WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc} |
| 1215 | else |
| 1216 | AR_FOR_BUILD="\$(AR)" |
| 1217 | AS_FOR_BUILD="\$(AS)" |
| 1218 | CC_FOR_BUILD="\$(CC)" |
| 1219 | CXX_FOR_BUILD="\$(CXX)" |
| 1220 | GCJ_FOR_BUILD="\$(GCJ)" |
| 1221 | GFORTRAN_FOR_BUILD="\$(GFORTRAN)" |
| 1222 | GOC_FOR_BUILD="\$(GOC)" |
| 1223 | DLLTOOL_FOR_BUILD="\$(DLLTOOL)" |
| 1224 | LD_FOR_BUILD="\$(LD)" |
| 1225 | NM_FOR_BUILD="\$(NM)" |
| 1226 | RANLIB_FOR_BUILD="\$(RANLIB)" |
| 1227 | WINDRES_FOR_BUILD="\$(WINDRES)" |
| 1228 | WINDMC_FOR_BUILD="\$(WINDMC)" |
| 1229 | fi |
| 1230 | |
| 1231 | AC_PROG_CC |
| 1232 | AC_PROG_CXX |
| 1233 | |
| 1234 | # We must set the default linker to the linker used by gcc for the correct |
| 1235 | # operation of libtool. If LD is not defined and we are using gcc, try to |
| 1236 | # set the LD default to the ld used by gcc. |
| 1237 | if test -z "$LD"; then |
| 1238 | if test "$GCC" = yes; then |
| 1239 | case $build in |
| 1240 | *-*-mingw*) |
| 1241 | gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;; |
| 1242 | *) |
| 1243 | gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;; |
| 1244 | esac |
| 1245 | case $gcc_prog_ld in |
| 1246 | # Accept absolute paths. |
| 1247 | [[\\/]* | [A-Za-z]:[\\/]*)] |
| 1248 | LD="$gcc_prog_ld" ;; |
| 1249 | esac |
| 1250 | fi |
| 1251 | fi |
| 1252 | |
| 1253 | # Check whether -static-libstdc++ -static-libgcc is supported. |
| 1254 | have_static_libs=no |
| 1255 | if test "$GCC" = yes; then |
| 1256 | saved_LDFLAGS="$LDFLAGS" |
| 1257 | |
| 1258 | LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc" |
| 1259 | AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc]) |
| 1260 | AC_LANG_PUSH(C++) |
| 1261 | AC_LINK_IFELSE([ |
| 1262 | #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5) |
| 1263 | #error -static-libstdc++ not implemented |
| 1264 | #endif |
| 1265 | int main() {}], |
| 1266 | [AC_MSG_RESULT([yes]); have_static_libs=yes], |
| 1267 | [AC_MSG_RESULT([no])]) |
| 1268 | AC_LANG_POP(C++) |
| 1269 | |
| 1270 | LDFLAGS="$saved_LDFLAGS" |
| 1271 | fi |
| 1272 | |
| 1273 | ACX_PROG_GNAT |
| 1274 | ACX_PROG_CMP_IGNORE_INITIAL |
| 1275 | |
| 1276 | AC_ARG_ENABLE([bootstrap], |
| 1277 | [AS_HELP_STRING([--enable-bootstrap], |
| 1278 | [enable bootstrapping @<:@yes if native build@:>@])],, |
| 1279 | enable_bootstrap=default) |
| 1280 | |
| 1281 | # Issue errors and warnings for invalid/strange bootstrap combinations. |
| 1282 | if test -r $srcdir/gcc/configure; then |
| 1283 | have_compiler=yes |
| 1284 | else |
| 1285 | have_compiler=no |
| 1286 | fi |
| 1287 | |
| 1288 | case "$have_compiler:$host:$target:$enable_bootstrap" in |
| 1289 | *:*:*:no) ;; |
| 1290 | |
| 1291 | # Default behavior. Enable bootstrap if we have a compiler |
| 1292 | # and we are in a native configuration. |
| 1293 | yes:$build:$build:default) |
| 1294 | enable_bootstrap=yes ;; |
| 1295 | |
| 1296 | *:*:*:default) |
| 1297 | enable_bootstrap=no ;; |
| 1298 | |
| 1299 | # We have a compiler and we are in a native configuration, bootstrap is ok |
| 1300 | yes:$build:$build:yes) |
| 1301 | ;; |
| 1302 | |
| 1303 | # Other configurations, but we have a compiler. Assume the user knows |
| 1304 | # what he's doing. |
| 1305 | yes:*:*:yes) |
| 1306 | AC_MSG_WARN([trying to bootstrap a cross compiler]) |
| 1307 | ;; |
| 1308 | |
| 1309 | # No compiler: if they passed --enable-bootstrap explicitly, fail |
| 1310 | no:*:*:yes) |
| 1311 | AC_MSG_ERROR([cannot bootstrap without a compiler]) ;; |
| 1312 | |
| 1313 | # Fail if wrong command line |
| 1314 | *) |
| 1315 | AC_MSG_ERROR([invalid option for --enable-bootstrap]) |
| 1316 | ;; |
| 1317 | esac |
| 1318 | |
| 1319 | # Used for setting $lt_cv_objdir |
| 1320 | _LT_CHECK_OBJDIR |
| 1321 | |
| 1322 | # Check for GMP, MPFR and MPC |
| 1323 | gmplibs="-lmpc -lmpfr -lgmp" |
| 1324 | gmpinc= |
| 1325 | have_gmp=no |
| 1326 | |
| 1327 | # Specify a location for mpc |
| 1328 | # check for this first so it ends up on the link line before mpfr. |
| 1329 | AC_ARG_WITH(mpc, |
| 1330 | [AS_HELP_STRING([--with-mpc=PATH], |
| 1331 | [specify prefix directory for installed MPC package. |
| 1332 | Equivalent to --with-mpc-include=PATH/include |
| 1333 | plus --with-mpc-lib=PATH/lib])]) |
| 1334 | AC_ARG_WITH(mpc-include, |
| 1335 | [AS_HELP_STRING([--with-mpc-include=PATH], |
| 1336 | [specify directory for installed MPC include files])]) |
| 1337 | AC_ARG_WITH(mpc-lib, |
| 1338 | [AS_HELP_STRING([--with-mpc-lib=PATH], |
| 1339 | [specify directory for the installed MPC library])]) |
| 1340 | |
| 1341 | if test "x$with_mpc" != x; then |
| 1342 | gmplibs="-L$with_mpc/lib $gmplibs" |
| 1343 | gmpinc="-I$with_mpc/include $gmpinc" |
| 1344 | fi |
| 1345 | if test "x$with_mpc_include" != x; then |
| 1346 | gmpinc="-I$with_mpc_include $gmpinc" |
| 1347 | fi |
| 1348 | if test "x$with_mpc_lib" != x; then |
| 1349 | gmplibs="-L$with_mpc_lib $gmplibs" |
| 1350 | fi |
| 1351 | if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then |
| 1352 | gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs" |
| 1353 | gmpinc='-I$$s/mpc/src '"$gmpinc" |
| 1354 | # Do not test the mpc version. Assume that it is sufficient, since |
| 1355 | # it is in the source tree, and the library has not been built yet |
| 1356 | # but it would be included on the link line in the version check below |
| 1357 | # hence making the test fail. |
| 1358 | have_gmp=yes |
| 1359 | fi |
| 1360 | |
| 1361 | # Specify a location for mpfr |
| 1362 | # check for this first so it ends up on the link line before gmp. |
| 1363 | AC_ARG_WITH(mpfr-dir, |
| 1364 | [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])], |
| 1365 | [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed. |
| 1366 | Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])]) |
| 1367 | |
| 1368 | AC_ARG_WITH(mpfr, |
| 1369 | [AS_HELP_STRING([--with-mpfr=PATH], |
| 1370 | [specify prefix directory for installed MPFR package. |
| 1371 | Equivalent to --with-mpfr-include=PATH/include |
| 1372 | plus --with-mpfr-lib=PATH/lib])]) |
| 1373 | AC_ARG_WITH(mpfr-include, |
| 1374 | [AS_HELP_STRING([--with-mpfr-include=PATH], |
| 1375 | [specify directory for installed MPFR include files])]) |
| 1376 | AC_ARG_WITH(mpfr-lib, |
| 1377 | [AS_HELP_STRING([--with-mpfr-lib=PATH], |
| 1378 | [specify directory for the installed MPFR library])]) |
| 1379 | |
| 1380 | if test "x$with_mpfr" != x; then |
| 1381 | gmplibs="-L$with_mpfr/lib $gmplibs" |
| 1382 | gmpinc="-I$with_mpfr/include $gmpinc" |
| 1383 | fi |
| 1384 | if test "x$with_mpfr_include" != x; then |
| 1385 | gmpinc="-I$with_mpfr_include $gmpinc" |
| 1386 | fi |
| 1387 | if test "x$with_mpfr_lib" != x; then |
| 1388 | gmplibs="-L$with_mpfr_lib $gmplibs" |
| 1389 | fi |
| 1390 | if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then |
| 1391 | # MPFR v3.1.0 moved the sources into a src sub-directory. |
| 1392 | if test -d ${srcdir}/mpfr/src; then |
| 1393 | gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs" |
| 1394 | gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc" |
| 1395 | extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir" |
| 1396 | else |
| 1397 | gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir $gmplibs" |
| 1398 | gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr -I$$s/mpfr '"$gmpinc" |
| 1399 | extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/'"$lt_cv_objdir" |
| 1400 | fi |
| 1401 | # Do not test the mpfr version. Assume that it is sufficient, since |
| 1402 | # it is in the source tree, and the library has not been built yet |
| 1403 | # but it would be included on the link line in the version check below |
| 1404 | # hence making the test fail. |
| 1405 | have_gmp=yes |
| 1406 | fi |
| 1407 | |
| 1408 | # Specify a location for gmp |
| 1409 | AC_ARG_WITH(gmp-dir, |
| 1410 | [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])], |
| 1411 | [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed. |
| 1412 | Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])]) |
| 1413 | |
| 1414 | AC_ARG_WITH(gmp, |
| 1415 | [AS_HELP_STRING([--with-gmp=PATH], |
| 1416 | [specify prefix directory for the installed GMP package. |
| 1417 | Equivalent to --with-gmp-include=PATH/include |
| 1418 | plus --with-gmp-lib=PATH/lib])]) |
| 1419 | AC_ARG_WITH(gmp-include, |
| 1420 | [AS_HELP_STRING([--with-gmp-include=PATH], |
| 1421 | [specify directory for installed GMP include files])]) |
| 1422 | AC_ARG_WITH(gmp-lib, |
| 1423 | [AS_HELP_STRING([--with-gmp-lib=PATH], |
| 1424 | [specify directory for the installed GMP library])]) |
| 1425 | |
| 1426 | |
| 1427 | if test "x$with_gmp" != x; then |
| 1428 | gmplibs="-L$with_gmp/lib $gmplibs" |
| 1429 | gmpinc="-I$with_gmp/include $gmpinc" |
| 1430 | fi |
| 1431 | if test "x$with_gmp_include" != x; then |
| 1432 | gmpinc="-I$with_gmp_include $gmpinc" |
| 1433 | fi |
| 1434 | if test "x$with_gmp_lib" != x; then |
| 1435 | gmplibs="-L$with_gmp_lib $gmplibs" |
| 1436 | fi |
| 1437 | if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then |
| 1438 | gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs" |
| 1439 | gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc" |
| 1440 | extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir" |
| 1441 | extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir" |
| 1442 | extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp' |
| 1443 | # Do not test the gmp version. Assume that it is sufficient, since |
| 1444 | # it is in the source tree, and the library has not been built yet |
| 1445 | # but it would be included on the link line in the version check below |
| 1446 | # hence making the test fail. |
| 1447 | have_gmp=yes |
| 1448 | fi |
| 1449 | |
| 1450 | if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then |
| 1451 | have_gmp=yes |
| 1452 | saved_CFLAGS="$CFLAGS" |
| 1453 | CFLAGS="$CFLAGS $gmpinc" |
| 1454 | # Check for the recommended and required versions of GMP. |
| 1455 | AC_MSG_CHECKING([for the correct version of gmp.h]) |
| 1456 | AC_TRY_COMPILE([#include "gmp.h"],[ |
| 1457 | #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c)) |
| 1458 | #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL) |
| 1459 | #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3) |
| 1460 | choke me |
| 1461 | #endif |
| 1462 | ], [AC_TRY_COMPILE([#include <gmp.h>],[ |
| 1463 | #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c)) |
| 1464 | #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL) |
| 1465 | #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2) |
| 1466 | choke me |
| 1467 | #endif |
| 1468 | ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])], |
| 1469 | [AC_MSG_RESULT([no]); have_gmp=no]) |
| 1470 | |
| 1471 | # If we have GMP, check the MPFR version. |
| 1472 | if test x"$have_gmp" = xyes; then |
| 1473 | # Check for the recommended and required versions of MPFR. |
| 1474 | AC_MSG_CHECKING([for the correct version of mpfr.h]) |
| 1475 | AC_TRY_COMPILE([#include <gmp.h> |
| 1476 | #include <mpfr.h>],[ |
| 1477 | #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0) |
| 1478 | choke me |
| 1479 | #endif |
| 1480 | ], [AC_TRY_COMPILE([#include <gmp.h> |
| 1481 | #include <mpfr.h>],[ |
| 1482 | #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2) |
| 1483 | choke me |
| 1484 | #endif |
| 1485 | ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])], |
| 1486 | [AC_MSG_RESULT([no]); have_gmp=no]) |
| 1487 | fi |
| 1488 | |
| 1489 | # Check for the MPC header version. |
| 1490 | if test x"$have_gmp" = xyes ; then |
| 1491 | # Check for the recommended and required versions of MPC. |
| 1492 | AC_MSG_CHECKING([for the correct version of mpc.h]) |
| 1493 | AC_TRY_COMPILE([#include <mpc.h>],[ |
| 1494 | #if MPC_VERSION < MPC_VERSION_NUM(0,8,0) |
| 1495 | choke me |
| 1496 | #endif |
| 1497 | ], [AC_TRY_COMPILE([#include <mpc.h>],[ |
| 1498 | #if MPC_VERSION < MPC_VERSION_NUM(0,8,1) |
| 1499 | choke me |
| 1500 | #endif |
| 1501 | ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])], |
| 1502 | [AC_MSG_RESULT([no]); have_gmp=no]) |
| 1503 | fi |
| 1504 | |
| 1505 | # Now check the MPFR library. |
| 1506 | if test x"$have_gmp" = xyes; then |
| 1507 | saved_LIBS="$LIBS" |
| 1508 | LIBS="$LIBS $gmplibs" |
| 1509 | AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries]) |
| 1510 | AC_TRY_LINK([#include <mpc.h>],[ |
| 1511 | mpfr_t n; |
| 1512 | mpfr_t x; |
| 1513 | mpc_t c; |
| 1514 | int t; |
| 1515 | mpfr_init (n); |
| 1516 | mpfr_init (x); |
| 1517 | mpfr_atan2 (n, n, x, GMP_RNDN); |
| 1518 | mpfr_erfc (n, x, GMP_RNDN); |
| 1519 | mpfr_subnormalize (x, t, GMP_RNDN); |
| 1520 | mpfr_clear(n); |
| 1521 | mpfr_clear(x); |
| 1522 | mpc_init2 (c, 53); |
| 1523 | mpc_set_ui_ui (c, 1, 1, MPC_RNDNN); |
| 1524 | mpc_cosh (c, c, MPC_RNDNN); |
| 1525 | mpc_pow (c, c, c, MPC_RNDNN); |
| 1526 | mpc_acosh (c, c, MPC_RNDNN); |
| 1527 | mpc_clear (c); |
| 1528 | ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no]) |
| 1529 | LIBS="$saved_LIBS" |
| 1530 | fi |
| 1531 | |
| 1532 | CFLAGS="$saved_CFLAGS" |
| 1533 | |
| 1534 | # The library versions listed in the error message below should match |
| 1535 | # the HARD-minimums enforced above. |
| 1536 | if test x$have_gmp != xyes; then |
| 1537 | AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+. |
| 1538 | Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify |
| 1539 | their locations. Source code for these libraries can be found at |
| 1540 | their respective hosting sites as well as at |
| 1541 | ftp://gcc.gnu.org/pub/gcc/infrastructure/. See also |
| 1542 | http://gcc.gnu.org/install/prerequisites.html for additional info. If |
| 1543 | you obtained GMP, MPFR and/or MPC from a vendor distribution package, |
| 1544 | make sure that you have installed both the libraries and the header |
| 1545 | files. They may be located in separate packages.]) |
| 1546 | fi |
| 1547 | fi |
| 1548 | |
| 1549 | # Flags needed for both GMP, MPFR and/or MPC. |
| 1550 | AC_SUBST(gmplibs) |
| 1551 | AC_SUBST(gmpinc) |
| 1552 | AC_SUBST(extra_mpfr_configure_flags) |
| 1553 | AC_SUBST(extra_mpc_gmp_configure_flags) |
| 1554 | AC_SUBST(extra_mpc_mpfr_configure_flags) |
| 1555 | AC_SUBST(extra_isl_gmp_configure_flags) |
| 1556 | |
| 1557 | # Allow host libstdc++ to be specified for static linking with PPL. |
| 1558 | AC_ARG_WITH(host-libstdcxx, |
| 1559 | [AS_HELP_STRING([--with-host-libstdcxx=L], |
| 1560 | [use linker arguments L to link with libstdc++ |
| 1561 | when linking with PPL])]) |
| 1562 | |
| 1563 | case $with_host_libstdcxx in |
| 1564 | no|yes) |
| 1565 | AC_MSG_ERROR([-with-host-libstdcxx needs an argument]) |
| 1566 | ;; |
| 1567 | esac |
| 1568 | |
| 1569 | # Libraries to use for stage1 or when not bootstrapping. |
| 1570 | AC_ARG_WITH(stage1-libs, |
| 1571 | [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])], |
| 1572 | [if test "$withval" = "no" -o "$withval" = "yes"; then |
| 1573 | stage1_libs= |
| 1574 | else |
| 1575 | stage1_libs=$withval |
| 1576 | fi], |
| 1577 | [stage1_libs=$with_host_libstdcxx]) |
| 1578 | AC_SUBST(stage1_libs) |
| 1579 | |
| 1580 | # Linker flags to use for stage1 or when not bootstrapping. |
| 1581 | AC_ARG_WITH(stage1-ldflags, |
| 1582 | [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])], |
| 1583 | [if test "$withval" = "no" -o "$withval" = "yes"; then |
| 1584 | stage1_ldflags= |
| 1585 | else |
| 1586 | stage1_ldflags=$withval |
| 1587 | fi], |
| 1588 | [stage1_ldflags= |
| 1589 | # In stage 1, default to linking libstdc++ and libgcc statically with GCC |
| 1590 | # if supported. But if the user explicitly specified the libraries to use, |
| 1591 | # trust that they are doing what they want. |
| 1592 | if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then |
| 1593 | stage1_ldflags="-static-libstdc++ -static-libgcc" |
| 1594 | fi]) |
| 1595 | AC_SUBST(stage1_ldflags) |
| 1596 | |
| 1597 | # Libraries to use for stage2 and later builds. This defaults to the |
| 1598 | # argument passed to --with-host-libstdcxx. |
| 1599 | AC_ARG_WITH(boot-libs, |
| 1600 | [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])], |
| 1601 | [if test "$withval" = "no" -o "$withval" = "yes"; then |
| 1602 | poststage1_libs= |
| 1603 | else |
| 1604 | poststage1_libs=$withval |
| 1605 | fi], |
| 1606 | [poststage1_libs=$with_host_libstdcxx]) |
| 1607 | AC_SUBST(poststage1_libs) |
| 1608 | |
| 1609 | # Linker flags to use for stage2 and later builds. |
| 1610 | AC_ARG_WITH(boot-ldflags, |
| 1611 | [AS_HELP_STRING([--with-boot-ldflags=FLAGS], |
| 1612 | [linker flags for stage2 and later])], |
| 1613 | [if test "$withval" = "no" -o "$withval" = "yes"; then |
| 1614 | poststage1_ldflags= |
| 1615 | else |
| 1616 | poststage1_ldflags=$withval |
| 1617 | fi], |
| 1618 | [poststage1_ldflags= |
| 1619 | # In stages 2 and 3, default to linking libstdc++ and libgcc |
| 1620 | # statically. But if the user explicitly specified the libraries to |
| 1621 | # use, trust that they are doing what they want. |
| 1622 | if test "$poststage1_libs" = ""; then |
| 1623 | poststage1_ldflags="-static-libstdc++ -static-libgcc" |
| 1624 | fi]) |
| 1625 | AC_SUBST(poststage1_ldflags) |
| 1626 | |
| 1627 | # GCC GRAPHITE dependences, ISL and CLOOG which in turn requires ISL. |
| 1628 | # Basic setup is inlined here, actual checks are in config/cloog.m4 and |
| 1629 | # config/isl.m4 |
| 1630 | |
| 1631 | AC_ARG_WITH(cloog, |
| 1632 | [AS_HELP_STRING( |
| 1633 | [--with-cloog=PATH], |
| 1634 | [Specify prefix directory for the installed CLooG-ISL package. |
| 1635 | Equivalent to --with-cloog-include=PATH/include |
| 1636 | plus --with-cloog-lib=PATH/lib])]) |
| 1637 | AC_ARG_WITH(isl, |
| 1638 | [AS_HELP_STRING( |
| 1639 | [--with-isl=PATH], |
| 1640 | [Specify prefix directory for the installed ISL package. |
| 1641 | Equivalent to --with-isl-include=PATH/include |
| 1642 | plus --with-isl-lib=PATH/lib])]) |
| 1643 | |
| 1644 | # Treat either --without-cloog or --without-isl as a request to disable |
| 1645 | # GRAPHITE support and skip all following checks. |
| 1646 | if test "x$with_isl" != "xno" && |
| 1647 | test "x$with_cloog" != "xno"; then |
| 1648 | # Check for ISL |
| 1649 | dnl Provide configure switches and initialize islinc & isllibs |
| 1650 | dnl with user input. |
| 1651 | ISL_INIT_FLAGS |
| 1652 | dnl The versions of ISL that work for Graphite |
| 1653 | ISL_CHECK_VERSION(0,10) |
| 1654 | if test "${gcc_cv_isl}" = no ; then |
| 1655 | ISL_CHECK_VERSION(0,11) |
| 1656 | if test "${gcc_cv_isl}" = no ; then |
| 1657 | ISL_CHECK_VERSION(0,12) |
| 1658 | fi |
| 1659 | fi |
| 1660 | dnl Only execute fail-action, if ISL has been requested. |
| 1661 | ISL_IF_FAILED([ |
| 1662 | AC_MSG_ERROR([Unable to find a usable ISL. See config.log for details.])]) |
| 1663 | |
| 1664 | if test "x$gcc_cv_isl" != "xno"; then |
| 1665 | # Check for CLOOG |
| 1666 | dnl Provide configure switches and initialize clooginc & clooglibs |
| 1667 | dnl with user input. |
| 1668 | CLOOG_INIT_FLAGS |
| 1669 | dnl The versions of CLooG that work for Graphite. |
| 1670 | CLOOG_CHECK_VERSION(0,17,0) |
| 1671 | if test "${gcc_cv_cloog}" = no ; then |
| 1672 | CLOOG_CHECK_VERSION(0,18,0) |
| 1673 | fi |
| 1674 | |
| 1675 | dnl Only execute fail-action, if CLooG has been requested. |
| 1676 | CLOOG_IF_FAILED([ |
| 1677 | AC_MSG_ERROR([Unable to find a usable CLooG. See config.log for details.])]) |
| 1678 | fi |
| 1679 | fi |
| 1680 | |
| 1681 | # If either the ISL or the CLooG check failed, disable builds of in-tree |
| 1682 | # variants of both |
| 1683 | if test "x$with_isl" = xno || |
| 1684 | test "x$with_cloog" = xno || |
| 1685 | test "x$gcc_cv_cloog" = xno || |
| 1686 | test "x$gcc_cv_isl" = xno; then |
| 1687 | noconfigdirs="$noconfigdirs cloog isl" |
| 1688 | islinc= |
| 1689 | clooginc= |
| 1690 | clooglibs= |
| 1691 | fi |
| 1692 | |
| 1693 | AC_SUBST(islinc) |
| 1694 | AC_SUBST(clooglibs) |
| 1695 | AC_SUBST(clooginc) |
| 1696 | |
| 1697 | |
| 1698 | # Check for LTO support. |
| 1699 | AC_ARG_ENABLE(lto, |
| 1700 | [AS_HELP_STRING([--enable-lto], [enable link time optimization support])], |
| 1701 | enable_lto=$enableval, |
| 1702 | enable_lto=yes; default_enable_lto=yes) |
| 1703 | |
| 1704 | ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always. |
| 1705 | build_lto_plugin=yes |
| 1706 | ],[if test x"$default_enable_lto" = x"yes" ; then |
| 1707 | case $target in |
| 1708 | *-apple-darwin9* | *-cygwin* | *-mingw*) ;; |
| 1709 | # On other non-ELF platforms, LTO has yet to be validated. |
| 1710 | *) enable_lto=no ;; |
| 1711 | esac |
| 1712 | else |
| 1713 | # Apart from ELF platforms, only Windows and Darwin support LTO so far. |
| 1714 | # It would also be nice to check the binutils support, but we don't |
| 1715 | # have gcc_GAS_CHECK_FEATURE available here. For now, we'll just |
| 1716 | # warn during gcc/ subconfigure; unless you're bootstrapping with |
| 1717 | # -flto it won't be needed until after installation anyway. |
| 1718 | case $target in |
| 1719 | *-cygwin* | *-mingw* | *-apple-darwin*) ;; |
| 1720 | *) if test x"$enable_lto" = x"yes"; then |
| 1721 | AC_MSG_ERROR([LTO support is not enabled for this target.]) |
| 1722 | fi |
| 1723 | ;; |
| 1724 | esac |
| 1725 | fi |
| 1726 | # Among non-ELF, only Windows platforms support the lto-plugin so far. |
| 1727 | # Build it unless LTO was explicitly disabled. |
| 1728 | case $target in |
| 1729 | *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;; |
| 1730 | *) ;; |
| 1731 | esac |
| 1732 | ]) |
| 1733 | |
| 1734 | |
| 1735 | # By default, C and C++ are the only stage 1 languages. |
| 1736 | stage1_languages=,c, |
| 1737 | |
| 1738 | # Target libraries that we bootstrap. |
| 1739 | bootstrap_target_libs=,target-libgcc, |
| 1740 | |
| 1741 | # Figure out what language subdirectories are present. |
| 1742 | # Look if the user specified --enable-languages="..."; if not, use |
| 1743 | # the environment variable $LANGUAGES if defined. $LANGUAGES might |
| 1744 | # go away some day. |
| 1745 | # NB: embedded tabs in this IF block -- do not untabify |
| 1746 | if test -d ${srcdir}/gcc; then |
| 1747 | if test x"${enable_languages+set}" != xset; then |
| 1748 | if test x"${LANGUAGES+set}" = xset; then |
| 1749 | enable_languages="${LANGUAGES}" |
| 1750 | echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2 |
| 1751 | else |
| 1752 | enable_languages=all |
| 1753 | fi |
| 1754 | else |
| 1755 | if test x"${enable_languages}" = x || |
| 1756 | test x"${enable_languages}" = xyes; |
| 1757 | then |
| 1758 | echo configure.in: --enable-languages needs at least one language argument 1>&2 |
| 1759 | exit 1 |
| 1760 | fi |
| 1761 | fi |
| 1762 | enable_languages=`echo "${enable_languages}" | sed -e 's/[[ ,]][[ ,]]*/,/g' -e 's/,$//'` |
| 1763 | |
| 1764 | # 'f95' is the old name for the 'fortran' language. We issue a warning |
| 1765 | # and make the substitution. |
| 1766 | case ,${enable_languages}, in |
| 1767 | *,f95,*) |
| 1768 | echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2 |
| 1769 | enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'` |
| 1770 | ;; |
| 1771 | esac |
| 1772 | |
| 1773 | # If bootstrapping, C++ must be enabled. |
| 1774 | case ",$enable_languages,:$enable_bootstrap" in |
| 1775 | *,c++,*:*) ;; |
| 1776 | *:yes) |
| 1777 | if test -f ${srcdir}/gcc/cp/config-lang.in; then |
| 1778 | enable_languages="${enable_languages},c++" |
| 1779 | else |
| 1780 | AC_MSG_ERROR([bootstrapping requires c++ sources]) |
| 1781 | fi |
| 1782 | ;; |
| 1783 | esac |
| 1784 | |
| 1785 | # First scan to see if an enabled language requires some other language. |
| 1786 | # We assume that a given config-lang.in will list all the language |
| 1787 | # front ends it requires, even if some are required indirectly. |
| 1788 | for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do |
| 1789 | case ${lang_frag} in |
| 1790 | ..) ;; |
| 1791 | # The odd quoting in the next line works around |
| 1792 | # an apparent bug in bash 1.12 on linux. |
| 1793 | ${srcdir}/gcc/[[*]]/config-lang.in) ;; |
| 1794 | *) |
| 1795 | # From the config-lang.in, get $language, $lang_requires, and |
| 1796 | # $lang_requires_boot_languages. |
| 1797 | language= |
| 1798 | lang_requires= |
| 1799 | lang_requires_boot_languages= |
| 1800 | . ${lang_frag} |
| 1801 | for other in ${lang_requires} ${lang_requires_boot_languages}; do |
| 1802 | case ,${enable_languages}, in |
| 1803 | *,$other,*) ;; |
| 1804 | *,all,*) ;; |
| 1805 | *,$language,*) |
| 1806 | echo " \`$other' language required by \`$language'; enabling" 1>&2 |
| 1807 | enable_languages="${enable_languages},${other}" |
| 1808 | ;; |
| 1809 | esac |
| 1810 | done |
| 1811 | for other in ${lang_requires_boot_languages} ; do |
| 1812 | if test "$other" != "c"; then |
| 1813 | case ,${enable_stage1_languages}, in |
| 1814 | *,$other,*) ;; |
| 1815 | *,all,*) ;; |
| 1816 | *) |
| 1817 | case ,${enable_languages}, in |
| 1818 | *,$language,*) |
| 1819 | echo " '$other' language required by '$language' in stage 1; enabling" 1>&2 |
| 1820 | enable_stage1_languages="$enable_stage1_languages,${other}" |
| 1821 | ;; |
| 1822 | esac |
| 1823 | ;; |
| 1824 | esac |
| 1825 | fi |
| 1826 | done |
| 1827 | ;; |
| 1828 | esac |
| 1829 | done |
| 1830 | |
| 1831 | new_enable_languages=,c, |
| 1832 | |
| 1833 | # If LTO is enabled, add the LTO front end. |
| 1834 | extra_host_libiberty_configure_flags= |
| 1835 | if test "$enable_lto" = "yes" ; then |
| 1836 | case ,${enable_languages}, in |
| 1837 | *,lto,*) ;; |
| 1838 | *) enable_languages="${enable_languages},lto" ;; |
| 1839 | esac |
| 1840 | if test "${build_lto_plugin}" = "yes" ; then |
| 1841 | configdirs="$configdirs lto-plugin" |
| 1842 | extra_host_libiberty_configure_flags=--enable-shared |
| 1843 | fi |
| 1844 | fi |
| 1845 | AC_SUBST(extra_host_libiberty_configure_flags) |
| 1846 | |
| 1847 | missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ ` |
| 1848 | potential_languages=,c, |
| 1849 | |
| 1850 | enabled_target_libs= |
| 1851 | disabled_target_libs= |
| 1852 | |
| 1853 | for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do |
| 1854 | case ${lang_frag} in |
| 1855 | ..) ;; |
| 1856 | # The odd quoting in the next line works around |
| 1857 | # an apparent bug in bash 1.12 on linux. |
| 1858 | ${srcdir}/gcc/[[*]]/config-lang.in) ;; |
| 1859 | *) |
| 1860 | # From the config-lang.in, get $language, $target_libs, |
| 1861 | # $lang_dirs, $boot_language, and $build_by_default |
| 1862 | language= |
| 1863 | target_libs= |
| 1864 | lang_dirs= |
| 1865 | subdir_requires= |
| 1866 | boot_language=no |
| 1867 | build_by_default=yes |
| 1868 | . ${lang_frag} |
| 1869 | if test x${language} = x; then |
| 1870 | echo "${lang_frag} doesn't set \$language." 1>&2 |
| 1871 | exit 1 |
| 1872 | fi |
| 1873 | |
| 1874 | if test "$language" = "c++"; then |
| 1875 | boot_language=yes |
| 1876 | fi |
| 1877 | |
| 1878 | add_this_lang=no |
| 1879 | case ,${enable_languages}, in |
| 1880 | *,${language},*) |
| 1881 | # Language was explicitly selected; include it |
| 1882 | # unless it is C, which is enabled by default. |
| 1883 | if test "$language" != "c"; then |
| 1884 | add_this_lang=yes |
| 1885 | fi |
| 1886 | ;; |
| 1887 | *,all,*) |
| 1888 | # 'all' was selected, select it if it is a default language |
| 1889 | if test "$language" != "c"; then |
| 1890 | add_this_lang=${build_by_default} |
| 1891 | fi |
| 1892 | ;; |
| 1893 | esac |
| 1894 | |
| 1895 | # Disable languages that need other directories if these aren't available. |
| 1896 | for i in $subdir_requires; do |
| 1897 | test -f "$srcdir/gcc/$i/config-lang.in" && continue |
| 1898 | case ,${enable_languages}, in |
| 1899 | *,${language},*) |
| 1900 | # Specifically requested language; tell them. |
| 1901 | AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing]) |
| 1902 | ;; |
| 1903 | *) |
| 1904 | # Silently disable. |
| 1905 | add_this_lang=unsupported |
| 1906 | ;; |
| 1907 | esac |
| 1908 | done |
| 1909 | |
| 1910 | # Disable Ada if no preexisting GNAT is available. |
| 1911 | case ,${enable_languages},:${language}:${have_gnat} in |
| 1912 | *,${language},*:ada:no) |
| 1913 | # Specifically requested language; tell them. |
| 1914 | AC_MSG_ERROR([GNAT is required to build $language]) |
| 1915 | ;; |
| 1916 | *:ada:no) |
| 1917 | # Silently disable. |
| 1918 | add_this_lang=unsupported |
| 1919 | ;; |
| 1920 | esac |
| 1921 | |
| 1922 | # Disable a language that is unsupported by the target. |
| 1923 | case " $unsupported_languages " in |
| 1924 | *" $language "*) |
| 1925 | add_this_lang=unsupported |
| 1926 | ;; |
| 1927 | esac |
| 1928 | |
| 1929 | case $add_this_lang in |
| 1930 | unsupported) |
| 1931 | # Remove language-dependent dirs. |
| 1932 | disabled_target_libs="$disabled_target_libs $target_libs" |
| 1933 | noconfigdirs="$noconfigdirs $lang_dirs" |
| 1934 | ;; |
| 1935 | no) |
| 1936 | # Remove language-dependent dirs; still show language as supported. |
| 1937 | disabled_target_libs="$disabled_target_libs $target_libs" |
| 1938 | noconfigdirs="$noconfigdirs $lang_dirs" |
| 1939 | potential_languages="${potential_languages}${language}," |
| 1940 | ;; |
| 1941 | yes) |
| 1942 | new_enable_languages="${new_enable_languages}${language}," |
| 1943 | potential_languages="${potential_languages}${language}," |
| 1944 | missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"` |
| 1945 | enabled_target_libs="$enabled_target_libs $target_libs" |
| 1946 | case "${boot_language}:,$enable_stage1_languages," in |
| 1947 | yes:* | *:*,$language,* | *:*,yes, | *:*,all,) |
| 1948 | # Add to (comma-separated) list of stage 1 languages. |
| 1949 | case ",$stage1_languages," in |
| 1950 | *,$language,* | ,yes, | ,all,) ;; |
| 1951 | *) stage1_languages="${stage1_languages}${language}," ;; |
| 1952 | esac |
| 1953 | # We need to bootstrap any supporting libraries. |
| 1954 | bootstrap_target_libs="${bootstrap_target_libs}${target_libs}," |
| 1955 | ;; |
| 1956 | esac |
| 1957 | ;; |
| 1958 | esac |
| 1959 | ;; |
| 1960 | esac |
| 1961 | done |
| 1962 | |
| 1963 | # Add target libraries which are only needed for disabled languages |
| 1964 | # to noconfigdirs. |
| 1965 | if test -n "$disabled_target_libs"; then |
| 1966 | for dir in $disabled_target_libs; do |
| 1967 | case " $enabled_target_libs " in |
| 1968 | *" ${dir} "*) ;; |
| 1969 | *) noconfigdirs="$noconfigdirs $dir" ;; |
| 1970 | esac |
| 1971 | done |
| 1972 | fi |
| 1973 | |
| 1974 | AC_ARG_ENABLE(stage1-languages, |
| 1975 | [AS_HELP_STRING([[--enable-stage1-languages[=all]]], |
| 1976 | [choose additional languages to build during |
| 1977 | stage1. Mostly useful for compiler development])], |
| 1978 | [case ,${enable_stage1_languages}, in |
| 1979 | ,no,|,,) |
| 1980 | # Set it to something that will have no effect in the loop below |
| 1981 | enable_stage1_languages=c ;; |
| 1982 | ,yes,) |
| 1983 | enable_stage1_languages=`echo $new_enable_languages | \ |
| 1984 | sed -e "s/^,//" -e "s/,$//" ` ;; |
| 1985 | *,all,*) |
| 1986 | enable_stage1_languages=`echo ,$enable_stage1_languages, | \ |
| 1987 | sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;; |
| 1988 | esac |
| 1989 | |
| 1990 | # Add "good" languages from enable_stage1_languages to stage1_languages, |
| 1991 | # while "bad" languages go in missing_languages. Leave no duplicates. |
| 1992 | for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do |
| 1993 | case $potential_languages in |
| 1994 | *,$i,*) |
| 1995 | case $stage1_languages in |
| 1996 | *,$i,*) ;; |
| 1997 | *) stage1_languages="$stage1_languages$i," ;; |
| 1998 | esac ;; |
| 1999 | *) |
| 2000 | case $missing_languages in |
| 2001 | *,$i,*) ;; |
| 2002 | *) missing_languages="$missing_languages$i," ;; |
| 2003 | esac ;; |
| 2004 | esac |
| 2005 | done]) |
| 2006 | |
| 2007 | # Remove leading/trailing commas that were added for simplicity |
| 2008 | potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"` |
| 2009 | missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"` |
| 2010 | stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"` |
| 2011 | new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"` |
| 2012 | |
| 2013 | if test "x$missing_languages" != x; then |
| 2014 | AC_MSG_ERROR([ |
| 2015 | The following requested languages could not be built: ${missing_languages} |
| 2016 | Supported languages are: ${potential_languages}]) |
| 2017 | fi |
| 2018 | if test "x$new_enable_languages" != "x$enable_languages"; then |
| 2019 | echo The following languages will be built: ${new_enable_languages} |
| 2020 | enable_languages="$new_enable_languages" |
| 2021 | fi |
| 2022 | |
| 2023 | AC_SUBST(stage1_languages) |
| 2024 | ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" ` |
| 2025 | fi |
| 2026 | |
| 2027 | # Handle --disable-<component> generically. |
| 2028 | for dir in $configdirs $build_configdirs $target_configdirs ; do |
| 2029 | dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g` |
| 2030 | varname=`echo $dirname | sed -e s/+/_/g` |
| 2031 | if eval test x\${enable_${varname}} "=" xno ; then |
| 2032 | noconfigdirs="$noconfigdirs $dir" |
| 2033 | fi |
| 2034 | done |
| 2035 | |
| 2036 | # Check for Boehm's garbage collector |
| 2037 | AC_ARG_ENABLE(objc-gc, |
| 2038 | [AS_HELP_STRING([--enable-objc-gc], |
| 2039 | [enable use of Boehm's garbage collector with the |
| 2040 | GNU Objective-C runtime])], |
| 2041 | [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in |
| 2042 | *,objc,*:*:yes:*target-boehm-gc*) |
| 2043 | AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration]) |
| 2044 | ;; |
| 2045 | esac]) |
| 2046 | |
| 2047 | # Make sure we only build Boehm's garbage collector if required. |
| 2048 | case ,${enable_languages},:${enable_objc_gc} in |
| 2049 | *,objc,*:yes) |
| 2050 | # Keep target-boehm-gc if requested for Objective-C. |
| 2051 | ;; |
| 2052 | *) |
| 2053 | # Otherwise remove target-boehm-gc depending on target-libjava. |
| 2054 | if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then |
| 2055 | noconfigdirs="$noconfigdirs target-boehm-gc" |
| 2056 | fi |
| 2057 | ;; |
| 2058 | esac |
| 2059 | |
| 2060 | # Disable libitm, libsanitizer, libvtv if we're not building C++ |
| 2061 | case ,${enable_languages}, in |
| 2062 | *,c++,*) ;; |
| 2063 | *) |
| 2064 | noconfigdirs="$noconfigdirs target-libcilkrts target-libitm target-libsanitizer target-libvtv" |
| 2065 | ;; |
| 2066 | esac |
| 2067 | |
| 2068 | # Remove the entries in $skipdirs and $noconfigdirs from $configdirs, |
| 2069 | # $build_configdirs and $target_configdirs. |
| 2070 | # If we have the source for $noconfigdirs entries, add them to $notsupp. |
| 2071 | |
| 2072 | notsupp="" |
| 2073 | for dir in . $skipdirs $noconfigdirs ; do |
| 2074 | dirname=`echo $dir | sed -e s/target-//g -e s/build-//g` |
| 2075 | if test $dir != . && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2076 | configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"` |
| 2077 | if test -r $srcdir/$dirname/configure ; then |
| 2078 | if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2079 | true |
| 2080 | else |
| 2081 | notsupp="$notsupp $dir" |
| 2082 | fi |
| 2083 | fi |
| 2084 | fi |
| 2085 | if test $dir != . && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2086 | build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"` |
| 2087 | if test -r $srcdir/$dirname/configure ; then |
| 2088 | if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2089 | true |
| 2090 | else |
| 2091 | notsupp="$notsupp $dir" |
| 2092 | fi |
| 2093 | fi |
| 2094 | fi |
| 2095 | if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2096 | target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"` |
| 2097 | if test -r $srcdir/$dirname/configure ; then |
| 2098 | if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2099 | true |
| 2100 | else |
| 2101 | notsupp="$notsupp $dir" |
| 2102 | fi |
| 2103 | fi |
| 2104 | fi |
| 2105 | done |
| 2106 | |
| 2107 | # Quietly strip out all directories which aren't configurable in this tree. |
| 2108 | # This relies on all configurable subdirectories being autoconfiscated, which |
| 2109 | # is now the case. |
| 2110 | build_configdirs_all="$build_configdirs" |
| 2111 | build_configdirs= |
| 2112 | for i in ${build_configdirs_all} ; do |
| 2113 | j=`echo $i | sed -e s/build-//g` |
| 2114 | if test -f ${srcdir}/$j/configure ; then |
| 2115 | build_configdirs="${build_configdirs} $i" |
| 2116 | fi |
| 2117 | done |
| 2118 | |
| 2119 | configdirs_all="$configdirs" |
| 2120 | configdirs= |
| 2121 | for i in ${configdirs_all} ; do |
| 2122 | if test -f ${srcdir}/$i/configure ; then |
| 2123 | configdirs="${configdirs} $i" |
| 2124 | fi |
| 2125 | done |
| 2126 | |
| 2127 | target_configdirs_all="$target_configdirs" |
| 2128 | target_configdirs= |
| 2129 | for i in ${target_configdirs_all} ; do |
| 2130 | j=`echo $i | sed -e s/target-//g` |
| 2131 | if test -f ${srcdir}/$j/configure ; then |
| 2132 | target_configdirs="${target_configdirs} $i" |
| 2133 | fi |
| 2134 | done |
| 2135 | |
| 2136 | # Produce a warning message for the subdirs we can't configure. |
| 2137 | # This isn't especially interesting in the Cygnus tree, but in the individual |
| 2138 | # FSF releases, it's important to let people know when their machine isn't |
| 2139 | # supported by the one or two programs in a package. |
| 2140 | |
| 2141 | if test -n "${notsupp}" && test -z "${norecursion}" ; then |
| 2142 | # If $appdirs is non-empty, at least one of those directories must still |
| 2143 | # be configured, or we error out. (E.g., if the gas release supports a |
| 2144 | # specified target in some subdirs but not the gas subdir, we shouldn't |
| 2145 | # pretend that all is well.) |
| 2146 | if test -n "$appdirs" ; then |
| 2147 | for dir in $appdirs ; do |
| 2148 | if test -r $dir/Makefile.in ; then |
| 2149 | if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then |
| 2150 | appdirs="" |
| 2151 | break |
| 2152 | fi |
| 2153 | if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then |
| 2154 | appdirs="" |
| 2155 | break |
| 2156 | fi |
| 2157 | fi |
| 2158 | done |
| 2159 | if test -n "$appdirs" ; then |
| 2160 | echo "*** This configuration is not supported by this package." 1>&2 |
| 2161 | exit 1 |
| 2162 | fi |
| 2163 | fi |
| 2164 | # Okay, some application will build, or we don't care to check. Still |
| 2165 | # notify of subdirs not getting built. |
| 2166 | echo "*** This configuration is not supported in the following subdirectories:" 1>&2 |
| 2167 | echo " ${notsupp}" 1>&2 |
| 2168 | echo " (Any other directories should still work fine.)" 1>&2 |
| 2169 | fi |
| 2170 | |
| 2171 | case "$host" in |
| 2172 | *msdosdjgpp*) |
| 2173 | enable_gdbtk=no ;; |
| 2174 | esac |
| 2175 | |
| 2176 | # To find our prefix, in gcc_cv_tool_prefix. |
| 2177 | ACX_TOOL_DIRS |
| 2178 | |
| 2179 | copy_dirs= |
| 2180 | |
| 2181 | AC_ARG_WITH([build-sysroot], |
| 2182 | [AS_HELP_STRING([--with-build-sysroot=SYSROOT], |
| 2183 | [use sysroot as the system root during the build])], |
| 2184 | [if test x"$withval" != x ; then |
| 2185 | SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval" |
| 2186 | fi], |
| 2187 | [SYSROOT_CFLAGS_FOR_TARGET=]) |
| 2188 | AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET) |
| 2189 | |
| 2190 | AC_ARG_WITH([debug-prefix-map], |
| 2191 | [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'], |
| 2192 | [map A to B, C to D ... in debug information])], |
| 2193 | [if test x"$withval" != x; then |
| 2194 | DEBUG_PREFIX_CFLAGS_FOR_TARGET= |
| 2195 | for debug_map in $withval; do |
| 2196 | DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map" |
| 2197 | done |
| 2198 | fi], |
| 2199 | [DEBUG_PREFIX_CFLAGS_FOR_TARGET=]) |
| 2200 | AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET) |
| 2201 | |
| 2202 | # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS |
| 2203 | # might be empty or "-g". We don't require a C++ compiler, so CXXFLAGS |
| 2204 | # might also be empty (or "-g", if a non-GCC C++ compiler is in the path). |
| 2205 | # We want to ensure that TARGET libraries (which we know are built with |
| 2206 | # gcc) are built with "-O2 -g", so include those options when setting |
| 2207 | # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET. |
| 2208 | if test "x$CFLAGS_FOR_TARGET" = x; then |
| 2209 | CFLAGS_FOR_TARGET=$CFLAGS |
| 2210 | case " $CFLAGS " in |
| 2211 | *" -O2 "*) ;; |
| 2212 | *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;; |
| 2213 | esac |
| 2214 | case " $CFLAGS " in |
| 2215 | *" -g "* | *" -g3 "*) ;; |
| 2216 | *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;; |
| 2217 | esac |
| 2218 | fi |
| 2219 | AC_SUBST(CFLAGS_FOR_TARGET) |
| 2220 | |
| 2221 | if test "x$CXXFLAGS_FOR_TARGET" = x; then |
| 2222 | CXXFLAGS_FOR_TARGET=$CXXFLAGS |
| 2223 | case " $CXXFLAGS " in |
| 2224 | *" -O2 "*) ;; |
| 2225 | *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;; |
| 2226 | esac |
| 2227 | case " $CXXFLAGS " in |
| 2228 | *" -g "* | *" -g3 "*) ;; |
| 2229 | *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;; |
| 2230 | esac |
| 2231 | fi |
| 2232 | AC_SUBST(CXXFLAGS_FOR_TARGET) |
| 2233 | |
| 2234 | AC_SUBST(LDFLAGS_FOR_TARGET) |
| 2235 | |
| 2236 | # Handle --with-headers=XXX. If the value is not "yes", the contents of |
| 2237 | # the named directory are copied to $(tooldir)/sys-include. |
| 2238 | if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then |
| 2239 | if test x${is_cross_compiler} = xno ; then |
| 2240 | echo 1>&2 '***' --with-headers is only supported when cross compiling |
| 2241 | exit 1 |
| 2242 | fi |
| 2243 | if test x"${with_headers}" != xyes ; then |
| 2244 | x=${gcc_cv_tool_prefix} |
| 2245 | copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include" |
| 2246 | fi |
| 2247 | fi |
| 2248 | |
| 2249 | # Handle --with-libs=XXX. If the value is not "yes", the contents of |
| 2250 | # the name directories are copied to $(tooldir)/lib. Multiple directories |
| 2251 | # are permitted. |
| 2252 | if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then |
| 2253 | if test x${is_cross_compiler} = xno ; then |
| 2254 | echo 1>&2 '***' --with-libs is only supported when cross compiling |
| 2255 | exit 1 |
| 2256 | fi |
| 2257 | if test x"${with_libs}" != xyes ; then |
| 2258 | # Copy the libraries in reverse order, so that files in the first named |
| 2259 | # library override files in subsequent libraries. |
| 2260 | x=${gcc_cv_tool_prefix} |
| 2261 | for l in ${with_libs}; do |
| 2262 | copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}" |
| 2263 | done |
| 2264 | fi |
| 2265 | fi |
| 2266 | |
| 2267 | # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate. |
| 2268 | # |
| 2269 | # This is done by determining whether or not the appropriate directory |
| 2270 | # is available, and by checking whether or not specific configurations |
| 2271 | # have requested that this magic not happen. |
| 2272 | # |
| 2273 | # The command line options always override the explicit settings in |
| 2274 | # configure.in, and the settings in configure.in override this magic. |
| 2275 | # |
| 2276 | # If the default for a toolchain is to use GNU as and ld, and you don't |
| 2277 | # want to do that, then you should use the --without-gnu-as and |
| 2278 | # --without-gnu-ld options for the configure script. Similarly, if |
| 2279 | # the default is to use the included zlib and you don't want to do that, |
| 2280 | # you should use the --with-system-zlib option for the configure script. |
| 2281 | |
| 2282 | if test x${use_gnu_as} = x && |
| 2283 | echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then |
| 2284 | with_gnu_as=yes |
| 2285 | extra_host_args="$extra_host_args --with-gnu-as" |
| 2286 | fi |
| 2287 | |
| 2288 | if test x${use_gnu_ld} = x && |
| 2289 | echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then |
| 2290 | with_gnu_ld=yes |
| 2291 | extra_host_args="$extra_host_args --with-gnu-ld" |
| 2292 | fi |
| 2293 | |
| 2294 | if test x${use_included_zlib} = x && |
| 2295 | echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then |
| 2296 | : |
| 2297 | else |
| 2298 | with_system_zlib=yes |
| 2299 | extra_host_args="$extra_host_args --with-system-zlib" |
| 2300 | fi |
| 2301 | |
| 2302 | # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure |
| 2303 | # can detect this case. |
| 2304 | |
| 2305 | if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then |
| 2306 | with_newlib=yes |
| 2307 | extra_host_args="$extra_host_args --with-newlib" |
| 2308 | fi |
| 2309 | |
| 2310 | # Handle ${copy_dirs} |
| 2311 | set fnord ${copy_dirs} |
| 2312 | shift |
| 2313 | while test $# != 0 ; do |
| 2314 | if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then |
| 2315 | : |
| 2316 | else |
| 2317 | echo Copying $1 to $2 |
| 2318 | |
| 2319 | # Use the install script to create the directory and all required |
| 2320 | # parent directories. |
| 2321 | if test -d $2 ; then |
| 2322 | : |
| 2323 | else |
| 2324 | echo >config.temp |
| 2325 | ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED |
| 2326 | fi |
| 2327 | |
| 2328 | # Copy the directory, assuming we have tar. |
| 2329 | # FIXME: Should we use B in the second tar? Not all systems support it. |
| 2330 | (cd $1; tar -cf - .) | (cd $2; tar -xpf -) |
| 2331 | |
| 2332 | # It is the responsibility of the user to correctly adjust all |
| 2333 | # symlinks. If somebody can figure out how to handle them correctly |
| 2334 | # here, feel free to add the code. |
| 2335 | |
| 2336 | echo $1 > $2/COPIED |
| 2337 | fi |
| 2338 | shift; shift |
| 2339 | done |
| 2340 | |
| 2341 | # Determine a target-dependent exec_prefix that the installed |
| 2342 | # gcc will search in. Keep this list sorted by triplet, with |
| 2343 | # the *-*-osname triplets last. |
| 2344 | md_exec_prefix= |
| 2345 | case "${target}" in |
| 2346 | i[[34567]]86-pc-msdosdjgpp*) |
| 2347 | md_exec_prefix=/dev/env/DJDIR/bin |
| 2348 | ;; |
| 2349 | *-*-hpux* | \ |
| 2350 | *-*-nto-qnx* | \ |
| 2351 | *-*-solaris2*) |
| 2352 | md_exec_prefix=/usr/ccs/bin |
| 2353 | ;; |
| 2354 | esac |
| 2355 | |
| 2356 | extra_arflags_for_target= |
| 2357 | extra_nmflags_for_target= |
| 2358 | extra_ranlibflags_for_target= |
| 2359 | target_makefile_frag=/dev/null |
| 2360 | case "${target}" in |
| 2361 | spu-*-*) |
| 2362 | target_makefile_frag="config/mt-spu" |
| 2363 | ;; |
| 2364 | mips*-sde-elf* | mips*-mti-elf*) |
| 2365 | target_makefile_frag="config/mt-sde" |
| 2366 | ;; |
| 2367 | mipsisa*-*-elfoabi*) |
| 2368 | target_makefile_frag="config/mt-mips-elfoabi" |
| 2369 | ;; |
| 2370 | mips*-*-*linux* | mips*-*-gnu*) |
| 2371 | target_makefile_frag="config/mt-mips-gnu" |
| 2372 | ;; |
| 2373 | *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu) |
| 2374 | target_makefile_frag="config/mt-gnu" |
| 2375 | ;; |
| 2376 | *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*) |
| 2377 | # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm |
| 2378 | # commands to handle both 32-bit and 64-bit objects. These flags are |
| 2379 | # harmless if we're using GNU nm or ar. |
| 2380 | extra_arflags_for_target=" -X32_64" |
| 2381 | extra_nmflags_for_target=" -B -X32_64" |
| 2382 | ;; |
| 2383 | esac |
| 2384 | |
| 2385 | alphaieee_frag=/dev/null |
| 2386 | case $target in |
| 2387 | alpha*-*-*) |
| 2388 | # This just makes sure to use the -mieee option to build target libs. |
| 2389 | # This should probably be set individually by each library. |
| 2390 | alphaieee_frag="config/mt-alphaieee" |
| 2391 | ;; |
| 2392 | esac |
| 2393 | |
| 2394 | # If --enable-target-optspace always use -Os instead of -O2 to build |
| 2395 | # the target libraries, similarly if it is not specified, use -Os |
| 2396 | # on selected platforms. |
| 2397 | ospace_frag=/dev/null |
| 2398 | case "${enable_target_optspace}:${target}" in |
| 2399 | yes:*) |
| 2400 | ospace_frag="config/mt-ospace" |
| 2401 | ;; |
| 2402 | :d30v-*) |
| 2403 | ospace_frag="config/mt-d30v" |
| 2404 | ;; |
| 2405 | :m32r-* | :d10v-* | :fr30-*) |
| 2406 | ospace_frag="config/mt-ospace" |
| 2407 | ;; |
| 2408 | no:* | :*) |
| 2409 | ;; |
| 2410 | *) |
| 2411 | echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2 |
| 2412 | ;; |
| 2413 | esac |
| 2414 | |
| 2415 | # Some systems (e.g., one of the i386-aix systems the gas testers are |
| 2416 | # using) don't handle "\$" correctly, so don't use it here. |
| 2417 | tooldir='${exec_prefix}'/${target_noncanonical} |
| 2418 | build_tooldir=${tooldir} |
| 2419 | |
| 2420 | # Create a .gdbinit file which runs the one in srcdir |
| 2421 | # and tells GDB to look there for source files. |
| 2422 | |
| 2423 | if test -r ${srcdir}/.gdbinit ; then |
| 2424 | case ${srcdir} in |
| 2425 | .) ;; |
| 2426 | *) cat > ./.gdbinit <<EOF |
| 2427 | # ${NO_EDIT} |
| 2428 | dir ${srcdir} |
| 2429 | dir . |
| 2430 | source ${srcdir}/.gdbinit |
| 2431 | EOF |
| 2432 | ;; |
| 2433 | esac |
| 2434 | fi |
| 2435 | |
| 2436 | # Make sure that the compiler is able to generate an executable. If it |
| 2437 | # can't, we are probably in trouble. We don't care whether we can run the |
| 2438 | # executable--we might be using a cross compiler--we only care whether it |
| 2439 | # can be created. At this point the main configure script has set CC. |
| 2440 | we_are_ok=no |
| 2441 | echo "int main () { return 0; }" > conftest.c |
| 2442 | ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c |
| 2443 | if test $? = 0 ; then |
| 2444 | if test -s conftest || test -s conftest.exe ; then |
| 2445 | we_are_ok=yes |
| 2446 | fi |
| 2447 | fi |
| 2448 | case $we_are_ok in |
| 2449 | no) |
| 2450 | echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed." |
| 2451 | echo 1>&2 "*** You must set the environment variable CC to a working compiler." |
| 2452 | rm -f conftest* |
| 2453 | exit 1 |
| 2454 | ;; |
| 2455 | esac |
| 2456 | rm -f conftest* |
| 2457 | |
| 2458 | # Decide which environment variable is used to find dynamic libraries. |
| 2459 | case "${host}" in |
| 2460 | *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;; |
| 2461 | *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;; |
| 2462 | *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;; |
| 2463 | *) RPATH_ENVVAR=LD_LIBRARY_PATH ;; |
| 2464 | esac |
| 2465 | |
| 2466 | # On systems where the dynamic library environment variable is PATH, |
| 2467 | # gcc/ will put dynamic libraries into a subdirectory to avoid adding |
| 2468 | # built executables to PATH. |
| 2469 | if test "$RPATH_ENVVAR" = PATH; then |
| 2470 | GCC_SHLIB_SUBDIR=/shlib |
| 2471 | else |
| 2472 | GCC_SHLIB_SUBDIR= |
| 2473 | fi |
| 2474 | |
| 2475 | # Record target_configdirs and the configure arguments for target and |
| 2476 | # build configuration in Makefile. |
| 2477 | target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'` |
| 2478 | build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'` |
| 2479 | |
| 2480 | # If we are building libgomp, bootstrap it. |
| 2481 | if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then |
| 2482 | bootstrap_target_libs=${bootstrap_target_libs}target-libgomp, |
| 2483 | fi |
| 2484 | |
| 2485 | # If we are building libsanitizer, bootstrap it. |
| 2486 | if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1 ; then |
| 2487 | bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer, |
| 2488 | fi |
| 2489 | |
| 2490 | # If we are building libvtv, bootstrap it. |
| 2491 | if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 ; then |
| 2492 | bootstrap_target_libs=${bootstrap_target_libs}target-libvtv, |
| 2493 | fi |
| 2494 | |
| 2495 | # Determine whether gdb needs tk/tcl or not. |
| 2496 | # Use 'maybe' since enable_gdbtk might be true even if tk isn't available |
| 2497 | # and in that case we want gdb to be built without tk. Ugh! |
| 2498 | # In fact I believe gdb is the *only* package directly dependent on tk, |
| 2499 | # so we should be able to put the 'maybe's in unconditionally and |
| 2500 | # leave out the maybe dependencies when enable_gdbtk is false. I'm not |
| 2501 | # 100% sure that that's safe though. |
| 2502 | |
| 2503 | gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui" |
| 2504 | case "$enable_gdbtk" in |
| 2505 | no) |
| 2506 | GDB_TK="" ;; |
| 2507 | yes) |
| 2508 | GDB_TK="${gdb_tk}" ;; |
| 2509 | *) |
| 2510 | # Only add the dependency on gdbtk when GDBtk is part of the gdb |
| 2511 | # distro. Eventually someone will fix this and move Insight, nee |
| 2512 | # gdbtk to a separate directory. |
| 2513 | if test -d ${srcdir}/gdb/gdbtk ; then |
| 2514 | GDB_TK="${gdb_tk}" |
| 2515 | else |
| 2516 | GDB_TK="" |
| 2517 | fi |
| 2518 | ;; |
| 2519 | esac |
| 2520 | CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g` |
| 2521 | INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g` |
| 2522 | |
| 2523 | # Strip out unwanted targets. |
| 2524 | |
| 2525 | # While at that, we remove Makefiles if we were started for recursive |
| 2526 | # configuration, so that the top-level Makefile reconfigures them, |
| 2527 | # like we used to do when configure itself was recursive. |
| 2528 | |
| 2529 | # Loop over modules. We used to use the "$extrasub" feature from Autoconf |
| 2530 | # but now we're fixing up the Makefile ourselves with the additional |
| 2531 | # commands passed to AC_CONFIG_FILES. Use separate variables |
| 2532 | # extrasub-{build,host,target} not because there is any reason to split |
| 2533 | # the substitutions up that way, but only to remain below the limit of |
| 2534 | # 99 commands in a script, for HP-UX sed. |
| 2535 | # Do not nest @if/@endif pairs, because configure will not warn you at all. |
| 2536 | |
| 2537 | case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in |
| 2538 | yes:yes:*\ gold\ *:*,c++,*) ;; |
| 2539 | yes:yes:*\ gold\ *:*) |
| 2540 | AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages]) |
| 2541 | ;; |
| 2542 | esac |
| 2543 | |
| 2544 | # Adjust the toplevel makefile according to whether bootstrap was selected. |
| 2545 | case $enable_bootstrap in |
| 2546 | yes) |
| 2547 | bootstrap_suffix=bootstrap |
| 2548 | BUILD_CONFIG=bootstrap-debug |
| 2549 | ;; |
| 2550 | no) |
| 2551 | bootstrap_suffix=no-bootstrap |
| 2552 | BUILD_CONFIG= |
| 2553 | ;; |
| 2554 | esac |
| 2555 | |
| 2556 | AC_MSG_CHECKING(for default BUILD_CONFIG) |
| 2557 | |
| 2558 | AC_ARG_WITH([build-config], |
| 2559 | [AS_HELP_STRING([--with-build-config='NAME NAME2...'], |
| 2560 | [use config/NAME.mk build configuration])], |
| 2561 | [case $with_build_config in |
| 2562 | yes) with_build_config= ;; |
| 2563 | no) with_build_config= BUILD_CONFIG= ;; |
| 2564 | esac]) |
| 2565 | |
| 2566 | if test "x${with_build_config}" != x; then |
| 2567 | BUILD_CONFIG=$with_build_config |
| 2568 | else |
| 2569 | case $BUILD_CONFIG in |
| 2570 | bootstrap-debug) |
| 2571 | if echo "int f (void) { return 0; }" > conftest.c && |
| 2572 | ${CC} -c conftest.c && |
| 2573 | mv conftest.o conftest.o.g0 && |
| 2574 | ${CC} -c -g conftest.c && |
| 2575 | mv conftest.o conftest.o.g && |
| 2576 | ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then |
| 2577 | : |
| 2578 | else |
| 2579 | BUILD_CONFIG= |
| 2580 | fi |
| 2581 | rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g |
| 2582 | ;; |
| 2583 | esac |
| 2584 | fi |
| 2585 | AC_MSG_RESULT($BUILD_CONFIG) |
| 2586 | AC_SUBST(BUILD_CONFIG) |
| 2587 | |
| 2588 | extrasub_build= |
| 2589 | for module in ${build_configdirs} ; do |
| 2590 | if test -z "${no_recursion}" \ |
| 2591 | && test -f ${build_subdir}/${module}/Makefile; then |
| 2592 | echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure" |
| 2593 | rm -f ${build_subdir}/${module}/Makefile |
| 2594 | fi |
| 2595 | extrasub_build="$extrasub_build |
| 2596 | /^@if build-$module\$/d |
| 2597 | /^@endif build-$module\$/d |
| 2598 | /^@if build-$module-$bootstrap_suffix\$/d |
| 2599 | /^@endif build-$module-$bootstrap_suffix\$/d" |
| 2600 | done |
| 2601 | extrasub_host= |
| 2602 | for module in ${configdirs} ; do |
| 2603 | if test -z "${no_recursion}"; then |
| 2604 | for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do |
| 2605 | if test -f ${file}; then |
| 2606 | echo 1>&2 "*** removing ${file} to force reconfigure" |
| 2607 | rm -f ${file} |
| 2608 | fi |
| 2609 | done |
| 2610 | fi |
| 2611 | extrasub_host="$extrasub_host |
| 2612 | /^@if $module\$/d |
| 2613 | /^@endif $module\$/d |
| 2614 | /^@if $module-$bootstrap_suffix\$/d |
| 2615 | /^@endif $module-$bootstrap_suffix\$/d" |
| 2616 | done |
| 2617 | extrasub_target= |
| 2618 | for module in ${target_configdirs} ; do |
| 2619 | if test -z "${no_recursion}" \ |
| 2620 | && test -f ${target_subdir}/${module}/Makefile; then |
| 2621 | echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure" |
| 2622 | rm -f ${target_subdir}/${module}/Makefile |
| 2623 | fi |
| 2624 | |
| 2625 | # We only bootstrap target libraries listed in bootstrap_target_libs. |
| 2626 | case $bootstrap_target_libs in |
| 2627 | *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;; |
| 2628 | *) target_bootstrap_suffix=no-bootstrap ;; |
| 2629 | esac |
| 2630 | |
| 2631 | extrasub_target="$extrasub_target |
| 2632 | /^@if target-$module\$/d |
| 2633 | /^@endif target-$module\$/d |
| 2634 | /^@if target-$module-$target_bootstrap_suffix\$/d |
| 2635 | /^@endif target-$module-$target_bootstrap_suffix\$/d" |
| 2636 | done |
| 2637 | |
| 2638 | # Do the final fixup along with target modules. |
| 2639 | extrasub_target="$extrasub_target |
| 2640 | /^@if /,/^@endif /d" |
| 2641 | |
| 2642 | # Create the serialization dependencies. This uses a temporary file. |
| 2643 | |
| 2644 | AC_ARG_ENABLE([serial-configure], |
| 2645 | [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]], |
| 2646 | [force sequential configuration of |
| 2647 | sub-packages for the host, target or build |
| 2648 | machine, or all sub-packages])]) |
| 2649 | |
| 2650 | case ${enable_serial_configure} in |
| 2651 | yes) |
| 2652 | enable_serial_build_configure=yes |
| 2653 | enable_serial_host_configure=yes |
| 2654 | enable_serial_target_configure=yes |
| 2655 | ;; |
| 2656 | esac |
| 2657 | |
| 2658 | # These force 'configure's to be done one at a time, to avoid problems |
| 2659 | # with contention over a shared config.cache. |
| 2660 | rm -f serdep.tmp |
| 2661 | echo '# serdep.tmp' > serdep.tmp |
| 2662 | olditem= |
| 2663 | test "x${enable_serial_build_configure}" = xyes && |
| 2664 | for item in ${build_configdirs} ; do |
| 2665 | case ${olditem} in |
| 2666 | "") ;; |
| 2667 | *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;; |
| 2668 | esac |
| 2669 | olditem=${item} |
| 2670 | done |
| 2671 | olditem= |
| 2672 | test "x${enable_serial_host_configure}" = xyes && |
| 2673 | for item in ${configdirs} ; do |
| 2674 | case ${olditem} in |
| 2675 | "") ;; |
| 2676 | *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;; |
| 2677 | esac |
| 2678 | olditem=${item} |
| 2679 | done |
| 2680 | olditem= |
| 2681 | test "x${enable_serial_target_configure}" = xyes && |
| 2682 | for item in ${target_configdirs} ; do |
| 2683 | case ${olditem} in |
| 2684 | "") ;; |
| 2685 | *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;; |
| 2686 | esac |
| 2687 | olditem=${item} |
| 2688 | done |
| 2689 | serialization_dependencies=serdep.tmp |
| 2690 | AC_SUBST_FILE(serialization_dependencies) |
| 2691 | |
| 2692 | # Base args. Strip norecursion, cache-file, srcdir, host, build, |
| 2693 | # target, nonopt, and variable assignments. These are the ones we |
| 2694 | # might not want to pass down to subconfigures. The exception being |
| 2695 | # --cache-file=/dev/null, which is used to turn off the use of cache |
| 2696 | # files altogether, and which should be passed on to subconfigures. |
| 2697 | # Also strip program-prefix, program-suffix, and program-transform-name, |
| 2698 | # so that we can pass down a consistent program-transform-name. |
| 2699 | baseargs= |
| 2700 | tbaseargs= |
| 2701 | keep_next=no |
| 2702 | skip_next=no |
| 2703 | eval "set -- $ac_configure_args" |
| 2704 | for ac_arg |
| 2705 | do |
| 2706 | if test X"$skip_next" = X"yes"; then |
| 2707 | skip_next=no |
| 2708 | continue |
| 2709 | fi |
| 2710 | if test X"$keep_next" = X"yes"; then |
| 2711 | case $ac_arg in |
| 2712 | *\'*) |
| 2713 | ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;; |
| 2714 | esac |
| 2715 | baseargs="$baseargs '$ac_arg'" |
| 2716 | tbaseargs="$tbaseargs '$ac_arg'" |
| 2717 | keep_next=no |
| 2718 | continue |
| 2719 | fi |
| 2720 | |
| 2721 | # Handle separated arguments. Based on the logic generated by |
| 2722 | # autoconf 2.59. |
| 2723 | case $ac_arg in |
| 2724 | *=* | --config-cache | -C | -disable-* | --disable-* \ |
| 2725 | | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \ |
| 2726 | | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \ |
| 2727 | | -with-* | --with-* | -without-* | --without-* | --x) |
| 2728 | separate_arg=no |
| 2729 | ;; |
| 2730 | -*) |
| 2731 | separate_arg=yes |
| 2732 | ;; |
| 2733 | *) |
| 2734 | separate_arg=no |
| 2735 | ;; |
| 2736 | esac |
| 2737 | |
| 2738 | skip_targ=no |
| 2739 | case $ac_arg in |
| 2740 | changequote(,) |
| 2741 | --with-* | --without-*) |
| 2742 | libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'` |
| 2743 | |
| 2744 | case $libopt in |
| 2745 | *[-_]include) |
| 2746 | lib=`echo "$libopt" | sed 's,[-_]include$,,'` |
| 2747 | ;; |
| 2748 | *[-_]lib) |
| 2749 | lib=`echo "$libopt" | sed 's,[-_]lib$,,'` |
| 2750 | ;; |
| 2751 | *) |
| 2752 | lib=$libopt |
| 2753 | ;; |
| 2754 | esac |
| 2755 | changequote([,]) |
| 2756 | |
| 2757 | case $lib in |
| 2758 | mpc | mpfr | gmp | cloog) |
| 2759 | # If we're processing --with-$lib, --with-$lib-include or |
| 2760 | # --with-$lib-lib, for one of the libs above, and target is |
| 2761 | # different from host, don't pass the current argument to any |
| 2762 | # target library's configure. |
| 2763 | if test x$is_cross_compiler = xyes; then |
| 2764 | skip_targ=yes |
| 2765 | fi |
| 2766 | ;; |
| 2767 | esac |
| 2768 | ;; |
| 2769 | esac |
| 2770 | |
| 2771 | case "$ac_arg" in |
| 2772 | --cache-file=/dev/null | \ |
| 2773 | -cache-file=/dev/null ) |
| 2774 | # Handled here to avoid the test to skip args below. |
| 2775 | baseargs="$baseargs '$ac_arg'" |
| 2776 | tbaseargs="$tbaseargs '$ac_arg'" |
| 2777 | # Assert: $separate_arg should always be no. |
| 2778 | keep_next=$separate_arg |
| 2779 | ;; |
| 2780 | --no*) |
| 2781 | continue |
| 2782 | ;; |
| 2783 | --c* | \ |
| 2784 | --sr* | \ |
| 2785 | --ho* | \ |
| 2786 | --bu* | \ |
| 2787 | --t* | \ |
| 2788 | --program-* | \ |
| 2789 | -cache_file* | \ |
| 2790 | -srcdir* | \ |
| 2791 | -host* | \ |
| 2792 | -build* | \ |
| 2793 | -target* | \ |
| 2794 | -program-prefix* | \ |
| 2795 | -program-suffix* | \ |
| 2796 | -program-transform-name* ) |
| 2797 | skip_next=$separate_arg |
| 2798 | continue |
| 2799 | ;; |
| 2800 | -*) |
| 2801 | # An option. Add it. |
| 2802 | case $ac_arg in |
| 2803 | *\'*) |
| 2804 | ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;; |
| 2805 | esac |
| 2806 | baseargs="$baseargs '$ac_arg'" |
| 2807 | if test X"$skip_targ" = Xno; then |
| 2808 | tbaseargs="$tbaseargs '$ac_arg'" |
| 2809 | fi |
| 2810 | keep_next=$separate_arg |
| 2811 | ;; |
| 2812 | *) |
| 2813 | # Either a variable assignment, or a nonopt (triplet). Don't |
| 2814 | # pass it down; let the Makefile handle this. |
| 2815 | continue |
| 2816 | ;; |
| 2817 | esac |
| 2818 | done |
| 2819 | # Remove the initial space we just introduced and, as these will be |
| 2820 | # expanded by make, quote '$'. |
| 2821 | baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'` |
| 2822 | |
| 2823 | # Add in --program-transform-name, after --program-prefix and |
| 2824 | # --program-suffix have been applied to it. Autoconf has already |
| 2825 | # doubled dollar signs and backslashes in program_transform_name; we want |
| 2826 | # the backslashes un-doubled, and then the entire thing wrapped in single |
| 2827 | # quotes, because this will be expanded first by make and then by the shell. |
| 2828 | # Also, because we want to override the logic in subdir configure scripts to |
| 2829 | # choose program_transform_name, replace any s,x,x, with s,y,y,. |
| 2830 | sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out |
| 2831 | ${program_transform_name} |
| 2832 | EOF_SED |
| 2833 | gcc_transform_name=`cat conftestsed.out` |
| 2834 | rm -f conftestsed.out |
| 2835 | baseargs="$baseargs --program-transform-name='${gcc_transform_name}'" |
| 2836 | tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'" |
| 2837 | if test "$silent" = yes; then |
| 2838 | baseargs="$baseargs --silent" |
| 2839 | tbaseargs="$tbaseargs --silent" |
| 2840 | fi |
| 2841 | baseargs="$baseargs --disable-option-checking" |
| 2842 | tbaseargs="$tbaseargs --disable-option-checking" |
| 2843 | |
| 2844 | # Record and document user additions to sub configure arguments. |
| 2845 | AC_ARG_VAR([build_configargs], |
| 2846 | [additional configure arguments for build directories]) |
| 2847 | AC_ARG_VAR([host_configargs], |
| 2848 | [additional configure arguments for host directories]) |
| 2849 | AC_ARG_VAR([target_configargs], |
| 2850 | [additional configure arguments for target directories]) |
| 2851 | |
| 2852 | # For the build-side libraries, we just need to pretend we're native, |
| 2853 | # and not use the same cache file. Multilibs are neither needed nor |
| 2854 | # desired. |
| 2855 | build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}" |
| 2856 | |
| 2857 | # For host modules, accept cache file option, or specification as blank. |
| 2858 | case "${cache_file}" in |
| 2859 | "") # empty |
| 2860 | cache_file_option="" ;; |
| 2861 | /* | [[A-Za-z]]:[[\\/]]* ) # absolute path |
| 2862 | cache_file_option="--cache-file=${cache_file}" ;; |
| 2863 | *) # relative path |
| 2864 | cache_file_option="--cache-file=../${cache_file}" ;; |
| 2865 | esac |
| 2866 | |
| 2867 | # Host dirs don't like to share a cache file either, horribly enough. |
| 2868 | # This seems to be due to autoconf 2.5x stupidity. |
| 2869 | host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}" |
| 2870 | |
| 2871 | target_configargs="$target_configargs ${tbaseargs}" |
| 2872 | |
| 2873 | # Passing a --with-cross-host argument lets the target libraries know |
| 2874 | # whether they are being built with a cross-compiler or being built |
| 2875 | # native. However, it would be better to use other mechanisms to make the |
| 2876 | # sorts of decisions they want to make on this basis. Please consider |
| 2877 | # this option to be deprecated. FIXME. |
| 2878 | if test x${is_cross_compiler} = xyes ; then |
| 2879 | target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}" |
| 2880 | fi |
| 2881 | |
| 2882 | # Default to --enable-multilib. |
| 2883 | if test x${enable_multilib} = x ; then |
| 2884 | target_configargs="--enable-multilib ${target_configargs}" |
| 2885 | fi |
| 2886 | |
| 2887 | # Pass --with-newlib if appropriate. Note that target_configdirs has |
| 2888 | # changed from the earlier setting of with_newlib. |
| 2889 | if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then |
| 2890 | target_configargs="--with-newlib ${target_configargs}" |
| 2891 | fi |
| 2892 | |
| 2893 | # Different target subdirs use different values of certain variables |
| 2894 | # (notably CXX). Worse, multilibs use *lots* of different values. |
| 2895 | # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that |
| 2896 | # it doesn't automatically accept command-line overrides of them. |
| 2897 | # This means it's not safe for target subdirs to share a cache file, |
| 2898 | # which is disgusting, but there you have it. Hopefully this can be |
| 2899 | # fixed in future. It's still worthwhile to use a cache file for each |
| 2900 | # directory. I think. |
| 2901 | |
| 2902 | # Pass the appropriate --build, --host, --target and --cache-file arguments. |
| 2903 | # We need to pass --target, as newer autoconf's requires consistency |
| 2904 | # for target_alias and gcc doesn't manage it consistently. |
| 2905 | target_configargs="--cache-file=./config.cache ${target_configargs}" |
| 2906 | |
| 2907 | FLAGS_FOR_TARGET= |
| 2908 | case " $target_configdirs " in |
| 2909 | *" newlib "*) |
| 2910 | case " $target_configargs " in |
| 2911 | *" --with-newlib "*) |
| 2912 | case "$target" in |
| 2913 | *-cygwin*) |
| 2914 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include' |
| 2915 | ;; |
| 2916 | esac |
| 2917 | |
| 2918 | # If we're not building GCC, don't discard standard headers. |
| 2919 | if test -d ${srcdir}/gcc; then |
| 2920 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc' |
| 2921 | |
| 2922 | if test "${build}" != "${host}"; then |
| 2923 | # On Canadian crosses, CC_FOR_TARGET will have already been set |
| 2924 | # by `configure', so we won't have an opportunity to add -Bgcc/ |
| 2925 | # to it. This is right: we don't want to search that directory |
| 2926 | # for binaries, but we want the header files in there, so add |
| 2927 | # them explicitly. |
| 2928 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed' |
| 2929 | |
| 2930 | # Someone might think of using the pre-installed headers on |
| 2931 | # Canadian crosses, in case the installed compiler is not fully |
| 2932 | # compatible with the compiler being built. In this case, it |
| 2933 | # would be better to flag an error than risking having |
| 2934 | # incompatible object files being constructed. We can't |
| 2935 | # guarantee that an error will be flagged, but let's hope the |
| 2936 | # compiler will do it, when presented with incompatible header |
| 2937 | # files. |
| 2938 | fi |
| 2939 | fi |
| 2940 | |
| 2941 | case "${target}-${is_cross_compiler}" in |
| 2942 | i[[3456789]]86-*-linux*-no) |
| 2943 | # Here host == target, so we don't need to build gcc, |
| 2944 | # so we don't want to discard standard headers. |
| 2945 | FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'` |
| 2946 | ;; |
| 2947 | *) |
| 2948 | # If we're building newlib, use its generic headers last, but search |
| 2949 | # for any libc-related directories first (so make it the last -B |
| 2950 | # switch). |
| 2951 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include' |
| 2952 | |
| 2953 | # If we're building libgloss, find the startup file, simulator library |
| 2954 | # and linker script. |
| 2955 | case " $target_configdirs " in |
| 2956 | *" libgloss "*) |
| 2957 | # Look for startup file, simulator library and maybe linker script. |
| 2958 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir" |
| 2959 | # Look for libnosys.a in case the target needs it. |
| 2960 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys' |
| 2961 | # Most targets have the linker script in the source directory. |
| 2962 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir" |
| 2963 | ;; |
| 2964 | esac |
| 2965 | ;; |
| 2966 | esac |
| 2967 | ;; |
| 2968 | esac |
| 2969 | ;; |
| 2970 | esac |
| 2971 | |
| 2972 | case "$target" in |
| 2973 | x86_64-*mingw* | *-w64-mingw*) |
| 2974 | # MinGW-w64 does not use newlib, nor does it use winsup. It may, |
| 2975 | # however, use a symlink named 'mingw' in ${prefix} . |
| 2976 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include' |
| 2977 | ;; |
| 2978 | *-mingw*) |
| 2979 | # MinGW can't be handled as Cygwin above since it does not use newlib. |
| 2980 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include' |
| 2981 | ;; |
| 2982 | esac |
| 2983 | |
| 2984 | # Allow the user to override the flags for |
| 2985 | # our build compiler if desired. |
| 2986 | if test x"${build}" = x"${host}" ; then |
| 2987 | CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}} |
| 2988 | CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}} |
| 2989 | LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}} |
| 2990 | fi |
| 2991 | |
| 2992 | # On Canadian crosses, we'll be searching the right directories for |
| 2993 | # the previously-installed cross compiler, so don't bother to add |
| 2994 | # flags for directories within the install tree of the compiler |
| 2995 | # being built; programs in there won't even run. |
| 2996 | if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then |
| 2997 | # Search for pre-installed headers if nothing else fits. |
| 2998 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include' |
| 2999 | fi |
| 3000 | |
| 3001 | if test "x${use_gnu_ld}" = x && |
| 3002 | echo " ${configdirs} " | grep " ld " > /dev/null ; then |
| 3003 | # Arrange for us to find uninstalled linker scripts. |
| 3004 | FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld' |
| 3005 | fi |
| 3006 | |
| 3007 | # Search for other target-specific linker scripts and such. |
| 3008 | case "${target}" in |
| 3009 | mep*) |
| 3010 | FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary" |
| 3011 | ;; |
| 3012 | esac |
| 3013 | |
| 3014 | # Makefile fragments. |
| 3015 | for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag; |
| 3016 | do |
| 3017 | eval fragval=\$$frag |
| 3018 | if test $fragval != /dev/null; then |
| 3019 | eval $frag=${srcdir}/$fragval |
| 3020 | fi |
| 3021 | done |
| 3022 | AC_SUBST_FILE(host_makefile_frag) |
| 3023 | AC_SUBST_FILE(target_makefile_frag) |
| 3024 | AC_SUBST_FILE(alphaieee_frag) |
| 3025 | AC_SUBST_FILE(ospace_frag) |
| 3026 | |
| 3027 | # Miscellanea: directories, flags, etc. |
| 3028 | AC_SUBST(RPATH_ENVVAR) |
| 3029 | AC_SUBST(GCC_SHLIB_SUBDIR) |
| 3030 | AC_SUBST(tooldir) |
| 3031 | AC_SUBST(build_tooldir) |
| 3032 | AC_SUBST(CONFIGURE_GDB_TK) |
| 3033 | AC_SUBST(GDB_TK) |
| 3034 | AC_SUBST(INSTALL_GDB_TK) |
| 3035 | |
| 3036 | # Build module lists & subconfigure args. |
| 3037 | AC_SUBST(build_configargs) |
| 3038 | AC_SUBST(build_configdirs) |
| 3039 | |
| 3040 | # Host module lists & subconfigure args. |
| 3041 | AC_SUBST(host_configargs) |
| 3042 | AC_SUBST(configdirs) |
| 3043 | AC_SUBST(target_configdirs) |
| 3044 | |
| 3045 | # Target module lists & subconfigure args. |
| 3046 | AC_SUBST(target_configargs) |
| 3047 | |
| 3048 | |
| 3049 | # Build tools. |
| 3050 | AC_SUBST(AR_FOR_BUILD) |
| 3051 | AC_SUBST(AS_FOR_BUILD) |
| 3052 | AC_SUBST(CC_FOR_BUILD) |
| 3053 | AC_SUBST(CFLAGS_FOR_BUILD) |
| 3054 | AC_SUBST(CXXFLAGS_FOR_BUILD) |
| 3055 | AC_SUBST(CXX_FOR_BUILD) |
| 3056 | AC_SUBST(DLLTOOL_FOR_BUILD) |
| 3057 | AC_SUBST(GCJ_FOR_BUILD) |
| 3058 | AC_SUBST(GFORTRAN_FOR_BUILD) |
| 3059 | AC_SUBST(GOC_FOR_BUILD) |
| 3060 | AC_SUBST(LDFLAGS_FOR_BUILD) |
| 3061 | AC_SUBST(LD_FOR_BUILD) |
| 3062 | AC_SUBST(NM_FOR_BUILD) |
| 3063 | AC_SUBST(RANLIB_FOR_BUILD) |
| 3064 | AC_SUBST(WINDMC_FOR_BUILD) |
| 3065 | AC_SUBST(WINDRES_FOR_BUILD) |
| 3066 | |
| 3067 | # Generate default definitions for YACC, M4, LEX and other programs that run |
| 3068 | # on the build machine. These are used if the Makefile can't locate these |
| 3069 | # programs in objdir. |
| 3070 | MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing |
| 3071 | |
| 3072 | AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y]) |
| 3073 | case " $build_configdirs " in |
| 3074 | *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;; |
| 3075 | esac |
| 3076 | |
| 3077 | AC_CHECK_PROGS([BISON], [bison], [$MISSING bison]) |
| 3078 | case " $build_configdirs " in |
| 3079 | *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;; |
| 3080 | esac |
| 3081 | |
| 3082 | AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4]) |
| 3083 | case " $build_configdirs " in |
| 3084 | *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;; |
| 3085 | esac |
| 3086 | |
| 3087 | AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex]) |
| 3088 | case " $build_configdirs " in |
| 3089 | *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;; |
| 3090 | *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;; |
| 3091 | esac |
| 3092 | |
| 3093 | AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex]) |
| 3094 | case " $build_configdirs " in |
| 3095 | *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;; |
| 3096 | esac |
| 3097 | |
| 3098 | AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo]) |
| 3099 | case " $build_configdirs " in |
| 3100 | *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;; |
| 3101 | *) |
| 3102 | changequote(,) |
| 3103 | # For an installed makeinfo, we require it to be from texinfo 4.7 or |
| 3104 | # higher, else we use the "missing" dummy. |
| 3105 | if ${MAKEINFO} --version \ |
| 3106 | | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then |
| 3107 | : |
| 3108 | else |
| 3109 | MAKEINFO="$MISSING makeinfo" |
| 3110 | fi |
| 3111 | ;; |
| 3112 | changequote([,]) |
| 3113 | esac |
| 3114 | |
| 3115 | # FIXME: expect and dejagnu may become build tools? |
| 3116 | |
| 3117 | AC_CHECK_PROGS(EXPECT, expect, expect) |
| 3118 | case " $configdirs " in |
| 3119 | *" expect "*) |
| 3120 | test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect' |
| 3121 | ;; |
| 3122 | esac |
| 3123 | |
| 3124 | AC_CHECK_PROGS(RUNTEST, runtest, runtest) |
| 3125 | case " $configdirs " in |
| 3126 | *" dejagnu "*) |
| 3127 | test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest' |
| 3128 | ;; |
| 3129 | esac |
| 3130 | |
| 3131 | |
| 3132 | # Host tools. |
| 3133 | NCN_STRICT_CHECK_TOOLS(AR, ar) |
| 3134 | NCN_STRICT_CHECK_TOOLS(AS, as) |
| 3135 | NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool) |
| 3136 | NCN_STRICT_CHECK_TOOLS(LD, ld) |
| 3137 | NCN_STRICT_CHECK_TOOLS(LIPO, lipo) |
| 3138 | NCN_STRICT_CHECK_TOOLS(NM, nm) |
| 3139 | NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true) |
| 3140 | NCN_STRICT_CHECK_TOOLS(STRIP, strip, true) |
| 3141 | NCN_STRICT_CHECK_TOOLS(WINDRES, windres) |
| 3142 | NCN_STRICT_CHECK_TOOLS(WINDMC, windmc) |
| 3143 | NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy) |
| 3144 | NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump) |
| 3145 | NCN_STRICT_CHECK_TOOLS(READELF, readelf) |
| 3146 | AC_SUBST(CC) |
| 3147 | AC_SUBST(CXX) |
| 3148 | AC_SUBST(CFLAGS) |
| 3149 | AC_SUBST(CXXFLAGS) |
| 3150 | |
| 3151 | # Target tools. |
| 3152 | AC_ARG_WITH([build-time-tools], |
| 3153 | [AS_HELP_STRING([--with-build-time-tools=PATH], |
| 3154 | [use given path to find target tools during the build])], |
| 3155 | [case x"$withval" in |
| 3156 | x/*) ;; |
| 3157 | *) |
| 3158 | with_build_time_tools= |
| 3159 | AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path]) |
| 3160 | ;; |
| 3161 | esac], |
| 3162 | [with_build_time_tools=]) |
| 3163 | |
| 3164 | NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc) |
| 3165 | NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx) |
| 3166 | NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET}) |
| 3167 | NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj) |
| 3168 | NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran) |
| 3169 | NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo) |
| 3170 | |
| 3171 | ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar) |
| 3172 | ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as) |
| 3173 | ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool) |
| 3174 | ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld) |
| 3175 | ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo) |
| 3176 | ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm) |
| 3177 | ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump) |
| 3178 | ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib) |
| 3179 | ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf) |
| 3180 | ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip) |
| 3181 | ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres) |
| 3182 | ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc) |
| 3183 | |
| 3184 | RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET" |
| 3185 | |
| 3186 | GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar]) |
| 3187 | GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new]) |
| 3188 | GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/]) |
| 3189 | dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS |
| 3190 | GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX, |
| 3191 | [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs], |
| 3192 | c++) |
| 3193 | GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX, |
| 3194 | [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs], |
| 3195 | c++) |
| 3196 | GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool]) |
| 3197 | GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/]) |
| 3198 | GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ, |
| 3199 | [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java) |
| 3200 | GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN, |
| 3201 | [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran) |
| 3202 | GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC, |
| 3203 | [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go) |
| 3204 | GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new]) |
| 3205 | GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO) |
| 3206 | GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new]) |
| 3207 | GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump]) |
| 3208 | GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib]) |
| 3209 | GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf]) |
| 3210 | GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new]) |
| 3211 | GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres]) |
| 3212 | GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc]) |
| 3213 | |
| 3214 | AC_SUBST(FLAGS_FOR_TARGET) |
| 3215 | AC_SUBST(RAW_CXX_FOR_TARGET) |
| 3216 | |
| 3217 | # Certain tools may need extra flags. |
| 3218 | AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target} |
| 3219 | RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target} |
| 3220 | NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target} |
| 3221 | |
| 3222 | # When building target libraries, except in a Canadian cross, we use |
| 3223 | # the same toolchain as the compiler we just built. |
| 3224 | COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)' |
| 3225 | COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)' |
| 3226 | COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)' |
| 3227 | if test $host = $build; then |
| 3228 | case " $configdirs " in |
| 3229 | *" gcc "*) |
| 3230 | COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as' |
| 3231 | COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld' |
| 3232 | COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target} |
| 3233 | ;; |
| 3234 | esac |
| 3235 | fi |
| 3236 | |
| 3237 | AC_SUBST(COMPILER_AS_FOR_TARGET) |
| 3238 | AC_SUBST(COMPILER_LD_FOR_TARGET) |
| 3239 | AC_SUBST(COMPILER_NM_FOR_TARGET) |
| 3240 | |
| 3241 | AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles]) |
| 3242 | AC_ARG_ENABLE(maintainer-mode, |
| 3243 | [AS_HELP_STRING([--enable-maintainer-mode], |
| 3244 | [enable make rules and dependencies not useful |
| 3245 | (and sometimes confusing) to the casual installer])], |
| 3246 | USE_MAINTAINER_MODE=$enableval, |
| 3247 | USE_MAINTAINER_MODE=no) |
| 3248 | AC_MSG_RESULT($USE_MAINTAINER_MODE) |
| 3249 | AC_SUBST(MAINTAINER_MODE_TRUE) |
| 3250 | AC_SUBST(MAINTAINER_MODE_FALSE) |
| 3251 | if test "$USE_MAINTAINER_MODE" = yes; then |
| 3252 | MAINTAINER_MODE_TRUE= |
| 3253 | MAINTAINER_MODE_FALSE='#' |
| 3254 | else |
| 3255 | MAINTAINER_MODE_TRUE='#' |
| 3256 | MAINTAINER_MODE_FALSE= |
| 3257 | fi |
| 3258 | MAINT=$MAINTAINER_MODE_TRUE |
| 3259 | AC_SUBST(MAINT)dnl |
| 3260 | |
| 3261 | # --------------------- |
| 3262 | # GCC bootstrap support |
| 3263 | # --------------------- |
| 3264 | |
| 3265 | # Stage specific cflags for build. |
| 3266 | stage1_cflags="-g" |
| 3267 | case $build in |
| 3268 | vax-*-*) |
| 3269 | case ${GCC} in |
| 3270 | yes) stage1_cflags="-g -Wa,-J" ;; |
| 3271 | *) stage1_cflags="-g -J" ;; |
| 3272 | esac ;; |
| 3273 | esac |
| 3274 | |
| 3275 | AC_SUBST(stage1_cflags) |
| 3276 | |
| 3277 | # Enable --enable-checking in stage1 of the compiler. |
| 3278 | AC_ARG_ENABLE(stage1-checking, |
| 3279 | [AS_HELP_STRING([[--enable-stage1-checking[=all]]], |
| 3280 | [choose additional checking for stage1 of the compiler])], |
| 3281 | [stage1_checking=--enable-checking=${enable_stage1_checking}], |
| 3282 | [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then |
| 3283 | stage1_checking=--enable-checking=yes,types |
| 3284 | else |
| 3285 | stage1_checking=--enable-checking=$enable_checking,types |
| 3286 | fi]) |
| 3287 | AC_SUBST(stage1_checking) |
| 3288 | |
| 3289 | # Enable -Werror in bootstrap stage2 and later. |
| 3290 | AC_ARG_ENABLE(werror, |
| 3291 | [AS_HELP_STRING([--enable-werror], |
| 3292 | [enable -Werror in bootstrap stage2 and later])], [], |
| 3293 | [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then |
| 3294 | enable_werror=yes |
| 3295 | else |
| 3296 | enable_werror=no |
| 3297 | fi]) |
| 3298 | case ${enable_werror} in |
| 3299 | yes) stage2_werror_flag="--enable-werror-always" ;; |
| 3300 | *) stage2_werror_flag="" ;; |
| 3301 | esac |
| 3302 | AC_SUBST(stage2_werror_flag) |
| 3303 | |
| 3304 | # Enable --enable-host-shared. |
| 3305 | AC_ARG_ENABLE(host-shared, |
| 3306 | [AS_HELP_STRING([--enable-host-shared], |
| 3307 | [build host code as shared libraries])], |
| 3308 | [host_shared=$enableval], [host_shared=no]) |
| 3309 | AC_SUBST(host_shared) |
| 3310 | |
| 3311 | # Specify what files to not compare during bootstrap. |
| 3312 | |
| 3313 | compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*" |
| 3314 | case "$target" in |
| 3315 | hppa*64*-*-hpux*) ;; |
| 3316 | hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;; |
| 3317 | powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;; |
| 3318 | esac |
| 3319 | AC_SUBST(compare_exclusions) |
| 3320 | |
| 3321 | AC_CONFIG_FILES([Makefile], |
| 3322 | [sed "$extrasub_build" Makefile | |
| 3323 | sed "$extrasub_host" | |
| 3324 | sed "$extrasub_target" > mf$$ |
| 3325 | mv -f mf$$ Makefile], |
| 3326 | [extrasub_build="$extrasub_build" |
| 3327 | extrasub_host="$extrasub_host" |
| 3328 | extrasub_target="$extrasub_target"]) |
| 3329 | AC_OUTPUT |