arch/arm/kernel/vmlinux.lds.S

   1 /* ld script to make ARM Linux kernel
   2  * taken from the i386 version by Russell King
   3  * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
   4  */
   5
   6 #include <asm-generic/vmlinux.lds.h>
   7 #include <asm/thread_info.h>
   8 #include <asm/memory.h>
   9
  10 OUTPUT_ARCH(arm)
  11 ENTRY(stext)
  12
  13 #ifndef __ARMEB__
  14 jiffies = jiffies_64;
  15 #else
  16 jiffies = jiffies_64 + 4;
  17 #endif
  18
  19 SECTIONS
  20 {
  21 #ifdef CONFIG_XIP_KERNEL
  22         . = XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR);
  23 #else
  24         . = PAGE_OFFSET + TEXT_OFFSET;
  25 #endif
  26         .text.head : {
  27                 _stext = .;
  28                 _sinittext = .;
  29                 *(.text.head)
  30         }
  31
  32         .init : {                       /* Init code and data           */
  33                         INIT_TEXT
  34                 _einittext = .;
  35                 __proc_info_begin = .;
  36                         *(.proc.info.init)
  37                 __proc_info_end = .;
  38                 __arch_info_begin = .;
  39                         *(.arch.info.init)
  40                 __arch_info_end = .;
  41                 __tagtable_begin = .;
  42                         *(.taglist.init)
  43                 __tagtable_end = .;
  44                 . = ALIGN(16);
  45                 __setup_start = .;
  46                         *(.init.setup)
  47                 __setup_end = .;
  48                 __early_begin = .;
  49                         *(.early_param.init)
  50                 __early_end = .;
  51                 __initcall_start = .;
  52                         INITCALLS
  53                 __initcall_end = .;
  54                 __con_initcall_start = .;
  55                         *(.con_initcall.init)
  56                 __con_initcall_end = .;
  57                 __security_initcall_start = .;
  58                         *(.security_initcall.init)
  59                 __security_initcall_end = .;
  60 #ifdef CONFIG_BLK_DEV_INITRD
  61                 . = ALIGN(32);
  62                 __initramfs_start = .;
  63                         usr/built-in.o(.init.ramfs)
  64                 __initramfs_end = .;
  65 #endif
  66                 . = ALIGN(4096);
  67                 __per_cpu_load = .;
  68                 __per_cpu_start = .;
  69                         *(.data.percpu.page_aligned)
  70                         *(.data.percpu)
  71                         *(.data.percpu.shared_aligned)
  72                 __per_cpu_end = .;
  73 #ifndef CONFIG_XIP_KERNEL
  74                 __init_begin = _stext;
  75                 INIT_DATA
  76                 . = ALIGN(4096);
  77                 __init_end = .;
  78 #endif
  79         }
  80
  81         /DISCARD/ : {                   /* Exit code and data           */
  82                 EXIT_TEXT
  83                 EXIT_DATA
  84                 *(.exitcall.exit)
  85                 *(.ARM.exidx.exit.text)
  86                 *(.ARM.extab.exit.text)
  87 #ifndef CONFIG_MMU
  88                 *(.fixup)
  89                 *(__ex_table)
  90 #endif
  91         }
  92
  93         .text : {                       /* Real text segment            */
  94                 _text = .;              /* Text and read-only data      */
  95                         __exception_text_start = .;
  96                         *(.exception.text)
  97                         __exception_text_end = .;
  98                         TEXT_TEXT
  99                         SCHED_TEXT
 100                         LOCK_TEXT
 101                         KPROBES_TEXT
 102 #ifdef CONFIG_MMU
 103                         *(.fixup)
 104 #endif
 105                         *(.gnu.warning)
 106                         *(.rodata)
 107                         *(.rodata.*)
 108                         *(.glue_7)
 109                         *(.glue_7t)
 110                 *(.got)                 /* Global offset table          */
 111         }
 112
 113         RODATA
 114
 115         _etext = .;                     /* End of text and rodata section */
 116
 117 #ifdef CONFIG_ARM_UNWIND
 118         /*
 119          * Stack unwinding tables
 120          */
 121         . = ALIGN(8);
 122         .ARM.unwind_idx : {
 123                 __start_unwind_idx = .;
 124                 *(.ARM.exidx*)
 125                 __stop_unwind_idx = .;
 126         }
 127         .ARM.unwind_tab : {
 128                 __start_unwind_tab = .;
 129                 *(.ARM.extab*)
 130                 __stop_unwind_tab = .;
 131         }
 132 #endif
 133
 134 #ifdef CONFIG_XIP_KERNEL
 135         __data_loc = ALIGN(4);          /* location in binary */
 136         . = PAGE_OFFSET + TEXT_OFFSET;
 137 #else
 138         . = ALIGN(THREAD_SIZE);
 139         __data_loc = .;
 140 #endif
 141
 142         .data : AT(__data_loc) {
 143                 _data = .;              /* address in memory */
 144                 _sdata = .;
 145
 146                 /*
 147                  * first, the init task union, aligned
 148                  * to an 8192 byte boundary.
 149                  */
 150                 *(.data.init_task)
 151
 152 #ifdef CONFIG_XIP_KERNEL
 153                 . = ALIGN(4096);
 154                 __init_begin = .;
 155                 INIT_DATA
 156                 . = ALIGN(4096);
 157                 __init_end = .;
 158 #endif
 159
 160                 . = ALIGN(4096);
 161                 __nosave_begin = .;
 162                 *(.data.nosave)
 163                 . = ALIGN(4096);
 164                 __nosave_end = .;
 165
 166                 /*
 167                  * then the cacheline aligned data
 168                  */
 169                 . = ALIGN(32);
 170                 *(.data.cacheline_aligned)
 171
 172                 /*
 173                  * The exception fixup table (might need resorting at runtime)
 174                  */
 175                 . = ALIGN(32);
 176                 __start___ex_table = .;
 177 #ifdef CONFIG_MMU
 178                 *(__ex_table)
 179 #endif
 180                 __stop___ex_table = .;
 181
 182                 /*
 183                  * and the usual data section
 184                  */
 185                 DATA_DATA
 186                 CONSTRUCTORS
 187
 188                 _edata = .;
 189         }
 190         _edata_loc = __data_loc + SIZEOF(.data);
 191
 192         .bss : {
 193                 __bss_start = .;        /* BSS                          */
 194                 *(.bss)
 195                 *(COMMON)
 196                 __bss_stop = .;
 197                 _end = .;
 198         }
 199                                         /* Stabs debugging sections.    */
 200         .stab 0 : { *(.stab) }
 201         .stabstr 0 : { *(.stabstr) }
 202         .stab.excl 0 : { *(.stab.excl) }
 203         .stab.exclstr 0 : { *(.stab.exclstr) }
 204         .stab.index 0 : { *(.stab.index) }
 205         .stab.indexstr 0 : { *(.stab.indexstr) }
 206         .comment 0 : { *(.comment) }
 207 }
 208
 209 /*
 210  * These must never be empty
 211  * If you have to comment these two assert statements out, your
 212  * binutils is too old (for other reasons as well)
 213  */
 214 ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support")
 215 ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined")