| 1 | lexer grammar CTFLexer; |
| 2 | |
| 3 | options { |
| 4 | language = Java; |
| 5 | } |
| 6 | |
| 7 | @lexer::header { |
| 8 | package org.eclipse.linuxtools.ctf.parser; |
| 9 | } |
| 10 | |
| 11 | /* |
| 12 | * Lexer grammers |
| 13 | */ |
| 14 | |
| 15 | /* |
| 16 | * Keywords |
| 17 | */ |
| 18 | ALIGNTOK : 'align' ; |
| 19 | CONSTTOK : 'const' ; |
| 20 | CHARTOK : 'char' ; |
| 21 | DOUBLETOK : 'double' ; |
| 22 | ENUMTOK : 'enum' ; |
| 23 | EVENTTOK : 'event' ; |
| 24 | FLOATINGPOINTTOK : 'floating_point' ; |
| 25 | FLOATTOK : 'float' ; |
| 26 | INTEGERTOK : 'integer' ; |
| 27 | INTTOK : 'int' ; |
| 28 | LONGTOK : 'long' ; |
| 29 | SHORTTOK : 'short' ; |
| 30 | SIGNEDTOK : 'signed' ; |
| 31 | STREAMTOK : 'stream' ; |
| 32 | STRINGTOK : 'string' ; |
| 33 | STRUCTTOK : 'struct' ; |
| 34 | TRACETOK : 'trace' ; |
| 35 | TYPEALIASTOK : 'typealias' ; |
| 36 | TYPEDEFTOK : 'typedef' ; |
| 37 | UNSIGNEDTOK : 'unsigned' ; |
| 38 | VARIANTTOK : 'variant' ; |
| 39 | VOIDTOK : 'void' ; |
| 40 | BOOLTOK : '_Bool' ; |
| 41 | COMPLEXTOK : '_Complex' ; |
| 42 | IMAGINARYTOK : '_Imaginary' ; |
| 43 | ENVTOK : 'env' ; |
| 44 | CLOCKTOK : 'clock' ; |
| 45 | /* |
| 46 | * Callsite tokens (v1.9) |
| 47 | */ |
| 48 | CALLSITETOK : 'callsite' ; |
| 49 | |
| 50 | |
| 51 | /* |
| 52 | * Spec still to come. |
| 53 | */ |
| 54 | NANNUMBERTOK : 'NaN' ; |
| 55 | INFINITYTOK : '+inf' ; |
| 56 | NINFINITYTOK : '-inf' ; |
| 57 | |
| 58 | /* |
| 59 | * Symbols |
| 60 | */ |
| 61 | SEPARATOR : ',' ; |
| 62 | COLON : ':' ; |
| 63 | ELIPSES : '...' ; |
| 64 | ASSIGNMENT : '=' ; |
| 65 | TYPE_ASSIGNMENT : ':=' ; |
| 66 | LT : '<' ; |
| 67 | GT : '>' ; |
| 68 | OPENBRAC : '[' ; |
| 69 | CLOSEBRAC : ']' ; |
| 70 | LPAREN : '(' ; |
| 71 | RPAREN : ')' ; |
| 72 | LCURL : '{' ; |
| 73 | RCURL : '}' ; |
| 74 | TERM : ';' ; |
| 75 | POINTER : '*' ; |
| 76 | SIGN : '+' | '-' ; |
| 77 | ARROW : '->' ; |
| 78 | DOT : '.' ; |
| 79 | fragment BACKSLASH : '\\' ; |
| 80 | |
| 81 | |
| 82 | /* |
| 83 | * Integer literals |
| 84 | */ |
| 85 | OCTAL_LITERAL : '0' ('0'..'7')+ INTEGER_TYPES_SUFFIX? ; |
| 86 | |
| 87 | DECIMAL_LITERAL : DIGIT+ INTEGER_TYPES_SUFFIX? ; |
| 88 | |
| 89 | HEX_LITERAL : HEX_PREFIX HEX_DIGIT+ INTEGER_TYPES_SUFFIX? ; |
| 90 | fragment HEX_DIGIT : DIGIT | ('a'..'f') | ('A'..'F') ; |
| 91 | fragment HEX_PREFIX : '0' ('x' | 'X') ; |
| 92 | |
| 93 | /* Helpers for integer literals */ |
| 94 | fragment DIGIT : '0'..'9' ; |
| 95 | fragment NONZERO_DIGIT : '1'..'9' ; |
| 96 | |
| 97 | |
| 98 | /** |
| 99 | * Integer suffix for long, long long and unsigned. |
| 100 | * |
| 101 | * Matches all possible combination of L, LL and U. |
| 102 | */ |
| 103 | fragment INTEGER_TYPES_SUFFIX : |
| 104 | ('l' ('l')? | 'L' ('L')?) // l, ll |
| 105 | | ('u' | 'U') // u |
| 106 | | ('u' | 'U') ('l' ('l')? | 'L' ('L')?) // ul, ull |
| 107 | | ('l' ('l')? | 'L' ('L')?) ('u'| 'U') // lu, llu |
| 108 | ; |
| 109 | |
| 110 | /** |
| 111 | * Escape sequences |
| 112 | */ |
| 113 | fragment ESCAPE_SEQUENCE : |
| 114 | BACKSLASH ('\'' | '"' | '?' | BACKSLASH | 'a' | 'b' | 'f' | 'n' | 'r' | 't' | 'v' ) |
| 115 | | OCTAL_ESCAPE |
| 116 | | UNICODE_ESCAPE |
| 117 | | HEXADECIMAL_ESCAPE |
| 118 | ; |
| 119 | |
| 120 | /** |
| 121 | * Octal escape sequence |
| 122 | */ |
| 123 | fragment OCTAL_ESCAPE : |
| 124 | BACKSLASH ('0'..'3') ('0'..'7') ('0'..'7') |
| 125 | | BACKSLASH ('0'..'7') ('0'..'7') |
| 126 | | BACKSLASH ('0'..'7') |
| 127 | ; |
| 128 | |
| 129 | /** |
| 130 | * Hexadecimal escape sequence |
| 131 | */ |
| 132 | fragment HEXADECIMAL_ESCAPE : BACKSLASH 'x' HEX_DIGIT+ ; |
| 133 | |
| 134 | /** |
| 135 | * Unicode escape sequence |
| 136 | */ |
| 137 | fragment UNICODE_ESCAPE : |
| 138 | BACKSLASH 'u' HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT |
| 139 | | BACKSLASH 'U' HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT HEX_DIGIT |
| 140 | ; |
| 141 | |
| 142 | |
| 143 | /* Used in both character and string literal */ |
| 144 | fragment STRINGPREFIX : 'L'; |
| 145 | |
| 146 | /* |
| 147 | * Character literal |
| 148 | */ |
| 149 | CHARACTER_LITERAL : STRINGPREFIX? SINGLEQUOTE CHAR_CONTENT+ SINGLEQUOTE ; |
| 150 | fragment CHAR_CONTENT : (ESCAPE_SEQUENCE | ~(BACKSLASH | SINGLEQUOTE)) ; |
| 151 | fragment SINGLEQUOTE : '\''; |
| 152 | |
| 153 | /* |
| 154 | * String literal |
| 155 | */ |
| 156 | STRING_LITERAL : STRINGPREFIX? DOUBLEQUOTE STRING_CONTENT* DOUBLEQUOTE ; |
| 157 | fragment STRING_CONTENT : (ESCAPE_SEQUENCE | ~(BACKSLASH | DOUBLEQUOTE)) ; |
| 158 | fragment DOUBLEQUOTE : '"' ; |
| 159 | |
| 160 | /** |
| 161 | * Whitespaces |
| 162 | */ |
| 163 | WS : (' ' | '\r' | '\t' | '\u000C' | '\n') { $channel=HIDDEN; } ; |
| 164 | |
| 165 | /** |
| 166 | * Multiline comment |
| 167 | */ |
| 168 | // About the greedy option: see page 100-101 of The Definitive ANTLR reference |
| 169 | // COMMENT : '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;} ; |
| 170 | COMMENT : COMMENT_OPEN .* COMMENT_CLOSE { $channel = HIDDEN; } ; |
| 171 | fragment COMMENT_OPEN : '/*'; |
| 172 | fragment COMMENT_CLOSE : '*/'; |
| 173 | |
| 174 | /** |
| 175 | * Single line comment |
| 176 | */ |
| 177 | LINE_COMMENT : '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;} ; |
| 178 | |
| 179 | /** |
| 180 | * Identifiers |
| 181 | */ |
| 182 | IDENTIFIER : NONDIGIT (NONDIGIT | DIGIT)* ; |
| 183 | fragment NONDIGIT : ('_') | ('A'..'Z') | ('a'..'z') ; |