| 1 | #!/usr/bin/perl -w |
| 2 | # (c) 2008, Steven Rostedt <srostedt@redhat.com> |
| 3 | # Licensed under the terms of the GNU GPL License version 2 |
| 4 | # |
| 5 | # recordmcount.pl - makes a section called __mcount_loc that holds |
| 6 | # all the offsets to the calls to mcount. |
| 7 | # |
| 8 | # |
| 9 | # What we want to end up with this is that each object file will have a |
| 10 | # section called __mcount_loc that will hold the list of pointers to mcount |
| 11 | # callers. After final linking, the vmlinux will have within .init.data the |
| 12 | # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc. |
| 13 | # Later on boot up, the kernel will read this list, save the locations and turn |
| 14 | # them into nops. When tracing or profiling is later enabled, these locations |
| 15 | # will then be converted back to pointers to some function. |
| 16 | # |
| 17 | # This is no easy feat. This script is called just after the original |
| 18 | # object is compiled and before it is linked. |
| 19 | # |
| 20 | # When parse this object file using 'objdump', the references to the call |
| 21 | # sites are offsets from the section that the call site is in. Hence, all |
| 22 | # functions in a section that has a call site to mcount, will have the |
| 23 | # offset from the beginning of the section and not the beginning of the |
| 24 | # function. |
| 25 | # |
| 26 | # But where this section will reside finally in vmlinx is undetermined at |
| 27 | # this point. So we can't use this kind of offsets to record the final |
| 28 | # address of this call site. |
| 29 | # |
| 30 | # The trick is to change the call offset referring the start of a section to |
| 31 | # referring a function symbol in this section. During the link step, 'ld' will |
| 32 | # compute the final address according to the information we record. |
| 33 | # |
| 34 | # e.g. |
| 35 | # |
| 36 | # .section ".sched.text", "ax" |
| 37 | # [...] |
| 38 | # func1: |
| 39 | # [...] |
| 40 | # call mcount (offset: 0x10) |
| 41 | # [...] |
| 42 | # ret |
| 43 | # .globl fun2 |
| 44 | # func2: (offset: 0x20) |
| 45 | # [...] |
| 46 | # [...] |
| 47 | # ret |
| 48 | # func3: |
| 49 | # [...] |
| 50 | # call mcount (offset: 0x30) |
| 51 | # [...] |
| 52 | # |
| 53 | # Both relocation offsets for the mcounts in the above example will be |
| 54 | # offset from .sched.text. If we choose global symbol func2 as a reference and |
| 55 | # make another file called tmp.s with the new offsets: |
| 56 | # |
| 57 | # .section __mcount_loc |
| 58 | # .quad func2 - 0x10 |
| 59 | # .quad func2 + 0x10 |
| 60 | # |
| 61 | # We can then compile this tmp.s into tmp.o, and link it back to the original |
| 62 | # object. |
| 63 | # |
| 64 | # In our algorithm, we will choose the first global function we meet in this |
| 65 | # section as the reference. But this gets hard if there is no global functions |
| 66 | # in this section. In such a case we have to select a local one. E.g. func1: |
| 67 | # |
| 68 | # .section ".sched.text", "ax" |
| 69 | # func1: |
| 70 | # [...] |
| 71 | # call mcount (offset: 0x10) |
| 72 | # [...] |
| 73 | # ret |
| 74 | # func2: |
| 75 | # [...] |
| 76 | # call mcount (offset: 0x20) |
| 77 | # [...] |
| 78 | # .section "other.section" |
| 79 | # |
| 80 | # If we make the tmp.s the same as above, when we link together with |
| 81 | # the original object, we will end up with two symbols for func1: |
| 82 | # one local, one global. After final compile, we will end up with |
| 83 | # an undefined reference to func1 or a wrong reference to another global |
| 84 | # func1 in other files. |
| 85 | # |
| 86 | # Since local objects can reference local variables, we need to find |
| 87 | # a way to make tmp.o reference the local objects of the original object |
| 88 | # file after it is linked together. To do this, we convert func1 |
| 89 | # into a global symbol before linking tmp.o. Then after we link tmp.o |
| 90 | # we will only have a single symbol for func1 that is global. |
| 91 | # We can convert func1 back into a local symbol and we are done. |
| 92 | # |
| 93 | # Here are the steps we take: |
| 94 | # |
| 95 | # 1) Record all the local and weak symbols by using 'nm' |
| 96 | # 2) Use objdump to find all the call site offsets and sections for |
| 97 | # mcount. |
| 98 | # 3) Compile the list into its own object. |
| 99 | # 4) Do we have to deal with local functions? If not, go to step 8. |
| 100 | # 5) Make an object that converts these local functions to global symbols |
| 101 | # with objcopy. |
| 102 | # 6) Link together this new object with the list object. |
| 103 | # 7) Convert the local functions back to local symbols and rename |
| 104 | # the result as the original object. |
| 105 | # 8) Link the object with the list object. |
| 106 | # 9) Move the result back to the original object. |
| 107 | # |
| 108 | |
| 109 | use strict; |
| 110 | |
| 111 | my $P = $0; |
| 112 | $P =~ s@.*/@@g; |
| 113 | |
| 114 | my $V = '0.1'; |
| 115 | |
| 116 | if ($#ARGV != 11) { |
| 117 | print "usage: $P arch endian bits objdump objcopy cc ld nm rm mv is_module inputfile\n"; |
| 118 | print "version: $V\n"; |
| 119 | exit(1); |
| 120 | } |
| 121 | |
| 122 | my ($arch, $endian, $bits, $objdump, $objcopy, $cc, |
| 123 | $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV; |
| 124 | |
| 125 | # This file refers to mcount and shouldn't be ftraced, so lets' ignore it |
| 126 | if ($inputfile =~ m,kernel/trace/ftrace\.o$,) { |
| 127 | exit(0); |
| 128 | } |
| 129 | |
| 130 | # Acceptable sections to record. |
| 131 | my %text_sections = ( |
| 132 | ".text" => 1, |
| 133 | ".ref.text" => 1, |
| 134 | ".sched.text" => 1, |
| 135 | ".spinlock.text" => 1, |
| 136 | ".irqentry.text" => 1, |
| 137 | ".kprobes.text" => 1, |
| 138 | ".text.unlikely" => 1, |
| 139 | ); |
| 140 | |
| 141 | # Note: we are nice to C-programmers here, thus we skip the '||='-idiom. |
| 142 | $objdump = 'objdump' if (!$objdump); |
| 143 | $objcopy = 'objcopy' if (!$objcopy); |
| 144 | $cc = 'gcc' if (!$cc); |
| 145 | $ld = 'ld' if (!$ld); |
| 146 | $nm = 'nm' if (!$nm); |
| 147 | $rm = 'rm' if (!$rm); |
| 148 | $mv = 'mv' if (!$mv); |
| 149 | |
| 150 | #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " . |
| 151 | # "'$nm' '$rm' '$mv' '$inputfile'\n"; |
| 152 | |
| 153 | my %locals; # List of local (static) functions |
| 154 | my %weak; # List of weak functions |
| 155 | my %convert; # List of local functions used that needs conversion |
| 156 | |
| 157 | my $type; |
| 158 | my $local_regex; # Match a local function (return function) |
| 159 | my $weak_regex; # Match a weak function (return function) |
| 160 | my $section_regex; # Find the start of a section |
| 161 | my $function_regex; # Find the name of a function |
| 162 | # (return offset and func name) |
| 163 | my $mcount_regex; # Find the call site to mcount (return offset) |
| 164 | my $mcount_adjust; # Address adjustment to mcount offset |
| 165 | my $alignment; # The .align value to use for $mcount_section |
| 166 | my $section_type; # Section header plus possible alignment command |
| 167 | my $can_use_local = 0; # If we can use local function references |
| 168 | |
| 169 | # Shut up recordmcount if user has older objcopy |
| 170 | my $quiet_recordmcount = ".tmp_quiet_recordmcount"; |
| 171 | my $print_warning = 1; |
| 172 | $print_warning = 0 if ( -f $quiet_recordmcount); |
| 173 | |
| 174 | ## |
| 175 | # check_objcopy - whether objcopy supports --globalize-symbols |
| 176 | # |
| 177 | # --globalize-symbols came out in 2.17, we must test the version |
| 178 | # of objcopy, and if it is less than 2.17, then we can not |
| 179 | # record local functions. |
| 180 | sub check_objcopy |
| 181 | { |
| 182 | open (IN, "$objcopy --version |") or die "error running $objcopy"; |
| 183 | while (<IN>) { |
| 184 | if (/objcopy.*\s(\d+)\.(\d+)/) { |
| 185 | $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17)); |
| 186 | last; |
| 187 | } |
| 188 | } |
| 189 | close (IN); |
| 190 | |
| 191 | if (!$can_use_local && $print_warning) { |
| 192 | print STDERR "WARNING: could not find objcopy version or version " . |
| 193 | "is less than 2.17.\n" . |
| 194 | "\tLocal function references are disabled.\n"; |
| 195 | open (QUIET, ">$quiet_recordmcount"); |
| 196 | printf QUIET "Disables the warning from recordmcount.pl\n"; |
| 197 | close QUIET; |
| 198 | } |
| 199 | } |
| 200 | |
| 201 | if ($arch =~ /(x86(_64)?)|(i386)/) { |
| 202 | if ($bits == 64) { |
| 203 | $arch = "x86_64"; |
| 204 | } else { |
| 205 | $arch = "i386"; |
| 206 | } |
| 207 | } |
| 208 | |
| 209 | # |
| 210 | # We base the defaults off of i386, the other archs may |
| 211 | # feel free to change them in the below if statements. |
| 212 | # |
| 213 | $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)"; |
| 214 | $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)"; |
| 215 | $section_regex = "Disassembly of section\\s+(\\S+):"; |
| 216 | $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:"; |
| 217 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)\$"; |
| 218 | $section_type = '@progbits'; |
| 219 | $mcount_adjust = 0; |
| 220 | $type = ".long"; |
| 221 | |
| 222 | if ($arch eq "x86_64") { |
| 223 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s(mcount|__fentry__)([+-]0x[0-9a-zA-Z]+)?\$"; |
| 224 | $type = ".quad"; |
| 225 | $alignment = 8; |
| 226 | $mcount_adjust = -1; |
| 227 | |
| 228 | # force flags for this arch |
| 229 | $ld .= " -m elf_x86_64"; |
| 230 | $objdump .= " -M x86-64"; |
| 231 | $objcopy .= " -O elf64-x86-64"; |
| 232 | $cc .= " -m64"; |
| 233 | |
| 234 | } elsif ($arch eq "i386") { |
| 235 | $alignment = 4; |
| 236 | $mcount_adjust = -1; |
| 237 | |
| 238 | # force flags for this arch |
| 239 | $ld .= " -m elf_i386"; |
| 240 | $objdump .= " -M i386"; |
| 241 | $objcopy .= " -O elf32-i386"; |
| 242 | $cc .= " -m32"; |
| 243 | |
| 244 | } elsif ($arch eq "s390" && $bits == 64) { |
| 245 | if ($cc =~ /-DCC_USING_HOTPATCH/) { |
| 246 | $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*c0 04 00 00 00 00\\s*brcl\\s*0,[0-9a-f]+ <([^\+]*)>\$"; |
| 247 | $mcount_adjust = 0; |
| 248 | } else { |
| 249 | $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$"; |
| 250 | $mcount_adjust = -14; |
| 251 | } |
| 252 | $alignment = 8; |
| 253 | $type = ".quad"; |
| 254 | $ld .= " -m elf64_s390"; |
| 255 | $cc .= " -m64"; |
| 256 | |
| 257 | } elsif ($arch eq "sh") { |
| 258 | $alignment = 2; |
| 259 | |
| 260 | # force flags for this arch |
| 261 | $ld .= " -m shlelf_linux"; |
| 262 | $objcopy .= " -O elf32-sh-linux"; |
| 263 | |
| 264 | } elsif ($arch eq "powerpc") { |
| 265 | $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)"; |
| 266 | $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:"; |
| 267 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$"; |
| 268 | |
| 269 | if ($bits == 64) { |
| 270 | $type = ".quad"; |
| 271 | } |
| 272 | |
| 273 | } elsif ($arch eq "arm") { |
| 274 | $alignment = 2; |
| 275 | $section_type = '%progbits'; |
| 276 | $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_ARM_(CALL|PC24|THM_CALL)" . |
| 277 | "\\s+(__gnu_mcount_nc|mcount)\$"; |
| 278 | |
| 279 | } elsif ($arch eq "arm64") { |
| 280 | $alignment = 3; |
| 281 | $section_type = '%progbits'; |
| 282 | $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_AARCH64_CALL26\\s+_mcount\$"; |
| 283 | $type = ".quad"; |
| 284 | } elsif ($arch eq "ia64") { |
| 285 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$"; |
| 286 | $type = "data8"; |
| 287 | |
| 288 | if ($is_module eq "0") { |
| 289 | $cc .= " -mconstant-gp"; |
| 290 | } |
| 291 | } elsif ($arch eq "sparc64") { |
| 292 | # In the objdump output there are giblets like: |
| 293 | # 0000000000000000 <igmp_net_exit-0x18>: |
| 294 | # As there's some data blobs that get emitted into the |
| 295 | # text section before the first instructions and the first |
| 296 | # real symbols. We don't want to match that, so to combat |
| 297 | # this we use '\w' so we'll match just plain symbol names, |
| 298 | # and not those that also include hex offsets inside of the |
| 299 | # '<>' brackets. Actually the generic function_regex setting |
| 300 | # could safely use this too. |
| 301 | $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:"; |
| 302 | |
| 303 | # Sparc64 calls '_mcount' instead of plain 'mcount'. |
| 304 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$"; |
| 305 | |
| 306 | $alignment = 8; |
| 307 | $type = ".xword"; |
| 308 | $ld .= " -m elf64_sparc"; |
| 309 | $cc .= " -m64"; |
| 310 | $objcopy .= " -O elf64-sparc"; |
| 311 | } elsif ($arch eq "mips") { |
| 312 | # To enable module support, we need to enable the -mlong-calls option |
| 313 | # of gcc for module, after using this option, we can not get the real |
| 314 | # offset of the calling to _mcount, but the offset of the lui |
| 315 | # instruction or the addiu one. herein, we record the address of the |
| 316 | # first one, and then we can replace this instruction by a branch |
| 317 | # instruction to jump over the profiling function to filter the |
| 318 | # indicated functions, or swith back to the lui instruction to trace |
| 319 | # them, which means dynamic tracing. |
| 320 | # |
| 321 | # c: 3c030000 lui v1,0x0 |
| 322 | # c: R_MIPS_HI16 _mcount |
| 323 | # c: R_MIPS_NONE *ABS* |
| 324 | # c: R_MIPS_NONE *ABS* |
| 325 | # 10: 64630000 daddiu v1,v1,0 |
| 326 | # 10: R_MIPS_LO16 _mcount |
| 327 | # 10: R_MIPS_NONE *ABS* |
| 328 | # 10: R_MIPS_NONE *ABS* |
| 329 | # 14: 03e0082d move at,ra |
| 330 | # 18: 0060f809 jalr v1 |
| 331 | # |
| 332 | # for the kernel: |
| 333 | # |
| 334 | # 10: 03e0082d move at,ra |
| 335 | # 14: 0c000000 jal 0 <loongson_halt> |
| 336 | # 14: R_MIPS_26 _mcount |
| 337 | # 14: R_MIPS_NONE *ABS* |
| 338 | # 14: R_MIPS_NONE *ABS* |
| 339 | # 18: 00020021 nop |
| 340 | if ($is_module eq "0") { |
| 341 | $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_26\\s+_mcount\$"; |
| 342 | } else { |
| 343 | $mcount_regex = "^\\s*([0-9a-fA-F]+): R_MIPS_HI16\\s+_mcount\$"; |
| 344 | } |
| 345 | $objdump .= " -Melf-trad".$endian."mips "; |
| 346 | |
| 347 | if ($endian eq "big") { |
| 348 | $endian = " -EB "; |
| 349 | $ld .= " -melf".$bits."btsmip"; |
| 350 | } else { |
| 351 | $endian = " -EL "; |
| 352 | $ld .= " -melf".$bits."ltsmip"; |
| 353 | } |
| 354 | |
| 355 | $cc .= " -mno-abicalls -fno-pic -mabi=" . $bits . $endian; |
| 356 | $ld .= $endian; |
| 357 | |
| 358 | if ($bits == 64) { |
| 359 | $function_regex = |
| 360 | "^([0-9a-fA-F]+)\\s+<(.|[^\$]L.*?|\$[^L].*?|[^\$][^L].*?)>:"; |
| 361 | $type = ".dword"; |
| 362 | } |
| 363 | } elsif ($arch eq "microblaze") { |
| 364 | # Microblaze calls '_mcount' instead of plain 'mcount'. |
| 365 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$"; |
| 366 | } elsif ($arch eq "blackfin") { |
| 367 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$"; |
| 368 | $mcount_adjust = -4; |
| 369 | } elsif ($arch eq "tilegx" || $arch eq "tile") { |
| 370 | # Default to the newer TILE-Gx architecture if only "tile" is given. |
| 371 | $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s__mcount\$"; |
| 372 | $type = ".quad"; |
| 373 | $alignment = 8; |
| 374 | } else { |
| 375 | die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD"; |
| 376 | } |
| 377 | |
| 378 | my $text_found = 0; |
| 379 | my $read_function = 0; |
| 380 | my $opened = 0; |
| 381 | my $mcount_section = "__mcount_loc"; |
| 382 | |
| 383 | my $dirname; |
| 384 | my $filename; |
| 385 | my $prefix; |
| 386 | my $ext; |
| 387 | |
| 388 | if ($inputfile =~ m,^(.*)/([^/]*)$,) { |
| 389 | $dirname = $1; |
| 390 | $filename = $2; |
| 391 | } else { |
| 392 | $dirname = "."; |
| 393 | $filename = $inputfile; |
| 394 | } |
| 395 | |
| 396 | if ($filename =~ m,^(.*)(\.\S),) { |
| 397 | $prefix = $1; |
| 398 | $ext = $2; |
| 399 | } else { |
| 400 | $prefix = $filename; |
| 401 | $ext = ""; |
| 402 | } |
| 403 | |
| 404 | my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s"; |
| 405 | my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o"; |
| 406 | |
| 407 | check_objcopy(); |
| 408 | |
| 409 | # |
| 410 | # Step 1: find all the local (static functions) and weak symbols. |
| 411 | # 't' is local, 'w/W' is weak |
| 412 | # |
| 413 | open (IN, "$nm $inputfile|") || die "error running $nm"; |
| 414 | while (<IN>) { |
| 415 | if (/$local_regex/) { |
| 416 | $locals{$1} = 1; |
| 417 | } elsif (/$weak_regex/) { |
| 418 | $weak{$2} = $1; |
| 419 | } |
| 420 | } |
| 421 | close(IN); |
| 422 | |
| 423 | my @offsets; # Array of offsets of mcount callers |
| 424 | my $ref_func; # reference function to use for offsets |
| 425 | my $offset = 0; # offset of ref_func to section beginning |
| 426 | |
| 427 | ## |
| 428 | # update_funcs - print out the current mcount callers |
| 429 | # |
| 430 | # Go through the list of offsets to callers and write them to |
| 431 | # the output file in a format that can be read by an assembler. |
| 432 | # |
| 433 | sub update_funcs |
| 434 | { |
| 435 | return unless ($ref_func and @offsets); |
| 436 | |
| 437 | # Sanity check on weak function. A weak function may be overwritten by |
| 438 | # another function of the same name, making all these offsets incorrect. |
| 439 | if (defined $weak{$ref_func}) { |
| 440 | die "$inputfile: ERROR: referencing weak function" . |
| 441 | " $ref_func for mcount\n"; |
| 442 | } |
| 443 | |
| 444 | # is this function static? If so, note this fact. |
| 445 | if (defined $locals{$ref_func}) { |
| 446 | |
| 447 | # only use locals if objcopy supports globalize-symbols |
| 448 | if (!$can_use_local) { |
| 449 | return; |
| 450 | } |
| 451 | $convert{$ref_func} = 1; |
| 452 | } |
| 453 | |
| 454 | # Loop through all the mcount caller offsets and print a reference |
| 455 | # to the caller based from the ref_func. |
| 456 | if (!$opened) { |
| 457 | open(FILE, ">$mcount_s") || die "can't create $mcount_s\n"; |
| 458 | $opened = 1; |
| 459 | print FILE "\t.section $mcount_section,\"a\",$section_type\n"; |
| 460 | print FILE "\t.align $alignment\n" if (defined($alignment)); |
| 461 | } |
| 462 | foreach my $cur_offset (@offsets) { |
| 463 | printf FILE "\t%s %s + %d\n", $type, $ref_func, $cur_offset - $offset; |
| 464 | } |
| 465 | } |
| 466 | |
| 467 | # |
| 468 | # Step 2: find the sections and mcount call sites |
| 469 | # |
| 470 | open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump"; |
| 471 | |
| 472 | my $text; |
| 473 | |
| 474 | |
| 475 | # read headers first |
| 476 | my $read_headers = 1; |
| 477 | |
| 478 | while (<IN>) { |
| 479 | |
| 480 | if ($read_headers && /$mcount_section/) { |
| 481 | # |
| 482 | # Somehow the make process can execute this script on an |
| 483 | # object twice. If it does, we would duplicate the mcount |
| 484 | # section and it will cause the function tracer self test |
| 485 | # to fail. Check if the mcount section exists, and if it does, |
| 486 | # warn and exit. |
| 487 | # |
| 488 | print STDERR "ERROR: $mcount_section already in $inputfile\n" . |
| 489 | "\tThis may be an indication that your build is corrupted.\n" . |
| 490 | "\tDelete $inputfile and try again. If the same object file\n" . |
| 491 | "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n"; |
| 492 | exit(-1); |
| 493 | } |
| 494 | |
| 495 | # is it a section? |
| 496 | if (/$section_regex/) { |
| 497 | $read_headers = 0; |
| 498 | |
| 499 | # Only record text sections that we know are safe |
| 500 | $read_function = defined($text_sections{$1}); |
| 501 | # print out any recorded offsets |
| 502 | update_funcs(); |
| 503 | |
| 504 | # reset all markers and arrays |
| 505 | $text_found = 0; |
| 506 | undef($ref_func); |
| 507 | undef(@offsets); |
| 508 | |
| 509 | # section found, now is this a start of a function? |
| 510 | } elsif ($read_function && /$function_regex/) { |
| 511 | $text_found = 1; |
| 512 | $text = $2; |
| 513 | |
| 514 | # if this is either a local function or a weak function |
| 515 | # keep looking for functions that are global that |
| 516 | # we can use safely. |
| 517 | if (!defined($locals{$text}) && !defined($weak{$text})) { |
| 518 | $ref_func = $text; |
| 519 | $read_function = 0; |
| 520 | $offset = hex $1; |
| 521 | } else { |
| 522 | # if we already have a function, and this is weak, skip it |
| 523 | if (!defined($ref_func) && !defined($weak{$text}) && |
| 524 | # PPC64 can have symbols that start with .L and |
| 525 | # gcc considers these special. Don't use them! |
| 526 | $text !~ /^\.L/) { |
| 527 | $ref_func = $text; |
| 528 | $offset = hex $1; |
| 529 | } |
| 530 | } |
| 531 | } |
| 532 | # is this a call site to mcount? If so, record it to print later |
| 533 | if ($text_found && /$mcount_regex/) { |
| 534 | push(@offsets, (hex $1) + $mcount_adjust); |
| 535 | } |
| 536 | } |
| 537 | |
| 538 | # dump out anymore offsets that may have been found |
| 539 | update_funcs(); |
| 540 | |
| 541 | # If we did not find any mcount callers, we are done (do nothing). |
| 542 | if (!$opened) { |
| 543 | exit(0); |
| 544 | } |
| 545 | |
| 546 | close(FILE); |
| 547 | |
| 548 | # |
| 549 | # Step 3: Compile the file that holds the list of call sites to mcount. |
| 550 | # |
| 551 | `$cc -o $mcount_o -c $mcount_s`; |
| 552 | |
| 553 | my @converts = keys %convert; |
| 554 | |
| 555 | # |
| 556 | # Step 4: Do we have sections that started with local functions? |
| 557 | # |
| 558 | if ($#converts >= 0) { |
| 559 | my $globallist = ""; |
| 560 | my $locallist = ""; |
| 561 | |
| 562 | foreach my $con (@converts) { |
| 563 | $globallist .= " --globalize-symbol $con"; |
| 564 | $locallist .= " --localize-symbol $con"; |
| 565 | } |
| 566 | |
| 567 | my $globalobj = $dirname . "/.tmp_gl_" . $filename; |
| 568 | my $globalmix = $dirname . "/.tmp_mx_" . $filename; |
| 569 | |
| 570 | # |
| 571 | # Step 5: set up each local function as a global |
| 572 | # |
| 573 | `$objcopy $globallist $inputfile $globalobj`; |
| 574 | |
| 575 | # |
| 576 | # Step 6: Link the global version to our list. |
| 577 | # |
| 578 | `$ld -r $globalobj $mcount_o -o $globalmix`; |
| 579 | |
| 580 | # |
| 581 | # Step 7: Convert the local functions back into local symbols |
| 582 | # |
| 583 | `$objcopy $locallist $globalmix $inputfile`; |
| 584 | |
| 585 | # Remove the temp files |
| 586 | `$rm $globalobj $globalmix`; |
| 587 | |
| 588 | } else { |
| 589 | |
| 590 | my $mix = $dirname . "/.tmp_mx_" . $filename; |
| 591 | |
| 592 | # |
| 593 | # Step 8: Link the object with our list of call sites object. |
| 594 | # |
| 595 | `$ld -r $inputfile $mcount_o -o $mix`; |
| 596 | |
| 597 | # |
| 598 | # Step 9: Move the result back to the original object. |
| 599 | # |
| 600 | `$mv $mix $inputfile`; |
| 601 | } |
| 602 | |
| 603 | # Clean up the temp files |
| 604 | `$rm $mcount_o $mcount_s`; |
| 605 | |
| 606 | exit(0); |