| 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| 2 | dnl Copyright (C) 1995-2014 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_PREREQ(2.59)dnl |
| 22 | AC_INIT(main.c) |
| 23 | AC_CONFIG_HEADER(config.h:config.in) |
| 24 | AM_MAINTAINER_MODE |
| 25 | |
| 26 | # Set the 'development' global. |
| 27 | . $srcdir/development.sh |
| 28 | |
| 29 | AC_PROG_CC |
| 30 | AC_USE_SYSTEM_EXTENSIONS |
| 31 | ACX_LARGEFILE |
| 32 | AM_PROG_CC_STDC |
| 33 | |
| 34 | AC_CONFIG_AUX_DIR(..) |
| 35 | AC_CANONICAL_SYSTEM |
| 36 | AC_ARG_PROGRAM |
| 37 | |
| 38 | # Dependency checking. |
| 39 | ZW_CREATE_DEPDIR |
| 40 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 41 | |
| 42 | # Check for the 'make' the user wants to use. |
| 43 | AC_CHECK_PROGS(MAKE, make) |
| 44 | MAKE_IS_GNU= |
| 45 | case "`$MAKE --version 2>&1 | sed 1q`" in |
| 46 | *GNU*) |
| 47 | MAKE_IS_GNU=yes |
| 48 | ;; |
| 49 | esac |
| 50 | AM_CONDITIONAL(GMAKE, test "$MAKE_IS_GNU" = yes) |
| 51 | AC_PROG_MAKE_SET |
| 52 | |
| 53 | # Configure gnulib. We need to build gnulib under some other |
| 54 | # directory not "gnulib", to avoid the problem of both GDB and |
| 55 | # GDBserver wanting to build it in the same directory, when building |
| 56 | # in the source dir. |
| 57 | ACX_CONFIGURE_DIR(["gnulib"], ["build-gnulib"]) |
| 58 | |
| 59 | dnl List of object files and targets accumulated by configure. |
| 60 | |
| 61 | CONFIG_OBS= |
| 62 | CONFIG_DEPS= |
| 63 | CONFIG_SRCS= |
| 64 | ENABLE_CFLAGS= |
| 65 | |
| 66 | CONFIG_ALL= |
| 67 | CONFIG_CLEAN= |
| 68 | CONFIG_INSTALL= |
| 69 | CONFIG_UNINSTALL= |
| 70 | |
| 71 | dnl Set up for gettext. |
| 72 | ZW_GNU_GETTEXT_SISTER_DIR |
| 73 | |
| 74 | localedir='${datadir}/locale' |
| 75 | AC_SUBST(localedir) |
| 76 | |
| 77 | if test x"$USE_NLS" = xyes; then |
| 78 | CONFIG_ALL="$CONFIG_ALL all-po" |
| 79 | CONFIG_CLEAN="$CONFIG_CLEAN clean-po" |
| 80 | CONFIG_INSTALL="$CONFIG_INSTALL install-po" |
| 81 | CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po" |
| 82 | fi |
| 83 | |
| 84 | GNULIB=build-gnulib/import |
| 85 | |
| 86 | # For Makefile dependencies. |
| 87 | GNULIB_STDINT_H= |
| 88 | if test x"$STDINT_H" != x; then |
| 89 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 90 | fi |
| 91 | AC_SUBST(GNULIB_STDINT_H) |
| 92 | |
| 93 | PACKAGE=gdb |
| 94 | AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ]) |
| 95 | AC_SUBST(PACKAGE) |
| 96 | |
| 97 | # We never need to detect it in this sub-configure. |
| 98 | # But preserve it for config.status --recheck. |
| 99 | AC_ARG_VAR(MAKEINFO, |
| 100 | [Parent configure detects if it is of sufficient version.]) |
| 101 | AC_ARG_VAR(MAKEINFOFLAGS, |
| 102 | [Parameters for MAKEINFO.]) |
| 103 | |
| 104 | MAKEINFO_EXTRA_FLAGS="" |
| 105 | AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click, |
| 106 | [echo '@clicksequence{a @click{} b}' >conftest.texinfo |
| 107 | if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then |
| 108 | gdb_cv_have_makeinfo_click=yes |
| 109 | else |
| 110 | gdb_cv_have_makeinfo_click=no |
| 111 | fi]) |
| 112 | if test x"$gdb_cv_have_makeinfo_click" = xyes; then |
| 113 | MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK" |
| 114 | fi |
| 115 | AC_SUBST(MAKEINFO_EXTRA_FLAGS) |
| 116 | |
| 117 | GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir, |
| 118 | [look for global separate debug info in this path @<:@LIBDIR/debug@:>@], |
| 119 | [${libdir}/debug]) |
| 120 | |
| 121 | # We can't pass paths as command line arguments. |
| 122 | # Mingw32 tries to be clever and will convert the paths for us. |
| 123 | # For example -DBINDIR="/usr/local/bin" passed on the command line may get |
| 124 | # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin". |
| 125 | # This breaks GDB's relocatable path conversions since paths passed in |
| 126 | # config.h would not get so translated, the path prefixes no longer match. |
| 127 | AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.]) |
| 128 | |
| 129 | # GDB's datadir relocation |
| 130 | |
| 131 | GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir, |
| 132 | [look for global separate data files in this path @<:@DATADIR/gdb@:>@], |
| 133 | [${datadir}/gdb]) |
| 134 | |
| 135 | AC_ARG_WITH(relocated-sources, |
| 136 | AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]), |
| 137 | [reloc_srcdir="${withval}" |
| 138 | AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir, |
| 139 | [Relocated directory for source files. ]) |
| 140 | ]) |
| 141 | |
| 142 | AC_MSG_CHECKING([for default auto-load directory]) |
| 143 | AC_ARG_WITH(auto-load-dir, |
| 144 | AS_HELP_STRING([--with-auto-load-dir=PATH], |
| 145 | [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),, |
| 146 | [with_auto_load_dir='$debugdir:$datadir/auto-load']) |
| 147 | escape_dir=`echo $with_auto_load_dir | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'` |
| 148 | AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir, |
| 149 | [Directories from which to load auto-loaded scripts.]) |
| 150 | AC_MSG_RESULT([$with_auto_load_dir]) |
| 151 | |
| 152 | AC_MSG_CHECKING([for default auto-load safe-path]) |
| 153 | AC_ARG_WITH(auto-load-safe-path, |
| 154 | AS_HELP_STRING([--with-auto-load-safe-path=PATH], |
| 155 | [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@]) |
| 156 | AS_HELP_STRING([--without-auto-load-safe-path], |
| 157 | [do not restrict auto-loaded files locations]), |
| 158 | [if test "$with_auto_load_safe_path" = "no"; then |
| 159 | with_auto_load_safe_path="/" |
| 160 | fi], |
| 161 | [with_auto_load_safe_path="$with_auto_load_dir"]) |
| 162 | escape_dir=`echo $with_auto_load_safe_path | sed 's/[[$]]\(datadir\|debugdir\)\>/\\\\\\\\\\\\&/g'` |
| 163 | AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir, |
| 164 | [Directories safe to hold auto-loaded files.]) |
| 165 | AC_MSG_RESULT([$with_auto_load_safe_path]) |
| 166 | |
| 167 | AC_CONFIG_SUBDIRS(testsuite) |
| 168 | |
| 169 | # Check whether to support alternative target configurations |
| 170 | AC_ARG_ENABLE(targets, |
| 171 | AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]), |
| 172 | [case "${enableval}" in |
| 173 | yes | "") AC_ERROR(enable-targets option must specify target names or 'all') |
| 174 | ;; |
| 175 | no) enable_targets= ;; |
| 176 | *) enable_targets=$enableval ;; |
| 177 | esac]) |
| 178 | |
| 179 | # Check whether to enable 64-bit support on 32-bit hosts |
| 180 | AC_ARG_ENABLE(64-bit-bfd, |
| 181 | AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]), |
| 182 | [case "${enableval}" in |
| 183 | yes) want64=true ;; |
| 184 | no) want64=false ;; |
| 185 | *) AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;; |
| 186 | esac],[want64=false])dnl |
| 187 | |
| 188 | # Provide defaults for some variables set by the per-host and per-target |
| 189 | # configuration. |
| 190 | gdb_host_obs=posix-hdep.o |
| 191 | |
| 192 | if test "${target}" = "${host}"; then |
| 193 | gdb_native=yes |
| 194 | else |
| 195 | gdb_native=no |
| 196 | fi |
| 197 | |
| 198 | . $srcdir/configure.host |
| 199 | |
| 200 | # Accumulate some settings from configure.tgt over all enabled targets |
| 201 | |
| 202 | TARGET_OBS= |
| 203 | all_targets= |
| 204 | HAVE_NATIVE_GCORE_TARGET= |
| 205 | |
| 206 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` |
| 207 | do |
| 208 | if test "$targ_alias" = "all"; then |
| 209 | all_targets=true |
| 210 | else |
| 211 | # Canonicalize the secondary target names. |
| 212 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
| 213 | if test -n "$result"; then |
| 214 | targ=$result |
| 215 | else |
| 216 | targ=$targ_alias |
| 217 | fi |
| 218 | |
| 219 | . ${srcdir}/configure.tgt |
| 220 | |
| 221 | AS_IF([test -z "${gdb_target_obs}"], |
| 222 | [AC_MSG_ERROR([configuration ${targ} is unsupported.])]) |
| 223 | |
| 224 | # Target-specific object files |
| 225 | for i in ${gdb_target_obs}; do |
| 226 | case " $TARGET_OBS " in |
| 227 | *" ${i} "*) ;; |
| 228 | *) |
| 229 | TARGET_OBS="$TARGET_OBS ${i}" |
| 230 | ;; |
| 231 | esac |
| 232 | done |
| 233 | |
| 234 | # Check whether this target needs 64-bit CORE_ADDR |
| 235 | if test x${want64} = xfalse; then |
| 236 | . ${srcdir}/../bfd/config.bfd |
| 237 | fi |
| 238 | |
| 239 | # Check whether this target is native and supports gcore. |
| 240 | if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \ |
| 241 | && $gdb_have_gcore; then |
| 242 | HAVE_NATIVE_GCORE_TARGET=1 |
| 243 | fi |
| 244 | fi |
| 245 | done |
| 246 | |
| 247 | if test x${all_targets} = xtrue; then |
| 248 | |
| 249 | # We want all 64-bit targets if we either: |
| 250 | # - run on a 64-bit host or |
| 251 | # - already require 64-bit support for some other target or |
| 252 | # - the --enable-64-bit-bfd option was supplied |
| 253 | # Otherwise we only support all 32-bit targets. |
| 254 | # |
| 255 | # NOTE: This test must be in sync with the corresponding |
| 256 | # tests in BFD! |
| 257 | |
| 258 | if test x${want64} = xfalse; then |
| 259 | AC_CHECK_SIZEOF(long) |
| 260 | if test "x${ac_cv_sizeof_long}" = "x8"; then |
| 261 | want64=true |
| 262 | fi |
| 263 | fi |
| 264 | if test x${want64} = xtrue; then |
| 265 | TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)' |
| 266 | else |
| 267 | TARGET_OBS='$(ALL_TARGET_OBS)' |
| 268 | fi |
| 269 | fi |
| 270 | |
| 271 | AC_SUBST(TARGET_OBS) |
| 272 | AC_SUBST(HAVE_NATIVE_GCORE_TARGET) |
| 273 | |
| 274 | # For other settings, only the main target counts. |
| 275 | gdb_sim= |
| 276 | gdb_osabi= |
| 277 | build_gdbserver= |
| 278 | targ=$target; . ${srcdir}/configure.tgt |
| 279 | |
| 280 | # Fetch the default architecture and default target vector from BFD. |
| 281 | targ=$target; . $srcdir/../bfd/config.bfd |
| 282 | |
| 283 | # We only want the first architecture, so strip off the others if |
| 284 | # there is more than one. |
| 285 | targ_archs=`echo $targ_archs | sed 's/ .*//'` |
| 286 | |
| 287 | if test "x$targ_archs" != x; then |
| 288 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs, |
| 289 | [Define to BFD's default architecture. ]) |
| 290 | fi |
| 291 | if test "x$targ_defvec" != x; then |
| 292 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec, |
| 293 | [Define to BFD's default target vector. ]) |
| 294 | fi |
| 295 | |
| 296 | # The CLI cannot be disabled yet, but may be in the future. |
| 297 | |
| 298 | # Enable CLI. |
| 299 | AC_ARG_ENABLE(gdbcli, |
| 300 | AS_HELP_STRING([--disable-gdbcli], [disable command-line interface (CLI)]), |
| 301 | [case $enableval in |
| 302 | yes) |
| 303 | ;; |
| 304 | no) |
| 305 | AC_MSG_ERROR([the command-line interface cannot be disabled yet]) ;; |
| 306 | *) |
| 307 | AC_MSG_ERROR([bad value $enableval for --enable-gdbcli]) ;; |
| 308 | esac], |
| 309 | [enable_gdbcli=yes]) |
| 310 | if test x"$enable_gdbcli" = xyes; then |
| 311 | if test -d $srcdir/cli; then |
| 312 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_CLI_OBS)" |
| 313 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_CLI_DEPS)" |
| 314 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_CLI_SRCS)" |
| 315 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_CLI_CFLAGS)" |
| 316 | fi |
| 317 | fi |
| 318 | |
| 319 | # Enable MI. |
| 320 | AC_ARG_ENABLE(gdbmi, |
| 321 | AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]), |
| 322 | [case $enableval in |
| 323 | yes | no) |
| 324 | ;; |
| 325 | *) |
| 326 | AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;; |
| 327 | esac], |
| 328 | [enable_gdbmi=yes]) |
| 329 | if test x"$enable_gdbmi" = xyes; then |
| 330 | if test -d $srcdir/mi; then |
| 331 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)" |
| 332 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)" |
| 333 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)" |
| 334 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)" |
| 335 | fi |
| 336 | fi |
| 337 | |
| 338 | # Enable TUI. |
| 339 | AC_ARG_ENABLE(tui, |
| 340 | AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]), |
| 341 | [case $enableval in |
| 342 | yes | no | auto) |
| 343 | ;; |
| 344 | *) |
| 345 | AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;; |
| 346 | esac],enable_tui=auto) |
| 347 | |
| 348 | # Enable gdbtk. |
| 349 | AC_ARG_ENABLE(gdbtk, |
| 350 | AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]), |
| 351 | [case $enableval in |
| 352 | yes | no) |
| 353 | ;; |
| 354 | *) |
| 355 | AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;; |
| 356 | esac], |
| 357 | [if test -d $srcdir/gdbtk; then |
| 358 | enable_gdbtk=yes |
| 359 | else |
| 360 | enable_gdbtk=no |
| 361 | fi]) |
| 362 | # We unconditionally disable gdbtk tests on selected platforms. |
| 363 | case $host_os in |
| 364 | go32* | windows*) |
| 365 | AC_MSG_WARN([gdbtk isn't supported on $host; disabling]) |
| 366 | enable_gdbtk=no ;; |
| 367 | esac |
| 368 | |
| 369 | # Libunwind support for ia64. |
| 370 | |
| 371 | AC_ARG_WITH(libunwind-ia64, |
| 372 | AS_HELP_STRING([--with-libunwind-ia64], |
| 373 | [use libunwind frame unwinding for ia64 targets]),, |
| 374 | [with_libunwind_ia64=auto]) |
| 375 | |
| 376 | # Backward compatibility option. |
| 377 | if test "${with_libunwind+set}" = set; then |
| 378 | if test x"$with_libunwind_ia64" != xauto; then |
| 379 | AC_MSG_ERROR( |
| 380 | [option --with-libunwind is deprecated, use --with-libunwind-ia64]) |
| 381 | fi |
| 382 | AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64]) |
| 383 | with_libunwind_ia64="$with_libunwind" |
| 384 | fi |
| 385 | |
| 386 | case "$with_libunwind_ia64" in |
| 387 | yes | no) |
| 388 | ;; |
| 389 | auto) |
| 390 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 391 | with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h |
| 392 | ;; |
| 393 | *) |
| 394 | AC_MSG_ERROR( |
| 395 | [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option]) |
| 396 | ;; |
| 397 | esac |
| 398 | |
| 399 | if test x"$with_libunwind_ia64" = xyes; then |
| 400 | AC_CHECK_HEADERS(libunwind-ia64.h) |
| 401 | if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then |
| 402 | AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h]) |
| 403 | fi |
| 404 | CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o" |
| 405 | CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o" |
| 406 | CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c" |
| 407 | fi |
| 408 | |
| 409 | opt_curses=no |
| 410 | AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval) |
| 411 | |
| 412 | prefer_curses=no |
| 413 | if test "$opt_curses" = "yes"; then |
| 414 | prefer_curses=yes |
| 415 | fi |
| 416 | |
| 417 | # Profiling support. |
| 418 | AC_ARG_ENABLE(profiling, |
| 419 | AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]), |
| 420 | [case $enableval in |
| 421 | yes | no) |
| 422 | ;; |
| 423 | *) |
| 424 | AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;; |
| 425 | esac], |
| 426 | [enable_profiling=no]) |
| 427 | |
| 428 | AC_CHECK_FUNCS(monstartup _mcleanup) |
| 429 | AC_CACHE_CHECK([for _etext], ac_cv_var__etext, |
| 430 | [AC_TRY_LINK( |
| 431 | [#include <stdlib.h> |
| 432 | extern char _etext; |
| 433 | ], |
| 434 | [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)]) |
| 435 | if test $ac_cv_var__etext = yes; then |
| 436 | AC_DEFINE(HAVE__ETEXT, 1, |
| 437 | [Define to 1 if your system has the _etext variable. ]) |
| 438 | fi |
| 439 | AC_CACHE_CHECK([for etext], ac_cv_var_etext, |
| 440 | [AC_TRY_LINK( |
| 441 | [#include <stdlib.h> |
| 442 | extern char etext; |
| 443 | ], |
| 444 | [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)]) |
| 445 | if test $ac_cv_var_etext = yes; then |
| 446 | AC_DEFINE(HAVE_ETEXT, 1, |
| 447 | [Define to 1 if your system has the etext variable. ]) |
| 448 | fi |
| 449 | if test "$enable_profiling" = yes ; then |
| 450 | if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then |
| 451 | AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup) |
| 452 | fi |
| 453 | PROFILE_CFLAGS=-pg |
| 454 | OLD_CFLAGS="$CFLAGS" |
| 455 | CFLAGS="$CFLAGS $PROFILE_CFLAGS" |
| 456 | |
| 457 | AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg, |
| 458 | [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes, |
| 459 | ac_cv_cc_supports_pg=no)]) |
| 460 | |
| 461 | if test $ac_cv_cc_supports_pg = no; then |
| 462 | AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg) |
| 463 | fi |
| 464 | |
| 465 | CFLAGS="$OLD_CFLAGS" |
| 466 | fi |
| 467 | |
| 468 | ACX_PKGVERSION([GDB]) |
| 469 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 470 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 471 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 472 | |
| 473 | # --------------------- # |
| 474 | # Checks for programs. # |
| 475 | # --------------------- # |
| 476 | |
| 477 | AC_PROG_AWK |
| 478 | AC_PROG_INSTALL |
| 479 | AC_PROG_LN_S |
| 480 | AC_PROG_RANLIB |
| 481 | AC_PROG_YACC |
| 482 | |
| 483 | AC_CHECK_TOOL(AR, ar) |
| 484 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| 485 | AC_CHECK_TOOL(WINDRES, windres) |
| 486 | |
| 487 | case $host_os in |
| 488 | gnu*) |
| 489 | # Needed for GNU Hurd hosts. |
| 490 | AC_CHECK_TOOL(MIG, mig) |
| 491 | if test x"$MIG" = x; then |
| 492 | AC_MSG_ERROR([MIG not found but required for $host hosts]) |
| 493 | fi |
| 494 | ;; |
| 495 | esac |
| 496 | |
| 497 | # ---------------------- # |
| 498 | # Checks for libraries. # |
| 499 | # ---------------------- # |
| 500 | |
| 501 | # We might need to link with -lm; most simulators need it. |
| 502 | AC_CHECK_LIB(m, main) |
| 503 | |
| 504 | # We need to link with -lw to get `wctype' on Solaris before Solaris |
| 505 | # 2.6. Solaris 2.6 and beyond have this function in libc, and have a |
| 506 | # libw that some versions of the GNU linker cannot hanle (GNU ld 2.9.1 |
| 507 | # is known to have this problem). Therefore we avoid libw if we can. |
| 508 | AC_CHECK_FUNC(wctype, [], |
| 509 | [AC_CHECK_LIB(w, wctype)]) |
| 510 | |
| 511 | # Some systems (e.g. Solaris) have `gethostbyname' in libnsl. |
| 512 | AC_SEARCH_LIBS(gethostbyname, nsl) |
| 513 | |
| 514 | # Some systems (e.g. Solaris) have `socketpair' in libsocket. |
| 515 | AC_SEARCH_LIBS(socketpair, socket) |
| 516 | |
| 517 | # Link in zlib if we can. This allows us to read compressed debug sections. |
| 518 | AM_ZLIB |
| 519 | |
| 520 | # On HP/UX we may need libxpdl for dlgetmodinfo (used by solib-pa64.c). |
| 521 | AC_SEARCH_LIBS(dlgetmodinfo, [dl xpdl]) |
| 522 | |
| 523 | AM_ICONV |
| 524 | |
| 525 | # GDB may fork/exec the iconv program to get the list of supported character |
| 526 | # sets. Allow the user to specify where to find it. |
| 527 | # There are several factors affecting the choice of option name: |
| 528 | # - There is already --with-libiconv-prefix but we can't use it, it specifies |
| 529 | # the build-time location of libiconv files. |
| 530 | # - The program we need to find is iconv, which comes with glibc. The user |
| 531 | # doesn't necessarily have libiconv installed. Therefore naming this |
| 532 | # --with-libiconv-foo feels wrong. |
| 533 | # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is |
| 534 | # defined to work on directories not files (though it really doesn't know |
| 535 | # the difference). |
| 536 | # - Calling this --with-iconv-prefix is perceived to cause too much confusion |
| 537 | # with --with-libiconv-prefix. |
| 538 | # Putting these together is why the option name is --with-iconv-bin. |
| 539 | |
| 540 | AC_ARG_WITH(iconv-bin, |
| 541 | AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]), |
| 542 | [iconv_bin="${withval}" |
| 543 | AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"], |
| 544 | [Path of directory of iconv program.]) |
| 545 | GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin}) |
| 546 | ]) |
| 547 | |
| 548 | # On alpha-osf, it appears that libtermcap and libcurses are not compatible. |
| 549 | # There is a very specific comment in /usr/include/curses.h explaining that |
| 550 | # termcap routines built into libcurses must not be used. |
| 551 | # |
| 552 | # The symptoms we observed so far is GDB unexpectedly changing |
| 553 | # the terminal settings when tgetent is called - this is particularly |
| 554 | # visible as the output is missing carriage returns, and so rapidly |
| 555 | # becomes very hard to read. |
| 556 | # |
| 557 | # The readline configure script has already decided that libtermcap |
| 558 | # was enough for its purposes, and so decided to build readline using |
| 559 | # libtermcap. Since the TUI mode requires curses, building GDB with |
| 560 | # TUI enabled results in both libraries to be used at the same time, |
| 561 | # which is not allowed. This basically means that GDB with TUI is |
| 562 | # broken on alpha-osf. |
| 563 | |
| 564 | case $host_os in |
| 565 | osf* ) |
| 566 | if test x"$enable_tui" = xyes; then |
| 567 | AC_MSG_ERROR([Building GDB with TUI mode is not supported on this host]) |
| 568 | fi |
| 569 | if test x"$enable_tui" = xauto; then |
| 570 | enable_tui=no |
| 571 | fi |
| 572 | ;; |
| 573 | esac |
| 574 | |
| 575 | # For the TUI, we need enhanced curses functionality. |
| 576 | if test x"$enable_tui" != xno; then |
| 577 | prefer_curses=yes |
| 578 | fi |
| 579 | |
| 580 | curses_found=no |
| 581 | if test x"$prefer_curses" = xyes; then |
| 582 | # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied |
| 583 | # curses library because the latter might not provide all the |
| 584 | # functionality we need. However, this leads to problems on systems |
| 585 | # where the linker searches /usr/local/lib, but the compiler doesn't |
| 586 | # search /usr/local/include, if ncurses is installed in /usr/local. A |
| 587 | # default installation of ncurses on alpha*-dec-osf* will lead to such |
| 588 | # a situation. |
| 589 | AC_SEARCH_LIBS(waddstr, [ncurses cursesX curses]) |
| 590 | |
| 591 | if test "$ac_cv_search_waddstr" != no; then |
| 592 | curses_found=yes |
| 593 | fi |
| 594 | fi |
| 595 | |
| 596 | # Check whether we should enable the TUI, but only do so if we really |
| 597 | # can. |
| 598 | if test x"$enable_tui" != xno; then |
| 599 | if test -d $srcdir/tui; then |
| 600 | if test "$curses_found" != no; then |
| 601 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)" |
| 602 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)" |
| 603 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)" |
| 604 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)" |
| 605 | else |
| 606 | if test x"$enable_tui" = xyes; then |
| 607 | AC_MSG_ERROR([no enhanced curses library found; disable TUI]) |
| 608 | else |
| 609 | AC_MSG_WARN([no enhanced curses library found; disabling TUI]) |
| 610 | fi |
| 611 | fi |
| 612 | fi |
| 613 | fi |
| 614 | |
| 615 | # Since GDB uses Readline, we need termcap functionality. In many |
| 616 | # cases this will be provided by the curses library, but some systems |
| 617 | # have a seperate termcap library, or no curses library at all. |
| 618 | |
| 619 | case $host_os in |
| 620 | cygwin*) |
| 621 | if test -d $srcdir/libtermcap; then |
| 622 | LIBS="../libtermcap/libtermcap.a $LIBS" |
| 623 | ac_cv_search_tgetent="../libtermcap/libtermcap.a" |
| 624 | fi ;; |
| 625 | go32* | *djgpp*) |
| 626 | ac_cv_search_tgetent="none required" |
| 627 | ;; |
| 628 | *mingw32*) |
| 629 | ac_cv_search_tgetent="none required" |
| 630 | CONFIG_OBS="$CONFIG_OBS windows-termcap.o" |
| 631 | ;; |
| 632 | esac |
| 633 | |
| 634 | # These are the libraries checked by Readline. |
| 635 | AC_SEARCH_LIBS(tgetent, [termcap tinfo curses ncurses]) |
| 636 | |
| 637 | if test "$ac_cv_search_tgetent" = no; then |
| 638 | AC_MSG_ERROR([no termcap library found]) |
| 639 | fi |
| 640 | |
| 641 | AC_ARG_WITH([system-readline], |
| 642 | [AS_HELP_STRING([--with-system-readline], |
| 643 | [use installed readline library])]) |
| 644 | |
| 645 | if test "$with_system_readline" = yes; then |
| 646 | READLINE=-lreadline |
| 647 | READLINE_DEPS= |
| 648 | READLINE_CFLAGS= |
| 649 | READLINE_TEXI_INCFLAG= |
| 650 | else |
| 651 | READLINE='$(READLINE_DIR)/libreadline.a' |
| 652 | READLINE_DEPS='$(READLINE)' |
| 653 | READLINE_CFLAGS='-I$(READLINE_SRC)/..' |
| 654 | READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)' |
| 655 | fi |
| 656 | AC_SUBST(READLINE) |
| 657 | AC_SUBST(READLINE_DEPS) |
| 658 | AC_SUBST(READLINE_CFLAGS) |
| 659 | AC_SUBST(READLINE_TEXI_INCFLAG) |
| 660 | |
| 661 | # Generate jit-reader.h |
| 662 | |
| 663 | # This is typedeffed to GDB_CORE_ADDR in jit-reader.h |
| 664 | TARGET_PTR= |
| 665 | |
| 666 | AC_CHECK_SIZEOF(unsigned long long) |
| 667 | AC_CHECK_SIZEOF(unsigned long) |
| 668 | AC_CHECK_SIZEOF(unsigned __int128) |
| 669 | |
| 670 | if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then |
| 671 | TARGET_PTR="unsigned long" |
| 672 | elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then |
| 673 | TARGET_PTR="unsigned long long" |
| 674 | elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then |
| 675 | TARGET_PTR="unsigned __int128" |
| 676 | else |
| 677 | TARGET_PTR="unsigned long" |
| 678 | fi |
| 679 | |
| 680 | AC_SUBST(TARGET_PTR) |
| 681 | AC_CONFIG_FILES([jit-reader.h:jit-reader.in]) |
| 682 | |
| 683 | AC_SEARCH_LIBS(dlopen, dl) |
| 684 | |
| 685 | GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir], |
| 686 | [directory to load the JIT readers from], |
| 687 | [${libdir}/gdb]) |
| 688 | |
| 689 | AC_ARG_WITH(expat, |
| 690 | AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]), |
| 691 | [], [with_expat=auto]) |
| 692 | AC_MSG_CHECKING([whether to use expat]) |
| 693 | AC_MSG_RESULT([$with_expat]) |
| 694 | |
| 695 | if test "${with_expat}" = no; then |
| 696 | AC_MSG_WARN([expat support disabled; some features may be unavailable.]) |
| 697 | HAVE_LIBEXPAT=no |
| 698 | else |
| 699 | AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"], |
| 700 | [XML_Parser p = XML_ParserCreate (0);]) |
| 701 | if test "$HAVE_LIBEXPAT" != yes; then |
| 702 | if test "$with_expat" = yes; then |
| 703 | AC_MSG_ERROR([expat is missing or unusable]) |
| 704 | else |
| 705 | AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.]) |
| 706 | fi |
| 707 | else |
| 708 | save_LIBS=$LIBS |
| 709 | LIBS="$LIBS $LIBEXPAT" |
| 710 | AC_CHECK_FUNCS(XML_StopParser) |
| 711 | LIBS=$save_LIBS |
| 712 | fi |
| 713 | fi |
| 714 | |
| 715 | # --------------------- # |
| 716 | # Check for libpython. # |
| 717 | # --------------------- # |
| 718 | |
| 719 | dnl Utility to simplify finding libpython. |
| 720 | dnl $1 = pythonX.Y |
| 721 | dnl $2 = the shell variable to assign the result to |
| 722 | dnl If libpython is found we store $version here. |
| 723 | dnl $3 = additional flags to add to CPPFLAGS |
| 724 | dnl $4 = additional flags to add to LIBS |
| 725 | |
| 726 | AC_DEFUN([AC_TRY_LIBPYTHON], |
| 727 | [ |
| 728 | version=$1 |
| 729 | define([have_libpython_var],$2) |
| 730 | new_CPPFLAGS=$3 |
| 731 | new_LIBS=$4 |
| 732 | AC_MSG_CHECKING([for ${version}]) |
| 733 | save_CPPFLAGS=$CPPFLAGS |
| 734 | save_LIBS=$LIBS |
| 735 | CPPFLAGS="$CPPFLAGS $new_CPPFLAGS" |
| 736 | LIBS="$LIBS $new_LIBS" |
| 737 | found_usable_python=no |
| 738 | AC_LINK_IFELSE(AC_LANG_PROGRAM([[#include "Python.h"]], |
| 739 | [[Py_Initialize ();]]), |
| 740 | [have_libpython_var=${version} |
| 741 | found_usable_python=yes |
| 742 | PYTHON_CPPFLAGS=$new_CPPFLAGS |
| 743 | PYTHON_LIBS=$new_LIBS]) |
| 744 | CPPFLAGS=$save_CPPFLAGS |
| 745 | LIBS=$save_LIBS |
| 746 | AC_MSG_RESULT([${found_usable_python}]) |
| 747 | ]) |
| 748 | |
| 749 | dnl There are several different values for --with-python: |
| 750 | dnl |
| 751 | dnl no - Don't include python support. |
| 752 | dnl yes - Include python support, error if it's missing. |
| 753 | dnl If we find python in $PATH, use it to fetch configure options, |
| 754 | dnl otherwise assume the compiler can find it with no help from us. |
| 755 | dnl Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn. |
| 756 | dnl auto - Same as "yes", but if python is missing from the system, |
| 757 | dnl fall back to "no". |
| 758 | dnl /path/to/python/exec-prefix - |
| 759 | dnl Use the python located in this directory. |
| 760 | dnl If /path/to/python/exec-prefix/bin/python exists, use it to find |
| 761 | dnl the compilation parameters. Otherwise use |
| 762 | dnl -I/path/to/python/exec-prefix/include, |
| 763 | dnl -L/path/to/python/exec-prefix/lib. |
| 764 | dnl Python 2.7, 2.6, 2.5, and then 2.4 are tried in turn. |
| 765 | dnl NOTE: This case is historical. It is what was done for 7.0/7.1 |
| 766 | dnl but is deprecated. |
| 767 | dnl /path/to/python/executable - |
| 768 | dnl Run python-config.py with this version of python to fetch the |
| 769 | dnl compilation parameters. |
| 770 | dnl NOTE: This needn't be the real python executable. |
| 771 | dnl In a cross-compilation scenario (build != host), this could be |
| 772 | dnl a shell script that provides what python-config.py provides for |
| 773 | dnl --ldflags, --includes, --exec-prefix. |
| 774 | dnl python-executable - |
| 775 | dnl Find python-executable in $PATH, and then handle the same as |
| 776 | dnl /path/to/python/executable. |
| 777 | dnl |
| 778 | dnl If a python program is specified, it is used to run python-config.py and |
| 779 | dnl is passed --ldflags, --includes, --exec-prefix. |
| 780 | |
| 781 | AC_ARG_WITH(python, |
| 782 | AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]), |
| 783 | [], [with_python=auto]) |
| 784 | AC_MSG_CHECKING([whether to use python]) |
| 785 | AC_MSG_RESULT([$with_python]) |
| 786 | |
| 787 | if test "${with_python}" = no; then |
| 788 | AC_MSG_WARN([python support disabled; some features may be unavailable.]) |
| 789 | have_libpython=no |
| 790 | else |
| 791 | case "${with_python}" in |
| 792 | [[\\/]]* | ?:[[\\/]]*) |
| 793 | if test -d ${with_python}; then |
| 794 | # Assume the python binary is ${with_python}/bin/python. |
| 795 | python_prog="${with_python}/bin/python" |
| 796 | python_prefix= |
| 797 | # If python does not exit ${with_python}/bin, then try in |
| 798 | # ${with_python}. On Windows/MinGW, this is where the Python |
| 799 | # executable is. |
| 800 | if test ! -x "${python_prog}"; then |
| 801 | python_prog="${with_python}/python" |
| 802 | python_prefix= |
| 803 | fi |
| 804 | if test ! -x "${python_prog}"; then |
| 805 | # Fall back to gdb 7.0/7.1 behaviour. |
| 806 | python_prog=missing |
| 807 | python_prefix=${with_python} |
| 808 | fi |
| 809 | elif test -x "${with_python}"; then |
| 810 | # While we can't run python compiled for $host (unless host == build), |
| 811 | # the user could write a script that provides the needed information, |
| 812 | # so we support that. |
| 813 | python_prog=${with_python} |
| 814 | python_prefix= |
| 815 | else |
| 816 | AC_ERROR(invalid value for --with-python) |
| 817 | fi |
| 818 | ;; |
| 819 | */*) |
| 820 | # Disallow --with-python=foo/bar. |
| 821 | AC_ERROR(invalid value for --with-python) |
| 822 | ;; |
| 823 | *) |
| 824 | # The user has either specified auto, yes, or the name of the python |
| 825 | # program assumed to be in $PATH. |
| 826 | python_prefix= |
| 827 | case "${with_python}" in |
| 828 | yes | auto) |
| 829 | if test ${build} = ${host}; then |
| 830 | AC_PATH_PROG(python_prog_path, python, missing) |
| 831 | if test "${python_prog_path}" = missing; then |
| 832 | python_prog=missing |
| 833 | else |
| 834 | python_prog=${python_prog_path} |
| 835 | fi |
| 836 | else |
| 837 | # Not much we can do except assume the cross-compiler will find the |
| 838 | # right files. |
| 839 | python_prog=missing |
| 840 | fi |
| 841 | ;; |
| 842 | *) |
| 843 | # While we can't run python compiled for $host (unless host == build), |
| 844 | # the user could write a script that provides the needed information, |
| 845 | # so we support that. |
| 846 | python_prog="${with_python}" |
| 847 | AC_PATH_PROG(python_prog_path, ${python_prog}, missing) |
| 848 | if test "${python_prog_path}" = missing; then |
| 849 | AC_ERROR(unable to find python program ${python_prog}) |
| 850 | fi |
| 851 | ;; |
| 852 | esac |
| 853 | esac |
| 854 | |
| 855 | if test "${python_prog}" != missing; then |
| 856 | # We have a python program to use, but it may be too old. |
| 857 | # Don't flag an error for --with-python=auto (the default). |
| 858 | have_python_config=yes |
| 859 | python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes` |
| 860 | if test $? != 0; then |
| 861 | have_python_config=failed |
| 862 | if test "${with_python}" != auto; then |
| 863 | AC_ERROR(failure running python-config --includes) |
| 864 | fi |
| 865 | fi |
| 866 | python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags` |
| 867 | if test $? != 0; then |
| 868 | have_python_config=failed |
| 869 | if test "${with_python}" != auto; then |
| 870 | AC_ERROR(failure running python-config --ldflags) |
| 871 | fi |
| 872 | fi |
| 873 | python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix` |
| 874 | if test $? != 0; then |
| 875 | have_python_config=failed |
| 876 | if test "${with_python}" != auto; then |
| 877 | AC_ERROR(failure running python-config --exec-prefix) |
| 878 | fi |
| 879 | fi |
| 880 | else |
| 881 | # We do not have a python executable we can use to determine where |
| 882 | # to find the Python headers and libs. We cannot guess the include |
| 883 | # path from the python_prefix either, because that include path |
| 884 | # depends on the Python version. So, there is nothing much we can |
| 885 | # do except assume that the compiler will be able to find those files. |
| 886 | python_includes= |
| 887 | python_libs= |
| 888 | have_python_config=no |
| 889 | fi |
| 890 | |
| 891 | # If we have python-config, only try the configuration it provides. |
| 892 | # Otherwise fallback on the old way of trying different versions of |
| 893 | # python in turn. |
| 894 | |
| 895 | have_libpython=no |
| 896 | if test "${have_python_config}" = yes; then |
| 897 | # Determine the Python version by extracting "-lpython<version>" |
| 898 | # part of the python_libs. <version> is usually X.Y with X and Y |
| 899 | # being decimal numbers, but can also be XY (seen on Windows). |
| 900 | # |
| 901 | # The extraction is performed using sed with a regular expression. |
| 902 | # Initially, the regexp used was using the '?' quantifier to make |
| 903 | # the dot in the version number optional. Unfortunately, this |
| 904 | # does not work with non-GNU versions of sed because, because of |
| 905 | # what looks like a limitation (the '?' quantifier does not work |
| 906 | # with back-references). We work around this limitation by using |
| 907 | # the '*' quantifier instead. It means that, in theory, we might |
| 908 | # match unexpected version strings such as "-lpython2..7", but |
| 909 | # this seems unlikely in practice. And even if that happens, |
| 910 | # an error will be triggered later on, when checking that version |
| 911 | # number. |
| 912 | python_version=`echo " ${python_libs} " \ |
| 913 | | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'` |
| 914 | case "${python_version}" in |
| 915 | python*) |
| 916 | AC_TRY_LIBPYTHON(${python_version}, have_libpython, |
| 917 | ${python_includes}, ${python_libs}) |
| 918 | ;; |
| 919 | *) |
| 920 | AC_MSG_ERROR([unable to determine python version from ${python_libs}]) |
| 921 | ;; |
| 922 | esac |
| 923 | elif test "${have_python_config}" != failed; then |
| 924 | if test "${have_libpython}" = no; then |
| 925 | AC_TRY_LIBPYTHON(python2.7, have_libpython, |
| 926 | ${python_includes}, "${python_libs} -lpython2.7") |
| 927 | fi |
| 928 | if test "${have_libpython}" = no; then |
| 929 | AC_TRY_LIBPYTHON(python2.6, have_libpython, |
| 930 | ${python_includes}, "${python_libs} -lpython2.6") |
| 931 | fi |
| 932 | if test ${have_libpython} = no; then |
| 933 | AC_TRY_LIBPYTHON(python2.5, have_libpython, |
| 934 | ${python_includes}, "${python_libs} -lpython2.5") |
| 935 | fi |
| 936 | if test ${have_libpython} = no; then |
| 937 | AC_TRY_LIBPYTHON(python2.4, have_libpython, |
| 938 | ${python_includes}, "${python_libs} -lpython2.4") |
| 939 | fi |
| 940 | fi |
| 941 | if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then |
| 942 | AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.]) |
| 943 | elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then |
| 944 | AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.]) |
| 945 | elif test "${have_libpython}" = python2.5 -o "${have_libpython}" = python25; then |
| 946 | AC_DEFINE(HAVE_LIBPYTHON2_5, 1, [Define if Python 2.5 is being used.]) |
| 947 | elif test "${have_libpython}" = python2.4 -o "${have_libpython}" = python24; then |
| 948 | AC_DEFINE(HAVE_LIBPYTHON2_4, 1, [Define if Python 2.4 is being used.]) |
| 949 | fi |
| 950 | |
| 951 | if test "${have_libpython}" = no; then |
| 952 | case "${with_python}" in |
| 953 | yes) |
| 954 | AC_MSG_ERROR([python is missing or unusable]) |
| 955 | ;; |
| 956 | auto) |
| 957 | AC_MSG_WARN([python is missing or unusable; some features may be unavailable.]) |
| 958 | ;; |
| 959 | *) |
| 960 | AC_MSG_ERROR([no usable python found at ${with_python}]) |
| 961 | ;; |
| 962 | esac |
| 963 | else |
| 964 | if test -n "${python_prefix}"; then |
| 965 | AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}", |
| 966 | [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.]) |
| 967 | GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix}) |
| 968 | fi |
| 969 | fi |
| 970 | fi |
| 971 | |
| 972 | if test "${have_libpython}" != no; then |
| 973 | AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.]) |
| 974 | CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)" |
| 975 | CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)" |
| 976 | CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)" |
| 977 | CONFIG_INSTALL="$CONFIG_INSTALL install-python" |
| 978 | ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)" |
| 979 | |
| 980 | # Flags needed to compile Python code (taken from python-config --cflags). |
| 981 | # We cannot call python-config directly because it will output whatever was |
| 982 | # used when compiling the Python interpreter itself, including flags which |
| 983 | # would make the python-related objects be compiled differently from the |
| 984 | # rest of GDB (e.g., -O2 and -fPIC). |
| 985 | if test "${GCC}" = yes; then |
| 986 | tentative_python_cflags="-fno-strict-aliasing -DNDEBUG -fwrapv" |
| 987 | fi |
| 988 | |
| 989 | if test "x${tentative_python_cflags}" != x; then |
| 990 | AC_MSG_CHECKING(compiler flags for python code) |
| 991 | for flag in ${tentative_python_cflags}; do |
| 992 | # Check that the compiler accepts it |
| 993 | saved_CFLAGS="$CFLAGS" |
| 994 | CFLAGS="$CFLAGS $flag" |
| 995 | AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",) |
| 996 | CFLAGS="$saved_CFLAGS" |
| 997 | done |
| 998 | AC_MSG_RESULT(${PYTHON_CFLAGS}) |
| 999 | fi |
| 1000 | |
| 1001 | # On IRIX, type siginfo is not defined. Instead, sys/siginfo.h provides: |
| 1002 | # #if _SGIAPI |
| 1003 | # #define siginfo __siginfo |
| 1004 | # #endif |
| 1005 | # The problem is that including Python causes some XOPEN macros to be |
| 1006 | # unilaterally defined, and that in turn causes _SGIAPI to evaluate |
| 1007 | # to false. So, we work around this issue by defining siginfo ourself |
| 1008 | # though the command-line. |
| 1009 | # |
| 1010 | # On x64 Windows, Python's include headers, and pyconfig.h in |
| 1011 | # particular, rely on MS_WIN64 macro to detect that it's a 64bit |
| 1012 | # version of Windows. Unfortunately, MS_WIN64 is only defined if |
| 1013 | # _MSC_VER, a Microsoft-specific macro, is defined. So, when |
| 1014 | # building on x64 Windows with GCC, we define MS_WIN64 ourselves. |
| 1015 | # The issue was reported to the Python community, but still isn't |
| 1016 | # solved as of 2012-10-02 (http://bugs.python.org/issue4709). |
| 1017 | |
| 1018 | case "$gdb_host" in |
| 1019 | irix*) if test "${GCC}" = yes; then |
| 1020 | CPPFLAGS="$CPPFLAGS -Dsiginfo=__siginfo" |
| 1021 | fi |
| 1022 | ;; |
| 1023 | mingw64) |
| 1024 | if test "${GCC}" = yes; then |
| 1025 | CPPFLAGS="$CPPFLAGS -DMS_WIN64" |
| 1026 | fi |
| 1027 | ;; |
| 1028 | esac |
| 1029 | |
| 1030 | # Note that "python -m threading" cannot be used to check for |
| 1031 | # threading support due to a bug in Python 2.7.3 |
| 1032 | # (http://bugs.python.org/issue15567). |
| 1033 | AC_MSG_CHECKING(whether python supports threads) |
| 1034 | saved_CPPFLAGS="${CPPFLAGS}" |
| 1035 | CPPFLAGS="${PYTHON_CPPFLAGS}" |
| 1036 | # Note that the test is reversed so that python_has_threads=yes on |
| 1037 | # unexpected failures. |
| 1038 | AC_PREPROC_IFELSE(AC_LANG_SOURCE([[ |
| 1039 | #include <Python.h> |
| 1040 | #ifdef WITH_THREAD |
| 1041 | # error |
| 1042 | #endif |
| 1043 | ]]), [python_has_threads=no], [python_has_threads=yes]) |
| 1044 | AC_MSG_RESULT(${python_has_threads}) |
| 1045 | CPPFLAGS="${saved_CPPFLAGS}" |
| 1046 | else |
| 1047 | # Even if Python support is not compiled in, we need to have these files |
| 1048 | # included. |
| 1049 | CONFIG_OBS="$CONFIG_OBS python.o py-value.o py-prettyprint.o py-auto-load.o" |
| 1050 | CONFIG_SRCS="$CONFIG_SRCS python/python.c python/py-value.c \ |
| 1051 | python/py-prettyprint.c python/py-auto-load.c" |
| 1052 | fi |
| 1053 | AC_SUBST(PYTHON_CFLAGS) |
| 1054 | AC_SUBST(PYTHON_CPPFLAGS) |
| 1055 | AC_SUBST(PYTHON_LIBS) |
| 1056 | |
| 1057 | # --------------------- # |
| 1058 | # Check for libmcheck. # |
| 1059 | # --------------------- # |
| 1060 | |
| 1061 | # Enable -lmcheck by default (it provides cheap-enough memory mangling), |
| 1062 | # but turn it off if Python is enabled with threads, since -lmcheck is |
| 1063 | # not thread safe (http://sourceware.org/bugzilla/show_bug.cgi?id=9939), |
| 1064 | # and for releases. |
| 1065 | if test \( "${have_libpython}" = "no" -o "${python_has_threads}" = "no" \) \ |
| 1066 | && $development; then |
| 1067 | libmcheck_default=yes |
| 1068 | else |
| 1069 | libmcheck_default=no |
| 1070 | fi |
| 1071 | GDB_AC_LIBMCHECK(${libmcheck_default}) |
| 1072 | |
| 1073 | if test "$ENABLE_LIBMCHECK" = "yes" \ |
| 1074 | -a "${have_libpython}" != "no" \ |
| 1075 | -a "${python_has_threads}" = "yes" ; then |
| 1076 | AC_MSG_WARN(--enable-libmcheck may lead to spurious crashes if threads are used in python) |
| 1077 | fi |
| 1078 | |
| 1079 | # ------------------------- # |
| 1080 | # Checks for header files. # |
| 1081 | # ------------------------- # |
| 1082 | |
| 1083 | AC_HEADER_STDC |
| 1084 | # elf_hp.h is for HP/UX 64-bit shared library support. |
| 1085 | AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \ |
| 1086 | thread_db.h \ |
| 1087 | sys/fault.h \ |
| 1088 | sys/file.h sys/filio.h sys/ioctl.h sys/param.h \ |
| 1089 | sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \ |
| 1090 | sys/reg.h sys/debugreg.h sys/select.h sys/syscall.h \ |
| 1091 | termios.h termio.h \ |
| 1092 | sgtty.h elf_hp.h \ |
| 1093 | dlfcn.h]) |
| 1094 | AC_CHECK_HEADERS(sys/proc.h, [], [], |
| 1095 | [#if HAVE_SYS_PARAM_H |
| 1096 | # include <sys/param.h> |
| 1097 | #endif |
| 1098 | ]) |
| 1099 | AC_CHECK_HEADERS(sys/user.h, [], [], |
| 1100 | [#if HAVE_SYS_PARAM_H |
| 1101 | # include <sys/param.h> |
| 1102 | #endif |
| 1103 | ]) |
| 1104 | |
| 1105 | # On Solaris 2.[789], we need to define _MSE_INT_H to avoid a clash |
| 1106 | # between <widec.h> and <wchar.h> that would cause AC_CHECK_HEADERS to |
| 1107 | # think that we don't have <curses.h> if we're using GCC. |
| 1108 | case $host_os in |
| 1109 | solaris2.[[789]]) |
| 1110 | if test "$GCC" = yes; then |
| 1111 | AC_DEFINE(_MSE_INT_H, 1, |
| 1112 | [Define to 1 to avoid a clash between <widec.h> and <wchar.h> on |
| 1113 | Solaris 2.[789] when using GCC. ]) |
| 1114 | fi ;; |
| 1115 | esac |
| 1116 | AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncurses/ncurses.h ncurses/term.h) |
| 1117 | AC_CHECK_HEADERS(term.h, [], [], |
| 1118 | [#if HAVE_CURSES_H |
| 1119 | # include <curses.h> |
| 1120 | #endif |
| 1121 | ]) |
| 1122 | |
| 1123 | # ------------------------- # |
| 1124 | # Checks for declarations. # |
| 1125 | # ------------------------- # |
| 1126 | |
| 1127 | AC_CHECK_DECLS([free, malloc, realloc, snprintf]) |
| 1128 | AM_LC_MESSAGES |
| 1129 | |
| 1130 | # ----------------------- # |
| 1131 | # Checks for structures. # |
| 1132 | # ----------------------- # |
| 1133 | |
| 1134 | AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize]) |
| 1135 | |
| 1136 | # ------------------ # |
| 1137 | # Checks for types. # |
| 1138 | # ------------------ # |
| 1139 | |
| 1140 | AC_TYPE_SIGNAL |
| 1141 | AC_CHECK_TYPES(socklen_t, [], [], |
| 1142 | [#include <sys/types.h> |
| 1143 | #include <sys/socket.h> |
| 1144 | ]) |
| 1145 | |
| 1146 | # ------------------------------------- # |
| 1147 | # Checks for compiler characteristics. # |
| 1148 | # ------------------------------------- # |
| 1149 | |
| 1150 | AC_C_CONST |
| 1151 | AC_C_INLINE |
| 1152 | AC_C_BIGENDIAN |
| 1153 | |
| 1154 | # ------------------------------ # |
| 1155 | # Checks for library functions. # |
| 1156 | # ------------------------------ # |
| 1157 | |
| 1158 | AC_FUNC_ALLOCA |
| 1159 | AC_FUNC_MMAP |
| 1160 | AC_FUNC_VFORK |
| 1161 | AC_CHECK_FUNCS([canonicalize_file_name realpath getrusage getuid getgid \ |
| 1162 | pipe poll pread pread64 pwrite readlink resize_term \ |
| 1163 | sbrk setpgid setpgrp setsid \ |
| 1164 | sigaction sigprocmask sigsetmask socketpair \ |
| 1165 | ttrace wborder wresize setlocale iconvlist libiconvlist btowc \ |
| 1166 | setrlimit getrlimit posix_madvise waitpid lstat \ |
| 1167 | ptrace64]) |
| 1168 | AM_LANGINFO_CODESET |
| 1169 | GDB_AC_COMMON |
| 1170 | |
| 1171 | # Check the return and argument types of ptrace. No canned test for |
| 1172 | # this, so roll our own. |
| 1173 | gdb_ptrace_headers=' |
| 1174 | #include <sys/types.h> |
| 1175 | #if HAVE_SYS_PTRACE_H |
| 1176 | # include <sys/ptrace.h> |
| 1177 | #endif |
| 1178 | #if HAVE_UNISTD_H |
| 1179 | # include <unistd.h> |
| 1180 | #endif |
| 1181 | ' |
| 1182 | # There is no point in checking if we don't have a prototype. |
| 1183 | AC_CHECK_DECLS(ptrace, [], [ |
| 1184 | : ${gdb_cv_func_ptrace_ret='int'} |
| 1185 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 1186 | ], $gdb_ptrace_headers) |
| 1187 | # Check return type. Varargs (used on GNU/Linux) conflict with the |
| 1188 | # empty argument list, so check for that explicitly. |
| 1189 | AC_CACHE_CHECK([return type of ptrace], gdb_cv_func_ptrace_ret, |
| 1190 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 1191 | [extern long ptrace (enum __ptrace_request, ...);], |
| 1192 | gdb_cv_func_ptrace_ret='long', |
| 1193 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 1194 | [extern int ptrace ();], |
| 1195 | gdb_cv_func_ptrace_ret='int', |
| 1196 | gdb_cv_func_ptrace_ret='long'))) |
| 1197 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_RET, $gdb_cv_func_ptrace_ret, |
| 1198 | [Define as the return type of ptrace.]) |
| 1199 | # Check argument types. |
| 1200 | AC_CACHE_CHECK([types of arguments for ptrace], gdb_cv_func_ptrace_args, [ |
| 1201 | AC_TRY_COMPILE($gdb_ptrace_headers, |
| 1202 | [extern long ptrace (enum __ptrace_request, ...);], |
| 1203 | [gdb_cv_func_ptrace_args='int,int,long,long'],[ |
| 1204 | for gdb_arg1 in 'int' 'long'; do |
| 1205 | for gdb_arg2 in 'pid_t' 'int' 'long'; do |
| 1206 | for gdb_arg3 in 'int *' 'caddr_t' 'int' 'long' 'void *'; do |
| 1207 | for gdb_arg4 in 'int' 'long' 'void *'; do |
| 1208 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 1209 | extern $gdb_cv_func_ptrace_ret |
| 1210 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4); |
| 1211 | ], [gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4"; |
| 1212 | break 4;]) |
| 1213 | for gdb_arg5 in 'int *' 'int' 'long'; do |
| 1214 | AC_TRY_COMPILE($gdb_ptrace_headers, [ |
| 1215 | extern $gdb_cv_func_ptrace_ret |
| 1216 | ptrace ($gdb_arg1, $gdb_arg2, $gdb_arg3, $gdb_arg4, $gdb_arg5); |
| 1217 | ], [ |
| 1218 | gdb_cv_func_ptrace_args="$gdb_arg1,$gdb_arg2,$gdb_arg3,$gdb_arg4,$gdb_arg5"; |
| 1219 | break 5;]) |
| 1220 | done |
| 1221 | done |
| 1222 | done |
| 1223 | done |
| 1224 | done |
| 1225 | # Provide a safe default value. |
| 1226 | : ${gdb_cv_func_ptrace_args='int,int,long,long'} |
| 1227 | ])]) |
| 1228 | ac_save_IFS=$IFS; IFS=',' |
| 1229 | set dummy `echo "$gdb_cv_func_ptrace_args" | sed 's/\*/\*/g'` |
| 1230 | IFS=$ac_save_IFS |
| 1231 | shift |
| 1232 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG3, $[3], |
| 1233 | [Define to the type of arg 3 for ptrace.]) |
| 1234 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG4, $[4], |
| 1235 | [Define to the type of arg 4 for ptrace.]) |
| 1236 | if test -n "$[5]"; then |
| 1237 | AC_DEFINE_UNQUOTED(PTRACE_TYPE_ARG5, $[5], |
| 1238 | [Define to the type of arg 5 for ptrace.]) |
| 1239 | fi |
| 1240 | |
| 1241 | dnl AC_FUNC_SETPGRP does not work when cross compiling |
| 1242 | dnl Instead, assume we will have a prototype for setpgrp if cross compiling. |
| 1243 | if test "$cross_compiling" = no; then |
| 1244 | AC_FUNC_SETPGRP |
| 1245 | else |
| 1246 | AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void, |
| 1247 | [AC_TRY_COMPILE([ |
| 1248 | #include <unistd.h> |
| 1249 | ], [ |
| 1250 | if (setpgrp(1,1) == -1) |
| 1251 | exit (0); |
| 1252 | else |
| 1253 | exit (1); |
| 1254 | ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)]) |
| 1255 | if test $ac_cv_func_setpgrp_void = yes; then |
| 1256 | AC_DEFINE(SETPGRP_VOID, 1) |
| 1257 | fi |
| 1258 | fi |
| 1259 | |
| 1260 | # Check if sigsetjmp is available. Using AC_CHECK_FUNCS won't do |
| 1261 | # since sigsetjmp might only be defined as a macro. |
| 1262 | AC_CACHE_CHECK([for sigsetjmp], gdb_cv_func_sigsetjmp, |
| 1263 | [AC_TRY_COMPILE([ |
| 1264 | #include <setjmp.h> |
| 1265 | ], [sigjmp_buf env; while (! sigsetjmp (env, 1)) siglongjmp (env, 1);], |
| 1266 | gdb_cv_func_sigsetjmp=yes, gdb_cv_func_sigsetjmp=no)]) |
| 1267 | if test $gdb_cv_func_sigsetjmp = yes; then |
| 1268 | AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available. ]) |
| 1269 | fi |
| 1270 | |
| 1271 | # Assume we'll default to using the included libiberty regex. |
| 1272 | gdb_use_included_regex=yes |
| 1273 | |
| 1274 | # However, if the system regex is GNU regex, then default to *not* |
| 1275 | # using the included regex. |
| 1276 | AC_CACHE_CHECK( |
| 1277 | [for GNU regex], |
| 1278 | [gdb_cv_have_gnu_regex], |
| 1279 | [AC_TRY_COMPILE( |
| 1280 | [#include <gnu-versions.h>], |
| 1281 | [#define REGEX_INTERFACE_VERSION 1 |
| 1282 | #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION |
| 1283 | # error "Version mismatch" |
| 1284 | #endif], |
| 1285 | gdb_cv_have_gnu_regex=yes, |
| 1286 | gdb_cv_have_gnu_regex=no)]) |
| 1287 | if test $gdb_cv_have_gnu_regex = yes; then |
| 1288 | gdb_use_included_regex=no |
| 1289 | fi |
| 1290 | |
| 1291 | AC_ARG_WITH(included-regex, |
| 1292 | AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]), |
| 1293 | gdb_with_regex=$withval, |
| 1294 | gdb_with_regex=$gdb_use_included_regex) |
| 1295 | if test "$gdb_with_regex" = yes; then |
| 1296 | AC_DEFINE(USE_INCLUDED_REGEX, 1, |
| 1297 | [Define to 1 if the regex included in libiberty should be used.]) |
| 1298 | fi |
| 1299 | |
| 1300 | # Check if <sys/proc.h> defines `struct thread' with a td_pcb member. |
| 1301 | AC_CHECK_MEMBERS([struct thread.td_pcb], [], [], |
| 1302 | [#include <sys/param.h> |
| 1303 | #include <sys/proc.h> |
| 1304 | ]) |
| 1305 | |
| 1306 | # See if <sys/lwp.h> defines `struct lwp`. |
| 1307 | AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp, |
| 1308 | [AC_TRY_COMPILE([#include <sys/param.h> |
| 1309 | #include <sys/lwp.h>], [struct lwp l;], |
| 1310 | gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)]) |
| 1311 | if test $gdb_cv_struct_lwp = yes; then |
| 1312 | AC_DEFINE(HAVE_STRUCT_LWP, 1, |
| 1313 | [Define to 1 if your system has struct lwp.]) |
| 1314 | fi |
| 1315 | |
| 1316 | # See if <machine/reg.h> degines `struct reg'. |
| 1317 | AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg, |
| 1318 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1319 | #include <machine/reg.h>], [struct reg r;], |
| 1320 | gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)]) |
| 1321 | if test $gdb_cv_struct_reg = yes; then |
| 1322 | AC_DEFINE(HAVE_STRUCT_REG, 1, |
| 1323 | [Define to 1 if your system has struct reg in <machine/reg.h>.]) |
| 1324 | fi |
| 1325 | |
| 1326 | # See if <machine/reg.h> supports the %fs and %gs i386 segment registers. |
| 1327 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| 1328 | AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [], |
| 1329 | [#include <machine/reg.h>]) |
| 1330 | |
| 1331 | # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers. |
| 1332 | # Older amd64 Linux's don't have the fs_base and gs_base members of |
| 1333 | # `struct user_regs_struct'. |
| 1334 | AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base], |
| 1335 | [], [], [#include <sys/user.h>]) |
| 1336 | |
| 1337 | # See if <sys/ptrace.h> provides the PTRACE_GETREGS request. |
| 1338 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 1339 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| 1340 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 1341 | [PTRACE_GETREGS;], |
| 1342 | [gdb_cv_have_ptrace_getregs=yes], |
| 1343 | [gdb_cv_have_ptrace_getregs=no])]) |
| 1344 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| 1345 | if test $gdb_cv_have_ptrace_getregs = yes; then |
| 1346 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 1347 | [Define if sys/ptrace.h defines the PTRACE_GETREGS request.]) |
| 1348 | fi |
| 1349 | |
| 1350 | # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request. |
| 1351 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 1352 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| 1353 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 1354 | [PTRACE_GETFPXREGS;], |
| 1355 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| 1356 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| 1357 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| 1358 | if test $gdb_cv_have_ptrace_getfpxregs = yes; then |
| 1359 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 1360 | [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.]) |
| 1361 | fi |
| 1362 | |
| 1363 | # See if <sys/ptrace.h> provides the PT_GETDBREGS request. |
| 1364 | AC_MSG_CHECKING(for PT_GETDBREGS) |
| 1365 | AC_CACHE_VAL(gdb_cv_have_pt_getdbregs, |
| 1366 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1367 | #include <sys/ptrace.h>], |
| 1368 | [PT_GETDBREGS;], |
| 1369 | [gdb_cv_have_pt_getdbregs=yes], |
| 1370 | [gdb_cv_have_pt_getdbregs=no])]) |
| 1371 | AC_MSG_RESULT($gdb_cv_have_pt_getdbregs) |
| 1372 | if test $gdb_cv_have_pt_getdbregs = yes; then |
| 1373 | AC_DEFINE(HAVE_PT_GETDBREGS, 1, |
| 1374 | [Define if sys/ptrace.h defines the PT_GETDBREGS request.]) |
| 1375 | fi |
| 1376 | |
| 1377 | # See if <sys/ptrace.h> provides the PT_GETXMMREGS request. |
| 1378 | AC_MSG_CHECKING(for PT_GETXMMREGS) |
| 1379 | AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs, |
| 1380 | [AC_TRY_COMPILE([#include <sys/types.h> |
| 1381 | #include <sys/ptrace.h>], |
| 1382 | [PT_GETXMMREGS;], |
| 1383 | [gdb_cv_have_pt_getxmmregs=yes], |
| 1384 | [gdb_cv_have_pt_getxmmregs=no])]) |
| 1385 | AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs) |
| 1386 | if test $gdb_cv_have_pt_getxmmregs = yes; then |
| 1387 | AC_DEFINE(HAVE_PT_GETXMMREGS, 1, |
| 1388 | [Define if sys/ptrace.h defines the PT_GETXMMREGS request.]) |
| 1389 | fi |
| 1390 | |
| 1391 | # Detect which type of /proc is in use, such as for Solaris. |
| 1392 | |
| 1393 | if test "${target}" = "${host}"; then |
| 1394 | case "${host}" in |
| 1395 | *-*-sysv4.2* | *-*-sysv5* ) |
| 1396 | AC_DEFINE(NEW_PROC_API, 1, |
| 1397 | [Define if you want to use new multi-fd /proc interface.]) |
| 1398 | ;; |
| 1399 | *-*-solaris2.[[6789]] | *-*-solaris2.1[[0-9]]*) |
| 1400 | AC_DEFINE(NEW_PROC_API, 1, |
| 1401 | [Define if you want to use new multi-fd /proc interface.]) |
| 1402 | ;; |
| 1403 | mips-sgi-irix5*) |
| 1404 | # Work around <sys/proc.h> needing _KMEMUSER problem on IRIX 5. |
| 1405 | AC_DEFINE([_KMEMUSER], 1, |
| 1406 | [Define to 1 so <sys/proc.h> gets a definition of anon_hdl. Works |
| 1407 | around a <sys/proc.h> problem on IRIX 5.]) |
| 1408 | ;; |
| 1409 | esac |
| 1410 | fi |
| 1411 | |
| 1412 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 1413 | BFD_HAVE_SYS_PROCFS_TYPE(gregset_t) |
| 1414 | BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t) |
| 1415 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 1416 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 1417 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t) |
| 1418 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 1419 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 1420 | BFD_HAVE_SYS_PROCFS_TYPE(prsysent_t) |
| 1421 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigset_t) |
| 1422 | BFD_HAVE_SYS_PROCFS_TYPE(pr_sigaction64_t) |
| 1423 | BFD_HAVE_SYS_PROCFS_TYPE(pr_siginfo64_t) |
| 1424 | |
| 1425 | |
| 1426 | dnl Check for broken prfpregset_t type |
| 1427 | |
| 1428 | dnl For Linux/i386, glibc 2.1.3 was released with a bogus |
| 1429 | dnl prfpregset_t type (it's a typedef for the pointer to a struct |
| 1430 | dnl instead of the struct itself). We detect this here, and work |
| 1431 | dnl around it in gdb_proc_service.h. |
| 1432 | |
| 1433 | if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then |
| 1434 | AC_MSG_CHECKING(whether prfpregset_t type is broken) |
| 1435 | AC_CACHE_VAL(gdb_cv_prfpregset_t_broken, |
| 1436 | [AC_TRY_RUN([#include <sys/procfs.h> |
| 1437 | int main () |
| 1438 | { |
| 1439 | if (sizeof (prfpregset_t) == sizeof (void *)) |
| 1440 | return 1; |
| 1441 | return 0; |
| 1442 | }], |
| 1443 | gdb_cv_prfpregset_t_broken=no, |
| 1444 | gdb_cv_prfpregset_t_broken=yes, |
| 1445 | gdb_cv_prfpregset_t_broken=yes)]) |
| 1446 | AC_MSG_RESULT($gdb_cv_prfpregset_t_broken) |
| 1447 | if test $gdb_cv_prfpregset_t_broken = yes; then |
| 1448 | AC_DEFINE(PRFPREGSET_T_BROKEN, 1, |
| 1449 | [Define if the prfpregset_t type is broken.]) |
| 1450 | fi |
| 1451 | fi |
| 1452 | fi |
| 1453 | |
| 1454 | # Check if the compiler supports the `long long' type. |
| 1455 | |
| 1456 | AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long, |
| 1457 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM( |
| 1458 | [[extern long long foo;]], |
| 1459 | [[switch (foo & 2) { case 0: return 1; }]])], |
| 1460 | gdb_cv_c_long_long=yes, |
| 1461 | gdb_cv_c_long_long=no)]) |
| 1462 | if test $gdb_cv_c_long_long != yes; then |
| 1463 | # libdecnumber requires long long. |
| 1464 | AC_MSG_ERROR([Compiler must support long long for GDB.]) |
| 1465 | fi |
| 1466 | |
| 1467 | # Check if the compiler and runtime support printing long longs. |
| 1468 | |
| 1469 | AC_CACHE_CHECK([for long long support in printf], |
| 1470 | gdb_cv_printf_has_long_long, |
| 1471 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1472 | [[char buf[32]; |
| 1473 | long long l = 0; |
| 1474 | l = (l << 16) + 0x0123; |
| 1475 | l = (l << 16) + 0x4567; |
| 1476 | l = (l << 16) + 0x89ab; |
| 1477 | l = (l << 16) + 0xcdef; |
| 1478 | sprintf (buf, "0x%016llx", l); |
| 1479 | return (strcmp ("0x0123456789abcdef", buf));]])], |
| 1480 | gdb_cv_printf_has_long_long=yes, |
| 1481 | gdb_cv_printf_has_long_long=no, |
| 1482 | gdb_cv_printf_has_long_long=no)]) |
| 1483 | if test $gdb_cv_printf_has_long_long = yes; then |
| 1484 | AC_DEFINE(PRINTF_HAS_LONG_LONG, 1, |
| 1485 | [Define to 1 if the "%ll" format works to print long longs.]) |
| 1486 | fi |
| 1487 | |
| 1488 | # Check if the compiler and runtime support printing decfloats. |
| 1489 | |
| 1490 | AC_CACHE_CHECK([for decfloat support in printf], |
| 1491 | gdb_cv_printf_has_decfloat, |
| 1492 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1493 | [[char buf[64]; |
| 1494 | _Decimal32 d32 = 1.2345df; |
| 1495 | _Decimal64 d64 = 1.2345dd; |
| 1496 | _Decimal128 d128 = 1.2345dl; |
| 1497 | sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128); |
| 1498 | return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])], |
| 1499 | gdb_cv_printf_has_decfloat=yes, |
| 1500 | gdb_cv_printf_has_decfloat=no, |
| 1501 | gdb_cv_printf_has_decfloat=no)]) |
| 1502 | if test $gdb_cv_printf_has_decfloat = yes; then |
| 1503 | AC_DEFINE(PRINTF_HAS_DECFLOAT, 1, |
| 1504 | [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.]) |
| 1505 | fi |
| 1506 | |
| 1507 | # Check if the compiler supports the `long double' type. We can't use |
| 1508 | # AC_C_LONG_DOUBLE because that one does additional checks on the |
| 1509 | # constants defined in <float.h> that fail on some systems, |
| 1510 | # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6. |
| 1511 | |
| 1512 | AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double, |
| 1513 | [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])], |
| 1514 | gdb_cv_c_long_double=yes, |
| 1515 | gdb_cv_c_long_double=no)]) |
| 1516 | if test $gdb_cv_c_long_double = yes; then |
| 1517 | AC_DEFINE(HAVE_LONG_DOUBLE, 1, |
| 1518 | [Define to 1 if the compiler supports long double.]) |
| 1519 | fi |
| 1520 | |
| 1521 | # Check if the compiler and runtime support printing long doubles. |
| 1522 | |
| 1523 | AC_CACHE_CHECK([for long double support in printf], |
| 1524 | gdb_cv_printf_has_long_double, |
| 1525 | [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT], |
| 1526 | [[char buf[16]; |
| 1527 | long double f = 3.141592653; |
| 1528 | sprintf (buf, "%Lg", f); |
| 1529 | return (strncmp ("3.14159", buf, 7));]])], |
| 1530 | gdb_cv_printf_has_long_double=yes, |
| 1531 | gdb_cv_printf_has_long_double=no, |
| 1532 | gdb_cv_printf_has_long_double=no)]) |
| 1533 | if test $gdb_cv_printf_has_long_double = yes; then |
| 1534 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1, |
| 1535 | [Define to 1 if the "%Lg" format works to print long doubles.]) |
| 1536 | fi |
| 1537 | |
| 1538 | # Check if the compiler and runtime support scanning long doubles. |
| 1539 | |
| 1540 | AC_CACHE_CHECK([for long double support in scanf], |
| 1541 | gdb_cv_scanf_has_long_double, |
| 1542 | [AC_RUN_IFELSE([AC_LANG_PROGRAM( |
| 1543 | [[#include <stdio.h>]], |
| 1544 | [[char *buf = "3.141592653"; |
| 1545 | long double f = 0; |
| 1546 | sscanf (buf, "%Lg", &f); |
| 1547 | return !(f > 3.14159 && f < 3.14160);]])], |
| 1548 | gdb_cv_scanf_has_long_double=yes, |
| 1549 | gdb_cv_scanf_has_long_double=no, |
| 1550 | gdb_cv_scanf_has_long_double=no)]) |
| 1551 | if test $gdb_cv_scanf_has_long_double = yes; then |
| 1552 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1, |
| 1553 | [Define to 1 if the "%Lg" format works to scan long doubles.]) |
| 1554 | fi |
| 1555 | |
| 1556 | case ${host_os} in |
| 1557 | aix*) |
| 1558 | AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [ |
| 1559 | SAVE_LDFLAGS=$LDFLAGS |
| 1560 | |
| 1561 | case $GCC in |
| 1562 | yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;; |
| 1563 | *) gdb_cv_bigtoc=-bbigtoc ;; |
| 1564 | esac |
| 1565 | |
| 1566 | LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc |
| 1567 | AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=]) |
| 1568 | LDFLAGS="${SAVE_LDFLAGS}" |
| 1569 | ]) |
| 1570 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}" |
| 1571 | ;; |
| 1572 | esac |
| 1573 | |
| 1574 | AC_MSG_CHECKING(for the dynamic export flag) |
| 1575 | dynamic_list=false |
| 1576 | if test "${gdb_native}" = yes; then |
| 1577 | # The dynamically loaded libthread_db needs access to symbols in the gdb |
| 1578 | # executable. Older GNU ld supports --export-dynamic but --dynamic-list |
| 1579 | # may not be supported there. |
| 1580 | old_LDFLAGS="$LDFLAGS" |
| 1581 | # Older GNU ld supports --export-dynamic but --dynamic-list it does not. |
| 1582 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 1583 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 1584 | if test "${have_libpython}" = no; then |
| 1585 | AC_TRY_LINK([], [], [dynamic_list=true]) |
| 1586 | else |
| 1587 | # Workaround http://bugs.python.org/issue4434 where static |
| 1588 | # libpythonX.Y.a would get its symbols required for |
| 1589 | # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list. |
| 1590 | # Problem does not happen for the recommended libpythonX.Y.so linkage. |
| 1591 | old_CFLAGS="$CFLAGS" |
| 1592 | CFLAGS="$CFLAGS $PYTHON_CFLAGS" |
| 1593 | old_LIBS="$LIBS" |
| 1594 | LIBS="$LIBS $PYTHON_LIBS" |
| 1595 | AC_RUN_IFELSE( |
| 1596 | AC_LANG_PROGRAM( |
| 1597 | [#include "]${have_libpython}[/Python.h"], |
| 1598 | [int err; |
| 1599 | Py_Initialize (); |
| 1600 | err = PyRun_SimpleString ("import itertools\n"); |
| 1601 | Py_Finalize (); |
| 1602 | return err == 0 ? 0 : 1;]), |
| 1603 | [dynamic_list=true], [], [true]) |
| 1604 | LIBS="$old_LIBS" |
| 1605 | CFLAGS="$old_CFLAGS" |
| 1606 | fi |
| 1607 | LDFLAGS="$old_LDFLAGS" |
| 1608 | fi |
| 1609 | if $dynamic_list; then |
| 1610 | found="-Wl,--dynamic-list" |
| 1611 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list' |
| 1612 | else |
| 1613 | found="-rdynamic" |
| 1614 | RDYNAMIC="-rdynamic" |
| 1615 | fi |
| 1616 | AC_SUBST(RDYNAMIC) |
| 1617 | AC_MSG_RESULT($found) |
| 1618 | |
| 1619 | dnl For certain native configurations, we need to check whether thread |
| 1620 | dnl support can be built in or not. |
| 1621 | dnl |
| 1622 | dnl Note that we only want this if we are both native (host == target), |
| 1623 | dnl and not doing a canadian cross build (build == host). |
| 1624 | |
| 1625 | if test ${build} = ${host} -a ${host} = ${target} ; then |
| 1626 | case ${host_os} in |
| 1627 | solaris*) |
| 1628 | # See if thread_db library is around for Solaris thread debugging. |
| 1629 | # Note that we must explicitly test for version 1 of the library |
| 1630 | # because version 0 (present on Solaris 2.4 or earlier) doesn't have |
| 1631 | # the same API. |
| 1632 | AC_MSG_CHECKING(for Solaris thread debugging library) |
| 1633 | if test -f /usr/lib/libthread_db.so.1 ; then |
| 1634 | AC_MSG_RESULT(yes) |
| 1635 | AC_DEFINE(HAVE_THREAD_DB_LIB, 1, |
| 1636 | [Define if using Solaris thread debugging.]) |
| 1637 | CONFIG_OBS="${CONFIG_OBS} sol-thread.o" |
| 1638 | CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c" |
| 1639 | AC_CHECK_LIB(dl, dlopen) |
| 1640 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} $RDYNAMIC" |
| 1641 | # Sun randomly tweaked the prototypes in <proc_service.h> |
| 1642 | # at one point. |
| 1643 | AC_MSG_CHECKING(if <proc_service.h> is old) |
| 1644 | AC_CACHE_VAL(gdb_cv_proc_service_is_old,[ |
| 1645 | AC_TRY_COMPILE([ |
| 1646 | #include <proc_service.h> |
| 1647 | ps_err_e ps_pdwrite |
| 1648 | (struct ps_prochandle*, psaddr_t, const void*, size_t); |
| 1649 | ],, gdb_cv_proc_service_is_old=no, |
| 1650 | gdb_cv_proc_service_is_old=yes) |
| 1651 | ]) |
| 1652 | AC_MSG_RESULT($gdb_cv_proc_service_is_old) |
| 1653 | if test $gdb_cv_proc_service_is_old = yes; then |
| 1654 | AC_DEFINE(PROC_SERVICE_IS_OLD, 1, |
| 1655 | [Define if <proc_service.h> on solaris uses int instead of |
| 1656 | size_t, and assorted other type changes.]) |
| 1657 | fi |
| 1658 | else |
| 1659 | AC_MSG_RESULT(no) |
| 1660 | fi |
| 1661 | ;; |
| 1662 | aix*) |
| 1663 | AC_MSG_CHECKING(for AiX thread debugging library) |
| 1664 | AC_CACHE_VAL(gdb_cv_have_aix_thread_debug, |
| 1665 | [AC_TRY_COMPILE([#include <sys/pthdebug.h>], |
| 1666 | [#ifndef PTHDB_VERSION_3 |
| 1667 | #error |
| 1668 | #endif], |
| 1669 | gdb_cv_have_aix_thread_debug=yes, |
| 1670 | gdb_cv_have_aix_thread_debug=no)]) |
| 1671 | AC_MSG_RESULT($gdb_cv_have_aix_thread_debug) |
| 1672 | if test $gdb_cv_have_aix_thread_debug = yes; then |
| 1673 | CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c" |
| 1674 | CONFIG_OBS="${CONFIG_OBS} aix-thread.o" |
| 1675 | LIBS="$LIBS -lpthdebug" |
| 1676 | |
| 1677 | # Older versions of AIX do not provide the declaration for |
| 1678 | # the getthrds function (it appears that it was introduced |
| 1679 | # with AIX 6.x). |
| 1680 | AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]]) |
| 1681 | fi |
| 1682 | ;; |
| 1683 | esac |
| 1684 | AC_SUBST(CONFIG_LDFLAGS) |
| 1685 | fi |
| 1686 | |
| 1687 | dnl See if we have a thread_db header file that has TD_NOTALLOC and |
| 1688 | dnl other error codes. |
| 1689 | if test "x$ac_cv_header_thread_db_h" = "xyes"; then |
| 1690 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC], |
| 1691 | gdb_cv_thread_db_h_has_td_notalloc, |
| 1692 | AC_TRY_COMPILE( |
| 1693 | [#include <thread_db.h>], |
| 1694 | [int i = TD_NOTALLOC;], |
| 1695 | gdb_cv_thread_db_h_has_td_notalloc=yes, |
| 1696 | gdb_cv_thread_db_h_has_td_notalloc=no |
| 1697 | ) |
| 1698 | ) |
| 1699 | AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION], |
| 1700 | gdb_cv_thread_db_h_has_td_version, |
| 1701 | AC_TRY_COMPILE( |
| 1702 | [#include <thread_db.h>], |
| 1703 | [int i = TD_VERSION;], |
| 1704 | gdb_cv_thread_db_h_has_td_version=yes, |
| 1705 | gdb_cv_thread_db_h_has_td_version=no |
| 1706 | ) |
| 1707 | ) |
| 1708 | AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS], |
| 1709 | gdb_cv_thread_db_h_has_td_notls, |
| 1710 | AC_TRY_COMPILE( |
| 1711 | [#include <thread_db.h>], |
| 1712 | [int i = TD_NOTLS;], |
| 1713 | gdb_cv_thread_db_h_has_td_notls=yes, |
| 1714 | gdb_cv_thread_db_h_has_td_notls=no |
| 1715 | ) |
| 1716 | ) |
| 1717 | fi |
| 1718 | if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then |
| 1719 | AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1, |
| 1720 | [Define if <thread_db.h> has the TD_NOTALLOC error code.]) |
| 1721 | fi |
| 1722 | if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then |
| 1723 | AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1, |
| 1724 | [Define if <thread_db.h> has the TD_VERSION error code.]) |
| 1725 | fi |
| 1726 | if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then |
| 1727 | AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1, |
| 1728 | [Define if <thread_db.h> has the TD_NOTLS error code.]) |
| 1729 | fi |
| 1730 | |
| 1731 | dnl See if we have a sys/syscall header file that has __NR_tkill. |
| 1732 | if test "x$ac_cv_header_sys_syscall_h" = "xyes"; then |
| 1733 | AC_CACHE_CHECK([whether <sys/syscall.h> has __NR_tkill], |
| 1734 | gdb_cv_sys_syscall_h_has_tkill, |
| 1735 | AC_TRY_COMPILE( |
| 1736 | [#include <sys/syscall.h>], |
| 1737 | [int i = __NR_tkill;], |
| 1738 | gdb_cv_sys_syscall_h_has_tkill=yes, |
| 1739 | gdb_cv_sys_syscall_h_has_tkill=no |
| 1740 | ) |
| 1741 | ) |
| 1742 | fi |
| 1743 | dnl See if we can issue tkill syscall. |
| 1744 | if test "x$gdb_cv_sys_syscall_h_has_tkill" = "xyes"; then |
| 1745 | AC_CHECK_FUNC(syscall, |
| 1746 | AC_DEFINE(HAVE_TKILL_SYSCALL, 1, [Define if you support the tkill syscall.]) |
| 1747 | ) |
| 1748 | fi |
| 1749 | |
| 1750 | dnl Check if we can disable the virtual address space randomization. |
| 1751 | dnl The functionality of setarch -R. |
| 1752 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 1753 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 1754 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 1755 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 1756 | # endif |
| 1757 | /* Test the flag could be set and stays set. */ |
| 1758 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 1759 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 1760 | return 1])]) |
| 1761 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 1762 | [have_personality=true], |
| 1763 | [have_personality=false], |
| 1764 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 1765 | [have_personality=true], |
| 1766 | [have_personality=false])]) |
| 1767 | if $have_personality |
| 1768 | then |
| 1769 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 1770 | [Define if you support the personality syscall.]) |
| 1771 | fi |
| 1772 | |
| 1773 | dnl Set the host's .gdbinit filename. |
| 1774 | case $host_os in |
| 1775 | go32* | *djgpp*) |
| 1776 | gdbinit=gdb.ini |
| 1777 | ;; |
| 1778 | *) |
| 1779 | gdbinit=.gdbinit |
| 1780 | ;; |
| 1781 | esac |
| 1782 | AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.]) |
| 1783 | |
| 1784 | dnl Handle optional features that can be enabled. |
| 1785 | |
| 1786 | # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR, |
| 1787 | # except that the argument to --with-sysroot is optional. |
| 1788 | # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path. |
| 1789 | if test "x$with_sysroot" = xyes; then |
| 1790 | with_sysroot="${exec_prefix}/${target_alias}/sys-root" |
| 1791 | fi |
| 1792 | AC_ARG_WITH(sysroot, |
| 1793 | AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@], |
| 1794 | [search for usr/lib et al within DIR]), |
| 1795 | [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=]) |
| 1796 | AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT, |
| 1797 | [search for usr/lib et al within DIR]) |
| 1798 | AC_SUBST(TARGET_SYSTEM_ROOT) |
| 1799 | GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir}) |
| 1800 | |
| 1801 | GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit, |
| 1802 | [automatically load a system-wide gdbinit file], |
| 1803 | []) |
| 1804 | |
| 1805 | AC_ARG_ENABLE(werror, |
| 1806 | AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]), |
| 1807 | [case "${enableval}" in |
| 1808 | yes | y) ERROR_ON_WARNING="yes" ;; |
| 1809 | no | n) ERROR_ON_WARNING="no" ;; |
| 1810 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;; |
| 1811 | esac]) |
| 1812 | |
| 1813 | # Enable -Werror by default when using gcc. Turn it off for releases. |
| 1814 | if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then |
| 1815 | ERROR_ON_WARNING=yes |
| 1816 | fi |
| 1817 | |
| 1818 | WERROR_CFLAGS="" |
| 1819 | if test "${ERROR_ON_WARNING}" = yes ; then |
| 1820 | WERROR_CFLAGS="-Werror" |
| 1821 | fi |
| 1822 | |
| 1823 | build_warnings="-Wall -Wdeclaration-after-statement -Wpointer-arith \ |
| 1824 | -Wpointer-sign \ |
| 1825 | -Wno-unused -Wunused-value -Wunused-function \ |
| 1826 | -Wno-switch -Wno-char-subscripts -Wmissing-prototypes \ |
| 1827 | -Wdeclaration-after-statement -Wempty-body -Wmissing-parameter-type \ |
| 1828 | -Wold-style-declaration -Wold-style-definition" |
| 1829 | |
| 1830 | # Enable -Wno-format by default when using gcc on mingw since many |
| 1831 | # GCC versions complain about %I64. |
| 1832 | case "${host}" in |
| 1833 | *-*-mingw32*) build_warnings="$build_warnings -Wno-format" ;; |
| 1834 | *) build_warnings="$build_warnings -Wformat-nonliteral" ;; |
| 1835 | esac |
| 1836 | |
| 1837 | AC_ARG_ENABLE(build-warnings, |
| 1838 | AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]), |
| 1839 | [case "${enableval}" in |
| 1840 | yes) ;; |
| 1841 | no) build_warnings="-w";; |
| 1842 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1843 | build_warnings="${build_warnings} ${t}";; |
| 1844 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1845 | build_warnings="${t} ${build_warnings}";; |
| 1846 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1847 | esac |
| 1848 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1849 | echo "Setting compiler warning flags = $build_warnings" 6>&1 |
| 1850 | fi])dnl |
| 1851 | AC_ARG_ENABLE(gdb-build-warnings, |
| 1852 | AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]), |
| 1853 | [case "${enableval}" in |
| 1854 | yes) ;; |
| 1855 | no) build_warnings="-w";; |
| 1856 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1857 | build_warnings="${build_warnings} ${t}";; |
| 1858 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 1859 | build_warnings="${t} ${build_warnings}";; |
| 1860 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 1861 | esac |
| 1862 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 1863 | echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1 |
| 1864 | fi])dnl |
| 1865 | WARN_CFLAGS="" |
| 1866 | if test "x${build_warnings}" != x -a "x$GCC" = xyes |
| 1867 | then |
| 1868 | AC_MSG_CHECKING(compiler warning flags) |
| 1869 | # Separate out the -Werror flag as some files just cannot be |
| 1870 | # compiled with it enabled. |
| 1871 | for w in ${build_warnings}; do |
| 1872 | case $w in |
| 1873 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| 1874 | *) # Check that GCC accepts it |
| 1875 | saved_CFLAGS="$CFLAGS" |
| 1876 | CFLAGS="$CFLAGS $w" |
| 1877 | AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",) |
| 1878 | CFLAGS="$saved_CFLAGS" |
| 1879 | esac |
| 1880 | done |
| 1881 | AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS}) |
| 1882 | fi |
| 1883 | AC_SUBST(WARN_CFLAGS) |
| 1884 | AC_SUBST(WERROR_CFLAGS) |
| 1885 | |
| 1886 | # In the Cygwin environment, we need some additional flags. |
| 1887 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| 1888 | [AC_EGREP_CPP(^lose$, [ |
| 1889 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| 1890 | lose |
| 1891 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| 1892 | |
| 1893 | |
| 1894 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| 1895 | SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o" |
| 1896 | case ${host} in |
| 1897 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| 1898 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| 1899 | *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;; |
| 1900 | esac |
| 1901 | AC_SUBST(SER_HARDWIRE) |
| 1902 | |
| 1903 | # libreadline needs libuser32.a in a cygwin environment |
| 1904 | WIN32LIBS= |
| 1905 | if test x$gdb_cv_os_cygwin = xyes; then |
| 1906 | WIN32LIBS="-luser32" |
| 1907 | case "${target}" in |
| 1908 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| 1909 | ;; |
| 1910 | esac |
| 1911 | fi |
| 1912 | |
| 1913 | # The ser-tcp.c module requires sockets. |
| 1914 | case ${host} in |
| 1915 | *mingw32*) |
| 1916 | AC_DEFINE(USE_WIN32API, 1, |
| 1917 | [Define if we should use the Windows API, instead of the |
| 1918 | POSIX API. On Windows, we use the Windows API when |
| 1919 | building for MinGW, but the POSIX API when building |
| 1920 | for Cygwin.]) |
| 1921 | WIN32LIBS="$WIN32LIBS -lws2_32" |
| 1922 | ;; |
| 1923 | esac |
| 1924 | AC_SUBST(WIN32LIBS) |
| 1925 | |
| 1926 | # Add ELF support to GDB, but only if BFD includes ELF support. |
| 1927 | GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf, |
| 1928 | [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h) |
| 1929 | if test $gdb_cv_var_elf = yes; then |
| 1930 | CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o" |
| 1931 | AC_DEFINE(HAVE_ELF, 1, |
| 1932 | [Define if ELF support should be included.]) |
| 1933 | # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>. |
| 1934 | if test "$plugins" = "yes"; then |
| 1935 | AC_SEARCH_LIBS(dlopen, dl) |
| 1936 | fi |
| 1937 | fi |
| 1938 | |
| 1939 | # Add macho support to GDB, but only if BFD includes it. |
| 1940 | GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho, |
| 1941 | [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h) |
| 1942 | if test $gdb_cv_var_macho = yes; then |
| 1943 | CONFIG_OBS="$CONFIG_OBS machoread.o" |
| 1944 | fi |
| 1945 | |
| 1946 | # Add SOM support to GDB, but only if BFD includes it. |
| 1947 | GDB_AC_CHECK_BFD([for SOM support in BFD], gdb_cv_var_som, |
| 1948 | [bfd_som_attach_aux_hdr (NULL, 0, NULL)], som.h) |
| 1949 | if test $gdb_cv_var_som = yes; then |
| 1950 | CONFIG_OBS="$CONFIG_OBS somread.o" |
| 1951 | fi |
| 1952 | |
| 1953 | # Add any host-specific objects to GDB. |
| 1954 | CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}" |
| 1955 | |
| 1956 | # If building on ELF, look for lzma support for embedded compressed debug info. |
| 1957 | if test $gdb_cv_var_elf = yes; then |
| 1958 | AC_ARG_WITH(lzma, |
| 1959 | AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]), |
| 1960 | [], [with_lzma=auto]) |
| 1961 | AC_MSG_CHECKING([whether to use lzma]) |
| 1962 | AC_MSG_RESULT([$with_lzma]) |
| 1963 | |
| 1964 | if test "${with_lzma}" != no; then |
| 1965 | AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"], |
| 1966 | [lzma_index_iter iter; |
| 1967 | lzma_index_iter_init (&iter, 0); |
| 1968 | lzma_mf_is_supported (LZMA_MF_HC3);]) |
| 1969 | if test "$HAVE_LIBLZMA" != yes; then |
| 1970 | if test "$with_lzma" = yes; then |
| 1971 | AC_MSG_ERROR([missing liblzma for --with-lzma]) |
| 1972 | fi |
| 1973 | fi |
| 1974 | fi |
| 1975 | fi |
| 1976 | |
| 1977 | LIBGUI="../libgui/src/libgui.a" |
| 1978 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| 1979 | AC_SUBST(LIBGUI) |
| 1980 | AC_SUBST(GUI_CFLAGS_X) |
| 1981 | |
| 1982 | WIN32LDAPP= |
| 1983 | AC_SUBST(WIN32LIBS) |
| 1984 | AC_SUBST(WIN32LDAPP) |
| 1985 | |
| 1986 | case "${host}" in |
| 1987 | *-*-cygwin* | *-*-mingw* ) |
| 1988 | configdir="win" |
| 1989 | ;; |
| 1990 | *) |
| 1991 | configdir="unix" |
| 1992 | ;; |
| 1993 | esac |
| 1994 | |
| 1995 | GDBTKLIBS= |
| 1996 | if test "${enable_gdbtk}" = "yes"; then |
| 1997 | |
| 1998 | # Gdbtk must have an absolute path to srcdir in order to run |
| 1999 | # properly when not installed. |
| 2000 | here=`pwd` |
| 2001 | cd ${srcdir} |
| 2002 | GDBTK_SRC_DIR=`pwd` |
| 2003 | cd $here |
| 2004 | |
| 2005 | SC_PATH_TCLCONFIG |
| 2006 | |
| 2007 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| 2008 | # point to doing Tcl. |
| 2009 | SC_PATH_TKCONFIG |
| 2010 | |
| 2011 | if test -z "${no_tcl}" -a -z "${no_tk}"; then |
| 2012 | SC_LOAD_TCLCONFIG |
| 2013 | |
| 2014 | # Check for in-tree tcl |
| 2015 | here=`pwd` |
| 2016 | cd ${srcdir}/.. |
| 2017 | topdir=`pwd` |
| 2018 | cd ${here} |
| 2019 | |
| 2020 | intree="no" |
| 2021 | if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then |
| 2022 | intree="yes" |
| 2023 | fi |
| 2024 | |
| 2025 | # Find Tcl private headers |
| 2026 | if test x"${intree}" = xno; then |
| 2027 | CY_AC_TCL_PRIVATE_HEADERS |
| 2028 | TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}" |
| 2029 | TCL_LIBRARY="${TCL_LIB_SPEC}" |
| 2030 | TCL_DEPS="" |
| 2031 | else |
| 2032 | # If building tcl in the same src tree, private headers |
| 2033 | # are not needed, but we need to be sure to use the right |
| 2034 | # headers library |
| 2035 | TCL_INCLUDE="-I${TCL_SRC_DIR}/generic" |
| 2036 | TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}" |
| 2037 | TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}" |
| 2038 | fi |
| 2039 | AC_SUBST(TCL_INCLUDE) |
| 2040 | AC_SUBST(TCL_LIBRARY) |
| 2041 | AC_SUBST(TCL_DEPS) |
| 2042 | |
| 2043 | SC_LOAD_TKCONFIG |
| 2044 | |
| 2045 | # Check for in-tree Tk |
| 2046 | intree="no" |
| 2047 | if test "${TK_SRC_DIR}" = "${topdir}/tk"; then |
| 2048 | intree="yes" |
| 2049 | fi |
| 2050 | |
| 2051 | # Find Tk private headers |
| 2052 | if test x"${intree}" = xno; then |
| 2053 | CY_AC_TK_PRIVATE_HEADERS |
| 2054 | TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}" |
| 2055 | TK_LIBRARY=${TK_LIB_SPEC} |
| 2056 | TK_DEPS="" |
| 2057 | else |
| 2058 | TK_INCLUDE="-I${TK_SRC_DIR}/generic" |
| 2059 | TK_LIBRARY="${TK_BUILD_LIB_SPEC}" |
| 2060 | TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}" |
| 2061 | fi |
| 2062 | AC_SUBST(TK_INCLUDE) |
| 2063 | AC_SUBST(TK_LIBRARY) |
| 2064 | AC_SUBST(TK_DEPS) |
| 2065 | AC_SUBST(TK_XINCLUDES) |
| 2066 | |
| 2067 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)" |
| 2068 | |
| 2069 | # Include some libraries that Tcl and Tk want. |
| 2070 | TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| 2071 | # Yes, the ordering seems wrong here. But it isn't. |
| 2072 | # TK_LIBS is the list of libraries that need to be linked |
| 2073 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| 2074 | # were in LIBS then any link tests after this point would |
| 2075 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| 2076 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| 2077 | |
| 2078 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)" |
| 2079 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)" |
| 2080 | CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)" |
| 2081 | CONFIG_ALL="${CONFIG_ALL} all-gdbtk" |
| 2082 | CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk" |
| 2083 | CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk" |
| 2084 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk" |
| 2085 | |
| 2086 | if test x$gdb_cv_os_cygwin = xyes; then |
| 2087 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| 2088 | WIN32LDAPP="-Wl,--subsystem,console" |
| 2089 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| 2090 | fi |
| 2091 | |
| 2092 | AC_CONFIG_SUBDIRS(gdbtk) |
| 2093 | fi |
| 2094 | fi |
| 2095 | |
| 2096 | AC_SUBST(X_CFLAGS) |
| 2097 | AC_SUBST(X_LDFLAGS) |
| 2098 | AC_SUBST(X_LIBS) |
| 2099 | AC_SUBST(GDBTKLIBS) |
| 2100 | AC_SUBST(GDBTK_CFLAGS) |
| 2101 | AC_SUBST(GDBTK_SRC_DIR) |
| 2102 | |
| 2103 | AC_PATH_X |
| 2104 | |
| 2105 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| 2106 | # presence of a gdb_sim definition in the target configure.tgt entry. |
| 2107 | # This code just checks for a few cases where we'd like to ignore those |
| 2108 | # definitions, even when they're present in the '.mt' file. These cases |
| 2109 | # are when --disable-sim is specified, or if the simulator directory is |
| 2110 | # not part of the source tree. |
| 2111 | # |
| 2112 | AC_ARG_ENABLE(sim, |
| 2113 | AS_HELP_STRING([--enable-sim], [link gdb with simulator]), |
| 2114 | [echo "enable_sim = $enable_sim"; |
| 2115 | echo "enableval = ${enableval}"; |
| 2116 | case "${enableval}" in |
| 2117 | yes) ignore_sim=false ;; |
| 2118 | no) ignore_sim=true ;; |
| 2119 | *) ignore_sim=false ;; |
| 2120 | esac], |
| 2121 | [ignore_sim=false]) |
| 2122 | |
| 2123 | if test ! -d "${srcdir}/../sim"; then |
| 2124 | ignore_sim=true |
| 2125 | fi |
| 2126 | |
| 2127 | SIM= |
| 2128 | SIM_OBS= |
| 2129 | if test "${ignore_sim}" = "false"; then |
| 2130 | if test x"${gdb_sim}" != x ; then |
| 2131 | SIM="${gdb_sim}" |
| 2132 | SIM_OBS="remote-sim.o" |
| 2133 | AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.]) |
| 2134 | fi |
| 2135 | fi |
| 2136 | AC_SUBST(SIM) |
| 2137 | AC_SUBST(SIM_OBS) |
| 2138 | |
| 2139 | AC_SUBST(ENABLE_CFLAGS) |
| 2140 | AC_SUBST(PROFILE_CFLAGS) |
| 2141 | |
| 2142 | AC_SUBST(CONFIG_OBS) |
| 2143 | AC_SUBST(CONFIG_DEPS) |
| 2144 | AC_SUBST(CONFIG_SRCS) |
| 2145 | AC_SUBST(CONFIG_ALL) |
| 2146 | AC_SUBST(CONFIG_CLEAN) |
| 2147 | AC_SUBST(CONFIG_INSTALL) |
| 2148 | AC_SUBST(CONFIG_UNINSTALL) |
| 2149 | |
| 2150 | # List of host floatformats. |
| 2151 | AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat]) |
| 2152 | AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat]) |
| 2153 | AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat]) |
| 2154 | |
| 2155 | # target_subdir is used by the testsuite to find the target libraries. |
| 2156 | target_subdir= |
| 2157 | if test "${host}" != "${target}"; then |
| 2158 | target_subdir="${target_alias}/" |
| 2159 | fi |
| 2160 | AC_SUBST(target_subdir) |
| 2161 | |
| 2162 | frags= |
| 2163 | if test "${gdb_native}" = "yes"; then |
| 2164 | host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh |
| 2165 | if test ! -f ${host_makefile_frag}; then |
| 2166 | AC_MSG_ERROR("*** Gdb does not support native target ${host}") |
| 2167 | fi |
| 2168 | frags="$frags $host_makefile_frag" |
| 2169 | else |
| 2170 | host_makefile_frag=/dev/null |
| 2171 | fi |
| 2172 | |
| 2173 | AC_SUBST_FILE(host_makefile_frag) |
| 2174 | AC_SUBST(frags) |
| 2175 | |
| 2176 | changequote(,)dnl |
| 2177 | if test "${gdb_native}" = "yes"; then |
| 2178 | # We pick this up from the host configuration file (.mh) because we |
| 2179 | # do not have a native configuration Makefile fragment. |
| 2180 | nativefile=`sed -n ' |
| 2181 | s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 2182 | ' ${host_makefile_frag}` |
| 2183 | fi |
| 2184 | changequote([,]) |
| 2185 | |
| 2186 | if test x"${gdb_osabi}" != x ; then |
| 2187 | AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi, |
| 2188 | [Define to the default OS ABI for this configuration.]) |
| 2189 | fi |
| 2190 | |
| 2191 | # Enable multi-ice-gdb-server. |
| 2192 | AC_ARG_ENABLE(multi-ice, |
| 2193 | AS_HELP_STRING([--enable-multi-ice], [build the multi-ice-gdb-server]), |
| 2194 | [case $enableval in |
| 2195 | yes | no) |
| 2196 | ;; |
| 2197 | *) AC_MSG_ERROR([bad value $enableval for --enable-multi-ice]) ;; |
| 2198 | esac]) |
| 2199 | if test "x$enable_multi_ice" = xyes; then |
| 2200 | AC_CONFIG_SUBDIRS(multi-ice) |
| 2201 | fi |
| 2202 | |
| 2203 | AC_ARG_ENABLE(gdbserver, |
| 2204 | AS_HELP_STRING([--enable-gdbserver], |
| 2205 | [automatically build gdbserver (yes/no/auto, default is auto)]), |
| 2206 | [case "${enableval}" in |
| 2207 | yes| no|auto) ;; |
| 2208 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;; |
| 2209 | esac],[enable_gdbserver=auto]) |
| 2210 | |
| 2211 | # We only build gdbserver automatically in a native configuration, and |
| 2212 | # only if the user did not explicitly disable its build. |
| 2213 | if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then |
| 2214 | AC_MSG_CHECKING(whether gdbserver is supported on this host) |
| 2215 | if test "x$build_gdbserver" = xyes; then |
| 2216 | AC_MSG_RESULT(yes) |
| 2217 | AC_CONFIG_SUBDIRS(gdbserver) |
| 2218 | gdbserver_build_enabled=yes |
| 2219 | else |
| 2220 | AC_MSG_RESULT(no) |
| 2221 | fi |
| 2222 | fi |
| 2223 | |
| 2224 | # If the user explicitly request the gdbserver to be built, verify that |
| 2225 | # we were in fact able to enable it. |
| 2226 | if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then |
| 2227 | AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration) |
| 2228 | fi |
| 2229 | |
| 2230 | # Check for babeltrace and babeltrace-ctf |
| 2231 | AC_ARG_WITH(babeltrace, |
| 2232 | AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]), |
| 2233 | [], [with_babeltrace=auto]) |
| 2234 | AC_MSG_CHECKING([whether to use babeltrace]) |
| 2235 | AC_MSG_RESULT([$with_babeltrace]) |
| 2236 | |
| 2237 | if test "x$with_babeltrace" = "xno"; then |
| 2238 | AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.]) |
| 2239 | else |
| 2240 | # Append -Werror to CFLAGS so that configure can catch the warning |
| 2241 | # "assignment from incompatible pointer type", which is related to |
| 2242 | # the babeltrace change from 1.0.3 to 1.1.0. Babeltrace 1.1.0 works |
| 2243 | # in GDB, while babeltrace 1.0.3 is broken. |
| 2244 | # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be |
| 2245 | # safe to save and restore CFLAGS here. |
| 2246 | saved_CFLAGS=$CFLAGS |
| 2247 | CFLAGS="$CFLAGS -Werror" |
| 2248 | AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf], |
| 2249 | [#include <babeltrace/babeltrace.h> |
| 2250 | #include <babeltrace/ctf/events.h> |
| 2251 | #include <babeltrace/ctf/iterator.h>], |
| 2252 | [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL)); |
| 2253 | struct bt_ctf_event *event = NULL; |
| 2254 | const struct bt_definition *scope; |
| 2255 | |
| 2256 | scope = bt_ctf_get_top_level_scope (event, |
| 2257 | BT_STREAM_EVENT_HEADER); |
| 2258 | bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id")); |
| 2259 | ]) |
| 2260 | CFLAGS=$saved_CFLAGS |
| 2261 | |
| 2262 | if test "$HAVE_LIBBABELTRACE" != yes; then |
| 2263 | if test "$with_babeltrace" = yes; then |
| 2264 | AC_MSG_ERROR([babeltrace is missing or unusable]) |
| 2265 | else |
| 2266 | AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.]) |
| 2267 | fi |
| 2268 | fi |
| 2269 | fi |
| 2270 | |
| 2271 | # If nativefile (NAT_FILE) is not set in config/*/*.m[ht] files, we link |
| 2272 | # to an empty version. |
| 2273 | |
| 2274 | files= |
| 2275 | links= |
| 2276 | |
| 2277 | rm -f nm.h |
| 2278 | if test "${nativefile}" != ""; then |
| 2279 | case "${nativefile}" in |
| 2280 | nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;; |
| 2281 | * ) GDB_NM_FILE="${nativefile}" |
| 2282 | esac |
| 2283 | files="${files} ${GDB_NM_FILE}" |
| 2284 | links="${links} nm.h" |
| 2285 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile]) |
| 2286 | fi |
| 2287 | AC_SUBST(GDB_NM_FILE) |
| 2288 | |
| 2289 | AC_LINK_FILES($files, $links) |
| 2290 | |
| 2291 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| 2292 | AC_EXEEXT |
| 2293 | |
| 2294 | dnl Detect the character set used by this host. |
| 2295 | dnl At the moment, we just assume it's UTF-8. |
| 2296 | AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8", |
| 2297 | [Define to be a string naming the default host character set.]) |
| 2298 | |
| 2299 | # Undo the $ec_script escaping suitable for Makefile. |
| 2300 | transform=`echo "$program_transform_name" | sed -e 's/[\\$][\\$]/\\$/g'` |
| 2301 | GDB_TRANSFORM_NAME=`echo gdb | sed -e "$transform"` |
| 2302 | if test "x$GDB_TRANSFORM_NAME" = x; then |
| 2303 | GDB_TRANSFORM_NAME=gdb |
| 2304 | fi |
| 2305 | AC_SUBST(GDB_TRANSFORM_NAME) |
| 2306 | GCORE_TRANSFORM_NAME=`echo gcore | sed -e "$transform"` |
| 2307 | if test "x$GCORE_TRANSFORM_NAME" = x; then |
| 2308 | GCORE_TRANSFORM_NAME=gcore |
| 2309 | fi |
| 2310 | AC_SUBST(GCORE_TRANSFORM_NAME) |
| 2311 | AC_CONFIG_FILES([gcore], [chmod +x gcore]) |
| 2312 | |
| 2313 | AC_OUTPUT(Makefile gdb-gdb.gdb doc/Makefile data-directory/Makefile, |
| 2314 | [ |
| 2315 | case x$CONFIG_HEADERS in |
| 2316 | xconfig.h:config.in) |
| 2317 | echo > stamp-h ;; |
| 2318 | esac |
| 2319 | ]) |
| 2320 | |
| 2321 | exit 0 |