| 1 | dnl Process this file with autoconf to produce a configure script. |
| 2 | dnl |
| 3 | |
| 4 | AC_PREREQ(2.59) |
| 5 | AC_INIT |
| 6 | AC_CONFIG_SRCDIR([z8k-dis.c]) |
| 7 | |
| 8 | AC_CANONICAL_TARGET |
| 9 | AC_ISC_POSIX |
| 10 | |
| 11 | # We currently only use the version number for the name of any shared |
| 12 | # library. For user convenience, we always use the same version |
| 13 | # number that BFD is using. |
| 14 | changequote(,)dnl |
| 15 | BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[ ]*\([^ ]*\)[ ]*).*/\1/p' < ${srcdir}/../bfd/configure.in` |
| 16 | changequote([,])dnl |
| 17 | |
| 18 | AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION}) |
| 19 | |
| 20 | dnl These must be called before AM_PROG_LIBTOOL, because it may want |
| 21 | dnl to call AC_CHECK_PROG. |
| 22 | AC_CHECK_TOOL(AR, ar) |
| 23 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| 24 | |
| 25 | dnl Default to a non shared library. This may be overridden by the |
| 26 | dnl configure option --enable-shared. |
| 27 | AM_DISABLE_SHARED |
| 28 | |
| 29 | AM_PROG_LIBTOOL |
| 30 | |
| 31 | AC_ARG_ENABLE(targets, |
| 32 | [ --enable-targets alternative target configurations], |
| 33 | [case "${enableval}" in |
| 34 | yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all']) |
| 35 | ;; |
| 36 | no) enable_targets= ;; |
| 37 | *) enable_targets=$enableval ;; |
| 38 | esac])dnl |
| 39 | AC_ARG_ENABLE(commonbfdlib, |
| 40 | [ --enable-commonbfdlib build shared BFD/opcodes/libiberty library], |
| 41 | [case "${enableval}" in |
| 42 | yes) commonbfdlib=true ;; |
| 43 | no) commonbfdlib=false ;; |
| 44 | *) AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;; |
| 45 | esac])dnl |
| 46 | |
| 47 | AM_BINUTILS_WARNINGS |
| 48 | |
| 49 | AM_CONFIG_HEADER(config.h:config.in) |
| 50 | |
| 51 | if test -z "$target" ; then |
| 52 | AC_MSG_ERROR(Unrecognized target system type; please check config.sub.) |
| 53 | fi |
| 54 | |
| 55 | AM_MAINTAINER_MODE |
| 56 | AM_INSTALL_LIBBFD |
| 57 | AC_EXEEXT |
| 58 | |
| 59 | # host-specific stuff: |
| 60 | |
| 61 | AC_PROG_CC |
| 62 | |
| 63 | ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN" |
| 64 | CY_GNU_GETTEXT |
| 65 | |
| 66 | . ${srcdir}/../bfd/configure.host |
| 67 | |
| 68 | BFD_CC_FOR_BUILD |
| 69 | |
| 70 | AC_SUBST(HDEFINES) |
| 71 | AC_PROG_INSTALL |
| 72 | |
| 73 | AC_CHECK_HEADERS(string.h strings.h stdlib.h) |
| 74 | |
| 75 | AC_CHECK_DECLS(basename) |
| 76 | |
| 77 | cgen_maint=no |
| 78 | cgendir='$(srcdir)/../cgen' |
| 79 | |
| 80 | AC_ARG_ENABLE(cgen-maint, |
| 81 | [ --enable-cgen-maint[=dir] build cgen generated files], |
| 82 | [case "${enableval}" in |
| 83 | yes) cgen_maint=yes ;; |
| 84 | no) cgen_maint=no ;; |
| 85 | *) |
| 86 | # argument is cgen install directory (not implemented yet). |
| 87 | # Having a `share' directory might be more appropriate for the .scm, |
| 88 | # .cpu, etc. files. |
| 89 | cgen_maint=yes |
| 90 | cgendir=${cgen_maint}/lib/cgen |
| 91 | ;; |
| 92 | esac])dnl |
| 93 | AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes) |
| 94 | AC_SUBST(cgendir) |
| 95 | |
| 96 | using_cgen=no |
| 97 | |
| 98 | # Horrible hacks to build DLLs on Windows. |
| 99 | WIN32LDFLAGS= |
| 100 | WIN32LIBADD= |
| 101 | case "${host}" in |
| 102 | *-*-cygwin*) |
| 103 | if test "$enable_shared" = "yes"; then |
| 104 | WIN32LDFLAGS="-no-undefined" |
| 105 | WIN32LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin" |
| 106 | fi |
| 107 | ;; |
| 108 | esac |
| 109 | AC_SUBST(WIN32LDFLAGS) |
| 110 | AC_SUBST(WIN32LIBADD) |
| 111 | |
| 112 | # target-specific stuff: |
| 113 | |
| 114 | # Canonicalize the secondary target names. |
| 115 | if test -n "$enable_targets" ; then |
| 116 | for targ in `echo $enable_targets | sed 's/,/ /g'` |
| 117 | do |
| 118 | result=`$ac_config_sub $targ 2>/dev/null` |
| 119 | if test -n "$result" ; then |
| 120 | canon_targets="$canon_targets $result" |
| 121 | else |
| 122 | # Allow targets that config.sub doesn't recognize, like "all". |
| 123 | canon_targets="$canon_targets $targ" |
| 124 | fi |
| 125 | done |
| 126 | fi |
| 127 | |
| 128 | all_targets=false |
| 129 | selarchs= |
| 130 | for targ in $target $canon_targets |
| 131 | do |
| 132 | if test "x$targ" = "xall" ; then |
| 133 | all_targets=true |
| 134 | else |
| 135 | . $srcdir/../bfd/config.bfd |
| 136 | selarchs="$selarchs $targ_archs" |
| 137 | fi |
| 138 | done |
| 139 | |
| 140 | # Utility var, documents generic cgen support files. |
| 141 | |
| 142 | cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo" |
| 143 | |
| 144 | # We don't do any links based on the target system, just makefile config. |
| 145 | |
| 146 | if test x${all_targets} = xfalse ; then |
| 147 | |
| 148 | # Target architecture .o files. |
| 149 | ta= |
| 150 | |
| 151 | for arch in $selarchs |
| 152 | do |
| 153 | ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g` |
| 154 | archdefs="$archdefs -DARCH_$ad" |
| 155 | case "$arch" in |
| 156 | bfd_alpha_arch) ta="$ta alpha-dis.lo alpha-opc.lo" ;; |
| 157 | bfd_arc_arch) ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;; |
| 158 | bfd_arm_arch) ta="$ta arm-dis.lo" ;; |
| 159 | bfd_avr_arch) ta="$ta avr-dis.lo" ;; |
| 160 | bfd_bfin_arch) ta="$ta bfin-dis.lo" ;; |
| 161 | bfd_cris_arch) ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;; |
| 162 | bfd_crx_arch) ta="$ta crx-dis.lo crx-opc.lo" ;; |
| 163 | bfd_d10v_arch) ta="$ta d10v-dis.lo d10v-opc.lo" ;; |
| 164 | bfd_d30v_arch) ta="$ta d30v-dis.lo d30v-opc.lo" ;; |
| 165 | bfd_dlx_arch) ta="$ta dlx-dis.lo" ;; |
| 166 | bfd_fr30_arch) ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;; |
| 167 | bfd_frv_arch) ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;; |
| 168 | bfd_h8300_arch) ta="$ta h8300-dis.lo" ;; |
| 169 | bfd_h8500_arch) ta="$ta h8500-dis.lo" ;; |
| 170 | bfd_hppa_arch) ta="$ta hppa-dis.lo" ;; |
| 171 | bfd_i370_arch) ta="$ta i370-dis.lo i370-opc.lo" ;; |
| 172 | bfd_i386_arch) ta="$ta i386-dis.lo" ;; |
| 173 | bfd_i860_arch) ta="$ta i860-dis.lo" ;; |
| 174 | bfd_i960_arch) ta="$ta i960-dis.lo" ;; |
| 175 | bfd_ia64_arch) ta="$ta ia64-dis.lo ia64-opc.lo" ;; |
| 176 | bfd_ip2k_arch) ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;; |
| 177 | bfd_iq2000_arch) ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;; |
| 178 | bfd_m32c_arch) ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;; |
| 179 | bfd_m32r_arch) ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;; |
| 180 | bfd_m68hc11_arch) ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;; |
| 181 | bfd_m68hc12_arch) ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;; |
| 182 | bfd_m68k_arch) ta="$ta m68k-dis.lo m68k-opc.lo" ;; |
| 183 | bfd_m88k_arch) ta="$ta m88k-dis.lo" ;; |
| 184 | bfd_maxq_arch) ta="$ta maxq-dis.lo" ;; |
| 185 | bfd_mcore_arch) ta="$ta mcore-dis.lo" ;; |
| 186 | bfd_mips_arch) ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;; |
| 187 | bfd_mmix_arch) ta="$ta mmix-dis.lo mmix-opc.lo" ;; |
| 188 | bfd_mn10200_arch) ta="$ta m10200-dis.lo m10200-opc.lo" ;; |
| 189 | bfd_mn10300_arch) ta="$ta m10300-dis.lo m10300-opc.lo" ;; |
| 190 | bfd_mt_arch) ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;; |
| 191 | bfd_msp430_arch) ta="$ta msp430-dis.lo" ;; |
| 192 | bfd_ns32k_arch) ta="$ta ns32k-dis.lo" ;; |
| 193 | bfd_openrisc_arch) ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;; |
| 194 | bfd_or32_arch) ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;; |
| 195 | bfd_pdp11_arch) ta="$ta pdp11-dis.lo pdp11-opc.lo" ;; |
| 196 | bfd_pj_arch) ta="$ta pj-dis.lo pj-opc.lo" ;; |
| 197 | bfd_powerpc_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 198 | bfd_powerpc_64_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 199 | bfd_pyramid_arch) ;; |
| 200 | bfd_romp_arch) ;; |
| 201 | bfd_rs6000_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 202 | bfd_s390_arch) ta="$ta s390-dis.lo s390-opc.lo" ;; |
| 203 | bfd_sh_arch) |
| 204 | # We can't decide what we want just from the CPU family. |
| 205 | # We want SH5 support unless a specific version of sh is |
| 206 | # specified, as in sh3-elf, sh3b-linux-gnu, etc. |
| 207 | # Include it just for ELF targets, since the SH5 bfd:s are ELF only. |
| 208 | for t in $target $canon_targets; do |
| 209 | case $t in |
| 210 | all | sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \ |
| 211 | sh-*-linux* | shl-*-linux*) |
| 212 | ta="$ta sh64-dis.lo sh64-opc.lo" |
| 213 | archdefs="$archdefs -DINCLUDE_SHMEDIA" |
| 214 | break;; |
| 215 | esac; |
| 216 | done |
| 217 | ta="$ta sh-dis.lo" ;; |
| 218 | bfd_sparc_arch) ta="$ta sparc-dis.lo sparc-opc.lo" ;; |
| 219 | bfd_tahoe_arch) ;; |
| 220 | bfd_tic30_arch) ta="$ta tic30-dis.lo" ;; |
| 221 | bfd_tic4x_arch) ta="$ta tic4x-dis.lo" ;; |
| 222 | bfd_tic54x_arch) ta="$ta tic54x-dis.lo tic54x-opc.lo" ;; |
| 223 | bfd_tic80_arch) ta="$ta tic80-dis.lo tic80-opc.lo" ;; |
| 224 | bfd_v850_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 225 | bfd_v850e_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 226 | bfd_v850ea_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 227 | bfd_vax_arch) ta="$ta vax-dis.lo" ;; |
| 228 | bfd_w65_arch) ta="$ta w65-dis.lo" ;; |
| 229 | bfd_we32k_arch) ;; |
| 230 | bfd_xc16x_arch) ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;; |
| 231 | bfd_xstormy16_arch) ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;; |
| 232 | bfd_xtensa_arch) ta="$ta xtensa-dis.lo" ;; |
| 233 | bfd_z80_arch) ta="$ta z80-dis.lo" ;; |
| 234 | bfd_z8k_arch) ta="$ta z8k-dis.lo" ;; |
| 235 | |
| 236 | "") ;; |
| 237 | *) AC_MSG_ERROR(*** unknown target architecture $arch) ;; |
| 238 | esac |
| 239 | done |
| 240 | |
| 241 | if test $using_cgen = yes ; then |
| 242 | ta="$ta $cgen_files" |
| 243 | fi |
| 244 | |
| 245 | # Weed out duplicate .o files. |
| 246 | f="" |
| 247 | for i in $ta ; do |
| 248 | case " $f " in |
| 249 | *" $i "*) ;; |
| 250 | *) f="$f $i" ;; |
| 251 | esac |
| 252 | done |
| 253 | ta="$f" |
| 254 | |
| 255 | # And duplicate -D flags. |
| 256 | f="" |
| 257 | for i in $archdefs ; do |
| 258 | case " $f " in |
| 259 | *" $i "*) ;; |
| 260 | *) f="$f $i" ;; |
| 261 | esac |
| 262 | done |
| 263 | archdefs="$f" |
| 264 | |
| 265 | BFD_MACHINES="$ta" |
| 266 | |
| 267 | else # all_targets is true |
| 268 | archdefs=-DARCH_all |
| 269 | BFD_MACHINES='$(ALL_MACHINES)' |
| 270 | fi |
| 271 | |
| 272 | AC_SUBST(archdefs) |
| 273 | AC_SUBST(BFD_MACHINES) |
| 274 | |
| 275 | AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in]) |
| 276 | AC_CONFIG_COMMANDS([default],[[sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile]],[[]]) |
| 277 | AC_OUTPUT |