| 1 | # Copyright 1999, 2000, 2002, 2003, 2004, 2005 Free Software Foundation, Inc. |
| 2 | |
| 3 | # This program is free software; you can redistribute it and/or modify |
| 4 | # it under the terms of the GNU General Public License as published by |
| 5 | # the Free Software Foundation; either version 2 of the License, or |
| 6 | # (at your option) any later version. |
| 7 | # |
| 8 | # This program is distributed in the hope that it will be useful, |
| 9 | # but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 10 | # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 11 | # GNU General Public License for more details. |
| 12 | # |
| 13 | # You should have received a copy of the GNU General Public License |
| 14 | # along with this program; if not, write to the Free Software |
| 15 | # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 16 | |
| 17 | # Please email any bugs, comments, and/or additions to this file to: |
| 18 | # bug-gdb@prep.ai.mit.edu |
| 19 | |
| 20 | # This file was based on a file written by Fred Fish. (fnf@cygnus.com) |
| 21 | |
| 22 | # Test setup routines that work with the MI interpreter. |
| 23 | |
| 24 | # The variable mi_gdb_prompt is a regexp which matches the gdb mi prompt. |
| 25 | # Set it if it is not already set. |
| 26 | global mi_gdb_prompt |
| 27 | if ![info exists mi_gdb_prompt] then { |
| 28 | set mi_gdb_prompt "\[(\]gdb\[)\] \r\n" |
| 29 | } |
| 30 | |
| 31 | global mi_inferior_spawn_id |
| 32 | global mi_inferior_tty_name |
| 33 | |
| 34 | set MIFLAGS "-i=mi" |
| 35 | |
| 36 | # |
| 37 | # mi_gdb_exit -- exit the GDB, killing the target program if necessary |
| 38 | # |
| 39 | proc mi_gdb_exit {} { |
| 40 | catch mi_uncatched_gdb_exit |
| 41 | } |
| 42 | |
| 43 | proc mi_uncatched_gdb_exit {} { |
| 44 | global GDB |
| 45 | global GDBFLAGS |
| 46 | global verbose |
| 47 | global gdb_spawn_id; |
| 48 | global gdb_prompt |
| 49 | global mi_gdb_prompt |
| 50 | global MIFLAGS |
| 51 | |
| 52 | gdb_stop_suppressing_tests; |
| 53 | |
| 54 | if { [info procs sid_exit] != "" } { |
| 55 | sid_exit |
| 56 | } |
| 57 | |
| 58 | if ![info exists gdb_spawn_id] { |
| 59 | return; |
| 60 | } |
| 61 | |
| 62 | verbose "Quitting $GDB $GDBFLAGS $MIFLAGS" |
| 63 | |
| 64 | if { [is_remote host] && [board_info host exists fileid] } { |
| 65 | send_gdb "999-gdb-exit\n"; |
| 66 | gdb_expect 10 { |
| 67 | -re "y or n" { |
| 68 | send_gdb "y\n"; |
| 69 | exp_continue; |
| 70 | } |
| 71 | -re "Undefined command.*$gdb_prompt $" { |
| 72 | send_gdb "quit\n" |
| 73 | exp_continue; |
| 74 | } |
| 75 | -re "DOSEXIT code" { } |
| 76 | default { } |
| 77 | } |
| 78 | } |
| 79 | |
| 80 | if ![is_remote host] { |
| 81 | remote_close host; |
| 82 | } |
| 83 | unset gdb_spawn_id |
| 84 | } |
| 85 | |
| 86 | # |
| 87 | # mi_gdb_start [INFERIOR_PTY] -- start gdb running, default procedure |
| 88 | # |
| 89 | # INFERIOR_PTY should be set to separate-inferior-tty to have the inferior work |
| 90 | # with it's own PTY. If set to same-inferior-tty, the inferior shares GDB's PTY. |
| 91 | # The default value is same-inferior-tty. |
| 92 | # |
| 93 | # When running over NFS, particularly if running many simultaneous |
| 94 | # tests on different hosts all using the same server, things can |
| 95 | # get really slow. Give gdb at least 3 minutes to start up. |
| 96 | # |
| 97 | proc mi_gdb_start { args } { |
| 98 | global verbose |
| 99 | global GDB |
| 100 | global GDBFLAGS |
| 101 | global gdb_prompt |
| 102 | global mi_gdb_prompt |
| 103 | global timeout |
| 104 | global gdb_spawn_id; |
| 105 | global MIFLAGS |
| 106 | |
| 107 | gdb_stop_suppressing_tests; |
| 108 | set inferior_pty no-tty |
| 109 | |
| 110 | if { [llength $args] == 1} { |
| 111 | set inferior_pty [lindex $args 0] |
| 112 | } |
| 113 | |
| 114 | set separate_inferior_pty [string match $inferior_pty separate-inferior-tty] |
| 115 | |
| 116 | # Start SID. |
| 117 | if { [info procs sid_start] != "" } { |
| 118 | verbose "Spawning SID" |
| 119 | sid_start |
| 120 | } |
| 121 | |
| 122 | verbose "Spawning $GDB -nw $GDBFLAGS $MIFLAGS" |
| 123 | |
| 124 | if [info exists gdb_spawn_id] { |
| 125 | return 0; |
| 126 | } |
| 127 | |
| 128 | if ![is_remote host] { |
| 129 | if { [which $GDB] == 0 } then { |
| 130 | perror "$GDB does not exist." |
| 131 | exit 1 |
| 132 | } |
| 133 | } |
| 134 | |
| 135 | # Create the new PTY for the inferior process. |
| 136 | if { $separate_inferior_pty } { |
| 137 | spawn -pty |
| 138 | global mi_inferior_spawn_id |
| 139 | global mi_inferior_tty_name |
| 140 | set mi_inferior_spawn_id $spawn_id |
| 141 | set mi_inferior_tty_name $spawn_out(slave,name) |
| 142 | } |
| 143 | |
| 144 | set res [remote_spawn host "$GDB -nw $GDBFLAGS $MIFLAGS [host_info gdb_opts]"]; |
| 145 | if { $res < 0 || $res == "" } { |
| 146 | perror "Spawning $GDB failed." |
| 147 | return 1; |
| 148 | } |
| 149 | gdb_expect { |
| 150 | -re "~\"GNU.*\r\n~\".*$mi_gdb_prompt$" { |
| 151 | # We have a new format mi startup prompt. If we are |
| 152 | # running mi1, then this is an error as we should be |
| 153 | # using the old-style prompt. |
| 154 | if { $MIFLAGS == "-i=mi1" } { |
| 155 | perror "(mi startup) Got unexpected new mi prompt." |
| 156 | remote_close host; |
| 157 | return -1; |
| 158 | } |
| 159 | verbose "GDB initialized." |
| 160 | } |
| 161 | -re "\[^~\].*$mi_gdb_prompt$" { |
| 162 | # We have an old format mi startup prompt. If we are |
| 163 | # not running mi1, then this is an error as we should be |
| 164 | # using the new-style prompt. |
| 165 | if { $MIFLAGS != "-i=mi1" } { |
| 166 | perror "(mi startup) Got unexpected old mi prompt." |
| 167 | remote_close host; |
| 168 | return -1; |
| 169 | } |
| 170 | verbose "GDB initialized." |
| 171 | } |
| 172 | -re ".*$gdb_prompt $" { |
| 173 | untested "Skip mi tests (got non-mi prompt)." |
| 174 | remote_close host; |
| 175 | return -1; |
| 176 | } |
| 177 | -re ".*unrecognized option.*for a complete list of options." { |
| 178 | untested "Skip mi tests (not compiled with mi support)." |
| 179 | remote_close host; |
| 180 | return -1; |
| 181 | } |
| 182 | -re ".*Interpreter `mi' unrecognized." { |
| 183 | untested "Skip mi tests (not compiled with mi support)." |
| 184 | remote_close host; |
| 185 | return -1; |
| 186 | } |
| 187 | timeout { |
| 188 | perror "(timeout) GDB never initialized after 10 seconds." |
| 189 | remote_close host; |
| 190 | return -1 |
| 191 | } |
| 192 | } |
| 193 | set gdb_spawn_id -1; |
| 194 | |
| 195 | # FIXME: mi output does not go through pagers, so these can be removed. |
| 196 | # force the height to "unlimited", so no pagers get used |
| 197 | send_gdb "100-gdb-set height 0\n" |
| 198 | gdb_expect 10 { |
| 199 | -re ".*100-gdb-set height 0\r\n100\\\^done\r\n$mi_gdb_prompt$" { |
| 200 | verbose "Setting height to 0." 2 |
| 201 | } |
| 202 | timeout { |
| 203 | warning "Couldn't set the height to 0" |
| 204 | } |
| 205 | } |
| 206 | # force the width to "unlimited", so no wraparound occurs |
| 207 | send_gdb "101-gdb-set width 0\n" |
| 208 | gdb_expect 10 { |
| 209 | -re ".*101-gdb-set width 0\r\n101\\\^done\r\n$mi_gdb_prompt$" { |
| 210 | verbose "Setting width to 0." 2 |
| 211 | } |
| 212 | timeout { |
| 213 | warning "Couldn't set the width to 0." |
| 214 | } |
| 215 | } |
| 216 | # If allowing the inferior to have its own PTY then assign the inferior |
| 217 | # its own terminal device here. |
| 218 | if { $separate_inferior_pty } { |
| 219 | send_gdb "102-inferior-tty-set $mi_inferior_tty_name\n" |
| 220 | gdb_expect 10 { |
| 221 | -re ".*102\\\^done\r\n$mi_gdb_prompt$" { |
| 222 | verbose "redirect inferior output to new terminal device." |
| 223 | } |
| 224 | timeout { |
| 225 | warning "Couldn't redirect inferior output." 2 |
| 226 | } |
| 227 | } |
| 228 | } |
| 229 | |
| 230 | return 0; |
| 231 | } |
| 232 | |
| 233 | # Many of the tests depend on setting breakpoints at various places and |
| 234 | # running until that breakpoint is reached. At times, we want to start |
| 235 | # with a clean-slate with respect to breakpoints, so this utility proc |
| 236 | # lets us do this without duplicating this code everywhere. |
| 237 | # |
| 238 | |
| 239 | proc mi_delete_breakpoints {} { |
| 240 | global mi_gdb_prompt |
| 241 | |
| 242 | # FIXME: The mi operation won't accept a prompt back and will use the 'all' arg |
| 243 | send_gdb "102-break-delete\n" |
| 244 | gdb_expect 30 { |
| 245 | -re "Delete all breakpoints.*y or n.*$" { |
| 246 | send_gdb "y\n"; |
| 247 | exp_continue |
| 248 | } |
| 249 | -re ".*102-break-delete\r\n102\\\^done\r\n$mi_gdb_prompt$" { |
| 250 | # This happens if there were no breakpoints |
| 251 | } |
| 252 | timeout { perror "Delete all breakpoints in mi_delete_breakpoints (timeout)" ; return } |
| 253 | } |
| 254 | |
| 255 | # The correct output is not "No breakpoints or watchpoints." but an |
| 256 | # empty BreakpointTable. Also, a query is not acceptable with mi. |
| 257 | send_gdb "103-break-list\n" |
| 258 | gdb_expect 30 { |
| 259 | -re "103-break-list\r\n103\\\^done,BreakpointTable=\{\}\r\n$mi_gdb_prompt$" {} |
| 260 | -re "103-break-list\r\n103\\\^done,BreakpointTable=\{nr_rows=\".\",nr_cols=\".\",hdr=\\\[\{width=\".*\",alignment=\".*\",col_name=\"number\",colhdr=\"Num\"\}.*colhdr=\"Type\".*colhdr=\"Disp\".*colhdr=\"Enb\".*colhdr=\"Address\".*colhdr=\"What\".*\\\],body=\\\[\\\]\}" {} |
| 261 | -re "103-break-list\r\n103\\\^doneNo breakpoints or watchpoints.\r\n\r\n$mi_gdb_prompt$" {warning "Unexpected console text received"} |
| 262 | -re "$mi_gdb_prompt$" { perror "Breakpoints not deleted" ; return } |
| 263 | -re "Delete all breakpoints.*or n.*$" { |
| 264 | warning "Unexpected prompt for breakpoints deletion"; |
| 265 | send_gdb "y\n"; |
| 266 | exp_continue |
| 267 | } |
| 268 | timeout { perror "-break-list (timeout)" ; return } |
| 269 | } |
| 270 | } |
| 271 | |
| 272 | proc mi_gdb_reinitialize_dir { subdir } { |
| 273 | global mi_gdb_prompt |
| 274 | global MIFLAGS |
| 275 | |
| 276 | global suppress_flag |
| 277 | if { $suppress_flag } { |
| 278 | return |
| 279 | } |
| 280 | |
| 281 | if [is_remote host] { |
| 282 | return ""; |
| 283 | } |
| 284 | |
| 285 | if { $MIFLAGS == "-i=mi1" } { |
| 286 | send_gdb "104-environment-directory\n" |
| 287 | gdb_expect 60 { |
| 288 | -re ".*Reinitialize source path to empty.*y or n. " { |
| 289 | warning "Got confirmation prompt for dir reinitialization." |
| 290 | send_gdb "y\n" |
| 291 | gdb_expect 60 { |
| 292 | -re "$mi_gdb_prompt$" {} |
| 293 | timeout {error "Dir reinitialization failed (timeout)"} |
| 294 | } |
| 295 | } |
| 296 | -re "$mi_gdb_prompt$" {} |
| 297 | timeout {error "Dir reinitialization failed (timeout)"} |
| 298 | } |
| 299 | } else { |
| 300 | send_gdb "104-environment-directory -r\n" |
| 301 | gdb_expect 60 { |
| 302 | -re "104\\\^done,source-path=.*\r\n$mi_gdb_prompt$" {} |
| 303 | -re "$mi_gdb_prompt$" {} |
| 304 | timeout {error "Dir reinitialization failed (timeout)"} |
| 305 | } |
| 306 | } |
| 307 | |
| 308 | send_gdb "105-environment-directory $subdir\n" |
| 309 | gdb_expect 60 { |
| 310 | -re "Source directories searched.*$mi_gdb_prompt$" { |
| 311 | verbose "Dir set to $subdir" |
| 312 | } |
| 313 | -re "105\\\^done.*\r\n$mi_gdb_prompt$" { |
| 314 | # FIXME: We return just the prompt for now. |
| 315 | verbose "Dir set to $subdir" |
| 316 | # perror "Dir \"$subdir\" failed." |
| 317 | } |
| 318 | } |
| 319 | } |
| 320 | |
| 321 | # Send GDB the "target" command. |
| 322 | # FIXME: Some of these patterns are not appropriate for MI. Based on |
| 323 | # config/monitor.exp:gdb_target_command. |
| 324 | proc mi_gdb_target_cmd { targetname serialport } { |
| 325 | global mi_gdb_prompt |
| 326 | |
| 327 | for {set i 1} {$i <= 3} {incr i} { |
| 328 | send_gdb "47-target-select $targetname $serialport\n" |
| 329 | gdb_expect 60 { |
| 330 | -re "47\\^connected.*$mi_gdb_prompt$" { |
| 331 | verbose "Set target to $targetname"; |
| 332 | return 0; |
| 333 | } |
| 334 | -re "Couldn't establish connection to remote.*$mi_gdb_prompt$" { |
| 335 | verbose "Connection failed"; |
| 336 | } |
| 337 | -re "Remote MIPS debugging.*$mi_gdb_prompt$" { |
| 338 | verbose "Set target to $targetname"; |
| 339 | return 0; |
| 340 | } |
| 341 | -re "Remote debugging using .*$serialport.*$mi_gdb_prompt$" { |
| 342 | verbose "Set target to $targetname"; |
| 343 | return 0; |
| 344 | } |
| 345 | -re "Remote target $targetname connected to.*$mi_gdb_prompt$" { |
| 346 | verbose "Set target to $targetname"; |
| 347 | return 0; |
| 348 | } |
| 349 | -re "Connected to.*$mi_gdb_prompt$" { |
| 350 | verbose "Set target to $targetname"; |
| 351 | return 0; |
| 352 | } |
| 353 | -re "Ending remote.*$mi_gdb_prompt$" { } |
| 354 | -re "Connection refused.*$mi_gdb_prompt$" { |
| 355 | verbose "Connection refused by remote target. Pausing, and trying again." |
| 356 | sleep 5 |
| 357 | continue |
| 358 | } |
| 359 | -re "Timeout reading from remote system.*$mi_gdb_prompt$" { |
| 360 | verbose "Got timeout error from gdb."; |
| 361 | } |
| 362 | timeout { |
| 363 | send_gdb "\ 3"; |
| 364 | break |
| 365 | } |
| 366 | } |
| 367 | } |
| 368 | return 1 |
| 369 | } |
| 370 | |
| 371 | # |
| 372 | # load a file into the debugger (file command only). |
| 373 | # return a -1 if anything goes wrong. |
| 374 | # |
| 375 | proc mi_gdb_file_cmd { arg } { |
| 376 | global verbose |
| 377 | global loadpath |
| 378 | global loadfile |
| 379 | global GDB |
| 380 | global mi_gdb_prompt |
| 381 | global last_mi_gdb_file |
| 382 | global last_mi_remote_file |
| 383 | upvar timeout timeout |
| 384 | |
| 385 | if { $arg == "" } { |
| 386 | set arg $last_mi_gdb_file; |
| 387 | } else { |
| 388 | set last_mi_gdb_file $arg |
| 389 | if { [ info exists last_mi_remote_file ] } { |
| 390 | unset last_mi_remote_file |
| 391 | } |
| 392 | } |
| 393 | |
| 394 | if [is_remote host] { |
| 395 | set arg [remote_download host $arg]; |
| 396 | if { $arg == "" } { |
| 397 | error "download failed" |
| 398 | return -1; |
| 399 | } |
| 400 | } |
| 401 | |
| 402 | # FIXME: Several of these patterns are only acceptable for console |
| 403 | # output. Queries are an error for mi. |
| 404 | send_gdb "105-file-exec-and-symbols $arg\n" |
| 405 | gdb_expect 120 { |
| 406 | -re "Reading symbols from.*done.*$mi_gdb_prompt$" { |
| 407 | verbose "\t\tLoaded $arg into the $GDB" |
| 408 | return 0 |
| 409 | } |
| 410 | -re "has no symbol-table.*$mi_gdb_prompt$" { |
| 411 | perror "$arg wasn't compiled with \"-g\"" |
| 412 | return -1 |
| 413 | } |
| 414 | -re "A program is being debugged already.*Kill it.*y or n. $" { |
| 415 | send_gdb "y\n" |
| 416 | verbose "\t\tKilling previous program being debugged" |
| 417 | exp_continue |
| 418 | } |
| 419 | -re "Load new symbol table from \".*\".*y or n. $" { |
| 420 | send_gdb "y\n" |
| 421 | gdb_expect 120 { |
| 422 | -re "Reading symbols from.*done.*$mi_gdb_prompt$" { |
| 423 | verbose "\t\tLoaded $arg with new symbol table into $GDB" |
| 424 | # All OK |
| 425 | } |
| 426 | timeout { |
| 427 | perror "(timeout) Couldn't load $arg, other program already loaded." |
| 428 | return -1 |
| 429 | } |
| 430 | } |
| 431 | } |
| 432 | -re "No such file or directory.*$mi_gdb_prompt$" { |
| 433 | perror "($arg) No such file or directory\n" |
| 434 | return -1 |
| 435 | } |
| 436 | -re "105-file-exec-and-symbols .*\r\n105\\\^done\r\n$mi_gdb_prompt$" { |
| 437 | # We (MI) are just giving the prompt back for now, instead of giving |
| 438 | # some acknowledgement. |
| 439 | return 0 |
| 440 | } |
| 441 | timeout { |
| 442 | perror "couldn't load $arg into $GDB (timed out)." |
| 443 | return -1 |
| 444 | } |
| 445 | eof { |
| 446 | # This is an attempt to detect a core dump, but seems not to |
| 447 | # work. Perhaps we need to match .* followed by eof, in which |
| 448 | # gdb_expect does not seem to have a way to do that. |
| 449 | perror "couldn't load $arg into $GDB (end of file)." |
| 450 | return -1 |
| 451 | } |
| 452 | } |
| 453 | } |
| 454 | |
| 455 | # |
| 456 | # load a file into the debugger. |
| 457 | # return a -1 if anything goes wrong. |
| 458 | # |
| 459 | proc mi_gdb_load { arg } { |
| 460 | global verbose |
| 461 | global loadpath |
| 462 | global loadfile |
| 463 | global GDB |
| 464 | global mi_gdb_prompt |
| 465 | upvar timeout timeout |
| 466 | |
| 467 | # ``gdb_unload'' |
| 468 | if { $arg != "" } { |
| 469 | mi_gdb_file_cmd $arg |
| 470 | } |
| 471 | |
| 472 | # ``load'' |
| 473 | if { [info procs gdbserver_gdb_load] != "" } { |
| 474 | global last_mi_gdb_file |
| 475 | global last_mi_remote_file |
| 476 | |
| 477 | if { ! [info exists last_mi_remote_file] } { |
| 478 | if [is_remote target] { |
| 479 | set last_mi_remote_file [remote_download target $arg /tmp/[file tail $arg].[pid]] |
| 480 | } else { |
| 481 | set last_mi_remote_file $last_mi_gdb_file |
| 482 | } |
| 483 | } |
| 484 | |
| 485 | set res [gdbserver_gdb_load $last_mi_remote_file] |
| 486 | set protocol [lindex $res 0] |
| 487 | set gdbport [lindex $res 1] |
| 488 | |
| 489 | if { [mi_gdb_target_cmd $protocol $gdbport] != 0 } { |
| 490 | return -1 |
| 491 | } |
| 492 | } elseif { [info procs send_target_sid] != "" } { |
| 493 | # For SID, things get complex |
| 494 | send_target_sid |
| 495 | gdb_expect 60 { |
| 496 | -re "\\^done,.*$mi_gdb_prompt$" { |
| 497 | } |
| 498 | timeout { |
| 499 | perror "Unable to connect to SID target" |
| 500 | return -1 |
| 501 | } |
| 502 | } |
| 503 | send_gdb "48-target-download\n" |
| 504 | gdb_expect 10 { |
| 505 | -re "48\\^done.*$mi_gdb_prompt$" { |
| 506 | } |
| 507 | timeout { |
| 508 | perror "Unable to download to SID target" |
| 509 | return -1 |
| 510 | } |
| 511 | } |
| 512 | } elseif { [target_info protocol] == "sim" } { |
| 513 | # For the simulator, just connect to it directly. |
| 514 | send_gdb "47-target-select sim\n" |
| 515 | gdb_expect 10 { |
| 516 | -re "47\\^connected.*$mi_gdb_prompt$" { |
| 517 | } |
| 518 | timeout { |
| 519 | perror "Unable to select sim target" |
| 520 | return -1 |
| 521 | } |
| 522 | } |
| 523 | send_gdb "48-target-download\n" |
| 524 | gdb_expect 10 { |
| 525 | -re "48\\^done.*$mi_gdb_prompt$" { |
| 526 | } |
| 527 | timeout { |
| 528 | perror "Unable to download to sim target" |
| 529 | return -1 |
| 530 | } |
| 531 | } |
| 532 | } elseif { [target_info gdb_protocol] == "remote" } { |
| 533 | # remote targets |
| 534 | if { [mi_gdb_target_cmd "remote" [target_info netport]] != 0 } { |
| 535 | perror "Unable to connect to remote target" |
| 536 | return -1 |
| 537 | } |
| 538 | send_gdb "48-target-download\n" |
| 539 | gdb_expect 10 { |
| 540 | -re "48\\^done.*$mi_gdb_prompt$" { |
| 541 | } |
| 542 | timeout { |
| 543 | perror "Unable to download to remote target" |
| 544 | return -1 |
| 545 | } |
| 546 | } |
| 547 | } |
| 548 | return 0 |
| 549 | } |
| 550 | |
| 551 | # mi_gdb_test COMMAND PATTERN MESSAGE [IPATTERN] -- send a command to gdb; |
| 552 | # test the result. |
| 553 | # |
| 554 | # COMMAND is the command to execute, send to GDB with send_gdb. If |
| 555 | # this is the null string no command is sent. |
| 556 | # PATTERN is the pattern to match for a PASS, and must NOT include |
| 557 | # the \r\n sequence immediately before the gdb prompt. |
| 558 | # MESSAGE is the message to be printed. (If this is the empty string, |
| 559 | # then sometimes we don't call pass or fail at all; I don't |
| 560 | # understand this at all.) |
| 561 | # IPATTERN is the pattern to match for the inferior's output. This parameter |
| 562 | # is optional. If present, it will produce a PASS if the match is |
| 563 | # successful, and a FAIL if unsuccessful. |
| 564 | # |
| 565 | # Returns: |
| 566 | # 1 if the test failed, |
| 567 | # 0 if the test passes, |
| 568 | # -1 if there was an internal error. |
| 569 | # |
| 570 | proc mi_gdb_test { args } { |
| 571 | global verbose |
| 572 | global mi_gdb_prompt |
| 573 | global GDB expect_out |
| 574 | upvar timeout timeout |
| 575 | |
| 576 | set command [lindex $args 0] |
| 577 | set pattern [lindex $args 1] |
| 578 | set message [lindex $args 2] |
| 579 | |
| 580 | if [llength $args]==4 { |
| 581 | set ipattern [lindex $args 3] |
| 582 | } |
| 583 | |
| 584 | if [llength $args]==5 { |
| 585 | set question_string [lindex $args 3]; |
| 586 | set response_string [lindex $args 4]; |
| 587 | } else { |
| 588 | set question_string "^FOOBAR$" |
| 589 | } |
| 590 | |
| 591 | if $verbose>2 then { |
| 592 | send_user "Sending \"$command\" to gdb\n" |
| 593 | send_user "Looking to match \"$pattern\"\n" |
| 594 | send_user "Message is \"$message\"\n" |
| 595 | } |
| 596 | |
| 597 | set result -1 |
| 598 | set string "${command}\n"; |
| 599 | if { $command != "" } { |
| 600 | while { "$string" != "" } { |
| 601 | set foo [string first "\n" "$string"]; |
| 602 | set len [string length "$string"]; |
| 603 | if { $foo < [expr $len - 1] } { |
| 604 | set str [string range "$string" 0 $foo]; |
| 605 | if { [send_gdb "$str"] != "" } { |
| 606 | global suppress_flag; |
| 607 | |
| 608 | if { ! $suppress_flag } { |
| 609 | perror "Couldn't send $command to GDB."; |
| 610 | } |
| 611 | fail "$message"; |
| 612 | return $result; |
| 613 | } |
| 614 | gdb_expect 2 { |
| 615 | -re "\[\r\n\]" { } |
| 616 | timeout { } |
| 617 | } |
| 618 | set string [string range "$string" [expr $foo + 1] end]; |
| 619 | } else { |
| 620 | break; |
| 621 | } |
| 622 | } |
| 623 | if { "$string" != "" } { |
| 624 | if { [send_gdb "$string"] != "" } { |
| 625 | global suppress_flag; |
| 626 | |
| 627 | if { ! $suppress_flag } { |
| 628 | perror "Couldn't send $command to GDB."; |
| 629 | } |
| 630 | fail "$message"; |
| 631 | return $result; |
| 632 | } |
| 633 | } |
| 634 | } |
| 635 | |
| 636 | if [info exists timeout] { |
| 637 | set tmt $timeout; |
| 638 | } else { |
| 639 | global timeout; |
| 640 | if [info exists timeout] { |
| 641 | set tmt $timeout; |
| 642 | } else { |
| 643 | set tmt 60; |
| 644 | } |
| 645 | } |
| 646 | gdb_expect $tmt { |
| 647 | -re "\\*\\*\\* DOSEXIT code.*" { |
| 648 | if { $message != "" } { |
| 649 | fail "$message"; |
| 650 | } |
| 651 | gdb_suppress_entire_file "GDB died"; |
| 652 | return -1; |
| 653 | } |
| 654 | -re "Ending remote debugging.*$mi_gdb_prompt\[ \]*$" { |
| 655 | if ![isnative] then { |
| 656 | warning "Can`t communicate to remote target." |
| 657 | } |
| 658 | gdb_exit |
| 659 | gdb_start |
| 660 | set result -1 |
| 661 | } |
| 662 | -re "\[\r\n\]*($pattern)\[\r\n\]+$mi_gdb_prompt\[ \]*$" { |
| 663 | if ![string match "" $message] then { |
| 664 | pass "$message" |
| 665 | } |
| 666 | set result 0 |
| 667 | } |
| 668 | -re "(${question_string})$" { |
| 669 | send_gdb "$response_string\n"; |
| 670 | exp_continue; |
| 671 | } |
| 672 | -re "Undefined.* command:.*$mi_gdb_prompt\[ \]*$" { |
| 673 | perror "Undefined command \"$command\"." |
| 674 | fail "$message" |
| 675 | set result 1 |
| 676 | } |
| 677 | -re "Ambiguous command.*$mi_gdb_prompt\[ \]*$" { |
| 678 | perror "\"$command\" is not a unique command name." |
| 679 | fail "$message" |
| 680 | set result 1 |
| 681 | } |
| 682 | -re "Program exited with code \[0-9\]+.*$mi_gdb_prompt\[ \]*$" { |
| 683 | if ![string match "" $message] then { |
| 684 | set errmsg "$message (the program exited)" |
| 685 | } else { |
| 686 | set errmsg "$command (the program exited)" |
| 687 | } |
| 688 | fail "$errmsg" |
| 689 | return -1 |
| 690 | } |
| 691 | -re "The program is not being run.*$mi_gdb_prompt\[ \]*$" { |
| 692 | if ![string match "" $message] then { |
| 693 | set errmsg "$message (the program is no longer running)" |
| 694 | } else { |
| 695 | set errmsg "$command (the program is no longer running)" |
| 696 | } |
| 697 | fail "$errmsg" |
| 698 | return -1 |
| 699 | } |
| 700 | -re ".*$mi_gdb_prompt\[ \]*$" { |
| 701 | if ![string match "" $message] then { |
| 702 | fail "$message" |
| 703 | } |
| 704 | set result 1 |
| 705 | } |
| 706 | "<return>" { |
| 707 | send_gdb "\n" |
| 708 | perror "Window too small." |
| 709 | fail "$message" |
| 710 | } |
| 711 | -re "\\(y or n\\) " { |
| 712 | send_gdb "n\n" |
| 713 | perror "Got interactive prompt." |
| 714 | fail "$message" |
| 715 | } |
| 716 | eof { |
| 717 | perror "Process no longer exists" |
| 718 | if { $message != "" } { |
| 719 | fail "$message" |
| 720 | } |
| 721 | return -1 |
| 722 | } |
| 723 | full_buffer { |
| 724 | perror "internal buffer is full." |
| 725 | fail "$message" |
| 726 | } |
| 727 | timeout { |
| 728 | if ![string match "" $message] then { |
| 729 | fail "$message (timeout)" |
| 730 | } |
| 731 | set result 1 |
| 732 | } |
| 733 | } |
| 734 | |
| 735 | # If the GDB output matched, compare the inferior output. |
| 736 | if { $result == 0 } { |
| 737 | if [ info exists ipattern ] { |
| 738 | global mi_inferior_spawn_id |
| 739 | expect { |
| 740 | -i $mi_inferior_spawn_id -re "$ipattern" { |
| 741 | pass "inferior_output:$message" |
| 742 | } |
| 743 | timeout { |
| 744 | fail "inferior output timeout" |
| 745 | set result 1 |
| 746 | } |
| 747 | } |
| 748 | } |
| 749 | } |
| 750 | |
| 751 | return $result |
| 752 | } |
| 753 | |
| 754 | # |
| 755 | # MI run command. (A modified version of gdb_run_cmd) |
| 756 | # |
| 757 | |
| 758 | # In patterns, the newline sequence ``\r\n'' is matched explicitly as |
| 759 | # ``.*$'' could swallow up output that we attempt to match elsewhere. |
| 760 | |
| 761 | proc mi_run_cmd {args} { |
| 762 | global suppress_flag |
| 763 | if { $suppress_flag } { |
| 764 | return -1 |
| 765 | } |
| 766 | global mi_gdb_prompt |
| 767 | |
| 768 | if [target_info exists gdb_init_command] { |
| 769 | send_gdb "[target_info gdb_init_command]\n"; |
| 770 | gdb_expect 30 { |
| 771 | -re "$mi_gdb_prompt$" { } |
| 772 | default { |
| 773 | perror "gdb_init_command for target failed"; |
| 774 | return; |
| 775 | } |
| 776 | } |
| 777 | } |
| 778 | |
| 779 | if [target_info exists use_gdb_stub] { |
| 780 | if [target_info exists gdb,do_reload_on_run] { |
| 781 | # Specifying no file, defaults to the executable |
| 782 | # currently being debugged. |
| 783 | if { [mi_gdb_load ""] < 0 } { |
| 784 | return; |
| 785 | } |
| 786 | send_gdb "000-exec-continue\n"; |
| 787 | gdb_expect 60 { |
| 788 | -re "000\\^running\[\r\n\]+$mi_gdb_prompt$" {} |
| 789 | default {} |
| 790 | } |
| 791 | return; |
| 792 | } |
| 793 | |
| 794 | if [target_info exists gdb,start_symbol] { |
| 795 | set start [target_info gdb,start_symbol]; |
| 796 | } else { |
| 797 | set start "start"; |
| 798 | } |
| 799 | |
| 800 | # HACK: Should either use 000-jump or fix the target code |
| 801 | # to better handle RUN. |
| 802 | send_gdb "jump *$start\n" |
| 803 | warning "Using CLI jump command, expect run-to-main FAIL" |
| 804 | return |
| 805 | } |
| 806 | |
| 807 | send_gdb "000-exec-run $args\n" |
| 808 | gdb_expect { |
| 809 | -re "000\\^running\r\n${mi_gdb_prompt}" { |
| 810 | } |
| 811 | timeout { |
| 812 | perror "Unable to start target" |
| 813 | return |
| 814 | } |
| 815 | } |
| 816 | # NOTE: Shortly after this there will be a ``000*stopping,...(gdb)'' |
| 817 | } |
| 818 | |
| 819 | # |
| 820 | # Just like run-to-main but works with the MI interface |
| 821 | # |
| 822 | |
| 823 | proc mi_run_to_main { } { |
| 824 | global suppress_flag |
| 825 | if { $suppress_flag } { |
| 826 | return -1 |
| 827 | } |
| 828 | |
| 829 | global srcdir |
| 830 | global subdir |
| 831 | global binfile |
| 832 | global srcfile |
| 833 | |
| 834 | mi_delete_breakpoints |
| 835 | mi_gdb_reinitialize_dir $srcdir/$subdir |
| 836 | mi_gdb_load ${binfile} |
| 837 | |
| 838 | mi_runto main |
| 839 | } |
| 840 | |
| 841 | |
| 842 | # Just like gdb's "runto" proc, it will run the target to a given |
| 843 | # function. The big difference here between mi_runto and mi_execute_to |
| 844 | # is that mi_execute_to must have the inferior running already. This |
| 845 | # proc will (like gdb's runto) (re)start the inferior, too. |
| 846 | # |
| 847 | # FUNC is the linespec of the place to stop (it inserts a breakpoint here). |
| 848 | # It returns: |
| 849 | # -1 if test suppressed, failed, timedout |
| 850 | # 0 if test passed |
| 851 | |
| 852 | proc mi_runto {func} { |
| 853 | global suppress_flag |
| 854 | if { $suppress_flag } { |
| 855 | return -1 |
| 856 | } |
| 857 | |
| 858 | global mi_gdb_prompt expect_out |
| 859 | global hex decimal fullname_syntax |
| 860 | |
| 861 | set test "mi runto $func" |
| 862 | mi_gdb_test "200-break-insert $func" \ |
| 863 | "200\\^done,bkpt=\{number=\"\[0-9\]+\",type=\"breakpoint\",disp=\"keep\",enabled=\"y\",addr=\"$hex\",func=\"$func\",file=\".*\",line=\"\[0-9\]*\",times=\"0\"\}" \ |
| 864 | "breakpoint at $func" |
| 865 | |
| 866 | if {![regexp {number="[0-9]+"} $expect_out(buffer) str] |
| 867 | || ![scan $str {number="%d"} bkptno]} { |
| 868 | set bkptno {[0-9]+} |
| 869 | } |
| 870 | |
| 871 | mi_run_cmd |
| 872 | gdb_expect { |
| 873 | -re ".*000\\*stopped,reason=\"breakpoint-hit\",bkptno=\"$bkptno\",thread-id=\"$decimal\",frame=\{addr=\"$hex\",func=\"$func\",args=\(\\\[.*\\\]\|\{.*\}\),file=\".*\",fullname=\"${fullname_syntax}.*\",line=\"\[0-9\]*\"\}\r\n$mi_gdb_prompt$" { |
| 874 | pass "$test" |
| 875 | return 0 |
| 876 | } |
| 877 | -re ".*$mi_gdb_prompt$" { |
| 878 | fail "$test (2)" |
| 879 | } |
| 880 | timeout { |
| 881 | fail "$test (timeout)" |
| 882 | return -1 |
| 883 | } |
| 884 | } |
| 885 | } |
| 886 | |
| 887 | |
| 888 | # Next to the next statement |
| 889 | # For return values, see mi_execute_to_helper |
| 890 | |
| 891 | proc mi_next { test } { |
| 892 | return [mi_next_to {.*} {.*} {.*} {.*} $test] |
| 893 | } |
| 894 | |
| 895 | |
| 896 | # Step to the next statement |
| 897 | # For return values, see mi_execute_to_helper |
| 898 | |
| 899 | proc mi_step { test } { |
| 900 | return [mi_step_to {.*} {.*} {.*} {.*} $test] |
| 901 | } |
| 902 | |
| 903 | # cmd should not include the number or newline (i.e. "exec-step 3", not |
| 904 | # "220-exec-step 3\n" |
| 905 | |
| 906 | # Can not match -re ".*\r\n${mi_gdb_prompt}", because of false positives |
| 907 | # after the first prompt is printed. |
| 908 | |
| 909 | proc mi_execute_to_helper { cmd reason func args file line extra test } { |
| 910 | global suppress_flag |
| 911 | if { $suppress_flag } { |
| 912 | return -1 |
| 913 | } |
| 914 | global mi_gdb_prompt |
| 915 | global hex |
| 916 | global decimal |
| 917 | global fullname_syntax |
| 918 | send_gdb "220-$cmd\n" |
| 919 | gdb_expect { |
| 920 | -re ".*220\\^running\r\n${mi_gdb_prompt}.*220\\*stopped,reason=\"$reason\",thread-id=\"$decimal\",frame=\{addr=\"$hex\",func=\"$func\",args=$args,file=\".*$file\",fullname=\"${fullname_syntax}$file\",line=\"$line\"\}$extra\r\n$mi_gdb_prompt$" { |
| 921 | pass "$test" |
| 922 | return 0 |
| 923 | } |
| 924 | -re ".*220\\^running\r\n${mi_gdb_prompt}.*220\\*stopped,reason=\"$reason\",thread-id=\"$decimal\",frame=\{addr=\"$hex\",func=\".*\",args=\[\\\[\{\].*\[\\\]\}\],file=\".*\",fullname=\"${fullname_syntax}.*\",line=\"\[0-9\]*\"\}.*\r\n$mi_gdb_prompt$" { |
| 925 | fail "$test (stopped at wrong place)" |
| 926 | return -1 |
| 927 | } |
| 928 | -re "220\\^running\r\n${mi_gdb_prompt}.*\r\n${mi_gdb_prompt}$" { |
| 929 | fail "$test (unknown output after running)" |
| 930 | return -1 |
| 931 | } |
| 932 | timeout { |
| 933 | fail "$test (timeout)" |
| 934 | return -1 |
| 935 | } |
| 936 | } |
| 937 | } |
| 938 | |
| 939 | proc mi_execute_to { cmd reason func args file line extra test } { |
| 940 | mi_execute_to_helper "$cmd" "$reason" "$func" "\\\[$args\\\]" \ |
| 941 | "$file" "$line" "$extra" "$test" |
| 942 | } |
| 943 | |
| 944 | proc mi_next_to { func args file line test } { |
| 945 | mi_execute_to "exec-next" "end-stepping-range" "$func" "$args" \ |
| 946 | "$file" "$line" "" "$test" |
| 947 | } |
| 948 | |
| 949 | proc mi_step_to { func args file line test } { |
| 950 | mi_execute_to "exec-step" "end-stepping-range" "$func" "$args" \ |
| 951 | "$file" "$line" "" "$test" |
| 952 | } |
| 953 | |
| 954 | proc mi_finish_to { func args file line result ret test } { |
| 955 | mi_execute_to "exec-finish" "function-finished" "$func" "$args" \ |
| 956 | "$file" "$line" \ |
| 957 | ",gdb-result-var=\"$result\",return-value=\"$ret\"" \ |
| 958 | "$test" |
| 959 | } |
| 960 | |
| 961 | proc mi_continue_to { bkptno func args file line test } { |
| 962 | mi_execute_to "exec-continue" "breakpoint-hit\",bkptno=\"$bkptno" \ |
| 963 | "$func" "$args" "$file" "$line" "" "$test" |
| 964 | } |
| 965 | |
| 966 | proc mi0_execute_to { cmd reason func args file line extra test } { |
| 967 | mi_execute_to_helper "$cmd" "$reason" "$func" "\{$args\}" \ |
| 968 | "$file" "$line" "$extra" "$test" |
| 969 | } |
| 970 | |
| 971 | proc mi0_next_to { func args file line test } { |
| 972 | mi0_execute_to "exec-next" "end-stepping-range" "$func" "$args" \ |
| 973 | "$file" "$line" "" "$test" |
| 974 | } |
| 975 | |
| 976 | proc mi0_step_to { func args file line test } { |
| 977 | mi0_execute_to "exec-step" "end-stepping-range" "$func" "$args" \ |
| 978 | "$file" "$line" "" "$test" |
| 979 | } |
| 980 | |
| 981 | proc mi0_finish_to { func args file line result ret test } { |
| 982 | mi0_execute_to "exec-finish" "function-finished" "$func" "$args" \ |
| 983 | "$file" "$line" \ |
| 984 | ",gdb-result-var=\"$result\",return-value=\"$ret\"" \ |
| 985 | "$test" |
| 986 | } |
| 987 | |
| 988 | proc mi0_continue_to { bkptno func args file line test } { |
| 989 | mi0_execute_to "exec-continue" "breakpoint-hit\",bkptno=\"$bkptno" \ |
| 990 | "$func" "$args" "$file" "$line" "" "$test" |
| 991 | } |