arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .init : {                       /* Init code and data           */
  27                 _stext = .;
  28                         _sinittext = .;
  29                         *(.init.text)
  30                         _einittext = .;
  31                 __proc_info_begin = .;
  32                         *(.proc.info.init)
  33                 __proc_info_end = .;
  34                 __arch_info_begin = .;
  35                         *(.arch.info.init)
  36                 __arch_info_end = .;
  37                 __tagtable_begin = .;
  38                         *(.taglist.init)
  39                 __tagtable_end = .;
  40                 . = ALIGN(16);
  41                 __setup_start = .;
  42                         *(.init.setup)
  43                 __setup_end = .;
  44                 __early_begin = .;
  45                         *(.early_param.init)
  46                 __early_end = .;
  47                 __initcall_start = .;
  48                         INITCALLS
  49                 __initcall_end = .;
  50                 __con_initcall_start = .;
  51                         *(.con_initcall.init)
  52                 __con_initcall_end = .;
  53                 __security_initcall_start = .;
  54                         *(.security_initcall.init)
  55                 __security_initcall_end = .;
  56 #ifdef CONFIG_BLK_DEV_INITRD
  57                 . = ALIGN(32);
  58                 __initramfs_start = .;
  59                         usr/built-in.o(.init.ramfs)
  60                 __initramfs_end = .;
  61 #endif
  62                 . = ALIGN(64);
  63                 __per_cpu_start = .;
  64                         *(.data.percpu)
  65                 __per_cpu_end = .;
  66 #ifndef CONFIG_XIP_KERNEL
  67                 __init_begin = _stext;
  68                 *(.init.data)
  69                 . = ALIGN(4096);
  70                 __init_end = .;
  71 #endif
  72         }
  73
  74         /DISCARD/ : {                   /* Exit code and data           */
  75                 *(.exit.text)
  76                 *(.exit.data)
  77                 *(.exitcall.exit)
  78 #ifndef CONFIG_MMU
  79                 *(.fixup)
  80                 *(__ex_table)
  81 #endif
  82         }
  83
  84         .text : {                       /* Real text segment            */
  85                 _text = .;              /* Text and read-only data      */
  86                         __exception_text_start = .;
  87                         *(.exception.text)
  88                         __exception_text_end = .;
  89                         *(.text)
  90                         SCHED_TEXT
  91                         LOCK_TEXT
  92 #ifdef CONFIG_MMU
  93                         *(.fixup)
  94 #endif
  95                         *(.gnu.warning)
  96                         *(.rodata)
  97                         *(.rodata.*)
  98                         *(.glue_7)
  99                         *(.glue_7t)
 100                 *(.got)                 /* Global offset table          */
 101         }
 102
 103         RODATA
 104
 105         _etext = .;                     /* End of text and rodata section */
 106
 107 #ifdef CONFIG_XIP_KERNEL
 108         __data_loc = ALIGN(4);          /* location in binary */
 109         . = PAGE_OFFSET + TEXT_OFFSET;
 110 #else
 111         . = ALIGN(THREAD_SIZE);
 112         __data_loc = .;
 113 #endif
 114
 115         .data : AT(__data_loc) {
 116                 __data_start = .;       /* address in memory */
 117
 118                 /*
 119                  * first, the init task union, aligned
 120                  * to an 8192 byte boundary.
 121                  */
 122                 *(.init.task)
 123
 124 #ifdef CONFIG_XIP_KERNEL
 125                 . = ALIGN(4096);
 126                 __init_begin = .;
 127                 *(.init.data)
 128                 . = ALIGN(4096);
 129                 __init_end = .;
 130 #endif
 131
 132                 . = ALIGN(4096);
 133                 __nosave_begin = .;
 134                 *(.data.nosave)
 135                 . = ALIGN(4096);
 136                 __nosave_end = .;
 137
 138                 /*
 139                  * then the cacheline aligned data
 140                  */
 141                 . = ALIGN(32);
 142                 *(.data.cacheline_aligned)
 143
 144                 /*
 145                  * The exception fixup table (might need resorting at runtime)
 146                  */
 147                 . = ALIGN(32);
 148                 __start___ex_table = .;
 149 #ifdef CONFIG_MMU
 150                 *(__ex_table)
 151 #endif
 152                 __stop___ex_table = .;
 153
 154                 /*
 155                  * and the usual data section
 156                  */
 157                 *(.data)
 158                 CONSTRUCTORS
 159
 160                 _edata = .;
 161         }
 162         _edata_loc = __data_loc + SIZEOF(.data);
 163
 164         .bss : {
 165                 __bss_start = .;        /* BSS                          */
 166                 *(.bss)
 167                 *(COMMON)
 168                 _end = .;
 169         }
 170                                         /* Stabs debugging sections.    */
 171         .stab 0 : { *(.stab) }
 172         .stabstr 0 : { *(.stabstr) }
 173         .stab.excl 0 : { *(.stab.excl) }
 174         .stab.exclstr 0 : { *(.stab.exclstr) }
 175         .stab.index 0 : { *(.stab.index) }
 176         .stab.indexstr 0 : { *(.stab.indexstr) }
 177         .comment 0 : { *(.comment) }
 178 }
 179
 180 /*
 181  * These must never be empty
 182  * If you have to comment these two assert statements out, your
 183  * binutils is too old (for other reasons as well)
 184  */
 185 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 186 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")