arch/arm/mm/abort-ev7.S

   1 #include <linux/linkage.h>
   2 #include <asm/assembler.h>
   3 /*
   4  * Function: v7_early_abort
   5  *
   6  * Params  : r2 = pt_regs
   7  *         : r4 = aborted context pc
   8  *         : r5 = aborted context psr
   9  *
  10  * Returns : r4 - r11, r13 preserved
  11  *
  12  * Purpose : obtain information about current aborted instruction.
  13  */
  14         .align  5
  15 ENTRY(v7_early_abort)
  16         mrc     p15, 0, r1, c5, c0, 0           @ get FSR
  17         mrc     p15, 0, r0, c6, c0, 0           @ get FAR
  18         uaccess_disable ip                      @ disable userspace access
  19
  20         /*
  21          * V6 code adjusts the returned DFSR.
  22          * New designs should not need to patch up faults.
  23          */
  24
  25 #if defined(CONFIG_VERIFY_PERMISSION_FAULT)
  26         /*
  27          * Detect erroneous permission failures and fix
  28          */
  29         ldr     r3, =0x40d                      @ On permission fault
  30         and     r3, r1, r3
  31         cmp     r3, #0x0d
  32         bne     do_DataAbort
  33
  34         mcr     p15, 0, r0, c7, c8, 0           @ Retranslate FAR
  35         isb
  36         mrc     p15, 0, ip, c7, c4, 0           @ Read the PAR
  37         and     r3, ip, #0x7b                   @ On translation fault
  38         cmp     r3, #0x0b
  39         bne     do_DataAbort
  40         bic     r1, r1, #0xf                    @ Fix up FSR FS[5:0]
  41         and     ip, ip, #0x7e
  42         orr     r1, r1, ip, LSR #1
  43 #endif
  44
  45         b       do_DataAbort
  46 ENDPROC(v7_early_abort)