arch/arm/boot/bootp/init.S

   1 /*
   2  *  linux/arch/arm/boot/bootp/init.S
   3  *
   4  *  Copyright (C) 2000-2003 Russell King.
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  *
  10  *  "Header" file for splitting kernel + initrd.  Note that we pass
  11  *  r0 through to r3 straight through.
  12  *
  13  *  This demonstrates how to append code to the start of the kernel
  14  *  zImage, and boot the kernel without copying it around.  This
  15  *  example would be simpler; if we didn't have an object of unknown
  16  *  size immediately following the kernel, we could build this into
  17  *  a binary blob, and concatenate the zImage using the cat command.
  18  */
  19                 .section .start,#alloc,#execinstr
  20                 .type   _start, #function
  21                 .globl  _start
  22
  23 _start:         add     lr, pc, #-0x8           @ lr = current load addr
  24                 adr     r13, data
  25                 ldmia   r13!, {r4-r6}           @ r5 = dest, r6 = length
  26                 add     r4, r4, lr              @ r4 = initrd_start + load addr
  27                 bl      move                    @ move the initrd
  28
  29 /*
  30  * Setup the initrd parameters to pass to the kernel.  This can only be
  31  * passed in via the tagged list.
  32  */
  33                 ldmia   r13, {r5-r9}            @ get size and addr of initrd
  34                                                 @ r5 = ATAG_CORE
  35                                                 @ r6 = ATAG_INITRD2
  36                                                 @ r7 = initrd start
  37                                                 @ r8 = initrd end
  38                                                 @ r9 = param_struct address
  39
  40                 ldr     r10, [r9, #4]           @ get first tag
  41                 teq     r10, r5                 @ is it ATAG_CORE?
  42 /*
  43  * If we didn't find a valid tag list, create a dummy ATAG_CORE entry.
  44  */
  45                 movne   r10, #0                 @ terminator
  46                 movne   r4, #2                  @ Size of this entry (2 words)
  47                 stmneia r9, {r4, r5, r10}       @ Size, ATAG_CORE, terminator
  48
  49 /*
  50  * find the end of the tag list, and then add an INITRD tag on the end.
  51  * If there is already an INITRD tag, then we ignore it; the last INITRD
  52  * tag takes precedence.
  53  */
  54 taglist:        ldr     r10, [r9, #0]           @ tag length
  55                 teq     r10, #0                 @ last tag (zero length)?
  56                 addne   r9, r9, r10, lsl #2
  57                 bne     taglist
  58
  59                 mov     r5, #4                  @ Size of initrd tag (4 words)
  60                 stmia   r9, {r5, r6, r7, r8, r10}
  61                 b       kernel_start            @ call kernel
  62
  63 /*
  64  * Move the block of memory length r6 from address r4 to address r5
  65  */
  66 move:           ldmia   r4!, {r7 - r10}         @ move 32-bytes at a time
  67                 stmia   r5!, {r7 - r10}
  68                 ldmia   r4!, {r7 - r10}
  69                 stmia   r5!, {r7 - r10}
  70                 subs    r6, r6, #8 * 4
  71                 bcs     move
  72                 mov     pc, lr
  73
  74                 .size   _start, . - _start
  75
  76                 .align
  77
  78                 .type   data,#object
  79 data:           .word   initrd_start            @ source initrd address
  80                 .word   initrd_phys             @ destination initrd address
  81                 .word   initrd_size             @ initrd size
  82
  83                 .word   0x54410001              @ r5 = ATAG_CORE
  84                 .word   0x54420005              @ r6 = ATAG_INITRD2
  85                 .word   initrd_phys             @ r7
  86                 .word   initrd_size             @ r8
  87                 .word   params_phys             @ r9
  88                 .size   data, . - data