arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/cache.h>
   8 #include <asm/thread_info.h>
   9 #include <asm/memory.h>
  10 #include <asm/page.h>
  11
  12 #define PROC_INFO                                                       \
  13         . = ALIGN(4);                                                   \
  14         VMLINUX_SYMBOL(__proc_info_begin) = .;                          \
  15         *(.proc.info.init)                                              \
  16         VMLINUX_SYMBOL(__proc_info_end) = .;
  17
  18 #define IDMAP_TEXT                                                      \
  19         ALIGN_FUNCTION();                                               \
  20         VMLINUX_SYMBOL(__idmap_text_start) = .;                         \
  21         *(.idmap.text)                                                  \
  22         VMLINUX_SYMBOL(__idmap_text_end) = .;                           \
  23         . = ALIGN(32);                                                  \
  24         VMLINUX_SYMBOL(__hyp_idmap_text_start) = .;                     \
  25         *(.hyp.idmap.text)                                              \
  26         VMLINUX_SYMBOL(__hyp_idmap_text_end) = .;
  27
  28 #ifdef CONFIG_HOTPLUG_CPU
  29 #define ARM_CPU_DISCARD(x)
  30 #define ARM_CPU_KEEP(x)         x
  31 #else
  32 #define ARM_CPU_DISCARD(x)      x
  33 #define ARM_CPU_KEEP(x)
  34 #endif
  35
  36 #if (defined(CONFIG_SMP_ON_UP) && !defined(CONFIG_DEBUG_SPINLOCK)) || \
  37         defined(CONFIG_GENERIC_BUG)
  38 #define ARM_EXIT_KEEP(x)        x
  39 #define ARM_EXIT_DISCARD(x)
  40 #else
  41 #define ARM_EXIT_KEEP(x)
  42 #define ARM_EXIT_DISCARD(x)     x
  43 #endif
  44
  45 OUTPUT_ARCH(arm)
  46 ENTRY(stext)
  47
  48 #ifndef __ARMEB__
  49 jiffies = jiffies_64;
  50 #else
  51 jiffies = jiffies_64 + 4;
  52 #endif
  53
  54 SECTIONS
  55 {
  56         /*
  57          * XXX: The linker does not define how output sections are
  58          * assigned to input sections when there are multiple statements
  59          * matching the same input section name.  There is no documented
  60          * order of matching.
  61          *
  62          * unwind exit sections must be discarded before the rest of the
  63          * unwind sections get included.
  64          */
  65         /DISCARD/ : {
  66                 *(.ARM.exidx.exit.text)
  67                 *(.ARM.extab.exit.text)
  68                 ARM_CPU_DISCARD(*(.ARM.exidx.cpuexit.text))
  69                 ARM_CPU_DISCARD(*(.ARM.extab.cpuexit.text))
  70                 ARM_EXIT_DISCARD(EXIT_TEXT)
  71                 ARM_EXIT_DISCARD(EXIT_DATA)
  72                 EXIT_CALL
  73 #ifndef CONFIG_MMU
  74                 *(.fixup)
  75                 *(__ex_table)
  76 #endif
  77 #ifndef CONFIG_SMP_ON_UP
  78                 *(.alt.smp.init)
  79 #endif
  80                 *(.discard)
  81                 *(.discard.*)
  82         }
  83
  84 #ifdef CONFIG_XIP_KERNEL
  85         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  86 #else
  87         . = PAGE_OFFSET + TEXT_OFFSET;
  88 #endif
  89         .head.text : {
  90                 _text = .;
  91                 HEAD_TEXT
  92         }
  93         .text : {                       /* Real text segment            */
  94                 _stext = .;             /* Text and read-only data      */
  95                         __exception_text_start = .;
  96                         *(.exception.text)
  97                         __exception_text_end = .;
  98                         IRQENTRY_TEXT
  99                         TEXT_TEXT
 100                         SCHED_TEXT
 101                         LOCK_TEXT
 102                         KPROBES_TEXT
 103                         IDMAP_TEXT
 104 #ifdef CONFIG_MMU
 105                         *(.fixup)
 106 #endif
 107                         *(.gnu.warning)
 108                         *(.glue_7)
 109                         *(.glue_7t)
 110                 . = ALIGN(4);
 111                 *(.got)                 /* Global offset table          */
 112                         ARM_CPU_KEEP(PROC_INFO)
 113         }
 114
 115         RO_DATA(PAGE_SIZE)
 116
 117         . = ALIGN(4);
 118         __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) {
 119                 __start___ex_table = .;
 120 #ifdef CONFIG_MMU
 121                 *(__ex_table)
 122 #endif
 123                 __stop___ex_table = .;
 124         }
 125
 126 #ifdef CONFIG_ARM_UNWIND
 127         /*
 128          * Stack unwinding tables
 129          */
 130         . = ALIGN(8);
 131         .ARM.unwind_idx : {
 132                 __start_unwind_idx = .;
 133                 *(.ARM.exidx*)
 134                 __stop_unwind_idx = .;
 135         }
 136         .ARM.unwind_tab : {
 137                 __start_unwind_tab = .;
 138                 *(.ARM.extab*)
 139                 __stop_unwind_tab = .;
 140         }
 141 #endif
 142
 143         NOTES
 144
 145         _etext = .;                     /* End of text and rodata section */
 146
 147 #ifndef CONFIG_XIP_KERNEL
 148         . = ALIGN(PAGE_SIZE);
 149         __init_begin = .;
 150 #endif
 151
 152         INIT_TEXT_SECTION(8)
 153         .exit.text : {
 154                 ARM_EXIT_KEEP(EXIT_TEXT)
 155         }
 156         .init.proc.info : {
 157                 ARM_CPU_DISCARD(PROC_INFO)
 158         }
 159         .init.arch.info : {
 160                 __arch_info_begin = .;
 161                 *(.arch.info.init)
 162                 __arch_info_end = .;
 163         }
 164         .init.tagtable : {
 165                 __tagtable_begin = .;
 166                 *(.taglist.init)
 167                 __tagtable_end = .;
 168         }
 169 #ifdef CONFIG_SMP_ON_UP
 170         .init.smpalt : {
 171                 __smpalt_begin = .;
 172                 *(.alt.smp.init)
 173                 __smpalt_end = .;
 174         }
 175 #endif
 176         .init.pv_table : {
 177                 __pv_table_begin = .;
 178                 *(.pv_table)
 179                 __pv_table_end = .;
 180         }
 181         .init.data : {
 182 #ifndef CONFIG_XIP_KERNEL
 183                 INIT_DATA
 184 #endif
 185                 INIT_SETUP(16)
 186                 INIT_CALLS
 187                 CON_INITCALL
 188                 SECURITY_INITCALL
 189                 INIT_RAM_FS
 190         }
 191 #ifndef CONFIG_XIP_KERNEL
 192         .exit.data : {
 193                 ARM_EXIT_KEEP(EXIT_DATA)
 194         }
 195 #endif
 196
 197 #ifdef CONFIG_SMP
 198         PERCPU_SECTION(L1_CACHE_BYTES)
 199 #endif
 200
 201 #ifdef CONFIG_XIP_KERNEL
 202         __data_loc = ALIGN(4);          /* location in binary */
 203         . = PAGE_OFFSET + TEXT_OFFSET;
 204 #else
 205         __init_end = .;
 206         . = ALIGN(THREAD_SIZE);
 207         __data_loc = .;
 208 #endif
 209
 210         .data : AT(__data_loc) {
 211                 _data = .;              /* address in memory */
 212                 _sdata = .;
 213
 214                 /*
 215                  * first, the init task union, aligned
 216                  * to an 8192 byte boundary.
 217                  */
 218                 INIT_TASK_DATA(THREAD_SIZE)
 219
 220 #ifdef CONFIG_XIP_KERNEL
 221                 . = ALIGN(PAGE_SIZE);
 222                 __init_begin = .;
 223                 INIT_DATA
 224                 ARM_EXIT_KEEP(EXIT_DATA)
 225                 . = ALIGN(PAGE_SIZE);
 226                 __init_end = .;
 227 #endif
 228
 229                 NOSAVE_DATA
 230                 CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
 231                 READ_MOSTLY_DATA(L1_CACHE_BYTES)
 232
 233                 /*
 234                  * and the usual data section
 235                  */
 236                 DATA_DATA
 237                 CONSTRUCTORS
 238
 239                 _edata = .;
 240         }
 241         _edata_loc = __data_loc + SIZEOF(.data);
 242
 243 #ifdef CONFIG_HAVE_TCM
 244         /*
 245          * We align everything to a page boundary so we can
 246          * free it after init has commenced and TCM contents have
 247          * been copied to its destination.
 248          */
 249         .tcm_start : {
 250                 . = ALIGN(PAGE_SIZE);
 251                 __tcm_start = .;
 252                 __itcm_start = .;
 253         }
 254
 255         /*
 256          * Link these to the ITCM RAM
 257          * Put VMA to the TCM address and LMA to the common RAM
 258          * and we'll upload the contents from RAM to TCM and free
 259          * the used RAM after that.
 260          */
 261         .text_itcm ITCM_OFFSET : AT(__itcm_start)
 262         {
 263                 __sitcm_text = .;
 264                 *(.tcm.text)
 265                 *(.tcm.rodata)
 266                 . = ALIGN(4);
 267                 __eitcm_text = .;
 268         }
 269
 270         /*
 271          * Reset the dot pointer, this is needed to create the
 272          * relative __dtcm_start below (to be used as extern in code).
 273          */
 274         . = ADDR(.tcm_start) + SIZEOF(.tcm_start) + SIZEOF(.text_itcm);
 275
 276         .dtcm_start : {
 277                 __dtcm_start = .;
 278         }
 279
 280         /* TODO: add remainder of ITCM as well, that can be used for data! */
 281         .data_dtcm DTCM_OFFSET : AT(__dtcm_start)
 282         {
 283                 . = ALIGN(4);
 284                 __sdtcm_data = .;
 285                 *(.tcm.data)
 286                 . = ALIGN(4);
 287                 __edtcm_data = .;
 288         }
 289
 290         /* Reset the dot pointer or the linker gets confused */
 291         . = ADDR(.dtcm_start) + SIZEOF(.data_dtcm);
 292
 293         /* End marker for freeing TCM copy in linked object */
 294         .tcm_end : AT(ADDR(.dtcm_start) + SIZEOF(.data_dtcm)){
 295                 . = ALIGN(PAGE_SIZE);
 296                 __tcm_end = .;
 297         }
 298 #endif
 299
 300         BSS_SECTION(0, 0, 0)
 301         _end = .;
 302
 303         STABS_DEBUG
 304         .comment 0 : { *(.comment) }
 305 }
 306
 307 /*
 308  * These must never be empty
 309  * If you have to comment these two assert statements out, your
 310  * binutils is too old (for other reasons as well)
 311  */
 312 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 313 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")
 314 /*
 315  * The HYP init code can't be more than a page long.
 316  * The above comment applies as well.
 317  */
 318 ASSERT(((__hyp_idmap_text_end - __hyp_idmap_text_start) <= PAGE_SIZE), "HYP init code too big")