| 1 | dnl Process this file with autoconf to produce a configure script. |
| 2 | dnl |
| 3 | |
| 4 | AC_PREREQ(2.59) |
| 5 | AC_INIT |
| 6 | AC_CONFIG_SRCDIR([z8k-dis.c]) |
| 7 | |
| 8 | AC_CANONICAL_TARGET |
| 9 | AC_ISC_POSIX |
| 10 | |
| 11 | # We currently only use the version number for the name of any shared |
| 12 | # library. For user convenience, we always use the same version |
| 13 | # number that BFD is using. |
| 14 | changequote(,)dnl |
| 15 | BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[ ]*\([^ ]*\)[ ]*).*/\1/p' < ${srcdir}/../bfd/configure.in` |
| 16 | changequote([,])dnl |
| 17 | |
| 18 | AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION}) |
| 19 | |
| 20 | AC_PROG_CC |
| 21 | AC_GNU_SOURCE |
| 22 | AC_USE_SYSTEM_EXTENSIONS |
| 23 | |
| 24 | dnl These must be called before LT_INIT, because it may want |
| 25 | dnl to call AC_CHECK_PROG. |
| 26 | AC_CHECK_TOOL(AR, ar) |
| 27 | AC_CHECK_TOOL(RANLIB, ranlib, :) |
| 28 | |
| 29 | dnl Default to a non shared library. This may be overridden by the |
| 30 | dnl configure option --enable-shared. |
| 31 | AC_DISABLE_SHARED |
| 32 | |
| 33 | LT_INIT |
| 34 | |
| 35 | AC_ARG_ENABLE(targets, |
| 36 | [ --enable-targets alternative target configurations], |
| 37 | [case "${enableval}" in |
| 38 | yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all']) |
| 39 | ;; |
| 40 | no) enable_targets= ;; |
| 41 | *) enable_targets=$enableval ;; |
| 42 | esac])dnl |
| 43 | |
| 44 | AM_BINUTILS_WARNINGS |
| 45 | |
| 46 | AC_CONFIG_HEADERS(config.h:config.in) |
| 47 | |
| 48 | if test -z "$target" ; then |
| 49 | AC_MSG_ERROR(Unrecognized target system type; please check config.sub.) |
| 50 | fi |
| 51 | |
| 52 | AM_MAINTAINER_MODE |
| 53 | AM_INSTALL_LIBBFD |
| 54 | AC_EXEEXT |
| 55 | |
| 56 | # host-specific stuff: |
| 57 | |
| 58 | ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN" |
| 59 | ZW_GNU_GETTEXT_SISTER_DIR |
| 60 | AM_PO_SUBDIRS |
| 61 | |
| 62 | . ${srcdir}/../bfd/configure.host |
| 63 | |
| 64 | BFD_CC_FOR_BUILD |
| 65 | |
| 66 | AC_SUBST(HDEFINES) |
| 67 | AC_PROG_INSTALL |
| 68 | |
| 69 | AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h) |
| 70 | |
| 71 | AC_CHECK_DECLS([basename, stpcpy]) |
| 72 | |
| 73 | cgen_maint=no |
| 74 | cgendir='$(srcdir)/../cgen' |
| 75 | |
| 76 | AC_ARG_ENABLE(cgen-maint, |
| 77 | [ --enable-cgen-maint[=dir] build cgen generated files], |
| 78 | [case "${enableval}" in |
| 79 | yes) cgen_maint=yes ;; |
| 80 | no) cgen_maint=no ;; |
| 81 | *) |
| 82 | # argument is cgen install directory (not implemented yet). |
| 83 | # Having a `share' directory might be more appropriate for the .scm, |
| 84 | # .cpu, etc. files. |
| 85 | cgen_maint=yes |
| 86 | cgendir=${cgen_maint}/lib/cgen |
| 87 | ;; |
| 88 | esac])dnl |
| 89 | AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes) |
| 90 | AC_SUBST(cgendir) |
| 91 | |
| 92 | using_cgen=no |
| 93 | |
| 94 | # Check if linker supports --as-needed and --no-as-needed options |
| 95 | AC_CACHE_CHECK(linker --as-needed support, bfd_cv_ld_as_needed, |
| 96 | [bfd_cv_ld_as_needed=no |
| 97 | if $LD --help 2>/dev/null | grep as-needed > /dev/null; then |
| 98 | bfd_cv_ld_as_needed=yes |
| 99 | fi |
| 100 | ]) |
| 101 | |
| 102 | LT_LIB_M |
| 103 | |
| 104 | #Libs for generator progs |
| 105 | if test "x$cross_compiling" = "xno"; then |
| 106 | BUILD_LIBS=../libiberty/libiberty.a |
| 107 | BUILD_LIB_DEPS=$BUILD_LIBS |
| 108 | else |
| 109 | # if cross-compiling, assume that the system provides -liberty |
| 110 | # and that the version is compatible with new headers. |
| 111 | BUILD_LIBS=-liberty |
| 112 | BUILD_LIB_DEPS= |
| 113 | fi |
| 114 | BUILD_LIBS="$BUILD_LIBS $LIBINTL" |
| 115 | BUILD_LIB_DEPS="$BUILD_LIB_DEPS $LIBINTL_DEP" |
| 116 | |
| 117 | AC_SUBST(BUILD_LIBS) |
| 118 | AC_SUBST(BUILD_LIB_DEPS) |
| 119 | |
| 120 | # Horrible hacks to build DLLs on Windows and a shared library elsewhere. |
| 121 | SHARED_LDFLAGS= |
| 122 | SHARED_LIBADD= |
| 123 | SHARED_DEPENDENCIES= |
| 124 | if test "$enable_shared" = "yes"; then |
| 125 | # When building a shared libopcodes, link against the pic version of libiberty |
| 126 | # so that apps that use libopcodes won't need libiberty just to satisfy any |
| 127 | # libopcodes references. |
| 128 | # We can't do that if a pic libiberty is unavailable since including non-pic |
| 129 | # code would insert text relocations into libopcodes. |
| 130 | # Note that linking against libbfd as we do here, which is itself linked |
| 131 | # against libiberty, may not satisfy all the libopcodes libiberty references |
| 132 | # since libbfd may not pull in the entirety of libiberty. |
| 133 | changequote(,)dnl |
| 134 | x=`sed -n -e 's/^[ ]*PICFLAG[ ]*=[ ]*//p' < ../libiberty/Makefile | sed -n '$p'` |
| 135 | changequote([,])dnl |
| 136 | if test -n "$x"; then |
| 137 | SHARED_LIBADD="-L`pwd`/../libiberty/pic -liberty" |
| 138 | fi |
| 139 | |
| 140 | case "${host}" in |
| 141 | *-*-cygwin*) |
| 142 | SHARED_LDFLAGS="-no-undefined" |
| 143 | SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin" |
| 144 | ;; |
| 145 | *-*-darwin*) |
| 146 | SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib ${SHARED_LIBADD}" |
| 147 | SHARED_DEPENDENCIES="../bfd/libbfd.la" |
| 148 | ;; |
| 149 | *) |
| 150 | case "$host_vendor" in |
| 151 | hp) |
| 152 | SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl ${SHARED_LIBADD}" |
| 153 | ;; |
| 154 | *) |
| 155 | SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so ${SHARED_LIBADD}" |
| 156 | ;; |
| 157 | esac |
| 158 | SHARED_DEPENDENCIES="../bfd/libbfd.la" |
| 159 | ;; |
| 160 | esac |
| 161 | |
| 162 | if test -n "$SHARED_LIBADD"; then |
| 163 | if test -n "$LIBM"; then |
| 164 | if test x"$bfd_cv_ld_as_needed" = xyes; then |
| 165 | # Link against libm only when needed. Put -lc, -lm inside -Wl |
| 166 | # to stop libtool reordering these options. |
| 167 | SHARED_LIBADD="$SHARED_LIBADD -Wl,-lc,--as-needed,`echo $LIBM | sed 's/ /,/g'`,--no-as-needed" |
| 168 | else |
| 169 | SHARED_LIBADD="$SHARED_LIBADD $LIBM" |
| 170 | fi |
| 171 | fi |
| 172 | fi |
| 173 | fi |
| 174 | AC_SUBST(SHARED_LDFLAGS) |
| 175 | AC_SUBST(SHARED_LIBADD) |
| 176 | AC_SUBST(SHARED_DEPENDENCIES) |
| 177 | |
| 178 | # target-specific stuff: |
| 179 | |
| 180 | # Canonicalize the secondary target names. |
| 181 | if test -n "$enable_targets" ; then |
| 182 | for targ in `echo $enable_targets | sed 's/,/ /g'` |
| 183 | do |
| 184 | result=`$ac_config_sub $targ 2>/dev/null` |
| 185 | if test -n "$result" ; then |
| 186 | canon_targets="$canon_targets $result" |
| 187 | else |
| 188 | # Allow targets that config.sub doesn't recognize, like "all". |
| 189 | canon_targets="$canon_targets $targ" |
| 190 | fi |
| 191 | done |
| 192 | fi |
| 193 | |
| 194 | all_targets=false |
| 195 | selarchs= |
| 196 | for targ in $target $canon_targets |
| 197 | do |
| 198 | if test "x$targ" = "xall" ; then |
| 199 | all_targets=true |
| 200 | else |
| 201 | . $srcdir/../bfd/config.bfd |
| 202 | selarchs="$selarchs $targ_archs" |
| 203 | fi |
| 204 | done |
| 205 | |
| 206 | # Utility var, documents generic cgen support files. |
| 207 | |
| 208 | cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo" |
| 209 | |
| 210 | # We don't do any links based on the target system, just makefile config. |
| 211 | |
| 212 | if test x${all_targets} = xfalse ; then |
| 213 | |
| 214 | # Target architecture .o files. |
| 215 | ta= |
| 216 | |
| 217 | for arch in $selarchs |
| 218 | do |
| 219 | ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g` |
| 220 | archdefs="$archdefs -DARCH_$ad" |
| 221 | case "$arch" in |
| 222 | bfd_alpha_arch) ta="$ta alpha-dis.lo alpha-opc.lo" ;; |
| 223 | bfd_arc_arch) ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;; |
| 224 | bfd_arm_arch) ta="$ta arm-dis.lo" ;; |
| 225 | bfd_avr_arch) ta="$ta avr-dis.lo" ;; |
| 226 | bfd_bfin_arch) ta="$ta bfin-dis.lo" ;; |
| 227 | bfd_cr16_arch) ta="$ta cr16-dis.lo cr16-opc.lo" ;; |
| 228 | bfd_cris_arch) ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;; |
| 229 | bfd_crx_arch) ta="$ta crx-dis.lo crx-opc.lo" ;; |
| 230 | bfd_d10v_arch) ta="$ta d10v-dis.lo d10v-opc.lo" ;; |
| 231 | bfd_d30v_arch) ta="$ta d30v-dis.lo d30v-opc.lo" ;; |
| 232 | bfd_dlx_arch) ta="$ta dlx-dis.lo" ;; |
| 233 | bfd_fr30_arch) ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;; |
| 234 | bfd_frv_arch) ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;; |
| 235 | bfd_moxie_arch) ta="$ta moxie-dis.lo moxie-opc.lo" ;; |
| 236 | bfd_h8300_arch) ta="$ta h8300-dis.lo" ;; |
| 237 | bfd_h8500_arch) ta="$ta h8500-dis.lo" ;; |
| 238 | bfd_hppa_arch) ta="$ta hppa-dis.lo" ;; |
| 239 | bfd_i370_arch) ta="$ta i370-dis.lo i370-opc.lo" ;; |
| 240 | bfd_i386_arch|bfd_l1om_arch) |
| 241 | ta="$ta i386-dis.lo i386-opc.lo" ;; |
| 242 | bfd_i860_arch) ta="$ta i860-dis.lo" ;; |
| 243 | bfd_i960_arch) ta="$ta i960-dis.lo" ;; |
| 244 | bfd_ia64_arch) ta="$ta ia64-dis.lo ia64-opc.lo" ;; |
| 245 | bfd_ip2k_arch) ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;; |
| 246 | bfd_iq2000_arch) ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;; |
| 247 | bfd_lm32_arch) ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;; |
| 248 | bfd_m32c_arch) ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;; |
| 249 | bfd_m32r_arch) ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;; |
| 250 | bfd_m68hc11_arch) ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;; |
| 251 | bfd_m68hc12_arch) ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;; |
| 252 | bfd_m68k_arch) ta="$ta m68k-dis.lo m68k-opc.lo" ;; |
| 253 | bfd_m88k_arch) ta="$ta m88k-dis.lo" ;; |
| 254 | bfd_maxq_arch) ta="$ta maxq-dis.lo" ;; |
| 255 | bfd_mcore_arch) ta="$ta mcore-dis.lo" ;; |
| 256 | bfd_mep_arch) ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;; |
| 257 | bfd_microblaze_arch) ta="$ta microblaze-dis.lo" ;; |
| 258 | bfd_mips_arch) ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;; |
| 259 | bfd_mmix_arch) ta="$ta mmix-dis.lo mmix-opc.lo" ;; |
| 260 | bfd_mn10200_arch) ta="$ta m10200-dis.lo m10200-opc.lo" ;; |
| 261 | bfd_mn10300_arch) ta="$ta m10300-dis.lo m10300-opc.lo" ;; |
| 262 | bfd_mt_arch) ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;; |
| 263 | bfd_msp430_arch) ta="$ta msp430-dis.lo" ;; |
| 264 | bfd_ns32k_arch) ta="$ta ns32k-dis.lo" ;; |
| 265 | bfd_openrisc_arch) ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;; |
| 266 | bfd_or32_arch) ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;; |
| 267 | bfd_pdp11_arch) ta="$ta pdp11-dis.lo pdp11-opc.lo" ;; |
| 268 | bfd_pj_arch) ta="$ta pj-dis.lo pj-opc.lo" ;; |
| 269 | bfd_powerpc_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 270 | bfd_powerpc_64_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 271 | bfd_pyramid_arch) ;; |
| 272 | bfd_romp_arch) ;; |
| 273 | bfd_rs6000_arch) ta="$ta ppc-dis.lo ppc-opc.lo" ;; |
| 274 | bfd_rx_arch) ta="$ta rx-dis.lo rx-decode.lo";; |
| 275 | bfd_s390_arch) ta="$ta s390-dis.lo s390-opc.lo" ;; |
| 276 | bfd_score_arch) ta="$ta score-dis.lo score7-dis.lo" ;; |
| 277 | bfd_sh_arch) |
| 278 | # We can't decide what we want just from the CPU family. |
| 279 | # We want SH5 support unless a specific version of sh is |
| 280 | # specified, as in sh3-elf, sh3b-linux-gnu, etc. |
| 281 | # Include it just for ELF targets, since the SH5 bfd:s are ELF only. |
| 282 | for t in $target $canon_targets; do |
| 283 | case $t in |
| 284 | all | sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \ |
| 285 | sh-*-linux* | shl-*-linux*) |
| 286 | ta="$ta sh64-dis.lo sh64-opc.lo" |
| 287 | archdefs="$archdefs -DINCLUDE_SHMEDIA" |
| 288 | break;; |
| 289 | esac; |
| 290 | done |
| 291 | ta="$ta sh-dis.lo cgen-bitset.lo" ;; |
| 292 | bfd_sparc_arch) ta="$ta sparc-dis.lo sparc-opc.lo" ;; |
| 293 | bfd_spu_arch) ta="$ta spu-dis.lo spu-opc.lo" ;; |
| 294 | bfd_tahoe_arch) ;; |
| 295 | bfd_tic30_arch) ta="$ta tic30-dis.lo" ;; |
| 296 | bfd_tic4x_arch) ta="$ta tic4x-dis.lo" ;; |
| 297 | bfd_tic54x_arch) ta="$ta tic54x-dis.lo tic54x-opc.lo" ;; |
| 298 | bfd_tic80_arch) ta="$ta tic80-dis.lo tic80-opc.lo" ;; |
| 299 | bfd_v850_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 300 | bfd_v850e_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 301 | bfd_v850ea_arch) ta="$ta v850-opc.lo v850-dis.lo" ;; |
| 302 | bfd_vax_arch) ta="$ta vax-dis.lo" ;; |
| 303 | bfd_w65_arch) ta="$ta w65-dis.lo" ;; |
| 304 | bfd_we32k_arch) ;; |
| 305 | bfd_xc16x_arch) ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;; |
| 306 | bfd_xstormy16_arch) ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;; |
| 307 | bfd_xtensa_arch) ta="$ta xtensa-dis.lo" ;; |
| 308 | bfd_z80_arch) ta="$ta z80-dis.lo" ;; |
| 309 | bfd_z8k_arch) ta="$ta z8k-dis.lo" ;; |
| 310 | |
| 311 | "") ;; |
| 312 | *) AC_MSG_ERROR(*** unknown target architecture $arch) ;; |
| 313 | esac |
| 314 | done |
| 315 | |
| 316 | if test $using_cgen = yes ; then |
| 317 | ta="$ta $cgen_files" |
| 318 | fi |
| 319 | |
| 320 | # Weed out duplicate .o files. |
| 321 | f="" |
| 322 | for i in $ta ; do |
| 323 | case " $f " in |
| 324 | *" $i "*) ;; |
| 325 | *) f="$f $i" ;; |
| 326 | esac |
| 327 | done |
| 328 | ta="$f" |
| 329 | |
| 330 | # And duplicate -D flags. |
| 331 | f="" |
| 332 | for i in $archdefs ; do |
| 333 | case " $f " in |
| 334 | *" $i "*) ;; |
| 335 | *) f="$f $i" ;; |
| 336 | esac |
| 337 | done |
| 338 | archdefs="$f" |
| 339 | |
| 340 | BFD_MACHINES="$ta" |
| 341 | |
| 342 | else # all_targets is true |
| 343 | archdefs=-DARCH_all |
| 344 | BFD_MACHINES='$(ALL_MACHINES)' |
| 345 | fi |
| 346 | |
| 347 | AC_SUBST(archdefs) |
| 348 | AC_SUBST(BFD_MACHINES) |
| 349 | |
| 350 | AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in]) |
| 351 | AC_OUTPUT |