| 1 | dnl Process this file with autoconf to produce a configure script |
| 2 | dnl |
| 3 | AC_PREREG(2.0) |
| 4 | AC_INIT(ldmain.c) |
| 5 | |
| 6 | AC_ARG_ENABLE(targets, |
| 7 | [ --enable-targets alternative target configurations], |
| 8 | [case "${enableval}" in |
| 9 | yes | "") AC_ERROR(enable-targets option must specify target names or 'all') |
| 10 | ;; |
| 11 | no) enable_targets= ;; |
| 12 | *) enable_targets=$enableval ;; |
| 13 | esac])dnl |
| 14 | AC_ARG_ENABLE(shared, |
| 15 | [ --enable-shared build shared BFD library], |
| 16 | [case "${enableval}" in |
| 17 | yes) shared=true ;; |
| 18 | no) shared=false ;; |
| 19 | *) AC_MSG_ERROR([bad value ${enableval} for BFD shared option]) ;; |
| 20 | esac])dnl |
| 21 | |
| 22 | AC_CONFIG_HEADER(config.h:config.in) |
| 23 | |
| 24 | AC_CONFIG_AUX_DIR(`cd $srcdir/..; pwd`) |
| 25 | AC_CANONICAL_SYSTEM |
| 26 | if test -z "$target" ; then |
| 27 | AC_MSG_ERROR(Unrecognized target system type; please check config.sub.) |
| 28 | fi |
| 29 | if test -z "$host" ; then |
| 30 | AC_MSG_ERROR(Unrecognized host system type; please check config.sub.) |
| 31 | fi |
| 32 | AC_ARG_PROGRAM |
| 33 | |
| 34 | # host-specific stuff: |
| 35 | |
| 36 | AC_PROG_CC |
| 37 | |
| 38 | . ${srcdir}/configure.host |
| 39 | |
| 40 | AC_SUBST(CFLAGS) |
| 41 | AC_SUBST(HLDFLAGS) |
| 42 | AC_SUBST(RPATH_ENVVAR) |
| 43 | AC_SUBST(HDEFINES) |
| 44 | AC_SUBST(HOSTING_CRT0) |
| 45 | AC_SUBST(HOSTING_LIBS) |
| 46 | AC_SUBST(NATIVE_LIB_DIRS) |
| 47 | |
| 48 | # For most hosts we can use a simple definition to pick up the BFD and |
| 49 | # opcodes libraries. However, if we are building shared libraries, we |
| 50 | # need to handle some hosts specially. |
| 51 | BFDLIB='-L../bfd -lbfd' |
| 52 | if test "${shared}" = "true"; then |
| 53 | case "${host}" in |
| 54 | *-*-sunos*) |
| 55 | # On SunOS, we must link against the name we are going to install, |
| 56 | # not -lbfd, since SunOS does not support SONAME. |
| 57 | BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`' |
| 58 | ;; |
| 59 | esac |
| 60 | fi |
| 61 | AC_SUBST(BFDLIB) |
| 62 | |
| 63 | AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h) |
| 64 | AC_CHECK_FUNCS(sbrk) |
| 65 | AC_HEADER_DIRENT |
| 66 | |
| 67 | BFD_BINARY_FOPEN |
| 68 | |
| 69 | BFD_NEED_DECLARATION(free) |
| 70 | |
| 71 | # target-specific stuff: |
| 72 | |
| 73 | all_targets= |
| 74 | EMUL= |
| 75 | all_emuls= |
| 76 | TDIRS= |
| 77 | |
| 78 | for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'` |
| 79 | do |
| 80 | if test "$targ_alias" = "all"; then |
| 81 | all_targets=true |
| 82 | else |
| 83 | # Canonicalize the secondary target names. |
| 84 | result=`$ac_config_sub $targ_alias 2>/dev/null` |
| 85 | if test -n "$result"; then |
| 86 | targ=$result |
| 87 | else |
| 88 | targ=$targ_alias |
| 89 | fi |
| 90 | |
| 91 | . ${srcdir}/configure.tgt |
| 92 | |
| 93 | if test "$targ" = "$target"; then |
| 94 | EMUL=$targ_emul |
| 95 | fi |
| 96 | |
| 97 | for i in $targ_emul $targ_extra_emuls; do |
| 98 | case " $all_emuls " in |
| 99 | *" e${i}.o "*) ;; |
| 100 | *) |
| 101 | all_emuls="$all_emuls e${i}.o" |
| 102 | eval result=\$tdir_$i |
| 103 | test -z "$result" && result=$targ_alias |
| 104 | TDIRS="$TDIRS\\ |
| 105 | tdir_$i=$result" |
| 106 | ;; |
| 107 | esac |
| 108 | done |
| 109 | fi |
| 110 | done |
| 111 | |
| 112 | AC_SUBST(EMUL) |
| 113 | AC_SUBST(TDIRS) |
| 114 | |
| 115 | if test x${all_targets} = xtrue; then |
| 116 | EMULATION_OFILES='$(ALL_EMULATIONS)' |
| 117 | else |
| 118 | EMULATION_OFILES=$all_emuls |
| 119 | fi |
| 120 | AC_SUBST(EMULATION_OFILES) |
| 121 | |
| 122 | AC_OUTPUT(Makefile, |
| 123 | [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac]) |