| 1 | dnl Autoconf configure script for GDB server. |
| 2 | dnl Copyright (C) 2000-2017 Free Software Foundation, Inc. |
| 3 | dnl |
| 4 | dnl This file is part of GDB. |
| 5 | dnl |
| 6 | dnl This program is free software; you can redistribute it and/or modify |
| 7 | dnl it under the terms of the GNU General Public License as published by |
| 8 | dnl the Free Software Foundation; either version 3 of the License, or |
| 9 | dnl (at your option) any later version. |
| 10 | dnl |
| 11 | dnl This program is distributed in the hope that it will be useful, |
| 12 | dnl but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 13 | dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 14 | dnl GNU General Public License for more details. |
| 15 | dnl |
| 16 | dnl You should have received a copy of the GNU General Public License |
| 17 | dnl along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 18 | |
| 19 | dnl Process this file with autoconf to produce a configure script. |
| 20 | |
| 21 | AC_PREREQ(2.59)dnl |
| 22 | |
| 23 | AC_INIT(server.c) |
| 24 | AC_CONFIG_HEADER(config.h:config.in) |
| 25 | |
| 26 | AM_MAINTAINER_MODE |
| 27 | |
| 28 | AC_PROG_CC |
| 29 | AC_PROG_CXX |
| 30 | AC_GNU_SOURCE |
| 31 | AC_SYS_LARGEFILE |
| 32 | |
| 33 | AC_CANONICAL_SYSTEM |
| 34 | |
| 35 | AC_PROG_INSTALL |
| 36 | AC_CHECK_TOOL(AR, ar) |
| 37 | AC_PROG_RANLIB |
| 38 | |
| 39 | AC_ARG_PROGRAM |
| 40 | |
| 41 | # We require a C++11 compiler. Check if one is available, and if |
| 42 | # necessary, set CXX_DIALECT to some -std=xxx switch. |
| 43 | AX_CXX_COMPILE_STDCXX(11, , mandatory) |
| 44 | |
| 45 | AC_HEADER_STDC |
| 46 | |
| 47 | # Set the 'development' global. |
| 48 | . $srcdir/../../bfd/development.sh |
| 49 | |
| 50 | # Enable -lmcheck by default (it provides cheap-enough memory |
| 51 | # mangling), but turn it off for releases. |
| 52 | if $development; then |
| 53 | libmcheck_default=yes |
| 54 | else |
| 55 | libmcheck_default=no |
| 56 | fi |
| 57 | GDB_AC_LIBMCHECK(${libmcheck_default}) |
| 58 | |
| 59 | if $development; then |
| 60 | AC_DEFINE(GDB_SELF_TEST, 1, |
| 61 | [Define if self-testing features should be enabled]) |
| 62 | fi |
| 63 | |
| 64 | ACX_NONCANONICAL_TARGET |
| 65 | ACX_NONCANONICAL_HOST |
| 66 | |
| 67 | # Dependency checking. |
| 68 | ZW_CREATE_DEPDIR |
| 69 | |
| 70 | # Create sub-directories for objects and dependencies. |
| 71 | CONFIG_SRC_SUBDIR="arch" |
| 72 | AC_SUBST(CONFIG_SRC_SUBDIR) |
| 73 | |
| 74 | AC_CONFIG_COMMANDS([gdbdepdir],[ |
| 75 | for subdir in ${CONFIG_SRC_SUBDIR} |
| 76 | do |
| 77 | $SHELL $ac_aux_dir/mkinstalldirs $subdir/$DEPDIR |
| 78 | done], |
| 79 | [ac_aux_dir=$ac_aux_dir DEPDIR=$DEPDIR CONFIG_SRC_SUBDIR="$CONFIG_SRC_SUBDIR"]) |
| 80 | |
| 81 | ZW_PROG_COMPILER_DEPENDENCIES([CC]) |
| 82 | |
| 83 | gnulib_extra_configure_args= |
| 84 | # If large-file support is disabled, make sure gnulib does the same. |
| 85 | if test "$enable_largefile" = no; then |
| 86 | gnulib_extra_configure_args="$gnulib_extra_configure_args --disable-largefile" |
| 87 | fi |
| 88 | |
| 89 | # Configure gnulib. We can't use AC_CONFIG_SUBDIRS as that'd expect |
| 90 | # to find the the source subdir to be configured directly under |
| 91 | # gdbserver/. We need to build gnulib under some other directory not |
| 92 | # "gnulib", to avoid the problem of both GDB and GDBserver wanting to |
| 93 | # build it in the same directory, when building in the source dir. |
| 94 | ACX_CONFIGURE_DIR(["../gnulib"], ["build-gnulib-gdbserver"], |
| 95 | ["$gnulib_extra_configure_args"]) |
| 96 | |
| 97 | ACX_CONFIGURE_DIR(["../../libiberty"], ["build-libiberty-gdbserver"]) |
| 98 | |
| 99 | AC_CHECK_HEADERS(termios.h sys/reg.h string.h dnl |
| 100 | proc_service.h sys/procfs.h linux/elf.h dnl |
| 101 | fcntl.h signal.h sys/file.h dnl |
| 102 | sys/ioctl.h netinet/in.h sys/socket.h netdb.h dnl |
| 103 | netinet/tcp.h arpa/inet.h) |
| 104 | AC_FUNC_FORK |
| 105 | AC_CHECK_FUNCS(getauxval pread pwrite pread64 setns) |
| 106 | |
| 107 | GDB_AC_COMMON |
| 108 | |
| 109 | # Check the return and argument types of ptrace. |
| 110 | GDB_AC_PTRACE |
| 111 | |
| 112 | # Check for UST |
| 113 | ustlibs="" |
| 114 | ustinc="" |
| 115 | |
| 116 | AC_ARG_WITH(ust, [ --with-ust=PATH Specify prefix directory for the installed UST package |
| 117 | Equivalent to --with-ust-include=PATH/include |
| 118 | plus --with-ust-lib=PATH/lib]) |
| 119 | AC_ARG_WITH(ust_include, [ --with-ust-include=PATH Specify directory for installed UST include files]) |
| 120 | AC_ARG_WITH(ust_lib, [ --with-ust-lib=PATH Specify the directory for the installed UST library]) |
| 121 | |
| 122 | case $with_ust in |
| 123 | no) |
| 124 | ustlibs= |
| 125 | ustinc= |
| 126 | ;; |
| 127 | "" | yes) |
| 128 | ustlibs=" -lust " |
| 129 | ustinc="" |
| 130 | ;; |
| 131 | *) |
| 132 | ustlibs="-L$with_ust/lib -lust" |
| 133 | ustinc="-I$with_ust/include " |
| 134 | ;; |
| 135 | esac |
| 136 | if test "x$with_ust_include" != x; then |
| 137 | ustinc="-I$with_ust_include " |
| 138 | fi |
| 139 | if test "x$with_ust_lib" != x; then |
| 140 | ustlibs="-L$with_ust_lib -lust" |
| 141 | fi |
| 142 | |
| 143 | if test "x$with_ust" != "xno"; then |
| 144 | saved_CFLAGS="$CFLAGS" |
| 145 | CFLAGS="$CFLAGS $ustinc" |
| 146 | AC_MSG_CHECKING([for ust]) |
| 147 | AC_TRY_COMPILE([ |
| 148 | #define CONFIG_UST_GDB_INTEGRATION |
| 149 | #include <ust/ust.h> |
| 150 | ],[], |
| 151 | [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_UST, 1, [Define if UST is available])], |
| 152 | [AC_MSG_RESULT([no]); ustlibs= ; ustinc= ]) |
| 153 | CFLAGS="$saved_CFLAGS" |
| 154 | fi |
| 155 | |
| 156 | # Flags needed for UST |
| 157 | AC_SUBST(ustlibs) |
| 158 | AC_SUBST(ustinc) |
| 159 | |
| 160 | AM_GDB_WARNINGS |
| 161 | dnl The codebase isn't clean yet with this flag. |
| 162 | case " $WARN_CFLAGS " in |
| 163 | *" -Wmissing-prototypes "*) |
| 164 | WARN_CFLAGS="$WARN_CFLAGS -Wno-missing-prototypes" |
| 165 | ;; |
| 166 | esac |
| 167 | |
| 168 | dnl dladdr is glibc-specific. It is used by thread-db.c but only for |
| 169 | dnl debugging messages. It lives in -ldl which is handled below so we don't |
| 170 | dnl use AC_CHECK_LIB (or AC_SEARCH_LIBS) here. Instead we just temporarily |
| 171 | dnl augment LIBS. |
| 172 | old_LIBS="$LIBS" |
| 173 | LIBS="$LIBS -ldl" |
| 174 | AC_CHECK_FUNCS(dladdr) |
| 175 | LIBS="$old_LIBS" |
| 176 | |
| 177 | libiberty_INIT |
| 178 | |
| 179 | AC_CHECK_DECLS([strerror, perror, vasprintf, vsnprintf]) |
| 180 | |
| 181 | AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize]) |
| 182 | |
| 183 | # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers. |
| 184 | # Older amd64 Linux's don't have the fs_base and gs_base members of |
| 185 | # `struct user_regs_struct'. |
| 186 | AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base], |
| 187 | [], [], [#include <sys/user.h>]) |
| 188 | |
| 189 | |
| 190 | AC_CHECK_TYPES(socklen_t, [], [], |
| 191 | [#include <sys/types.h> |
| 192 | #include <sys/socket.h> |
| 193 | ]) |
| 194 | |
| 195 | case "${target}" in |
| 196 | *-android*) |
| 197 | # Starting with NDK version 9, <elf.h> actually includes definitions |
| 198 | # of Elf32_auxv_t and Elf64_auxv_t. But sadly, <elf.h> includes |
| 199 | # <sys/exec_elf.h> which defines some of the ELF types incorrectly, |
| 200 | # leading to conflicts with the defintions from <linux/elf.h>. |
| 201 | # This makes it impossible for us to include both <elf.h> and |
| 202 | # <linux/elf.h>, which means that, in practice, we do not have |
| 203 | # access to Elf32_auxv_t and Elf64_auxv_t on this platform. |
| 204 | # Therefore, do not try to auto-detect availability, as it would |
| 205 | # get it wrong on this platform. |
| 206 | ;; |
| 207 | *) |
| 208 | AC_CHECK_TYPES([Elf32_auxv_t, Elf64_auxv_t], [], [], |
| 209 | #include <elf.h> |
| 210 | ) |
| 211 | esac |
| 212 | |
| 213 | ACX_PKGVERSION([GDB]) |
| 214 | ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/]) |
| 215 | AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description]) |
| 216 | AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address]) |
| 217 | |
| 218 | # Check for various supplementary target information (beyond the |
| 219 | # triplet) which might affect the choices in configure.srv. |
| 220 | case "${target}" in |
| 221 | changequote(,)dnl |
| 222 | i[34567]86-*-linux*) |
| 223 | changequote([,])dnl |
| 224 | AC_CACHE_CHECK([if building for x86-64], [gdb_cv_i386_is_x86_64], |
| 225 | [save_CPPFLAGS="$CPPFLAGS" |
| 226 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 227 | AC_EGREP_CPP([got it], [ |
| 228 | #if __x86_64__ |
| 229 | got it |
| 230 | #endif |
| 231 | ], [gdb_cv_i386_is_x86_64=yes], |
| 232 | [gdb_cv_i386_is_x86_64=no]) |
| 233 | CPPFLAGS="$save_CPPFLAGS"]) |
| 234 | ;; |
| 235 | |
| 236 | x86_64-*-linux*) |
| 237 | AC_CACHE_CHECK([if building for x32], [gdb_cv_x86_is_x32], |
| 238 | [save_CPPFLAGS="$CPPFLAGS" |
| 239 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 240 | AC_EGREP_CPP([got it], [ |
| 241 | #if __x86_64__ && __ILP32__ |
| 242 | got it |
| 243 | #endif |
| 244 | ], [gdb_cv_x86_is_x32=yes], |
| 245 | [gdb_cv_x86_is_x32=no]) |
| 246 | CPPFLAGS="$save_CPPFLAGS"]) |
| 247 | ;; |
| 248 | |
| 249 | m68k-*-*) |
| 250 | AC_CACHE_CHECK([if building for Coldfire], [gdb_cv_m68k_is_coldfire], |
| 251 | [save_CPPFLAGS="$CPPFLAGS" |
| 252 | CPPFLAGS="$CPPFLAGS $CFLAGS" |
| 253 | AC_EGREP_CPP([got it], [ |
| 254 | #ifdef __mcoldfire__ |
| 255 | got it |
| 256 | #endif |
| 257 | ], [gdb_cv_m68k_is_coldfire=yes], |
| 258 | [gdb_cv_m68k_is_coldfire=no]) |
| 259 | CPPFLAGS="$save_CPPFLAGS"]) |
| 260 | ;; |
| 261 | esac |
| 262 | |
| 263 | . ${srcdir}/configure.srv |
| 264 | |
| 265 | # Add in the common host objects. |
| 266 | . ${srcdir}/../common/common.host |
| 267 | srv_host_obs="$common_host_obs" |
| 268 | |
| 269 | if test "${srv_mingwce}" = "yes"; then |
| 270 | LIBS="$LIBS -lws2" |
| 271 | elif test "${srv_mingw}" = "yes"; then |
| 272 | LIBS="$LIBS -lws2_32" |
| 273 | elif test "${srv_qnx}" = "yes"; then |
| 274 | LIBS="$LIBS -lsocket" |
| 275 | elif test "${srv_lynxos}" = "yes"; then |
| 276 | LIBS="$LIBS -lnetinet" |
| 277 | fi |
| 278 | |
| 279 | if test "${srv_mingw}" = "yes"; then |
| 280 | AC_DEFINE(USE_WIN32API, 1, |
| 281 | [Define if we should use the Windows API, instead of the |
| 282 | POSIX API. On Windows, we use the Windows API when |
| 283 | building for MinGW, but the POSIX API when building |
| 284 | for Cygwin.]) |
| 285 | fi |
| 286 | |
| 287 | if test "${srv_linux_usrregs}" = "yes"; then |
| 288 | AC_DEFINE(HAVE_LINUX_USRREGS, 1, |
| 289 | [Define if the target supports PTRACE_PEEKUSR for register ] |
| 290 | [access.]) |
| 291 | fi |
| 292 | |
| 293 | if test "${srv_linux_regsets}" = "yes"; then |
| 294 | AC_DEFINE(HAVE_LINUX_REGSETS, 1, |
| 295 | [Define if the target supports register sets.]) |
| 296 | |
| 297 | AC_MSG_CHECKING(for PTRACE_GETREGS) |
| 298 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getregs, |
| 299 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 300 | [PTRACE_GETREGS;], |
| 301 | [gdbsrv_cv_have_ptrace_getregs=yes], |
| 302 | [gdbsrv_cv_have_ptrace_getregs=no])]) |
| 303 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getregs) |
| 304 | if test "${gdbsrv_cv_have_ptrace_getregs}" = "yes"; then |
| 305 | AC_DEFINE(HAVE_PTRACE_GETREGS, 1, |
| 306 | [Define if the target supports PTRACE_GETREGS for register ] |
| 307 | [access.]) |
| 308 | fi |
| 309 | |
| 310 | AC_MSG_CHECKING(for PTRACE_GETFPXREGS) |
| 311 | AC_CACHE_VAL(gdbsrv_cv_have_ptrace_getfpxregs, |
| 312 | [AC_TRY_COMPILE([#include <sys/ptrace.h>], |
| 313 | [PTRACE_GETFPXREGS;], |
| 314 | [gdbsrv_cv_have_ptrace_getfpxregs=yes], |
| 315 | [gdbsrv_cv_have_ptrace_getfpxregs=no])]) |
| 316 | AC_MSG_RESULT($gdbsrv_cv_have_ptrace_getfpxregs) |
| 317 | if test "${gdbsrv_cv_have_ptrace_getfpxregs}" = "yes"; then |
| 318 | AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1, |
| 319 | [Define if the target supports PTRACE_GETFPXREGS for extended ] |
| 320 | [register access.]) |
| 321 | fi |
| 322 | fi |
| 323 | |
| 324 | if test "${srv_linux_btrace}" = "yes"; then |
| 325 | AC_DEFINE(HAVE_LINUX_BTRACE, 1, |
| 326 | [Define if the target supports branch tracing.]) |
| 327 | fi |
| 328 | |
| 329 | if test "$ac_cv_header_sys_procfs_h" = yes; then |
| 330 | BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t) |
| 331 | BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t) |
| 332 | BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t) |
| 333 | BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t) |
| 334 | BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t) |
| 335 | fi |
| 336 | |
| 337 | dnl Some systems (e.g., Android) have lwpid_t defined in libthread_db.h. |
| 338 | if test "$bfd_cv_have_sys_procfs_type_lwpid_t" != yes; then |
| 339 | GDBSERVER_HAVE_THREAD_DB_TYPE(lwpid_t) |
| 340 | fi |
| 341 | |
| 342 | dnl Some systems (e.g., Android) have psaddr_t defined in libthread_db.h. |
| 343 | if test "$bfd_cv_have_sys_procfs_type_psaddr_t" != yes; then |
| 344 | GDBSERVER_HAVE_THREAD_DB_TYPE(psaddr_t) |
| 345 | fi |
| 346 | |
| 347 | dnl Check for libdl, but do not add it to LIBS as only gdbserver |
| 348 | dnl needs it (and gdbreplay doesn't). |
| 349 | old_LIBS="$LIBS" |
| 350 | AC_CHECK_LIB(dl, dlopen) |
| 351 | LIBS="$old_LIBS" |
| 352 | |
| 353 | srv_thread_depfiles= |
| 354 | srv_libs= |
| 355 | |
| 356 | if test "$srv_linux_thread_db" = "yes"; then |
| 357 | if test "$ac_cv_lib_dl_dlopen" = "yes"; then |
| 358 | srv_libs="-ldl" |
| 359 | AC_MSG_CHECKING(for the dynamic export flag) |
| 360 | old_LDFLAGS="$LDFLAGS" |
| 361 | # Older GNU ld supports --export-dynamic but --dynamic-list may not be |
| 362 | # supported there. |
| 363 | RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list" |
| 364 | LDFLAGS="$LDFLAGS $RDYNAMIC" |
| 365 | AC_TRY_LINK([], [], |
| 366 | [found="-Wl,--dynamic-list" |
| 367 | RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'], |
| 368 | [RDYNAMIC="-rdynamic" |
| 369 | LDFLAGS="$old_LDFLAGS $RDYNAMIC" |
| 370 | AC_TRY_LINK([], [], |
| 371 | [found="-rdynamic"], |
| 372 | [found="no" |
| 373 | RDYNAMIC=""])]) |
| 374 | AC_SUBST(RDYNAMIC) |
| 375 | LDFLAGS="$old_LDFLAGS" |
| 376 | AC_MSG_RESULT($found) |
| 377 | else |
| 378 | srv_libs="-lthread_db" |
| 379 | fi |
| 380 | |
| 381 | srv_thread_depfiles="thread-db.o proc-service.o" |
| 382 | AC_DEFINE(USE_THREAD_DB, 1, [Define if we should use libthread_db.]) |
| 383 | AC_CACHE_CHECK([for TD_VERSION], gdbsrv_cv_have_td_version, |
| 384 | [AC_TRY_COMPILE([#include <thread_db.h>], [TD_VERSION;], |
| 385 | [gdbsrv_cv_have_td_version=yes], |
| 386 | [gdbsrv_cv_have_td_version=no])]) |
| 387 | if test $gdbsrv_cv_have_td_version = yes; then |
| 388 | AC_DEFINE(HAVE_TD_VERSION, 1, [Define if TD_VERSION is available.]) |
| 389 | fi |
| 390 | fi |
| 391 | |
| 392 | AC_ARG_WITH(libthread-db, |
| 393 | AS_HELP_STRING([--with-libthread-db=PATH], [use given libthread_db directly]), |
| 394 | [srv_libthread_db_path="${withval}" |
| 395 | srv_libs="$srv_libthread_db_path" |
| 396 | ]) |
| 397 | |
| 398 | if test "$srv_libs" != "" -a "$srv_libs" != "-ldl"; then |
| 399 | AC_DEFINE(USE_LIBTHREAD_DB_DIRECTLY, 1, [Define if we should use libthread_db directly.]) |
| 400 | fi |
| 401 | |
| 402 | if test "$srv_xmlfiles" != ""; then |
| 403 | srv_xmlbuiltin="xml-builtin.o" |
| 404 | AC_DEFINE(USE_XML, 1, [Define if an XML target description is available.]) |
| 405 | |
| 406 | tmp_xmlfiles=$srv_xmlfiles |
| 407 | srv_xmlfiles="" |
| 408 | for f in $tmp_xmlfiles; do |
| 409 | srv_xmlfiles="$srv_xmlfiles \$(XML_DIR)/$f" |
| 410 | done |
| 411 | fi |
| 412 | |
| 413 | GDBSERVER_DEPFILES="$srv_regobj $srv_tgtobj $srv_hostio_err_objs $srv_thread_depfiles $srv_host_obs" |
| 414 | GDBSERVER_LIBS="$srv_libs" |
| 415 | |
| 416 | dnl Check whether the target supports __sync_*_compare_and_swap. |
| 417 | AC_CACHE_CHECK([whether the target supports __sync_*_compare_and_swap], |
| 418 | gdbsrv_cv_have_sync_builtins, [ |
| 419 | AC_TRY_LINK([], [int foo, bar; bar = __sync_val_compare_and_swap(&foo, 0, 1);], |
| 420 | gdbsrv_cv_have_sync_builtins=yes, |
| 421 | gdbsrv_cv_have_sync_builtins=no)]) |
| 422 | if test $gdbsrv_cv_have_sync_builtins = yes; then |
| 423 | AC_DEFINE(HAVE_SYNC_BUILTINS, 1, |
| 424 | [Define to 1 if the target supports __sync_*_compare_and_swap]) |
| 425 | fi |
| 426 | |
| 427 | dnl Check for -fvisibility=hidden support in the compiler. |
| 428 | saved_cflags="$CFLAGS" |
| 429 | CFLAGS="$CFLAGS -fvisibility=hidden" |
| 430 | AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), |
| 431 | [gdbsrv_cv_have_visibility_hidden=yes], |
| 432 | [gdbsrv_cv_have_visibility_hidden=no]) |
| 433 | CFLAGS="$saved_cflags" |
| 434 | |
| 435 | dnl Check if we can disable the virtual address space randomization. |
| 436 | dnl The functionality of setarch -R. |
| 437 | AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>]) |
| 438 | define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [ |
| 439 | # if !HAVE_DECL_ADDR_NO_RANDOMIZE |
| 440 | # define ADDR_NO_RANDOMIZE 0x0040000 |
| 441 | # endif |
| 442 | /* Test the flag could be set and stays set. */ |
| 443 | personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE); |
| 444 | if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE)) |
| 445 | return 1])]) |
| 446 | AC_RUN_IFELSE([PERSONALITY_TEST], |
| 447 | [gdbsrv_cv_have_personality=true], |
| 448 | [gdbsrv_cv_have_personality=false], |
| 449 | [AC_LINK_IFELSE([PERSONALITY_TEST], |
| 450 | [gdbsrv_cv_have_personality=true], |
| 451 | [gdbsrv_cv_have_personality=false])]) |
| 452 | if $gdbsrv_cv_have_personality |
| 453 | then |
| 454 | AC_DEFINE([HAVE_PERSONALITY], 1, |
| 455 | [Define if you support the personality syscall.]) |
| 456 | fi |
| 457 | |
| 458 | |
| 459 | IPA_DEPFILES="" |
| 460 | extra_libraries="" |
| 461 | |
| 462 | # check whether to enable the inprocess agent |
| 463 | if test "$ipa_obj" != "" \ |
| 464 | -a "$gdbsrv_cv_have_sync_builtins" = yes \ |
| 465 | -a "$gdbsrv_cv_have_visibility_hidden" = yes; then |
| 466 | have_ipa=true |
| 467 | else |
| 468 | have_ipa=false |
| 469 | fi |
| 470 | |
| 471 | AC_ARG_ENABLE(inprocess-agent, |
| 472 | AS_HELP_STRING([--enable-inprocess-agent], [inprocess agent]), |
| 473 | [case "$enableval" in |
| 474 | yes) want_ipa=true ;; |
| 475 | no) want_ipa=false ;; |
| 476 | *) AC_MSG_ERROR([bad value $enableval for inprocess-agent]) ;; |
| 477 | esac], |
| 478 | [want_ipa=$have_ipa]) |
| 479 | |
| 480 | if $want_ipa ; then |
| 481 | if $have_ipa ; then |
| 482 | IPA_DEPFILES="$ipa_obj" |
| 483 | extra_libraries="$extra_libraries libinproctrace.so" |
| 484 | else |
| 485 | AC_MSG_ERROR([inprocess agent not supported for this target]) |
| 486 | fi |
| 487 | fi |
| 488 | |
| 489 | AC_SUBST(GDBSERVER_DEPFILES) |
| 490 | AC_SUBST(GDBSERVER_LIBS) |
| 491 | AC_SUBST(srv_xmlbuiltin) |
| 492 | AC_SUBST(srv_xmlfiles) |
| 493 | AC_SUBST(IPA_DEPFILES) |
| 494 | AC_SUBST(extra_libraries) |
| 495 | |
| 496 | GNULIB=build-gnulib-gdbserver/import |
| 497 | |
| 498 | GNULIB_STDINT_H= |
| 499 | if test x"$STDINT_H" != x; then |
| 500 | GNULIB_STDINT_H=$GNULIB/$STDINT_H |
| 501 | fi |
| 502 | AC_SUBST(GNULIB_STDINT_H) |
| 503 | |
| 504 | AC_CONFIG_FILES([Makefile], |
| 505 | [case x$CONFIG_HEADERS in |
| 506 | xconfig.h:config.in) |
| 507 | echo > stamp-h ;; |
| 508 | esac |
| 509 | ]) |
| 510 | |
| 511 | AC_OUTPUT |