| 1 | dnl Autoconf configure script for GDB, the GNU debugger. |
| 2 | dnl Copyright 1995, 1996, 1997, 1998, 1999, 2000 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 2 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program; if not, write to the Free Software |
| 18 | dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 19 | |
| 20 | dnl Process this file with autoconf to produce a configure script. |
| 21 | |
| 22 | AC_PREREQ(2.13)dnl |
| 23 | AC_INIT(main.c) |
| 24 | AC_CONFIG_HEADER(config.h:config.in) |
| 25 | AM_MAINTAINER_MODE |
| 26 | |
| 27 | AC_PROG_CC |
| 28 | AC_AIX |
| 29 | AC_ISC_POSIX |
| 30 | AM_PROG_CC_STDC |
| 31 | |
| 32 | AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..) |
| 33 | AC_CANONICAL_SYSTEM |
| 34 | |
| 35 | dnl gdb doesn't use gettext, but bfd does. We call this to ensure we |
| 36 | dnl link with the correct libraries. |
| 37 | ALL_LINGUAS= |
| 38 | CY_GNU_GETTEXT |
| 39 | |
| 40 | dnl List of object files added by configure. |
| 41 | |
| 42 | CONFIG_OBS= |
| 43 | CONFIG_DEPS= |
| 44 | CONFIG_SRCS= |
| 45 | CONFIG_INITS= |
| 46 | ENABLE_CFLAGS= |
| 47 | CONFIG_ALL= |
| 48 | CONFIG_CLEAN= |
| 49 | CONFIG_INSTALL= |
| 50 | CONFIG_UNINSTALL= |
| 51 | |
| 52 | configdirs="doc testsuite" |
| 53 | |
| 54 | AC_ARG_ENABLE(multi-ice, |
| 55 | [ --enable-multi-ice Build the multi-ice-gdb-server], |
| 56 | [case "${enableval}" in |
| 57 | yes ) enable_multi_ice="yes" ;; |
| 58 | no) enable_multi_ice="no" ;; |
| 59 | *) AC_MSG_ERROR(Bad value for --enable-multi-ice: ${enableval}) ;; |
| 60 | esac |
| 61 | ]) |
| 62 | |
| 63 | if test "${enable_multi_ice}" = "yes"; then |
| 64 | configdirs="${configdirs} multi-ice" |
| 65 | fi |
| 66 | |
| 67 | dnl |
| 68 | changequote(,)dnl |
| 69 | |
| 70 | . ${srcdir}/configure.host |
| 71 | |
| 72 | . ${srcdir}/configure.tgt |
| 73 | |
| 74 | targ=${target} ; . ${srcdir}/../bfd/config.bfd |
| 75 | |
| 76 | dnl |
| 77 | changequote([,])dnl |
| 78 | |
| 79 | dnl use BFD to determine the default architecture and byte order |
| 80 | dnl (bfd_vec->byteorder provides the latter). |
| 81 | targ=${target} |
| 82 | . ${srcdir}/../bfd/config.bfd |
| 83 | |
| 84 | dnl We only want the first arch, if there is more than one. |
| 85 | targ_archs=`echo ${targ_archs} | sed -e 's/ .*//;'` |
| 86 | |
| 87 | if test x"${targ_archs}" != x ; then |
| 88 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, ${targ_archs}) |
| 89 | fi |
| 90 | if test x"${targ_defvec}" != x ; then |
| 91 | AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, ${targ_defvec}) |
| 92 | fi |
| 93 | |
| 94 | AC_PROG_AWK |
| 95 | AC_PROG_INSTALL |
| 96 | AC_CHECK_TOOL(AR, ar) |
| 97 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| 98 | AC_CHECK_TOOL(DLLTOOL, dlltool) |
| 99 | AC_CHECK_TOOL(WINDRES, windres) |
| 100 | AC_PROG_YACC |
| 101 | |
| 102 | dnl MiG is needed for the Hurd. |
| 103 | AC_CHECK_TOOL(MIG, mig) |
| 104 | |
| 105 | AC_ARG_PROGRAM |
| 106 | |
| 107 | AC_TYPE_SIGNAL |
| 108 | |
| 109 | AC_HEADER_STDC |
| 110 | |
| 111 | dnl Solaris 7 needs _MSE_INT_H defined to avoid a clash between <widec.h> |
| 112 | dnl and <wchar.h> that causes AC_CHECK_HEADERS to think <curses.h> doesn't |
| 113 | dnl exist. |
| 114 | |
| 115 | case $host_os in solaris2.7 | solaris2.8) case "$GCC" in yes) |
| 116 | AC_DEFINE(_MSE_INT_H) |
| 117 | esac; esac |
| 118 | |
| 119 | AC_CHECK_HEADERS(ctype.h endian.h link.h thread_db.h proc_service.h \ |
| 120 | memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \ |
| 121 | string.h sys/procfs.h sys/ptrace.h sys/reg.h stdint.h \ |
| 122 | term.h termio.h termios.h unistd.h wait.h sys/wait.h \ |
| 123 | wchar.h wctype.h asm/debugreg.h sys/debugreg.h sys/select.h \ |
| 124 | time.h sys/ioctl.h sys/user.h \ |
| 125 | dirent.h sys/ndir.h sys/dir.h ndir.h \ |
| 126 | curses.h ncurses.h \ |
| 127 | poll.h sys/poll.h) |
| 128 | AC_HEADER_STAT |
| 129 | |
| 130 | AC_C_CONST |
| 131 | |
| 132 | AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc poll sigprocmask vfork) |
| 133 | AC_FUNC_ALLOCA |
| 134 | |
| 135 | # See if machine/reg.h supports the %fs and %gs i386 segment registers. |
| 136 | # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'. |
| 137 | AC_CACHE_CHECK([for r_fs in struct reg], gdb_cv_struct_reg_r_fs, |
| 138 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_fs;], |
| 139 | gdb_cv_struct_reg_r_fs=yes, gdb_cv_struct_reg_r_fs=no)]) |
| 140 | if test $gdb_cv_struct_reg_r_fs = yes; then |
| 141 | AC_DEFINE(HAVE_STRUCT_REG_R_FS) |
| 142 | fi |
| 143 | AC_CACHE_CHECK([for r_gs in struct reg], gdb_cv_struct_reg_r_gs, |
| 144 | [AC_TRY_COMPILE([#include <machine/reg.h>], [struct reg r; r.r_gs;], |
| 145 | gdb_cv_struct_reg_r_gs=yes, gdb_cv_struct_reg_r_gs=no)]) |
| 146 | if test $gdb_cv_struct_reg_r_gs = yes; then |
| 147 | AC_DEFINE(HAVE_STRUCT_REG_R_GS) |
| 148 | fi |
| 149 | |
| 150 | dnl See if ptrace.h provides the PTRACE_GETREGS request. |
| 151 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 152 | AC_CACHE_VAL(gdb_cv_have_ptrace_getregs, |
| 153 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 154 | [PTRACE_GETREGS;], |
| 155 | [gdb_cv_have_ptrace_getregs=yes], |
| 156 | [gdb_cv_have_ptrace_getregs=no])]) |
| 157 | AC_MSG_RESULT($gdb_cv_have_ptrace_getregs) |
| 158 | if test $gdb_cv_have_ptrace_getregs = yes; then |
| 159 | AC_DEFINE(HAVE_PTRACE_GETREGS) |
| 160 | fi |
| 161 | |
| 162 | dnl See if ptrace.h provides the PTRACE_GETFPXREGS request. |
| 163 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 164 | AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs, |
| 165 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 166 | [PTRACE_GETFPXREGS;], |
| 167 | [gdb_cv_have_ptrace_getfpxregs=yes], |
| 168 | [gdb_cv_have_ptrace_getfpxregs=no])]) |
| 169 | AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs) |
| 170 | if test $gdb_cv_have_ptrace_getfpxregs = yes; then |
| 171 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS) |
| 172 | fi |
| 173 | |
| 174 | AC_CHECK_LIB(socket, socketpair) |
| 175 | AC_CHECK_FUNCS(socketpair) |
| 176 | |
| 177 | |
| 178 | BFD_NEED_DECLARATION(malloc) |
| 179 | BFD_NEED_DECLARATION(realloc) |
| 180 | BFD_NEED_DECLARATION(free) |
| 181 | BFD_NEED_DECLARATION(strerror) |
| 182 | BFD_NEED_DECLARATION(strdup) |
| 183 | BFD_NEED_DECLARATION(strstr) |
| 184 | |
| 185 | |
| 186 | # The following save_state_t checkery is only necessary for HPUX |
| 187 | # versions earlier than 10.20. When those fade from memory, this |
| 188 | # could be expunged. --jsm 1999-03-22 |
| 189 | |
| 190 | AC_MSG_CHECKING(for HPUX save_state structure) |
| 191 | AC_EGREP_HEADER(save_state_t, machine/save_state.h, |
| 192 | gdb_cv_hpux_savestate=yes, gdb_cv_hpux_savestate=no) |
| 193 | AC_EGREP_HEADER(ss_wide, machine/save_state.h, gdb_cv_hpux_sswide=yes, |
| 194 | gdb_cv_hpux_sswide=no) |
| 195 | if test $gdb_cv_hpux_savestate = yes |
| 196 | then |
| 197 | AC_DEFINE(HAVE_STRUCT_SAVE_STATE_T, 1) |
| 198 | fi |
| 199 | if test $gdb_cv_hpux_sswide = yes |
| 200 | then |
| 201 | AC_DEFINE(HAVE_STRUCT_MEMBER_SS_WIDE, 1) |
| 202 | fi |
| 203 | AC_MSG_RESULT($gdb_cv_hpux_sswide) |
| 204 | |
| 205 | |
| 206 | # If we are configured native on GNU/Linux, work around problems with |
| 207 | # sys/procfs.h |
| 208 | # Also detect which type of /proc is in use, such as for Unixware or Solaris. |
| 209 | |
| 210 | if test "${target}" = "${host}"; then |
| 211 | case "${host}" in |
| 212 | i[[3456]]86-*-linux*) |
| 213 | AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2) |
| 214 | AC_DEFINE(sys_quotactl) |
| 215 | ;; |
| 216 | *-*-unixware* | *-*-sysv4.2* | *-*-sysv5*) |
| 217 | AC_DEFINE(NEW_PROC_API) |
| 218 | ;; |
| 219 | *-*-solaris2.[[678]]) |
| 220 | AC_DEFINE(NEW_PROC_API) |
| 221 | ;; |
| 222 | esac |
| 223 | fi |
| 224 | |
| 225 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 226 | BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t) |
| 227 | BFD_HAVE_SYS_PROCFS_TYPE(prrun_t) |
| 228 | BFD_HAVE_SYS_PROCFS_TYPE(gregset_t) |
| 229 | BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t) |
| 230 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 231 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 232 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t) |
| 233 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset32_t) |
| 234 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 235 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 236 | |
| 237 | dnl Check for struct link_map32 type, which allows a 64-bit Solaris |
| 238 | dnl debugger to debug a 32-bit Solaris app with 32-bit shared libraries. |
| 239 | |
| 240 | AC_MSG_CHECKING(for struct link_map32 in sys/link.h) |
| 241 | AC_CACHE_VAL(gdb_cv_have_struct_link_map32, |
| 242 | [AC_TRY_COMPILE([#define _SYSCALL32 |
| 243 | #include <sys/link.h>], [struct link_map32 l;], |
| 244 | gdb_cv_have_struct_link_map32=yes, |
| 245 | gdb_cv_have_struct_link_map32=no)]) |
| 246 | AC_MSG_RESULT($gdb_cv_have_struct_link_map32) |
| 247 | if test $gdb_cv_have_struct_link_map32 = yes; then |
| 248 | AC_DEFINE(HAVE_STRUCT_LINK_MAP32) |
| 249 | fi |
| 250 | |
| 251 | dnl Check for broken prfpregset_t type |
| 252 | |
| 253 | dnl For Linux/i386, glibc 2.1.3 was released with a bogus |
| 254 | dnl prfpregset_t type (it's a typedef for the pointer to a struct |
| 255 | dnl instead of the struct itself). We detect this here, and work |
| 256 | dnl around it in lin-thread.c. |
| 257 | |
| 258 | if test $bfd_cv_have_sys_procfs_type_prfpregset_t = yes; then |
| 259 | AC_MSG_CHECKING(whether prfpregset_t type is broken) |
| 260 | AC_CACHE_VAL(gdb_cv_prfpregset_t_broken, |
| 261 | [AC_TRY_RUN([#include <sys/procfs.h> |
| 262 | int main () |
| 263 | { |
| 264 | if (sizeof (prfpregset_t) == sizeof (void *)) |
| 265 | return 1; |
| 266 | return 0; |
| 267 | }], |
| 268 | gdb_cv_prfpregset_t_broken=no, |
| 269 | gdb_cv_prfpregset_t_broken=yes, |
| 270 | gdb_cv_prfpregset_t_broken=yes)]) |
| 271 | AC_MSG_RESULT($gdb_cv_prfpregset_t_broken) |
| 272 | if test $gdb_cv_prfpregset_t_broken = yes; then |
| 273 | AC_DEFINE(PRFPREGSET_T_BROKEN) |
| 274 | fi |
| 275 | fi |
| 276 | |
| 277 | dnl Check for PIOCSET ioctl entry |
| 278 | |
| 279 | AC_MSG_CHECKING(for PIOCSET ioctl entry in sys/procfs.h) |
| 280 | AC_CACHE_VAL(gdb_cv_have_procfs_piocset, |
| 281 | [AC_TRY_COMPILE([#include <unistd.h> |
| 282 | #include <sys/types.h> |
| 283 | #include <sys/procfs.h> |
| 284 | ], [ |
| 285 | int dummy;; |
| 286 | dummy = ioctl(0, PIOCSET, &dummy); |
| 287 | ], |
| 288 | gdb_cv_have_procfs_piocset=yes, gdb_cv_have_procfs_piocset=no)]) |
| 289 | AC_MSG_RESULT($gdb_cv_have_procfs_piocset) |
| 290 | if test $gdb_cv_have_procfs_piocset = yes; then |
| 291 | AC_DEFINE(HAVE_PROCFS_PIOCSET) |
| 292 | fi |
| 293 | fi |
| 294 | |
| 295 | dnl See if host has libm. This is usually needed by simulators. |
| 296 | AC_CHECK_LIB(m, main) |
| 297 | |
| 298 | dnl Solaris puts wctype in /usr/lib/libw.a before Solaris 2.6. |
| 299 | dnl |
| 300 | dnl A bug in GNU ld 2.9.1 causes a problem if we link in -lw |
| 301 | dnl under Solaris 2.6 because it is some funky empty library. |
| 302 | dnl So only link in libw if we have to. |
| 303 | AC_CHECK_LIB(c, wctype,: ,AC_CHECK_LIB(w, wctype)) |
| 304 | |
| 305 | dnl See if compiler supports "long long" type. |
| 306 | |
| 307 | AC_MSG_CHECKING(for long long support in compiler) |
| 308 | AC_CACHE_VAL(gdb_cv_c_long_long, |
| 309 | [AC_TRY_COMPILE(, [ |
| 310 | extern long long foo; |
| 311 | switch (foo & 2) { case 0: return 1; } |
| 312 | ], |
| 313 | gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)]) |
| 314 | AC_MSG_RESULT($gdb_cv_c_long_long) |
| 315 | if test $gdb_cv_c_long_long = yes; then |
| 316 | AC_DEFINE(CC_HAS_LONG_LONG) |
| 317 | fi |
| 318 | |
| 319 | dnl See if the compiler and runtime support printing long long |
| 320 | |
| 321 | AC_MSG_CHECKING(for long long support in printf) |
| 322 | AC_CACHE_VAL(gdb_cv_printf_has_long_long, |
| 323 | [AC_TRY_RUN([ |
| 324 | int main () { |
| 325 | char buf[32]; |
| 326 | long long l = 0; |
| 327 | l = (l << 16) + 0x0123; |
| 328 | l = (l << 16) + 0x4567; |
| 329 | l = (l << 16) + 0x89ab; |
| 330 | l = (l << 16) + 0xcdef; |
| 331 | sprintf (buf, "0x%016llx", l); |
| 332 | return (strcmp ("0x0123456789abcdef", buf)); |
| 333 | }], |
| 334 | gdb_cv_printf_has_long_long=yes, |
| 335 | gdb_cv_printf_has_long_long=no, |
| 336 | gdb_cv_printf_has_long_long=no)]) |
| 337 | if test $gdb_cv_printf_has_long_long = yes; then |
| 338 | AC_DEFINE(PRINTF_HAS_LONG_LONG) |
| 339 | fi |
| 340 | AC_MSG_RESULT($gdb_cv_printf_has_long_long) |
| 341 | |
| 342 | dnl See if compiler supports "long double" type. Can't use AC_C_LONG_DOUBLE |
| 343 | dnl because autoconf complains about cross-compilation issues. However, this |
| 344 | dnl code uses the same variables as the macro for compatibility. |
| 345 | |
| 346 | AC_MSG_CHECKING(for long double support in compiler) |
| 347 | AC_CACHE_VAL(ac_cv_c_long_double, |
| 348 | [AC_TRY_COMPILE(, [long double foo;], |
| 349 | ac_cv_c_long_double=yes, ac_cv_c_long_double=no)]) |
| 350 | AC_MSG_RESULT($ac_cv_c_long_double) |
| 351 | if test $ac_cv_c_long_double = yes; then |
| 352 | AC_DEFINE(HAVE_LONG_DOUBLE) |
| 353 | fi |
| 354 | |
| 355 | dnl See if the compiler and runtime support printing long doubles |
| 356 | |
| 357 | AC_MSG_CHECKING(for long double support in printf) |
| 358 | AC_CACHE_VAL(gdb_cv_printf_has_long_double, |
| 359 | [AC_TRY_RUN([ |
| 360 | int main () { |
| 361 | char buf[16]; |
| 362 | long double f = 3.141592653; |
| 363 | sprintf (buf, "%Lg", f); |
| 364 | return (strncmp ("3.14159", buf, 7)); |
| 365 | }], |
| 366 | gdb_cv_printf_has_long_double=yes, |
| 367 | gdb_cv_printf_has_long_double=no, |
| 368 | gdb_cv_printf_has_long_double=no)]) |
| 369 | if test $gdb_cv_printf_has_long_double = yes; then |
| 370 | AC_DEFINE(PRINTF_HAS_LONG_DOUBLE) |
| 371 | fi |
| 372 | AC_MSG_RESULT($gdb_cv_printf_has_long_double) |
| 373 | |
| 374 | dnl See if the compiler and runtime support scanning long doubles |
| 375 | |
| 376 | AC_MSG_CHECKING(for long double support in scanf) |
| 377 | AC_CACHE_VAL(gdb_cv_scanf_has_long_double, |
| 378 | [AC_TRY_RUN([ |
| 379 | int main () { |
| 380 | char *buf = "3.141592653"; |
| 381 | long double f = 0; |
| 382 | sscanf (buf, "%Lg", &f); |
| 383 | return !(f > 3.14159 && f < 3.14160); |
| 384 | }], |
| 385 | gdb_cv_scanf_has_long_double=yes, |
| 386 | gdb_cv_scanf_has_long_double=no, |
| 387 | gdb_cv_scanf_has_long_double=no)]) |
| 388 | if test $gdb_cv_scanf_has_long_double = yes; then |
| 389 | AC_DEFINE(SCANF_HAS_LONG_DOUBLE) |
| 390 | fi |
| 391 | AC_MSG_RESULT($gdb_cv_scanf_has_long_double) |
| 392 | |
| 393 | AC_FUNC_MMAP |
| 394 | |
| 395 | dnl See if thread_db library is around for Solaris thread debugging. Note that |
| 396 | dnl we must explicitly test for version 1 of the library because version 0 |
| 397 | dnl (present on Solaris 2.4 or earlier) doesn't have the same API. |
| 398 | |
| 399 | dnl Note that we only want this if we are both native (host == target), and |
| 400 | dnl not doing a canadian cross build (build == host). |
| 401 | |
| 402 | if test ${build} = ${host} -a ${host} = ${target} ; then |
| 403 | case ${host_os} in |
| 404 | hpux*) |
| 405 | AC_MSG_CHECKING(for HPUX/OSF thread support) |
| 406 | if test -f /usr/include/dce/cma_config.h ; then |
| 407 | if test "$GCC" = "yes" ; then |
| 408 | AC_MSG_RESULT(yes) |
| 409 | AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT) |
| 410 | CONFIG_OBS="${CONFIG_OJS} hpux-thread.o" |
| 411 | CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c" |
| 412 | else |
| 413 | AC_MSG_RESULT(no (suppressed because you are not using GCC)) |
| 414 | fi |
| 415 | else |
| 416 | AC_MSG_RESULT(no) |
| 417 | fi |
| 418 | ;; |
| 419 | solaris*) |
| 420 | AC_MSG_CHECKING(for Solaris thread debugging library) |
| 421 | if test -f /usr/lib/libthread_db.so.1 ; then |
| 422 | AC_MSG_RESULT(yes) |
| 423 | AC_DEFINE(HAVE_THREAD_DB_LIB) |
| 424 | CONFIG_OBS="${CONFIG_OBS} sol-thread.o" |
| 425 | CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c" |
| 426 | AC_CHECK_LIB(dl, dlopen) |
| 427 | if test "$GCC" = "yes" ; then |
| 428 | # The GNU linker requires the -export-dynamic option to make |
| 429 | # all symbols visible in the dynamic symbol table. |
| 430 | hold_ldflags=$LDFLAGS |
| 431 | AC_MSG_CHECKING(for the ld -export-dynamic flag) |
| 432 | LDFLAGS="${LDFLAGS} -Wl,-export-dynamic" |
| 433 | AC_TRY_LINK(, [int i;], found=yes, found=no) |
| 434 | LDFLAGS=$hold_ldflags |
| 435 | AC_MSG_RESULT($found) |
| 436 | if test $found = yes; then |
| 437 | CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic" |
| 438 | fi |
| 439 | fi |
| 440 | # Sun randomly tweaked the prototypes in <proc_service.h> |
| 441 | # at one point. |
| 442 | AC_MSG_CHECKING(if <proc_service.h> is old) |
| 443 | AC_CACHE_VAL(gdb_cv_proc_service_is_old,[ |
| 444 | AC_TRY_COMPILE([ |
| 445 | #include <proc_service.h> |
| 446 | ps_err_e ps_pdwrite |
| 447 | (struct ps_prochandle*, psaddr_t, const void*, size_t); |
| 448 | ],, gdb_cv_proc_service_is_old=no, |
| 449 | gdb_cv_proc_service_is_old=yes) |
| 450 | ]) |
| 451 | AC_MSG_RESULT($gdb_cv_proc_service_is_old) |
| 452 | if test $gdb_cv_proc_service_is_old = yes; then |
| 453 | AC_DEFINE(PROC_SERVICE_IS_OLD) |
| 454 | fi |
| 455 | else |
| 456 | AC_MSG_RESULT(no) |
| 457 | fi |
| 458 | ;; |
| 459 | esac |
| 460 | AC_SUBST(CONFIG_LDFLAGS) |
| 461 | fi |
| 462 | |
| 463 | dnl The CLI cannot be disabled yet, but may be in the future |
| 464 | |
| 465 | dnl Handle CLI sub-directory configury. |
| 466 | AC_ARG_ENABLE(gdbcli, |
| 467 | [ --enable-gdbcli Enable GDB-CLI interface], |
| 468 | [ |
| 469 | case "${enable_gdbcli}" in |
| 470 | yes) ;; |
| 471 | "") enable_gdbcli=yes ;; |
| 472 | no) |
| 473 | AC_MSG_ERROR(The CLI cannot be disabled yet) |
| 474 | ;; |
| 475 | *) |
| 476 | AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval}) |
| 477 | ;; |
| 478 | esac |
| 479 | ], |
| 480 | [enable_gdbcli=yes]) |
| 481 | case ${enable_gdbcli} in |
| 482 | "yes" ) |
| 483 | if test -d "${srcdir}/mi" ; then |
| 484 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_CLI_OBS)" |
| 485 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_CLI_DEPS)" |
| 486 | CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_CLI_SRCS)" |
| 487 | CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_CLI_INITS)" |
| 488 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_CLI_CFLAGS)" |
| 489 | CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_CLI_ALL)" |
| 490 | CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_CLI_CLEAN)" |
| 491 | CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_CLI_INSTALL)" |
| 492 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_CLI_UNINSTALL)" |
| 493 | fi |
| 494 | ;; |
| 495 | esac |
| 496 | |
| 497 | dnl Handle optional features that can be enabled. |
| 498 | |
| 499 | dnl Handle MI sub-directory configury. |
| 500 | AC_ARG_ENABLE(gdbmi, |
| 501 | [ --enable-gdbmi Enable GDB-MI interface], |
| 502 | [ |
| 503 | case "${enable_gdbmi}" in |
| 504 | yes | no) ;; |
| 505 | "") enable_gdbmi=yes ;; |
| 506 | *) |
| 507 | AC_MSG_ERROR(Bad value for --enable-gdbmi: ${enableval}) |
| 508 | ;; |
| 509 | esac |
| 510 | ]) |
| 511 | case ${enable_gdbmi} in |
| 512 | "yes" ) |
| 513 | if test -d "${srcdir}/mi" ; then |
| 514 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_MI_OBS)" |
| 515 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_MI_DEPS)" |
| 516 | CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_MI_SRCS)" |
| 517 | CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_MI_INITS)" |
| 518 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_MI_CFLAGS)" |
| 519 | CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_MI_ALL)" |
| 520 | CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_MI_CLEAN)" |
| 521 | CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_MI_INSTALL)" |
| 522 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_MI_UNINSTALL)" |
| 523 | fi |
| 524 | ;; |
| 525 | esac |
| 526 | |
| 527 | AC_ARG_ENABLE(tui, |
| 528 | [ --enable-tui Enable full-screen terminal user interface], |
| 529 | [ |
| 530 | case "${enable_tui}" in |
| 531 | yes | no) ;; |
| 532 | "") enable_tui=yes ;; |
| 533 | *) |
| 534 | AC_MSG_ERROR(Bad value for --enable-tui: ${enableval}) |
| 535 | ;; |
| 536 | esac |
| 537 | ]) |
| 538 | case ${enable_tui} in |
| 539 | "yes" ) |
| 540 | if test -d "${srcdir}/tui" ; then |
| 541 | CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_TUI_OBS)" |
| 542 | CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_TUI_DEPS)" |
| 543 | CONFIG_SRCS="${CONFIG_SRS} \$(SUBDIR_TUI_SRCS)" |
| 544 | CONFIG_INITS="${CONFIG_INITS} \$(SUBDIR_TUI_INITS)" |
| 545 | ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_TUI_CFLAGS)" |
| 546 | CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_TUI_ALL)" |
| 547 | CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_TUI_CLEAN)" |
| 548 | CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_TUI_INSTALL)" |
| 549 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_TUI_UNINSTALL)" |
| 550 | fi |
| 551 | ;; |
| 552 | esac |
| 553 | |
| 554 | AC_ARG_ENABLE(netrom, |
| 555 | [ --enable-netrom Enable NetROM support], |
| 556 | [case "${enableval}" in |
| 557 | yes) enable_netrom=yes ;; |
| 558 | no) enable_netrom=no ;; |
| 559 | *) AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;; |
| 560 | esac]) |
| 561 | |
| 562 | if test "${enable_netrom}" = "yes"; then |
| 563 | CONFIG_OBS="${CONFIG_OBS} remote-nrom.o" |
| 564 | CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c" |
| 565 | fi |
| 566 | |
| 567 | |
| 568 | # NOTE: Don't add -Wall or -Wunused, they both include |
| 569 | # -Wunused-parameter which reports bogus warnings. |
| 570 | # NOTE: If you add to this list, remember to update |
| 571 | # gdb/doc/gdbint.texinfo. |
| 572 | build_warnings="-Wimplicit -Wreturn-type -Wcomment -Wtrigraphs \ |
| 573 | -Wformat -Wparentheses -Wpointer-arith -Wuninitialized" |
| 574 | # Up for debate: -Wswitch -Wcomment -trigraphs -Wtrigraphs |
| 575 | # -Wunused-function -Wunused-label -Wunused-variable -Wunused-value |
| 576 | # -Wchar-subscripts -Wuninitialized -Wtraditional -Wshadow -Wcast-qual |
| 577 | # -Wcast-align -Wwrite-strings -Wconversion -Wstrict-prototypes |
| 578 | # -Wmissing-prototypes -Wmissing-declarations -Wredundant-decls |
| 579 | # -Woverloaded-virtual -Winline -Werror" |
| 580 | AC_ARG_ENABLE(build-warnings, |
| 581 | [ --enable-build-warnings Enable build-time compiler warnings if gcc is used], |
| 582 | [case "${enableval}" in |
| 583 | yes) ;; |
| 584 | no) build_warnings="-w";; |
| 585 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 586 | build_warnings="${build_warnings} ${t}";; |
| 587 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 588 | build_warnings="${t} ${build_warnings}";; |
| 589 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 590 | esac |
| 591 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 592 | echo "Setting compiler warning flags = $build_warnings" 6>&1 |
| 593 | fi])dnl |
| 594 | AC_ARG_ENABLE(gdb-build-warnings, |
| 595 | [ --enable-gdb-build-warnings Enable GDB specific build-time compiler warnings if gcc is used], |
| 596 | [case "${enableval}" in |
| 597 | yes) ;; |
| 598 | no) build_warnings="-w";; |
| 599 | ,*) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 600 | build_warnings="${build_warnings} ${t}";; |
| 601 | *,) t=`echo "${enableval}" | sed -e "s/,/ /g"` |
| 602 | build_warnings="${t} ${build_warnings}";; |
| 603 | *) build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;; |
| 604 | esac |
| 605 | if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then |
| 606 | echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1 |
| 607 | fi])dnl |
| 608 | WARN_CFLAGS="" |
| 609 | WERROR_CFLAGS="" |
| 610 | if test "x${build_warnings}" != x -a "x$GCC" = xyes |
| 611 | then |
| 612 | AC_MSG_CHECKING(compiler warning flags) |
| 613 | # Separate out the -Werror flag as some files just cannot be |
| 614 | # compiled with it enabled. |
| 615 | for w in ${build_warnings}; do |
| 616 | case $w in |
| 617 | -Werr*) WERROR_CFLAGS=-Werror ;; |
| 618 | *) # Check that GCC accepts it |
| 619 | if $CC $w 2>&1 | grep 'unrecognized option' > /dev/null; then |
| 620 | : |
| 621 | else |
| 622 | WARN_CFLAGS="${WARN_CFLAGS} $w" |
| 623 | fi |
| 624 | esac |
| 625 | done |
| 626 | AC_MSG_RESULT(${WARN_CFLAGS}${WERROR_CFLAGS}) |
| 627 | fi |
| 628 | AC_SUBST(WARN_CFLAGS) |
| 629 | AC_SUBST(WERROR_CFLAGS) |
| 630 | |
| 631 | MMALLOC_CFLAGS= |
| 632 | MMALLOC= |
| 633 | AC_SUBST(MMALLOC_CFLAGS) |
| 634 | AC_SUBST(MMALLOC) |
| 635 | |
| 636 | AC_ARG_WITH(mmalloc, |
| 637 | [ --with-mmalloc Use memory mapped malloc package], |
| 638 | [case "${withval}" in |
| 639 | yes) want_mmalloc=true ;; |
| 640 | no) want_mmalloc=false;; |
| 641 | *) AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;; |
| 642 | esac],[want_mmalloc=false])dnl |
| 643 | |
| 644 | if test x$want_mmalloc = xtrue; then |
| 645 | AC_DEFINE(USE_MMALLOC) |
| 646 | AC_DEFINE(MMCHECK_FORCE) |
| 647 | MMALLOC_CFLAGS="-I$srcdir/../mmalloc" |
| 648 | MMALLOC='../mmalloc/libmmalloc.a' |
| 649 | fi |
| 650 | |
| 651 | AC_ARG_WITH(included-regex, |
| 652 | [ --with-included-regex Use included regex], |
| 653 | [case "${withval}" in |
| 654 | yes) want_included_regex=true ;; |
| 655 | no) want_included_regex=false;; |
| 656 | *) AC_MSG_ERROR(bad value ${withval} for GDB with-included-regex option) ;; |
| 657 | esac],[want_included_regex=true])dnl |
| 658 | |
| 659 | if test $want_included_regex = false; then |
| 660 | AC_MSG_CHECKING(for GNU regex) |
| 661 | AC_CACHE_VAL(gdb_cv_have_gnu_regex, |
| 662 | [AC_TRY_COMPILE([#include <gnu-versions.h> |
| 663 | #include <sys/types.h> |
| 664 | #include <regex.h>], |
| 665 | [#if !defined _GNU_REGEX_INTERFACE_VERSION || !defined __GLIBC__ || __GLIBC__ < 2 |
| 666 | #error No valid GNU regex. |
| 667 | #endif |
| 668 | ], |
| 669 | [gdb_cv_have_gnu_regex=yes], |
| 670 | [gdb_cv_have_gnu_regex=no])]) |
| 671 | AC_MSG_RESULT($gdb_cv_have_gnu_regex) |
| 672 | if test $gdb_cv_have_gnu_regex = no; then |
| 673 | want_included_regex=true |
| 674 | fi |
| 675 | fi |
| 676 | |
| 677 | if test x${want_included_regex} = xtrue; then |
| 678 | REGEX="gnu-regex.o" |
| 679 | AC_DEFINE(USE_INCLUDED_REGEX) |
| 680 | fi |
| 681 | AC_SUBST(REGEX) |
| 682 | |
| 683 | # In the Cygwin environment, we need some additional flags. |
| 684 | AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin, |
| 685 | [AC_EGREP_CPP(lose, [ |
| 686 | #if defined (__CYGWIN__) || defined (__CYGWIN32__) |
| 687 | lose |
| 688 | #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])]) |
| 689 | |
| 690 | |
| 691 | dnl Figure out which of the many generic ser-*.c files the _host_ supports. |
| 692 | SER_HARDWIRE="ser-unix.o ser-pipe.o ser-tcp.o" |
| 693 | case ${host} in |
| 694 | *go32* ) SER_HARDWIRE=ser-go32.o ;; |
| 695 | *djgpp* ) SER_HARDWIRE=ser-go32.o ;; |
| 696 | esac |
| 697 | AC_SUBST(SER_HARDWIRE) |
| 698 | |
| 699 | |
| 700 | dnl Figure out which term library to use. |
| 701 | if test x$gdb_host = xgo32; then |
| 702 | TERM_LIB= |
| 703 | else |
| 704 | if test x$gdb_cv_os_cygwin = xyes; then |
| 705 | TERM_LIB='`if test -r ../libtermcap/libtermcap.a; then echo ../libtermcap/libtermcap.a; else echo -ltermcap; fi`' |
| 706 | else |
| 707 | TERM_LIB= |
| 708 | AC_CHECK_LIB(ncurses, tgetent, TERM_LIB=-lncurses, |
| 709 | AC_CHECK_LIB(Hcurses, tgetent, TERM_LIB=-lHcurses, |
| 710 | AC_CHECK_LIB(termlib, tgetent, TERM_LIB=-ltermlib, |
| 711 | AC_CHECK_LIB(termcap, tgetent, TERM_LIB=-ltermcap, |
| 712 | AC_CHECK_LIB(curses, tgetent, TERM_LIB=-lcurses, |
| 713 | AC_CHECK_LIB(terminfo, tgetent, TERM_LIB=-lterminfo)))))) |
| 714 | |
| 715 | if test "x$TERM_LIB" = x |
| 716 | then |
| 717 | AC_MSG_ERROR(Could not find a term library, e.g. termcap or termlib!) |
| 718 | fi |
| 719 | fi |
| 720 | fi |
| 721 | AC_SUBST(TERM_LIB) |
| 722 | |
| 723 | # libreadline needs libuser32.a in a cygwin environment |
| 724 | WIN32LIBS= |
| 725 | if test x$gdb_cv_os_cygwin = xyes; then |
| 726 | WIN32LIBS="-luser32" |
| 727 | case "${target}" in |
| 728 | *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp" |
| 729 | ;; |
| 730 | esac |
| 731 | fi |
| 732 | AC_SUBST(WIN32LIBS) |
| 733 | |
| 734 | LIBGUI="../libgui/src/libgui.a" |
| 735 | GUI_CFLAGS_X="-I${srcdir}/../libgui/src" |
| 736 | AC_SUBST(LIBGUI) |
| 737 | AC_SUBST(GUI_CFLAGS_X) |
| 738 | |
| 739 | AC_ARG_WITH(cpu, |
| 740 | [ --with-cpu=CPU Set the default CPU variant to debug], |
| 741 | [case "${target}" in |
| 742 | powerpc-* | powerpcle-* ) |
| 743 | ## It would be nice to keep this table in sync with the one in |
| 744 | ## gcc/configure. |
| 745 | case "${with_cpu}" in |
| 746 | ppc-uisa | rs6000 | 403 | 403GC | 505 | 860 | 601 | 602 | 603 \ |
| 747 | | 604 | 750 ) |
| 748 | ## Those are all handled in variants in rs6000-tdep.c, so they're fine. |
| 749 | ;; |
| 750 | common | power | power2 | rios | rios1 | rios2 | rsc | rsc1 ) |
| 751 | ## These are all RS6000 variants, as far as GDB is concerned. |
| 752 | with_cpu=rs6000 |
| 753 | ;; |
| 754 | 603e | ec603e ) |
| 755 | with_cpu=603 |
| 756 | ;; |
| 757 | 604e ) |
| 758 | with_cpu=604 |
| 759 | ;; |
| 760 | * ) |
| 761 | AC_MSG_WARN(GDB: unknown --with-cpu value: \`${with_cpu}'; using \`ppc-uisa'.) |
| 762 | with_cpu=ppc-uisa |
| 763 | ;; |
| 764 | esac |
| 765 | ;; |
| 766 | * ) |
| 767 | AC_MSG_WARN(GDB may ignore the --with-cpu flag for ${target} targets) |
| 768 | ;; |
| 769 | esac |
| 770 | AC_DEFINE_UNQUOTED(TARGET_CPU_DEFAULT, "${with_cpu}") |
| 771 | ],) |
| 772 | |
| 773 | |
| 774 | AC_ARG_ENABLE(gdbtk, |
| 775 | [ --enable-gdbtk Enable GDBTK GUI front end], |
| 776 | [case "${enableval}" in |
| 777 | yes) |
| 778 | case "$host" in |
| 779 | *go32*) |
| 780 | AC_MSG_WARN([GDB does not support GDBtk on host ${host}. GDBtk will be disabled.]) |
| 781 | enable_gdbtk=no ;; |
| 782 | *windows*) |
| 783 | AC_MSG_WARN([GDB does not support GDBtk on host ${host}. GDBtk will be disabled.]) |
| 784 | enable_gdbtk=no ;; |
| 785 | *) |
| 786 | enable_gdbtk=yes ;; |
| 787 | esac ;; |
| 788 | no) |
| 789 | enable_gdbtk=no ;; |
| 790 | *) |
| 791 | AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;; |
| 792 | esac], |
| 793 | [ |
| 794 | # Default is on for everything but go32 and Cygwin |
| 795 | case "$host" in |
| 796 | *go32* | *windows*) |
| 797 | ;; |
| 798 | *) |
| 799 | if test -d "${srcdir}/gdbtk" ; then |
| 800 | enable_gdbtk=yes |
| 801 | fi |
| 802 | ;; |
| 803 | esac |
| 804 | ]) |
| 805 | |
| 806 | WIN32LDAPP= |
| 807 | AC_SUBST(WIN32LIBS) |
| 808 | AC_SUBST(WIN32LDAPP) |
| 809 | |
| 810 | configdir="unix" |
| 811 | |
| 812 | GDBTKLIBS= |
| 813 | if test "${enable_gdbtk}" = "yes"; then |
| 814 | |
| 815 | CY_AC_PATH_TCLCONFIG |
| 816 | if test -z "${no_tcl}"; then |
| 817 | CY_AC_LOAD_TCLCONFIG |
| 818 | CY_AC_PATH_TKCONFIG |
| 819 | |
| 820 | # If $no_tk is nonempty, then we can't do Tk, and there is no |
| 821 | # point to doing Tcl. |
| 822 | if test -z "${no_tk}"; then |
| 823 | CY_AC_LOAD_TKCONFIG |
| 824 | CY_AC_PATH_TCLH |
| 825 | CY_AC_PATH_TKH |
| 826 | CY_AC_PATH_ITCLH |
| 827 | CY_AC_PATH_ITKH |
| 828 | CY_AC_PATH_TIXH |
| 829 | |
| 830 | # now look for Itcl library stuff |
| 831 | |
| 832 | CY_AC_PATH_ITCLCONFIG |
| 833 | if test -z "${no_itcl}"; then |
| 834 | CY_AC_LOAD_ITCLCONFIG |
| 835 | case "${host}" in |
| 836 | *-*-cygwin*) |
| 837 | itcldir=../itcl/itcl/win/ |
| 838 | ;; |
| 839 | *) |
| 840 | itcldir=../itcl/itcl/unix/ |
| 841 | ;; |
| 842 | esac |
| 843 | |
| 844 | |
| 845 | ITCLLIB="${ITCL_BUILD_LIB_SPEC}" |
| 846 | ITCL_DEPS="${itcldir}${ITCL_LIB_FILE}" |
| 847 | fi |
| 848 | |
| 849 | |
| 850 | # now look for Itk library stuff |
| 851 | CY_AC_PATH_ITKCONFIG |
| 852 | if test -z "${no_itcl}"; then |
| 853 | CY_AC_LOAD_ITKCONFIG |
| 854 | |
| 855 | case "${host}" in |
| 856 | *-*-cygwin*) |
| 857 | itkdir=../itcl/itk/win/ |
| 858 | ;; |
| 859 | *) |
| 860 | itkdir=../itcl/itk/unix/ |
| 861 | ;; |
| 862 | esac |
| 863 | |
| 864 | ITKLIB="${ITK_BUILD_LIB_SPEC}" |
| 865 | ITK_DEPS="${itkdir}${ITK_LIB_FILE}" |
| 866 | fi |
| 867 | |
| 868 | # now look for Tix library stuff |
| 869 | CY_AC_PATH_TIXCONFIG |
| 870 | if test -z "${no_tix}"; then |
| 871 | CY_AC_LOAD_TIXCONFIG |
| 872 | TIXLIB="${TIX_BUILD_LIB_SPEC}" |
| 873 | TIX_DEPS="${TIX_BUILD_LOCATION}/${TIX_LIB_FILE}" |
| 874 | fi |
| 875 | |
| 876 | ENABLE_CFLAGS="$ENABLE_CFLAGS -DGDBTK" |
| 877 | # Tcl/Tk 8.1 require -fwritable strings. I don't |
| 878 | # know whether 8.2 will or not, but I bet it will. |
| 879 | # I don't have to worry about 7.x since we don't support it. |
| 880 | GDBTK_CFLAGS="" |
| 881 | if test "$GCC" = "yes"; then |
| 882 | if test "$TCL_VERSION" != "8.0" ; then |
| 883 | GDBTK_CFLAGS="-fwritable-strings" |
| 884 | fi |
| 885 | fi |
| 886 | |
| 887 | # Include some libraries that Tcl and Tk want. |
| 888 | TCL_LIBS='$(LIBGUI) $(ITCL) $(ITK) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)' |
| 889 | CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(ITK_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)' |
| 890 | # Yes, the ordering seems wrong here. But it isn't. |
| 891 | # TK_LIBS is the list of libraries that need to be linked |
| 892 | # after Tcl/Tk. Note that this isn't put into LIBS. If it |
| 893 | # were in LIBS then any link tests after this point would |
| 894 | # try to include things like `$(LIBGUI)', which wouldn't work. |
| 895 | GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}" |
| 896 | CONFIG_SRCS="${CONFIG_SRCS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c" |
| 897 | CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o gdbtk-varobj.o gdbtk-wrapper.o" |
| 898 | CONFIG_INITS="${CONFIG_INITS} gdbtk/generic/gdbtk.c gdbtk/generic/gdbtk-cmds.c gdbtk/generic/gdbtk-hooks.c gdbtk/generic/gdbtk-varobj.c gdbtk/generic/gdbtk-wrapper.c" |
| 899 | CONFIG_ALL="${CONFIG_ALL} \$(SUBDIR_GDBTK_ALL)" |
| 900 | CONFIG_CLEAN="${CONFIG_CLEAN} \$(SUBDIR_GDBTK_CLEAN)" |
| 901 | CONFIG_INSTALL="${CONFIG_INSTALL} \$(SUBDIR_GDBTK_INSTALL)" |
| 902 | CONFIG_UNINSTALL="${CONFIG_UNINSTALL} \$(SUBDIR_GDBTK_UNINSTALL)" |
| 903 | |
| 904 | if test x$gdb_cv_os_cygwin = xyes; then |
| 905 | WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32" |
| 906 | WIN32LDAPP="-Wl,--subsystem,console" |
| 907 | CONFIG_OBS="${CONFIG_OBS} gdbres.o" |
| 908 | fi |
| 909 | fi |
| 910 | fi |
| 911 | fi |
| 912 | |
| 913 | AC_SUBST(X_CFLAGS) |
| 914 | AC_SUBST(X_LDFLAGS) |
| 915 | AC_SUBST(X_LIBS) |
| 916 | AC_SUBST(ITCLLIB) |
| 917 | AC_SUBST(ITCL_DEPS) |
| 918 | AC_SUBST(ITKLIB) |
| 919 | AC_SUBST(ITK_DEPS) |
| 920 | AC_SUBST(TIXLIB) |
| 921 | AC_SUBST(TIX_DEPS) |
| 922 | AC_SUBST(GDBTKLIBS) |
| 923 | AC_SUBST(GDBTK_CFLAGS) |
| 924 | |
| 925 | AC_PATH_X |
| 926 | |
| 927 | |
| 928 | # Unlike the sim directory, whether a simulator is linked is controlled by |
| 929 | # presence of a SIM= and a SIM_OBS= definition in the target '.mt' file. |
| 930 | # This code just checks for a few cases where we'd like to ignore those |
| 931 | # definitions, even when they're present in the '.mt' file. These cases |
| 932 | # are when --disable-sim is specified, or if the simulator directory is |
| 933 | # not part of the soruce tree. |
| 934 | # |
| 935 | AC_ARG_ENABLE(sim, |
| 936 | [ --enable-sim Link gdb with simulator], |
| 937 | [echo "enable_sim = $enable_sim"; |
| 938 | echo "enableval = ${enableval}"; |
| 939 | case "${enableval}" in |
| 940 | yes) ignore_sim=false ;; |
| 941 | no) ignore_sim=true ;; |
| 942 | *) ignore_sim=false ;; |
| 943 | esac], |
| 944 | [ignore_sim=false]) |
| 945 | |
| 946 | if test ! -d "${srcdir}/../sim"; then |
| 947 | ignore_sim=true |
| 948 | fi |
| 949 | |
| 950 | if test "${ignore_sim}" = "true"; then |
| 951 | IGNORE_SIM="SIM=" |
| 952 | IGNORE_SIM_OBS="SIM_OBS=" |
| 953 | else |
| 954 | IGNORE_SIM="" |
| 955 | IGNORE_SIM_OBS="" |
| 956 | AC_DEFINE(WITH_SIM) |
| 957 | fi |
| 958 | AC_SUBST(IGNORE_SIM) |
| 959 | AC_SUBST(IGNORE_SIM_OBS) |
| 960 | |
| 961 | AC_SUBST(ENABLE_CFLAGS) |
| 962 | |
| 963 | AC_SUBST(CONFIG_OBS) |
| 964 | AC_SUBST(CONFIG_DEPS) |
| 965 | AC_SUBST(CONFIG_SRCS) |
| 966 | AC_SUBST(CONFIG_INITS) |
| 967 | AC_SUBST(CONFIG_ALL) |
| 968 | AC_SUBST(CONFIG_CLEAN) |
| 969 | AC_SUBST(CONFIG_INSTALL) |
| 970 | AC_SUBST(CONFIG_UNINSTALL) |
| 971 | |
| 972 | # Begin stuff to support --enable-shared |
| 973 | AC_ARG_ENABLE(shared, |
| 974 | [ --enable-shared Use shared libraries], |
| 975 | [case "${enableval}" in |
| 976 | yes) shared=true ;; |
| 977 | no) shared=false ;; |
| 978 | *) shared=true ;; |
| 979 | esac])dnl |
| 980 | |
| 981 | HLDFLAGS= |
| 982 | HLDENV= |
| 983 | # If we have shared libraries, try to set rpath reasonably. |
| 984 | if test "${shared}" = "true"; then |
| 985 | case "${host}" in |
| 986 | *-*-hpux*) |
| 987 | HLDFLAGS='-Wl,+s,+b,$(libdir)' |
| 988 | ;; |
| 989 | *-*-irix5* | *-*-irix6*) |
| 990 | HLDFLAGS='-Wl,-rpath,$(libdir)' |
| 991 | ;; |
| 992 | *-*-linux*aout*) |
| 993 | ;; |
| 994 | *-*-linux* | *-pc-linux-gnu*) |
| 995 | HLDFLAGS='-Wl,-rpath,$(libdir)' |
| 996 | ;; |
| 997 | *-*-solaris*) |
| 998 | HLDFLAGS='-R $(libdir)' |
| 999 | ;; |
| 1000 | *-*-sysv4*) |
| 1001 | HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;' |
| 1002 | ;; |
| 1003 | esac |
| 1004 | fi |
| 1005 | |
| 1006 | # On SunOS, if the linker supports the -rpath option, use it to |
| 1007 | # prevent ../bfd and ../opcodes from being included in the run time |
| 1008 | # search path. |
| 1009 | case "${host}" in |
| 1010 | *-*-sunos*) |
| 1011 | echo 'main () { }' > conftest.c |
| 1012 | ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t |
| 1013 | if grep 'unrecognized' conftest.t >/dev/null 2>&1; then |
| 1014 | : |
| 1015 | elif grep 'No such file' conftest.t >/dev/null 2>&1; then |
| 1016 | : |
| 1017 | elif grep 'do not mix' conftest.t >/dev/null 2>&1; then |
| 1018 | : |
| 1019 | elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then |
| 1020 | : |
| 1021 | elif test "${shared}" = "true"; then |
| 1022 | HLDFLAGS='-Wl,-rpath=$(libdir)' |
| 1023 | else |
| 1024 | HLDFLAGS='-Wl,-rpath=' |
| 1025 | fi |
| 1026 | rm -f conftest.t conftest.c conftest |
| 1027 | ;; |
| 1028 | esac |
| 1029 | AC_SUBST(HLDFLAGS) |
| 1030 | AC_SUBST(HLDENV) |
| 1031 | # End stuff to support --enable-shared |
| 1032 | |
| 1033 | # target_subdir is used by the testsuite to find the target libraries. |
| 1034 | target_subdir= |
| 1035 | if test "${host}" != "${target}"; then |
| 1036 | target_subdir="${target_alias}/" |
| 1037 | fi |
| 1038 | AC_SUBST(target_subdir) |
| 1039 | |
| 1040 | frags= |
| 1041 | host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh |
| 1042 | if test ! -f ${host_makefile_frag}; then |
| 1043 | AC_MSG_ERROR("*** Gdb does not support host ${host}") |
| 1044 | fi |
| 1045 | frags="$frags $host_makefile_frag" |
| 1046 | |
| 1047 | target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt |
| 1048 | if test ! -f ${target_makefile_frag}; then |
| 1049 | AC_MSG_ERROR("*** Gdb does not support target ${target}") |
| 1050 | fi |
| 1051 | frags="$frags $target_makefile_frag" |
| 1052 | |
| 1053 | AC_SUBST_FILE(host_makefile_frag) |
| 1054 | AC_SUBST_FILE(target_makefile_frag) |
| 1055 | AC_SUBST(frags) |
| 1056 | |
| 1057 | changequote(,)dnl |
| 1058 | hostfile=`sed -n ' |
| 1059 | s/XM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1060 | ' ${host_makefile_frag}` |
| 1061 | |
| 1062 | targetfile=`sed -n ' |
| 1063 | s/TM_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1064 | ' ${target_makefile_frag}` |
| 1065 | |
| 1066 | GDB_MULTI_ARCH=`sed -n ' |
| 1067 | s/GDB_MULTI_ARCH[ ]*=[ ]*\([^ ]*\)[ ]*/\1/p |
| 1068 | ' ${target_makefile_frag}` |
| 1069 | |
| 1070 | # these really aren't orthogonal true/false values of the same condition, |
| 1071 | # but shells are slow enough that I like to reuse the test conditions |
| 1072 | # whenever possible |
| 1073 | if test "${target}" = "${host}"; then |
| 1074 | nativefile=`sed -n ' |
| 1075 | s/NAT_FILE[ ]*=[ ]*\([^ ]*\)/\1/p |
| 1076 | ' ${host_makefile_frag}` |
| 1077 | # else |
| 1078 | # GDBserver is only useful in a "native" enviroment |
| 1079 | # configdirs=`echo $configdirs | sed 's/gdbserver//'` |
| 1080 | fi |
| 1081 | changequote([,]) |
| 1082 | |
| 1083 | # New targets should just set gdb_multi_arch=yes in configure.tgt. |
| 1084 | # Old targets being converted can either do that or set GDB_MULTI_ARCH |
| 1085 | # in the target specific makefile frag. Eventually gdb_multi_arch=yes |
| 1086 | # will be the default. |
| 1087 | if test x"${GDB_MULTI_ARCH}" = x ; then |
| 1088 | case "${gdb_multi_arch}" in |
| 1089 | yes ) GDB_MULTI_ARCH=GDB_MULTI_ARCH_PURE ;; |
| 1090 | no ) GDB_MULTI_ARCH=0 ;; |
| 1091 | 0|1|2 ) GDB_MULTI_ARCH=${gdb_multi_arch} ;; |
| 1092 | esac |
| 1093 | fi |
| 1094 | if test x"${GDB_MULTI_ARCH}" != x ; then |
| 1095 | AC_DEFINE_UNQUOTED(GDB_MULTI_ARCH, ${GDB_MULTI_ARCH}) |
| 1096 | fi |
| 1097 | # Warn the user when they use an old pratice |
| 1098 | case "${GDB_MULTI_ARCH}" in |
| 1099 | "" ) ;; |
| 1100 | 0 | GDB_MULTI_ARCH_PARTIAL | 1 | GDB_MULTI_ARCH_TM | 2 ) |
| 1101 | AC_MSG_WARN("GDB: Target is not pure multi-arch") ;; |
| 1102 | GDB_MULTI_ARCH_PURE ) |
| 1103 | if test x"${targetfile}" != x ; then |
| 1104 | AC_MSG_WARN("GDB: Ingoring TM_FILE in ${target_makefile_frag}") |
| 1105 | targetfile="" |
| 1106 | fi ;; |
| 1107 | *) AC_MSG_ERROR("GDB: Unknown GDB_MULTI_ARCH value ${GDB_MULTI_ARCH}");; |
| 1108 | esac |
| 1109 | |
| 1110 | |
| 1111 | SUBDIRS="doc testsuite nlm" |
| 1112 | if test "${enable_multi_ice}" = "yes"; then |
| 1113 | SUBDIRS="${SUBDIRS} multi-ice" |
| 1114 | fi |
| 1115 | |
| 1116 | AC_SUBST(SUBDIRS) |
| 1117 | |
| 1118 | # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile |
| 1119 | # (NAT_FILE) is not set in config/*/*.m[ht] files, we link to an empty |
| 1120 | # version. |
| 1121 | |
| 1122 | files= |
| 1123 | links= |
| 1124 | |
| 1125 | rm -f xm.h |
| 1126 | xm_h="" |
| 1127 | if test "${hostfile}" != ""; then |
| 1128 | xm_h=xm.h |
| 1129 | GDB_XM_FILE="config/${gdb_host_cpu}/${hostfile}" |
| 1130 | files="${files} ${GDB_XM_FILE}" |
| 1131 | links="${links} xm.h" |
| 1132 | AC_DEFINE_UNQUOTED(GDB_XM_FILE, ${GDB_XM_FILE}) |
| 1133 | fi |
| 1134 | AC_SUBST(xm_h) |
| 1135 | |
| 1136 | rm -f tm.h |
| 1137 | tm_h="" |
| 1138 | if test "${targetfile}" != ""; then |
| 1139 | tm_h=tm.h |
| 1140 | GDB_TM_FILE="config/${gdb_target_cpu}/${targetfile}" |
| 1141 | files="${files} ${GDB_TM_FILE}" |
| 1142 | links="${links} tm.h" |
| 1143 | AC_DEFINE_UNQUOTED(GDB_TM_FILE, ${GDB_TM_FILE}) |
| 1144 | fi |
| 1145 | AC_SUBST(tm_h) |
| 1146 | |
| 1147 | rm -f nm.h |
| 1148 | nm_h="" |
| 1149 | if test "${nativefile}" != ""; then |
| 1150 | nm_h=nm.h |
| 1151 | GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" |
| 1152 | files="${files} ${GDB_NM_FILE}" |
| 1153 | links="${links} nm.h" |
| 1154 | AC_DEFINE_UNQUOTED(GDB_NM_FILE, ${GDB_NM_FILE}) |
| 1155 | fi |
| 1156 | AC_SUBST(nm_h) |
| 1157 | |
| 1158 | AC_PROG_LN_S |
| 1159 | |
| 1160 | AC_LINK_FILES($files, $links) |
| 1161 | |
| 1162 | dnl Check for exe extension set on certain hosts (e.g. Win32) |
| 1163 | AC_EXEEXT |
| 1164 | |
| 1165 | AC_CONFIG_SUBDIRS($configdirs) |
| 1166 | AC_OUTPUT(Makefile .gdbinit:gdbinit.in, |
| 1167 | [ |
| 1168 | dnl Autoconf doesn't provide a mechanism for modifying definitions |
| 1169 | dnl provided by makefile fragments. |
| 1170 | dnl |
| 1171 | if test "${nativefile}" = ""; then |
| 1172 | sed -e '/^NATDEPFILES[[ ]]*=[[ ]]*/s//# NATDEPFILES=/' \ |
| 1173 | < Makefile > Makefile.tem |
| 1174 | mv -f Makefile.tem Makefile |
| 1175 | fi |
| 1176 | |
| 1177 | changequote(,)dnl |
| 1178 | sed -e '/^TM_FILE[ ]*=/s,^TM_FILE[ ]*=[ ]*,&config/'"${gdb_target_cpu}"'/, |
| 1179 | /^XM_FILE[ ]*=/s,^XM_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/, |
| 1180 | /^NAT_FILE[ ]*=/s,^NAT_FILE[ ]*=[ ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp |
| 1181 | mv -f Makefile.tmp Makefile |
| 1182 | changequote([,])dnl |
| 1183 | |
| 1184 | |
| 1185 | case x$CONFIG_HEADERS in |
| 1186 | xconfig.h:config.in) |
| 1187 | echo > stamp-h ;; |
| 1188 | esac |
| 1189 | ], |
| 1190 | [ |
| 1191 | gdb_host_cpu=$gdb_host_cpu |
| 1192 | gdb_target_cpu=$gdb_target_cpu |
| 1193 | nativefile=$nativefile |
| 1194 | ]) |
| 1195 | |
| 1196 | exit 0 |