arch/arm/kernel/entry-common.S

   1 /*
   2  *  linux/arch/arm/kernel/entry-common.S
   3  *
   4  *  Copyright (C) 2000 Russell King
   5  *
   6  * This program is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License version 2 as
   8  * published by the Free Software Foundation.
   9  */
  10
  11 #include <asm/assembler.h>
  12 #include <asm/unistd.h>
  13 #include <asm/ftrace.h>
  14 #include <asm/unwind.h>
  15
  16 #ifdef CONFIG_NEED_RET_TO_USER
  17 #include <mach/entry-macro.S>
  18 #else
  19         .macro  arch_ret_to_user, tmp1, tmp2
  20         .endm
  21 #endif
  22
  23 #include "entry-header.S"
  24
  25
  26         .align  5
  27 /*
  28  * This is the fast syscall return path.  We do as little as
  29  * possible here, and this includes saving r0 back into the SVC
  30  * stack.
  31  */
  32 ret_fast_syscall:
  33  UNWIND(.fnstart        )
  34  UNWIND(.cantunwind     )
  35         disable_irq                             @ disable interrupts
  36         ldr     r1, [tsk, #TI_FLAGS]
  37         tst     r1, #_TIF_WORK_MASK
  38         bne     fast_work_pending
  39         asm_trace_hardirqs_on
  40
  41         /* perform architecture specific actions before user return */
  42         arch_ret_to_user r1, lr
  43         ct_user_enter
  44
  45         restore_user_regs fast = 1, offset = S_OFF
  46  UNWIND(.fnend          )
  47
  48 /*
  49  * Ok, we need to do extra processing, enter the slow path.
  50  */
  51 fast_work_pending:
  52         str     r0, [sp, #S_R0+S_OFF]!          @ returned r0
  53 work_pending:
  54         mov     r0, sp                          @ 'regs'
  55         mov     r2, why                         @ 'syscall'
  56         bl      do_work_pending
  57         cmp     r0, #0
  58         beq     no_work_pending
  59         movlt   scno, #(__NR_restart_syscall - __NR_SYSCALL_BASE)
  60         ldmia   sp, {r0 - r6}                   @ have to reload r0 - r6
  61         b       local_restart                   @ ... and off we go
  62
  63 /*
  64  * "slow" syscall return path.  "why" tells us if this was a real syscall.
  65  */
  66 ENTRY(ret_to_user)
  67 ret_slow_syscall:
  68         disable_irq                             @ disable interrupts
  69 ENTRY(ret_to_user_from_irq)
  70         ldr     r1, [tsk, #TI_FLAGS]
  71         tst     r1, #_TIF_WORK_MASK
  72         bne     work_pending
  73 no_work_pending:
  74         asm_trace_hardirqs_on
  75
  76         /* perform architecture specific actions before user return */
  77         arch_ret_to_user r1, lr
  78         ct_user_enter save = 0
  79
  80         restore_user_regs fast = 0, offset = 0
  81 ENDPROC(ret_to_user_from_irq)
  82 ENDPROC(ret_to_user)
  83
  84 /*
  85  * This is how we return from a fork.
  86  */
  87 ENTRY(ret_from_fork)
  88         bl      schedule_tail
  89         cmp     r5, #0
  90         movne   r0, r4
  91         adrne   lr, BSYM(1f)
  92         retne   r5
  93 1:      get_thread_info tsk
  94         b       ret_slow_syscall
  95 ENDPROC(ret_from_fork)
  96
  97         .equ NR_syscalls,0
  98 #define CALL(x) .equ NR_syscalls,NR_syscalls+1
  99 #include "calls.S"
 100
 101 /*
 102  * Ensure that the system call table is equal to __NR_syscalls,
 103  * which is the value the rest of the system sees
 104  */
 105 .ifne NR_syscalls - __NR_syscalls
 106 .error "__NR_syscalls is not equal to the size of the syscall table"
 107 .endif
 108
 109 #undef CALL
 110 #define CALL(x) .long x
 111
 112 #ifdef CONFIG_FUNCTION_TRACER
 113 /*
 114  * When compiling with -pg, gcc inserts a call to the mcount routine at the
 115  * start of every function.  In mcount, apart from the function's address (in
 116  * lr), we need to get hold of the function's caller's address.
 117  *
 118  * Older GCCs (pre-4.4) inserted a call to a routine called mcount like this:
 119  *
 120  *      bl      mcount
 121  *
 122  * These versions have the limitation that in order for the mcount routine to
 123  * be able to determine the function's caller's address, an APCS-style frame
 124  * pointer (which is set up with something like the code below) is required.
 125  *
 126  *      mov     ip, sp
 127  *      push    {fp, ip, lr, pc}
 128  *      sub     fp, ip, #4
 129  *
 130  * With EABI, these frame pointers are not available unless -mapcs-frame is
 131  * specified, and if building as Thumb-2, not even then.
 132  *
 133  * Newer GCCs (4.4+) solve this problem by introducing a new version of mcount,
 134  * with call sites like:
 135  *
 136  *      push    {lr}
 137  *      bl      __gnu_mcount_nc
 138  *
 139  * With these compilers, frame pointers are not necessary.
 140  *
 141  * mcount can be thought of as a function called in the middle of a subroutine
 142  * call.  As such, it needs to be transparent for both the caller and the
 143  * callee: the original lr needs to be restored when leaving mcount, and no
 144  * registers should be clobbered.  (In the __gnu_mcount_nc implementation, we
 145  * clobber the ip register.  This is OK because the ARM calling convention
 146  * allows it to be clobbered in subroutines and doesn't use it to hold
 147  * parameters.)
 148  *
 149  * When using dynamic ftrace, we patch out the mcount call by a "mov r0, r0"
 150  * for the mcount case, and a "pop {lr}" for the __gnu_mcount_nc case (see
 151  * arch/arm/kernel/ftrace.c).
 152  */
 153
 154 #ifndef CONFIG_OLD_MCOUNT
 155 #if (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 4))
 156 #error Ftrace requires CONFIG_FRAME_POINTER=y with GCC older than 4.4.0.
 157 #endif
 158 #endif
 159
 160 .macro mcount_adjust_addr rd, rn
 161         bic     \rd, \rn, #1            @ clear the Thumb bit if present
 162         sub     \rd, \rd, #MCOUNT_INSN_SIZE
 163 .endm
 164
 165 .macro __mcount suffix
 166         mcount_enter
 167         ldr     r0, =ftrace_trace_function
 168         ldr     r2, [r0]
 169         adr     r0, .Lftrace_stub
 170         cmp     r0, r2
 171         bne     1f
 172
 173 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 174         ldr     r1, =ftrace_graph_return
 175         ldr     r2, [r1]
 176         cmp     r0, r2
 177         bne     ftrace_graph_caller\suffix
 178
 179         ldr     r1, =ftrace_graph_entry
 180         ldr     r2, [r1]
 181         ldr     r0, =ftrace_graph_entry_stub
 182         cmp     r0, r2
 183         bne     ftrace_graph_caller\suffix
 184 #endif
 185
 186         mcount_exit
 187
 188 1:      mcount_get_lr   r1                      @ lr of instrumented func
 189         mcount_adjust_addr      r0, lr          @ instrumented function
 190         adr     lr, BSYM(2f)
 191         mov     pc, r2
 192 2:      mcount_exit
 193 .endm
 194
 195 .macro __ftrace_caller suffix
 196         mcount_enter
 197
 198         mcount_get_lr   r1                      @ lr of instrumented func
 199         mcount_adjust_addr      r0, lr          @ instrumented function
 200
 201         .globl ftrace_call\suffix
 202 ftrace_call\suffix:
 203         bl      ftrace_stub
 204
 205 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 206         .globl ftrace_graph_call\suffix
 207 ftrace_graph_call\suffix:
 208         mov     r0, r0
 209 #endif
 210
 211         mcount_exit
 212 .endm
 213
 214 .macro __ftrace_graph_caller
 215         sub     r0, fp, #4              @ &lr of instrumented routine (&parent)
 216 #ifdef CONFIG_DYNAMIC_FTRACE
 217         @ called from __ftrace_caller, saved in mcount_enter
 218         ldr     r1, [sp, #16]           @ instrumented routine (func)
 219         mcount_adjust_addr      r1, r1
 220 #else
 221         @ called from __mcount, untouched in lr
 222         mcount_adjust_addr      r1, lr  @ instrumented routine (func)
 223 #endif
 224         mov     r2, fp                  @ frame pointer
 225         bl      prepare_ftrace_return
 226         mcount_exit
 227 .endm
 228
 229 #ifdef CONFIG_OLD_MCOUNT
 230 /*
 231  * mcount
 232  */
 233
 234 .macro mcount_enter
 235         stmdb   sp!, {r0-r3, lr}
 236 .endm
 237
 238 .macro mcount_get_lr reg
 239         ldr     \reg, [fp, #-4]
 240 .endm
 241
 242 .macro mcount_exit
 243         ldr     lr, [fp, #-4]
 244         ldmia   sp!, {r0-r3, pc}
 245 .endm
 246
 247 ENTRY(mcount)
 248 #ifdef CONFIG_DYNAMIC_FTRACE
 249         stmdb   sp!, {lr}
 250         ldr     lr, [fp, #-4]
 251         ldmia   sp!, {pc}
 252 #else
 253         __mcount _old
 254 #endif
 255 ENDPROC(mcount)
 256
 257 #ifdef CONFIG_DYNAMIC_FTRACE
 258 ENTRY(ftrace_caller_old)
 259         __ftrace_caller _old
 260 ENDPROC(ftrace_caller_old)
 261 #endif
 262
 263 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 264 ENTRY(ftrace_graph_caller_old)
 265         __ftrace_graph_caller
 266 ENDPROC(ftrace_graph_caller_old)
 267 #endif
 268
 269 .purgem mcount_enter
 270 .purgem mcount_get_lr
 271 .purgem mcount_exit
 272 #endif
 273
 274 /*
 275  * __gnu_mcount_nc
 276  */
 277
 278 .macro mcount_enter
 279 /*
 280  * This pad compensates for the push {lr} at the call site.  Note that we are
 281  * unable to unwind through a function which does not otherwise save its lr.
 282  */
 283  UNWIND(.pad    #4)
 284         stmdb   sp!, {r0-r3, lr}
 285  UNWIND(.save   {r0-r3, lr})
 286 .endm
 287
 288 .macro mcount_get_lr reg
 289         ldr     \reg, [sp, #20]
 290 .endm
 291
 292 .macro mcount_exit
 293         ldmia   sp!, {r0-r3, ip, lr}
 294         ret     ip
 295 .endm
 296
 297 ENTRY(__gnu_mcount_nc)
 298 UNWIND(.fnstart)
 299 #ifdef CONFIG_DYNAMIC_FTRACE
 300         mov     ip, lr
 301         ldmia   sp!, {lr}
 302         ret     ip
 303 #else
 304         __mcount
 305 #endif
 306 UNWIND(.fnend)
 307 ENDPROC(__gnu_mcount_nc)
 308
 309 #ifdef CONFIG_DYNAMIC_FTRACE
 310 ENTRY(ftrace_caller)
 311 UNWIND(.fnstart)
 312         __ftrace_caller
 313 UNWIND(.fnend)
 314 ENDPROC(ftrace_caller)
 315 #endif
 316
 317 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 318 ENTRY(ftrace_graph_caller)
 319 UNWIND(.fnstart)
 320         __ftrace_graph_caller
 321 UNWIND(.fnend)
 322 ENDPROC(ftrace_graph_caller)
 323 #endif
 324
 325 .purgem mcount_enter
 326 .purgem mcount_get_lr
 327 .purgem mcount_exit
 328
 329 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 330         .globl return_to_handler
 331 return_to_handler:
 332         stmdb   sp!, {r0-r3}
 333         mov     r0, fp                  @ frame pointer
 334         bl      ftrace_return_to_handler
 335         mov     lr, r0                  @ r0 has real ret addr
 336         ldmia   sp!, {r0-r3}
 337         ret     lr
 338 #endif
 339
 340 ENTRY(ftrace_stub)
 341 .Lftrace_stub:
 342         ret     lr
 343 ENDPROC(ftrace_stub)
 344
 345 #endif /* CONFIG_FUNCTION_TRACER */
 346
 347 /*=============================================================================
 348  * SWI handler
 349  *-----------------------------------------------------------------------------
 350  */
 351
 352         .align  5
 353 ENTRY(vector_swi)
 354 #ifdef CONFIG_CPU_V7M
 355         v7m_exception_entry
 356 #else
 357         sub     sp, sp, #S_FRAME_SIZE
 358         stmia   sp, {r0 - r12}                  @ Calling r0 - r12
 359  ARM(   add     r8, sp, #S_PC           )
 360  ARM(   stmdb   r8, {sp, lr}^           )       @ Calling sp, lr
 361  THUMB( mov     r8, sp                  )
 362  THUMB( store_user_sp_lr r8, r10, S_SP  )       @ calling sp, lr
 363         mrs     r8, spsr                        @ called from non-FIQ mode, so ok.
 364         str     lr, [sp, #S_PC]                 @ Save calling PC
 365         str     r8, [sp, #S_PSR]                @ Save CPSR
 366         str     r0, [sp, #S_OLD_R0]             @ Save OLD_R0
 367 #endif
 368         zero_fp
 369         alignment_trap ip, __cr_alignment
 370         enable_irq
 371         ct_user_exit
 372         get_thread_info tsk
 373
 374         /*
 375          * Get the system call number.
 376          */
 377
 378 #if defined(CONFIG_OABI_COMPAT)
 379
 380         /*
 381          * If we have CONFIG_OABI_COMPAT then we need to look at the swi
 382          * value to determine if it is an EABI or an old ABI call.
 383          */
 384 #ifdef CONFIG_ARM_THUMB
 385         tst     r8, #PSR_T_BIT
 386         movne   r10, #0                         @ no thumb OABI emulation
 387  USER(  ldreq   r10, [lr, #-4]          )       @ get SWI instruction
 388 #else
 389  USER(  ldr     r10, [lr, #-4]          )       @ get SWI instruction
 390 #endif
 391  ARM_BE8(rev    r10, r10)                       @ little endian instruction
 392
 393 #elif defined(CONFIG_AEABI)
 394
 395         /*
 396          * Pure EABI user space always put syscall number into scno (r7).
 397          */
 398 #elif defined(CONFIG_ARM_THUMB)
 399         /* Legacy ABI only, possibly thumb mode. */
 400         tst     r8, #PSR_T_BIT                  @ this is SPSR from save_user_regs
 401         addne   scno, r7, #__NR_SYSCALL_BASE    @ put OS number in
 402  USER(  ldreq   scno, [lr, #-4]         )
 403
 404 #else
 405         /* Legacy ABI only. */
 406  USER(  ldr     scno, [lr, #-4]         )       @ get SWI instruction
 407 #endif
 408
 409         adr     tbl, sys_call_table             @ load syscall table pointer
 410
 411 #if defined(CONFIG_OABI_COMPAT)
 412         /*
 413          * If the swi argument is zero, this is an EABI call and we do nothing.
 414          *
 415          * If this is an old ABI call, get the syscall number into scno and
 416          * get the old ABI syscall table address.
 417          */
 418         bics    r10, r10, #0xff000000
 419         eorne   scno, r10, #__NR_OABI_SYSCALL_BASE
 420         ldrne   tbl, =sys_oabi_call_table
 421 #elif !defined(CONFIG_AEABI)
 422         bic     scno, scno, #0xff000000         @ mask off SWI op-code
 423         eor     scno, scno, #__NR_SYSCALL_BASE  @ check OS number
 424 #endif
 425
 426 local_restart:
 427         ldr     r10, [tsk, #TI_FLAGS]           @ check for syscall tracing
 428         stmdb   sp!, {r4, r5}                   @ push fifth and sixth args
 429
 430         tst     r10, #_TIF_SYSCALL_WORK         @ are we tracing syscalls?
 431         bne     __sys_trace
 432
 433         cmp     scno, #NR_syscalls              @ check upper syscall limit
 434         adr     lr, BSYM(ret_fast_syscall)      @ return address
 435         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 436
 437         add     r1, sp, #S_OFF
 438 2:      cmp     scno, #(__ARM_NR_BASE - __NR_SYSCALL_BASE)
 439         eor     r0, scno, #__NR_SYSCALL_BASE    @ put OS number back
 440         bcs     arm_syscall
 441         mov     why, #0                         @ no longer a real syscall
 442         b       sys_ni_syscall                  @ not private func
 443
 444 #if defined(CONFIG_OABI_COMPAT) || !defined(CONFIG_AEABI)
 445         /*
 446          * We failed to handle a fault trying to access the page
 447          * containing the swi instruction, but we're not really in a
 448          * position to return -EFAULT. Instead, return back to the
 449          * instruction and re-enter the user fault handling path trying
 450          * to page it in. This will likely result in sending SEGV to the
 451          * current task.
 452          */
 453 9001:
 454         sub     lr, lr, #4
 455         str     lr, [sp, #S_PC]
 456         b       ret_fast_syscall
 457 #endif
 458 ENDPROC(vector_swi)
 459
 460         /*
 461          * This is the really slow path.  We're going to be doing
 462          * context switches, and waiting for our parent to respond.
 463          */
 464 __sys_trace:
 465         mov     r1, scno
 466         add     r0, sp, #S_OFF
 467         bl      syscall_trace_enter
 468
 469         adr     lr, BSYM(__sys_trace_return)    @ return address
 470         mov     scno, r0                        @ syscall number (possibly new)
 471         add     r1, sp, #S_R0 + S_OFF           @ pointer to regs
 472         cmp     scno, #NR_syscalls              @ check upper syscall limit
 473         ldmccia r1, {r0 - r6}                   @ have to reload r0 - r6
 474         stmccia sp, {r4, r5}                    @ and update the stack args
 475         ldrcc   pc, [tbl, scno, lsl #2]         @ call sys_* routine
 476         cmp     scno, #-1                       @ skip the syscall?
 477         bne     2b
 478         add     sp, sp, #S_OFF                  @ restore stack
 479         b       ret_slow_syscall
 480
 481 __sys_trace_return:
 482         str     r0, [sp, #S_R0 + S_OFF]!        @ save returned r0
 483         mov     r0, sp
 484         bl      syscall_trace_exit
 485         b       ret_slow_syscall
 486
 487         .align  5
 488 #ifdef CONFIG_ALIGNMENT_TRAP
 489         .type   __cr_alignment, #object
 490 __cr_alignment:
 491         .word   cr_alignment
 492 #endif
 493         .ltorg
 494
 495 /*
 496  * This is the syscall table declaration for native ABI syscalls.
 497  * With EABI a couple syscalls are obsolete and defined as sys_ni_syscall.
 498  */
 499 #define ABI(native, compat) native
 500 #ifdef CONFIG_AEABI
 501 #define OBSOLETE(syscall) sys_ni_syscall
 502 #else
 503 #define OBSOLETE(syscall) syscall
 504 #endif
 505
 506         .type   sys_call_table, #object
 507 ENTRY(sys_call_table)
 508 #include "calls.S"
 509 #undef ABI
 510 #undef OBSOLETE
 511
 512 /*============================================================================
 513  * Special system call wrappers
 514  */
 515 @ r0 = syscall number
 516 @ r8 = syscall table
 517 sys_syscall:
 518                 bic     scno, r0, #__NR_OABI_SYSCALL_BASE
 519                 cmp     scno, #__NR_syscall - __NR_SYSCALL_BASE
 520                 cmpne   scno, #NR_syscalls      @ check range
 521                 stmloia sp, {r5, r6}            @ shuffle args
 522                 movlo   r0, r1
 523                 movlo   r1, r2
 524                 movlo   r2, r3
 525                 movlo   r3, r4
 526                 ldrlo   pc, [tbl, scno, lsl #2]
 527                 b       sys_ni_syscall
 528 ENDPROC(sys_syscall)
 529
 530 sys_sigreturn_wrapper:
 531                 add     r0, sp, #S_OFF
 532                 mov     why, #0         @ prevent syscall restart handling
 533                 b       sys_sigreturn
 534 ENDPROC(sys_sigreturn_wrapper)
 535
 536 sys_rt_sigreturn_wrapper:
 537                 add     r0, sp, #S_OFF
 538                 mov     why, #0         @ prevent syscall restart handling
 539                 b       sys_rt_sigreturn
 540 ENDPROC(sys_rt_sigreturn_wrapper)
 541
 542 sys_statfs64_wrapper:
 543                 teq     r1, #88
 544                 moveq   r1, #84
 545                 b       sys_statfs64
 546 ENDPROC(sys_statfs64_wrapper)
 547
 548 sys_fstatfs64_wrapper:
 549                 teq     r1, #88
 550                 moveq   r1, #84
 551                 b       sys_fstatfs64
 552 ENDPROC(sys_fstatfs64_wrapper)
 553
 554 /*
 555  * Note: off_4k (r5) is always units of 4K.  If we can't do the requested
 556  * offset, we return EINVAL.
 557  */
 558 sys_mmap2:
 559 #if PAGE_SHIFT > 12
 560                 tst     r5, #PGOFF_MASK
 561                 moveq   r5, r5, lsr #PAGE_SHIFT - 12
 562                 streq   r5, [sp, #4]
 563                 beq     sys_mmap_pgoff
 564                 mov     r0, #-EINVAL
 565                 ret     lr
 566 #else
 567                 str     r5, [sp, #4]
 568                 b       sys_mmap_pgoff
 569 #endif
 570 ENDPROC(sys_mmap2)
 571
 572 #ifdef CONFIG_OABI_COMPAT
 573
 574 /*
 575  * These are syscalls with argument register differences
 576  */
 577
 578 sys_oabi_pread64:
 579                 stmia   sp, {r3, r4}
 580                 b       sys_pread64
 581 ENDPROC(sys_oabi_pread64)
 582
 583 sys_oabi_pwrite64:
 584                 stmia   sp, {r3, r4}
 585                 b       sys_pwrite64
 586 ENDPROC(sys_oabi_pwrite64)
 587
 588 sys_oabi_truncate64:
 589                 mov     r3, r2
 590                 mov     r2, r1
 591                 b       sys_truncate64
 592 ENDPROC(sys_oabi_truncate64)
 593
 594 sys_oabi_ftruncate64:
 595                 mov     r3, r2
 596                 mov     r2, r1
 597                 b       sys_ftruncate64
 598 ENDPROC(sys_oabi_ftruncate64)
 599
 600 sys_oabi_readahead:
 601                 str     r3, [sp]
 602                 mov     r3, r2
 603                 mov     r2, r1
 604                 b       sys_readahead
 605 ENDPROC(sys_oabi_readahead)
 606
 607 /*
 608  * Let's declare a second syscall table for old ABI binaries
 609  * using the compatibility syscall entries.
 610  */
 611 #define ABI(native, compat) compat
 612 #define OBSOLETE(syscall) syscall
 613
 614         .type   sys_oabi_call_table, #object
 615 ENTRY(sys_oabi_call_table)
 616 #include "calls.S"
 617 #undef ABI
 618 #undef OBSOLETE
 619
 620 #endif
 621