| 1 | dnl written by Rob Savoye <rob@cygnus.com> for Cygnus Support |
| 2 | dnl major rewriting for Tcl 7.5 by Don Libes <libes@nist.gov> |
| 3 | |
| 4 | dnl gdb/configure.in uses BFD_NEED_DECLARATION, so get its definition. |
| 5 | sinclude(../bfd/bfd.m4) |
| 6 | |
| 7 | dnl This gets the standard macros |
| 8 | sinclude(../config/acinclude.m4) |
| 9 | |
| 10 | dnl This gets autoconf bugfixes |
| 11 | sinclude(../config/override.m4) |
| 12 | |
| 13 | sinclude(../config/gettext-sister.m4) |
| 14 | |
| 15 | dnl For AC_LIB_HAVE_LINKFLAGS. |
| 16 | sinclude(../config/lib-ld.m4) |
| 17 | sinclude(../config/lib-prefix.m4) |
| 18 | sinclude(../config/lib-link.m4) |
| 19 | |
| 20 | dnl For ACX_PKGVERSION and ACX_BUGURL. |
| 21 | sinclude(../config/acx.m4) |
| 22 | |
| 23 | dnl for TCL definitions |
| 24 | sinclude(../config/tcl.m4) |
| 25 | |
| 26 | dnl For dependency tracking macros. |
| 27 | sinclude([../config/depstand.m4]) |
| 28 | |
| 29 | # |
| 30 | # Sometimes the native compiler is a bogus stub for gcc or /usr/ucb/cc. This |
| 31 | # makes configure think it's cross compiling. If --target wasn't used, then |
| 32 | # we can't configure, so something is wrong. We don't use the cache |
| 33 | # here cause if somebody fixes their compiler install, we want this to work. |
| 34 | AC_DEFUN([CY_AC_C_WORKS], |
| 35 | [# If we cannot compile and link a trivial program, we can't expect anything to work |
| 36 | AC_MSG_CHECKING(whether the compiler ($CC) actually works) |
| 37 | AC_TRY_COMPILE(, [/* don't need anything here */], |
| 38 | c_compiles=yes, c_compiles=no) |
| 39 | |
| 40 | AC_TRY_LINK(, [/* don't need anything here */], |
| 41 | c_links=yes, c_links=no) |
| 42 | |
| 43 | if test x"${c_compiles}" = x"no" ; then |
| 44 | AC_MSG_ERROR(the native compiler is broken and won't compile.) |
| 45 | fi |
| 46 | |
| 47 | if test x"${c_links}" = x"no" ; then |
| 48 | AC_MSG_ERROR(the native compiler is broken and won't link.) |
| 49 | fi |
| 50 | AC_MSG_RESULT(yes) |
| 51 | ]) |
| 52 | |
| 53 | ## ----------------------------------------- ## |
| 54 | ## ANSIfy the C compiler whenever possible. ## |
| 55 | ## From Franc,ois Pinard ## |
| 56 | ## ----------------------------------------- ## |
| 57 | |
| 58 | # Copyright (C) 1996, 1997, 1999, 2000, 2001, 2008 Free Software Foundation, Inc. |
| 59 | |
| 60 | # This program is free software; you can redistribute it and/or modify |
| 61 | # it under the terms of the GNU General Public License as published by |
| 62 | # the Free Software Foundation; either version 2, or (at your option) |
| 63 | # any later version. |
| 64 | |
| 65 | # This program is distributed in the hope that it will be useful, |
| 66 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 67 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 68 | # GNU General Public License for more details. |
| 69 | |
| 70 | # You should have received a copy of the GNU General Public License |
| 71 | # along with this program; if not, write to the Free Software |
| 72 | # Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 73 | # Boston, MA 02110-1301, USA. |
| 74 | |
| 75 | # serial 1 |
| 76 | |
| 77 | # @defmac AC_PROG_CC_STDC |
| 78 | # @maindex PROG_CC_STDC |
| 79 | # @ovindex CC |
| 80 | # If the C compiler in not in ANSI C mode by default, try to add an option |
| 81 | # to output variable @code{CC} to make it so. This macro tries various |
| 82 | # options that select ANSI C on some system or another. It considers the |
| 83 | # compiler to be in ANSI C mode if it handles function prototypes correctly. |
| 84 | # |
| 85 | # If you use this macro, you should check after calling it whether the C |
| 86 | # compiler has been set to accept ANSI C; if not, the shell variable |
| 87 | # @code{am_cv_prog_cc_stdc} is set to @samp{no}. If you wrote your source |
| 88 | # code in ANSI C, you can make an un-ANSIfied copy of it by using the |
| 89 | # program @code{ansi2knr}, which comes with Ghostscript. |
| 90 | # @end defmac |
| 91 | |
| 92 | AC_DEFUN([AM_PROG_CC_STDC], |
| 93 | [AC_REQUIRE([AC_PROG_CC]) |
| 94 | AC_BEFORE([$0], [AC_C_INLINE]) |
| 95 | AC_BEFORE([$0], [AC_C_CONST]) |
| 96 | dnl Force this before AC_PROG_CPP. Some cpp's, eg on HPUX, require |
| 97 | dnl a magic option to avoid problems with ANSI preprocessor commands |
| 98 | dnl like #elif. |
| 99 | dnl FIXME: can't do this because then AC_AIX won't work due to a |
| 100 | dnl circular dependency. |
| 101 | dnl AC_BEFORE([$0], [AC_PROG_CPP]) |
| 102 | AC_MSG_CHECKING([for ${CC-cc} option to accept ANSI C]) |
| 103 | AC_CACHE_VAL(am_cv_prog_cc_stdc, |
| 104 | [am_cv_prog_cc_stdc=no |
| 105 | ac_save_CC="$CC" |
| 106 | # Don't try gcc -ansi; that turns off useful extensions and |
| 107 | # breaks some systems' header files. |
| 108 | # AIX -qlanglvl=ansi |
| 109 | # Ultrix and OSF/1 -std1 |
| 110 | # HP-UX 10.20 and later -Ae |
| 111 | # HP-UX older versions -Aa -D_HPUX_SOURCE |
| 112 | # SVR4 -Xc -D__EXTENSIONS__ |
| 113 | for ac_arg in "" -qlanglvl=ansi -std1 -Ae "-Aa -D_HPUX_SOURCE" "-Xc -D__EXTENSIONS__" |
| 114 | do |
| 115 | CC="$ac_save_CC $ac_arg" |
| 116 | AC_TRY_COMPILE( |
| 117 | [#include <stdarg.h> |
| 118 | #include <stdio.h> |
| 119 | #include <sys/types.h> |
| 120 | #include <sys/stat.h> |
| 121 | /* Most of the following tests are stolen from RCS 5.7's src/conf.sh. */ |
| 122 | struct buf { int x; }; |
| 123 | FILE * (*rcsopen) (struct buf *, struct stat *, int); |
| 124 | static char *e (p, i) |
| 125 | char **p; |
| 126 | int i; |
| 127 | { |
| 128 | return p[i]; |
| 129 | } |
| 130 | static char *f (char * (*g) (char **, int), char **p, ...) |
| 131 | { |
| 132 | char *s; |
| 133 | va_list v; |
| 134 | va_start (v,p); |
| 135 | s = g (p, va_arg (v,int)); |
| 136 | va_end (v); |
| 137 | return s; |
| 138 | } |
| 139 | int test (int i, double x); |
| 140 | struct s1 {int (*f) (int a);}; |
| 141 | struct s2 {int (*f) (double a);}; |
| 142 | int pairnames (int, char **, FILE *(*)(struct buf *, struct stat *, int), int, int); |
| 143 | int argc; |
| 144 | char **argv; |
| 145 | ], [ |
| 146 | return f (e, argv, 0) != argv[0] || f (e, argv, 1) != argv[1]; |
| 147 | ], |
| 148 | [am_cv_prog_cc_stdc="$ac_arg"; break]) |
| 149 | done |
| 150 | CC="$ac_save_CC" |
| 151 | ]) |
| 152 | if test -z "$am_cv_prog_cc_stdc"; then |
| 153 | AC_MSG_RESULT([none needed]) |
| 154 | else |
| 155 | AC_MSG_RESULT([$am_cv_prog_cc_stdc]) |
| 156 | fi |
| 157 | case "x$am_cv_prog_cc_stdc" in |
| 158 | x|xno) ;; |
| 159 | *) CC="$CC $am_cv_prog_cc_stdc" ;; |
| 160 | esac |
| 161 | ]) |
| 162 | |
| 163 | dnl From Bruno Haible. |
| 164 | |
| 165 | AC_DEFUN([AM_ICONV], |
| 166 | [ |
| 167 | dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and |
| 168 | dnl those with the standalone portable GNU libiconv installed). |
| 169 | |
| 170 | AC_ARG_WITH([libiconv-prefix], |
| 171 | [ --with-libiconv-prefix=DIR search for libiconv in DIR/include and DIR/lib], [ |
| 172 | for dir in `echo "$withval" | tr : ' '`; do |
| 173 | if test -d $dir/include; then CPPFLAGS="$CPPFLAGS -I$dir/include"; fi |
| 174 | if test -d $dir/lib; then LDFLAGS="$LDFLAGS -L$dir/lib"; fi |
| 175 | done |
| 176 | ]) |
| 177 | |
| 178 | AC_CACHE_CHECK(for iconv, am_cv_func_iconv, [ |
| 179 | am_cv_func_iconv="no, consider installing GNU libiconv" |
| 180 | am_cv_lib_iconv=no |
| 181 | AC_TRY_LINK([#include <stdlib.h> |
| 182 | #include <iconv.h>], |
| 183 | [iconv_t cd = iconv_open("",""); |
| 184 | iconv(cd,NULL,NULL,NULL,NULL); |
| 185 | iconv_close(cd);], |
| 186 | am_cv_func_iconv=yes) |
| 187 | if test "$am_cv_func_iconv" != yes; then |
| 188 | am_save_LIBS="$LIBS" |
| 189 | LIBS="$LIBS -liconv" |
| 190 | AC_TRY_LINK([#include <stdlib.h> |
| 191 | #include <iconv.h>], |
| 192 | [iconv_t cd = iconv_open("",""); |
| 193 | iconv(cd,NULL,NULL,NULL,NULL); |
| 194 | iconv_close(cd);], |
| 195 | am_cv_lib_iconv=yes |
| 196 | am_cv_func_iconv=yes) |
| 197 | LIBS="$am_save_LIBS" |
| 198 | fi |
| 199 | ]) |
| 200 | if test "$am_cv_func_iconv" = yes; then |
| 201 | AC_DEFINE(HAVE_ICONV, 1, [Define if you have the iconv() function.]) |
| 202 | AC_MSG_CHECKING([for iconv declaration]) |
| 203 | AC_CACHE_VAL(am_cv_proto_iconv, [ |
| 204 | AC_TRY_COMPILE([ |
| 205 | #include <stdlib.h> |
| 206 | #include <iconv.h> |
| 207 | extern |
| 208 | #ifdef __cplusplus |
| 209 | "C" |
| 210 | #endif |
| 211 | #if defined(__STDC__) || defined(__cplusplus) |
| 212 | size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft); |
| 213 | #else |
| 214 | size_t iconv(); |
| 215 | #endif |
| 216 | ], [], am_cv_proto_iconv_arg1="", am_cv_proto_iconv_arg1="const") |
| 217 | am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"]) |
| 218 | am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'` |
| 219 | AC_MSG_RESULT([$]{ac_t:- |
| 220 | }[$]am_cv_proto_iconv) |
| 221 | AC_DEFINE_UNQUOTED(ICONV_CONST, $am_cv_proto_iconv_arg1, |
| 222 | [Define as const if the declaration of iconv() needs const.]) |
| 223 | fi |
| 224 | LIBICONV= |
| 225 | if test "$am_cv_lib_iconv" = yes; then |
| 226 | LIBICONV="-liconv" |
| 227 | fi |
| 228 | AC_SUBST(LIBICONV) |
| 229 | ]) |
| 230 | |
| 231 | dnl written by Guido Draheim <guidod@gmx.de>, original by Alexandre Oliva |
| 232 | dnl Version 1.3 (2001/03/02) |
| 233 | dnl source http://www.gnu.org/software/ac-archive/Miscellaneous/ac_define_dir.html |
| 234 | |
| 235 | AC_DEFUN([AC_DEFINE_DIR], [ |
| 236 | test "x$prefix" = xNONE && prefix="$ac_default_prefix" |
| 237 | test "x$exec_prefix" = xNONE && exec_prefix='${prefix}' |
| 238 | ac_define_dir=`eval echo [$]$2` |
| 239 | ac_define_dir=`eval echo [$]ac_define_dir` |
| 240 | ifelse($3, , |
| 241 | AC_DEFINE_UNQUOTED($1, "$ac_define_dir"), |
| 242 | AC_DEFINE_UNQUOTED($1, "$ac_define_dir", $3)) |
| 243 | ]) |
| 244 | |
| 245 | dnl See whether we need a declaration for a function. |
| 246 | dnl The result is highly dependent on the INCLUDES passed in, so make sure |
| 247 | dnl to use a different cache variable name in this macro if it is invoked |
| 248 | dnl in a different context somewhere else. |
| 249 | dnl gcc_AC_CHECK_DECL(SYMBOL, |
| 250 | dnl [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND [, INCLUDES]]]) |
| 251 | AC_DEFUN([gcc_AC_CHECK_DECL], |
| 252 | [AC_MSG_CHECKING([whether $1 is declared]) |
| 253 | AC_CACHE_VAL(gcc_cv_have_decl_$1, |
| 254 | [AC_TRY_COMPILE([$4], |
| 255 | [#ifndef $1 |
| 256 | char *(*pfn) = (char *(*)) $1 ; |
| 257 | #endif], eval "gcc_cv_have_decl_$1=yes", eval "gcc_cv_have_decl_$1=no")]) |
| 258 | if eval "test \"`echo '$gcc_cv_have_decl_'$1`\" = yes"; then |
| 259 | AC_MSG_RESULT(yes) ; ifelse([$2], , :, [$2]) |
| 260 | else |
| 261 | AC_MSG_RESULT(no) ; ifelse([$3], , :, [$3]) |
| 262 | fi |
| 263 | ])dnl |
| 264 | |
| 265 | dnl Check multiple functions to see whether each needs a declaration. |
| 266 | dnl Arrange to define HAVE_DECL_<FUNCTION> to 0 or 1 as appropriate. |
| 267 | dnl gcc_AC_CHECK_DECLS(SYMBOLS, |
| 268 | dnl [ACTION-IF-NEEDED [, ACTION-IF-NOT-NEEDED [, INCLUDES]]]) |
| 269 | AC_DEFUN([gcc_AC_CHECK_DECLS], |
| 270 | [for ac_func in $1 |
| 271 | do |
| 272 | changequote(, )dnl |
| 273 | ac_tr_decl=HAVE_DECL_`echo $ac_func | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'` |
| 274 | changequote([, ])dnl |
| 275 | gcc_AC_CHECK_DECL($ac_func, |
| 276 | [AC_DEFINE_UNQUOTED($ac_tr_decl, 1) $2], |
| 277 | [AC_DEFINE_UNQUOTED($ac_tr_decl, 0) $3], |
| 278 | dnl It is possible that the include files passed in here are local headers |
| 279 | dnl which supply a backup declaration for the relevant prototype based on |
| 280 | dnl the definition of (or lack of) the HAVE_DECL_ macro. If so, this test |
| 281 | dnl will always return success. E.g. see libiberty.h's handling of |
| 282 | dnl `basename'. To avoid this, we define the relevant HAVE_DECL_ macro to |
| 283 | dnl 1 so that any local headers used do not provide their own prototype |
| 284 | dnl during this test. |
| 285 | #undef $ac_tr_decl |
| 286 | #define $ac_tr_decl 1 |
| 287 | $4 |
| 288 | ) |
| 289 | done |
| 290 | dnl Automatically generate config.h entries via autoheader. |
| 291 | if test x = y ; then |
| 292 | patsubst(translit([$1], [a-z], [A-Z]), [\w+], |
| 293 | [AC_DEFINE([HAVE_DECL_\&], 1, |
| 294 | [Define to 1 if we found this declaration otherwise define to 0.])])dnl |
| 295 | fi |
| 296 | ]) |
| 297 | |
| 298 | dnl Find the location of the private Tcl headers |
| 299 | dnl When Tcl is installed, this is TCL_INCLUDE_SPEC/tcl-private/generic |
| 300 | dnl When Tcl is in the build tree, this is not needed. |
| 301 | dnl |
| 302 | dnl Note: you must use first use SC_LOAD_TCLCONFIG! |
| 303 | AC_DEFUN([CY_AC_TCL_PRIVATE_HEADERS], [ |
| 304 | AC_MSG_CHECKING([for Tcl private headers]) |
| 305 | private_dir="" |
| 306 | dir=`echo ${TCL_INCLUDE_SPEC}/tcl-private/generic | sed -e s/-I//` |
| 307 | if test -f ${dir}/tclInt.h ; then |
| 308 | private_dir=${dir} |
| 309 | fi |
| 310 | |
| 311 | if test x"${private_dir}" = x; then |
| 312 | AC_ERROR(could not find private Tcl headers) |
| 313 | else |
| 314 | TCL_PRIVATE_INCLUDE="-I${private_dir}" |
| 315 | AC_MSG_RESULT(${private_dir}) |
| 316 | fi |
| 317 | ]) |
| 318 | |
| 319 | dnl Find the location of the private Tk headers |
| 320 | dnl When Tk is installed, this is TK_INCLUDE_SPEC/tk-private/generic |
| 321 | dnl When Tk is in the build tree, this not needed. |
| 322 | dnl |
| 323 | dnl Note: you must first use SC_LOAD_TKCONFIG |
| 324 | AC_DEFUN([CY_AC_TK_PRIVATE_HEADERS], [ |
| 325 | AC_MSG_CHECKING([for Tk private headers]) |
| 326 | private_dir="" |
| 327 | dir=`echo ${TK_INCLUDE_SPEC}/tk-private/generic | sed -e s/-I//` |
| 328 | if test -f ${dir}/tkInt.h; then |
| 329 | private_dir=${dir} |
| 330 | fi |
| 331 | |
| 332 | if test x"${private_dir}" = x; then |
| 333 | AC_ERROR(could not find Tk private headers) |
| 334 | else |
| 335 | TK_PRIVATE_INCLUDE="-I${private_dir}" |
| 336 | AC_MSG_RESULT(${private_dir}) |
| 337 | fi |
| 338 | ]) |