| 1 | cat <<EOF |
| 2 | OUTPUT_FORMAT("${OUTPUT_FORMAT}","${OUTPUT_FORMAT}","${OUTPUT_FORMAT}") |
| 3 | OUTPUT_ARCH(${ARCH}) |
| 4 | |
| 5 | MEMORY |
| 6 | { |
| 7 | text (rx) : ORIGIN = $ROM_START, LENGTH = $ROM_SIZE |
| 8 | data (rwx) : ORIGIN = $RAM_START, LENGTH = $RAM_SIZE |
| 9 | vectors (rw) : ORIGIN = 0xffe0, LENGTH = 0x20 |
| 10 | } |
| 11 | |
| 12 | SECTIONS |
| 13 | { |
| 14 | /* Read-only sections, merged into text segment. */ |
| 15 | ${TEXT_DYNAMIC+${DYNAMIC}} |
| 16 | .hash ${RELOCATING-0} : { *(.hash) } |
| 17 | .dynsym ${RELOCATING-0} : { *(.dynsym) } |
| 18 | .dynstr ${RELOCATING-0} : { *(.dynstr) } |
| 19 | .gnu.version ${RELOCATING-0} : { *(.gnu.version) } |
| 20 | .gnu.version_d ${RELOCATING-0} : { *(.gnu.version_d) } |
| 21 | .gnu.version_r ${RELOCATING-0} : { *(.gnu.version_r) } |
| 22 | |
| 23 | .rel.init ${RELOCATING-0} : { *(.rel.init) } |
| 24 | .rela.init ${RELOCATING-0} : { *(.rela.init) } |
| 25 | .rel.text ${RELOCATING-0} : |
| 26 | { |
| 27 | *(.rel.text) |
| 28 | ${RELOCATING+*(.rel.text.*)} |
| 29 | ${RELOCATING+*(.rel.gnu.linkonce.t*)} |
| 30 | } |
| 31 | .rela.text ${RELOCATING-0} : |
| 32 | { |
| 33 | *(.rela.text) |
| 34 | ${RELOCATING+*(.rela.text.*)} |
| 35 | ${RELOCATING+*(.rela.gnu.linkonce.t*)} |
| 36 | } |
| 37 | .rel.fini ${RELOCATING-0} : { *(.rel.fini) } |
| 38 | .rela.fini ${RELOCATING-0} : { *(.rela.fini) } |
| 39 | .rel.rodata ${RELOCATING-0} : |
| 40 | { |
| 41 | *(.rel.rodata) |
| 42 | ${RELOCATING+*(.rel.rodata.*)} |
| 43 | ${RELOCATING+*(.rel.gnu.linkonce.r*)} |
| 44 | } |
| 45 | .rela.rodata ${RELOCATING-0} : |
| 46 | { |
| 47 | *(.rela.rodata) |
| 48 | ${RELOCATING+*(.rela.rodata.*)} |
| 49 | ${RELOCATING+*(.rela.gnu.linkonce.r*)} |
| 50 | } |
| 51 | .rel.data ${RELOCATING-0} : |
| 52 | { |
| 53 | *(.rel.data) |
| 54 | ${RELOCATING+*(.rel.data.*)} |
| 55 | ${RELOCATING+*(.rel.gnu.linkonce.d*)} |
| 56 | } |
| 57 | .rela.data ${RELOCATING-0} : |
| 58 | { |
| 59 | *(.rela.data) |
| 60 | ${RELOCATING+*(.rela.data.*)} |
| 61 | ${RELOCATING+*(.rela.gnu.linkonce.d*)} |
| 62 | } |
| 63 | .rel.ctors ${RELOCATING-0} : { *(.rel.ctors) } |
| 64 | .rela.ctors ${RELOCATING-0} : { *(.rela.ctors) } |
| 65 | .rel.dtors ${RELOCATING-0} : { *(.rel.dtors) } |
| 66 | .rela.dtors ${RELOCATING-0} : { *(.rela.dtors) } |
| 67 | .rel.got ${RELOCATING-0} : { *(.rel.got) } |
| 68 | .rela.got ${RELOCATING-0} : { *(.rela.got) } |
| 69 | .rel.bss ${RELOCATING-0} : { *(.rel.bss) } |
| 70 | .rela.bss ${RELOCATING-0} : { *(.rela.bss) } |
| 71 | .rel.plt ${RELOCATING-0} : { *(.rel.plt) } |
| 72 | .rela.plt ${RELOCATING-0} : { *(.rela.plt) } |
| 73 | |
| 74 | /* Internal text space. */ |
| 75 | .text : |
| 76 | { |
| 77 | ${RELOCATING+. = ALIGN(2);} |
| 78 | *(SORT_NONE(.init)) |
| 79 | *(SORT_NONE(.init0)) /* Start here after reset. */ |
| 80 | *(SORT_NONE(.init1)) |
| 81 | *(SORT_NONE(.init2)) |
| 82 | *(SORT_NONE(.init3)) |
| 83 | *(SORT_NONE(.init4)) |
| 84 | *(SORT_NONE(.init5)) |
| 85 | *(SORT_NONE(.init6)) /* C++ constructors. */ |
| 86 | *(SORT_NONE(.init7)) |
| 87 | *(SORT_NONE(.init8)) |
| 88 | *(SORT_NONE(.init9)) /* Call main(). */ |
| 89 | |
| 90 | ${CONSTRUCTING+ __ctors_start = . ; } |
| 91 | ${CONSTRUCTING+ *(.ctors) } |
| 92 | ${CONSTRUCTING+ __ctors_end = . ; } |
| 93 | ${CONSTRUCTING+ __dtors_start = . ; } |
| 94 | ${CONSTRUCTING+ *(.dtors) } |
| 95 | ${CONSTRUCTING+ __dtors_end = . ; } |
| 96 | |
| 97 | ${RELOCATING+. = ALIGN(2);} |
| 98 | *(.text) |
| 99 | ${RELOCATING+. = ALIGN(2);} |
| 100 | *(.text.*) |
| 101 | |
| 102 | ${RELOCATING+. = ALIGN(2);} |
| 103 | *(SORT_NONE(.fini9)) |
| 104 | *(SORT_NONE(.fini8)) |
| 105 | *(SORT_NONE(.fini7)) |
| 106 | *(SORT_NONE(.fini6)) /* C++ destructors. */ |
| 107 | *(SORT_NONE(.fini5)) |
| 108 | *(SORT_NONE(.fini4)) |
| 109 | *(SORT_NONE(.fini3)) |
| 110 | *(SORT_NONE(.fini2)) |
| 111 | *(SORT_NONE(.fini1)) |
| 112 | *(SORT_NONE(.fini0)) /* Infinite loop after program termination. */ |
| 113 | *(SORT_NONE(.fini)) |
| 114 | |
| 115 | ${RELOCATING+ _etext = . ; } |
| 116 | } ${RELOCATING+ > text} |
| 117 | |
| 118 | .data ${RELOCATING-0} : ${RELOCATING+AT (ADDR (.text) + SIZEOF (.text))} |
| 119 | { |
| 120 | ${RELOCATING+ PROVIDE (__data_start = .) ; } |
| 121 | ${RELOCATING+. = ALIGN(2);} |
| 122 | *(.data) |
| 123 | *(.data.*) |
| 124 | *(.gnu.linkonce.d*) |
| 125 | ${RELOCATING+. = ALIGN(2);} |
| 126 | ${RELOCATING+ _edata = . ; } |
| 127 | } ${RELOCATING+ > data} |
| 128 | |
| 129 | .bss ${RELOCATING+ SIZEOF(.data) + ADDR(.data)} : |
| 130 | { |
| 131 | ${RELOCATING+. = ALIGN(2);} |
| 132 | ${RELOCATING+ PROVIDE (__bss_start = .) ; } |
| 133 | *(.bss) |
| 134 | *(COMMON) |
| 135 | ${RELOCATING+ PROVIDE (__bss_end = .) ; } |
| 136 | ${RELOCATING+ _end = . ; } |
| 137 | } ${RELOCATING+ > data} |
| 138 | |
| 139 | .noinit ${RELOCATING+ SIZEOF(.bss) + ADDR(.bss)} : |
| 140 | { |
| 141 | ${RELOCATING+ PROVIDE (__noinit_start = .) ; } |
| 142 | *(.noinit) |
| 143 | *(COMMON) |
| 144 | ${RELOCATING+ PROVIDE (__noinit_end = .) ; } |
| 145 | ${RELOCATING+ _end = . ; } |
| 146 | } ${RELOCATING+ > data} |
| 147 | |
| 148 | .vectors ${RELOCATING-0}: |
| 149 | { |
| 150 | ${RELOCATING+ PROVIDE (__vectors_start = .) ; } |
| 151 | *(.vectors*) |
| 152 | ${RELOCATING+ _vectors_end = . ; } |
| 153 | } ${RELOCATING+ > vectors} |
| 154 | |
| 155 | /* Stabs debugging sections. */ |
| 156 | .stab 0 : { *(.stab) } |
| 157 | .stabstr 0 : { *(.stabstr) } |
| 158 | .stab.excl 0 : { *(.stab.excl) } |
| 159 | .stab.exclstr 0 : { *(.stab.exclstr) } |
| 160 | .stab.index 0 : { *(.stab.index) } |
| 161 | .stab.indexstr 0 : { *(.stab.indexstr) } |
| 162 | .comment 0 : { *(.comment) } |
| 163 | |
| 164 | EOF |
| 165 | |
| 166 | source $srcdir/scripttempl/DWARF.sc |
| 167 | |
| 168 | cat <<EOF |
| 169 | PROVIDE (__stack = ${STACK}) ; |
| 170 | PROVIDE (__data_start_rom = _etext) ; |
| 171 | PROVIDE (__data_end_rom = _etext + SIZEOF (.data)) ; |
| 172 | PROVIDE (__noinit_start_rom = _etext + SIZEOF (.data)) ; |
| 173 | PROVIDE (__noinit_end_rom = _etext + SIZEOF (.data) + SIZEOF (.noinit)) ; |
| 174 | } |
| 175 | EOF |