| 1 | #!/usr/bin/perl -w |
| 2 | # |
| 3 | # headers_install prepare the listed header files for use in |
| 4 | # user space and copy the files to their destination. |
| 5 | # |
| 6 | # Usage: headers_install.pl readdir installdir arch [files...] |
| 7 | # installdir: dir to install the files to |
| 8 | # arch: current architecture |
| 9 | # arch is used to force a reinstallation when the arch |
| 10 | # changes because kbuild then detect a command line change. |
| 11 | # files: list of files to check |
| 12 | # |
| 13 | # Step in preparation for users space: |
| 14 | # 1) Drop all use of compiler.h definitions |
| 15 | # 2) Drop include of compiler.h |
| 16 | # 3) Drop all sections defined out by __KERNEL__ (using unifdef) |
| 17 | |
| 18 | use strict; |
| 19 | |
| 20 | my ($installdir, $arch, @files) = @ARGV; |
| 21 | |
| 22 | my $unifdef = "scripts/unifdef -U__KERNEL__ -D__EXPORTED_HEADERS__"; |
| 23 | |
| 24 | foreach my $filename (@files) { |
| 25 | my $file = $filename; |
| 26 | $file =~ s!^.*/!!; |
| 27 | |
| 28 | my $tmpfile = "$installdir/$file.tmp"; |
| 29 | |
| 30 | open(my $in, '<', $filename) |
| 31 | or die "$filename: $!\n"; |
| 32 | open(my $out, '>', $tmpfile) |
| 33 | or die "$tmpfile: $!\n"; |
| 34 | while (my $line = <$in>) { |
| 35 | $line =~ s/([\s(])__user\s/$1/g; |
| 36 | $line =~ s/([\s(])__force\s/$1/g; |
| 37 | $line =~ s/([\s(])__iomem\s/$1/g; |
| 38 | $line =~ s/\s__attribute_const__\s/ /g; |
| 39 | $line =~ s/\s__attribute_const__$//g; |
| 40 | $line =~ s/\b__packed\b/__attribute__((packed))/g; |
| 41 | $line =~ s/^#include <linux\/compiler.h>//; |
| 42 | $line =~ s/(^|\s)(inline)\b/$1__$2__/g; |
| 43 | $line =~ s/(^|\s)(asm)\b(\s|[(]|$)/$1__$2__$3/g; |
| 44 | $line =~ s/(^|\s|[(])(volatile)\b(\s|[(]|$)/$1__$2__$3/g; |
| 45 | $line =~ s/#ifndef\s+_UAPI/#ifndef /; |
| 46 | $line =~ s/#define\s+_UAPI/#define /; |
| 47 | $line =~ s!#endif\s+/[*]\s*_UAPI!#endif /* !; |
| 48 | printf {$out} "%s", $line; |
| 49 | } |
| 50 | close $out; |
| 51 | close $in; |
| 52 | |
| 53 | system $unifdef . " $tmpfile > $installdir/$file"; |
| 54 | # unifdef will exit 0 on success, and will exit 1 when the |
| 55 | # file was processed successfully but no changes were made, |
| 56 | # so abort only when it's higher than that. |
| 57 | my $e = $? >> 8; |
| 58 | if ($e > 1) { |
| 59 | die "$tmpfile: $!\n"; |
| 60 | } |
| 61 | unlink $tmpfile; |
| 62 | } |
| 63 | exit 0; |